src/HOL/IntDiv.thy
author nipkow
Sat Jan 31 09:04:16 2009 +0100 (2009-01-31)
changeset 29700 22faf21db3df
parent 29668 33ba3faeaa0e
child 29936 d3dfb67f0f59
permissions -rw-r--r--
added some simp rules
     1 (*  Title:      HOL/IntDiv.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 
     5 *)
     6 
     7 header{* The Division Operators div and mod *}
     8 
     9 theory IntDiv
    10 imports Int Divides FunDef
    11 begin
    12 
    13 definition divmod_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
    14     --{*definition of quotient and remainder*}
    15     [code]: "divmod_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
    16                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
    17 
    18 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
    19     --{*for the division algorithm*}
    20     [code]: "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
    21                          else (2 * q, r))"
    22 
    23 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
    24 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
    25   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
    26      else adjust b (posDivAlg a (2 * b)))"
    27 by auto
    28 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))") auto
    29 
    30 text{*algorithm for the case @{text "a<0, b>0"}*}
    31 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
    32   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
    33      else adjust b (negDivAlg a (2 * b)))"
    34 by auto
    35 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))") auto
    36 
    37 text{*algorithm for the general case @{term "b\<noteq>0"}*}
    38 definition negateSnd :: "int \<times> int \<Rightarrow> int \<times> int" where
    39   [code inline]: "negateSnd = apsnd uminus"
    40 
    41 definition divmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
    42     --{*The full division algorithm considers all possible signs for a, b
    43        including the special case @{text "a=0, b<0"} because 
    44        @{term negDivAlg} requires @{term "a<0"}.*}
    45   "divmod a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
    46                   else if a = 0 then (0, 0)
    47                        else negateSnd (negDivAlg (-a) (-b))
    48                else 
    49                   if 0 < b then negDivAlg a b
    50                   else negateSnd (posDivAlg (-a) (-b)))"
    51 
    52 instantiation int :: Divides.div
    53 begin
    54 
    55 definition
    56   div_def: "a div b = fst (divmod a b)"
    57 
    58 definition
    59   mod_def: "a mod b = snd (divmod a b)"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma divmod_mod_div:
    66   "divmod p q = (p div q, p mod q)"
    67   by (auto simp add: div_def mod_def)
    68 
    69 text{*
    70 Here is the division algorithm in ML:
    71 
    72 \begin{verbatim}
    73     fun posDivAlg (a,b) =
    74       if a<b then (0,a)
    75       else let val (q,r) = posDivAlg(a, 2*b)
    76 	       in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
    77 	   end
    78 
    79     fun negDivAlg (a,b) =
    80       if 0\<le>a+b then (~1,a+b)
    81       else let val (q,r) = negDivAlg(a, 2*b)
    82 	       in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
    83 	   end;
    84 
    85     fun negateSnd (q,r:int) = (q,~r);
    86 
    87     fun divmod (a,b) = if 0\<le>a then 
    88 			  if b>0 then posDivAlg (a,b) 
    89 			   else if a=0 then (0,0)
    90 				else negateSnd (negDivAlg (~a,~b))
    91 		       else 
    92 			  if 0<b then negDivAlg (a,b)
    93 			  else        negateSnd (posDivAlg (~a,~b));
    94 \end{verbatim}
    95 *}
    96 
    97 
    98 
    99 subsection{*Uniqueness and Monotonicity of Quotients and Remainders*}
   100 
   101 lemma unique_quotient_lemma:
   102      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
   103       ==> q' \<le> (q::int)"
   104 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
   105  prefer 2 apply (simp add: right_diff_distrib)
   106 apply (subgoal_tac "0 < b * (1 + q - q') ")
   107 apply (erule_tac [2] order_le_less_trans)
   108  prefer 2 apply (simp add: right_diff_distrib right_distrib)
   109 apply (subgoal_tac "b * q' < b * (1 + q) ")
   110  prefer 2 apply (simp add: right_diff_distrib right_distrib)
   111 apply (simp add: mult_less_cancel_left)
   112 done
   113 
   114 lemma unique_quotient_lemma_neg:
   115      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
   116       ==> q \<le> (q'::int)"
   117 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
   118     auto)
   119 
   120 lemma unique_quotient:
   121      "[| divmod_rel a b (q, r); divmod_rel a b (q', r');  b \<noteq> 0 |]  
   122       ==> q = q'"
   123 apply (simp add: divmod_rel_def linorder_neq_iff split: split_if_asm)
   124 apply (blast intro: order_antisym
   125              dest: order_eq_refl [THEN unique_quotient_lemma] 
   126              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
   127 done
   128 
   129 
   130 lemma unique_remainder:
   131      "[| divmod_rel a b (q, r); divmod_rel a b (q', r');  b \<noteq> 0 |]  
   132       ==> r = r'"
   133 apply (subgoal_tac "q = q'")
   134  apply (simp add: divmod_rel_def)
   135 apply (blast intro: unique_quotient)
   136 done
   137 
   138 
   139 subsection{*Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends*}
   140 
   141 text{*And positive divisors*}
   142 
   143 lemma adjust_eq [simp]:
   144      "adjust b (q,r) = 
   145       (let diff = r-b in  
   146 	if 0 \<le> diff then (2*q + 1, diff)   
   147                      else (2*q, r))"
   148 by (simp add: Let_def adjust_def)
   149 
   150 declare posDivAlg.simps [simp del]
   151 
   152 text{*use with a simproc to avoid repeatedly proving the premise*}
   153 lemma posDivAlg_eqn:
   154      "0 < b ==>  
   155       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
   156 by (rule posDivAlg.simps [THEN trans], simp)
   157 
   158 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
   159 theorem posDivAlg_correct:
   160   assumes "0 \<le> a" and "0 < b"
   161   shows "divmod_rel a b (posDivAlg a b)"
   162 using prems apply (induct a b rule: posDivAlg.induct)
   163 apply auto
   164 apply (simp add: divmod_rel_def)
   165 apply (subst posDivAlg_eqn, simp add: right_distrib)
   166 apply (case_tac "a < b")
   167 apply simp_all
   168 apply (erule splitE)
   169 apply (auto simp add: right_distrib Let_def)
   170 done
   171 
   172 
   173 subsection{*Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends*}
   174 
   175 text{*And positive divisors*}
   176 
   177 declare negDivAlg.simps [simp del]
   178 
   179 text{*use with a simproc to avoid repeatedly proving the premise*}
   180 lemma negDivAlg_eqn:
   181      "0 < b ==>  
   182       negDivAlg a b =       
   183        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
   184 by (rule negDivAlg.simps [THEN trans], simp)
   185 
   186 (*Correctness of negDivAlg: it computes quotients correctly
   187   It doesn't work if a=0 because the 0/b equals 0, not -1*)
   188 lemma negDivAlg_correct:
   189   assumes "a < 0" and "b > 0"
   190   shows "divmod_rel a b (negDivAlg a b)"
   191 using prems apply (induct a b rule: negDivAlg.induct)
   192 apply (auto simp add: linorder_not_le)
   193 apply (simp add: divmod_rel_def)
   194 apply (subst negDivAlg_eqn, assumption)
   195 apply (case_tac "a + b < (0\<Colon>int)")
   196 apply simp_all
   197 apply (erule splitE)
   198 apply (auto simp add: right_distrib Let_def)
   199 done
   200 
   201 
   202 subsection{*Existence Shown by Proving the Division Algorithm to be Correct*}
   203 
   204 (*the case a=0*)
   205 lemma divmod_rel_0: "b \<noteq> 0 ==> divmod_rel 0 b (0, 0)"
   206 by (auto simp add: divmod_rel_def linorder_neq_iff)
   207 
   208 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
   209 by (subst posDivAlg.simps, auto)
   210 
   211 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
   212 by (subst negDivAlg.simps, auto)
   213 
   214 lemma negateSnd_eq [simp]: "negateSnd(q,r) = (q,-r)"
   215 by (simp add: negateSnd_def)
   216 
   217 lemma divmod_rel_neg: "divmod_rel (-a) (-b) qr ==> divmod_rel a b (negateSnd qr)"
   218 by (auto simp add: split_ifs divmod_rel_def)
   219 
   220 lemma divmod_correct: "b \<noteq> 0 ==> divmod_rel a b (divmod a b)"
   221 by (force simp add: linorder_neq_iff divmod_rel_0 divmod_def divmod_rel_neg
   222                     posDivAlg_correct negDivAlg_correct)
   223 
   224 text{*Arbitrary definitions for division by zero.  Useful to simplify 
   225     certain equations.*}
   226 
   227 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
   228 by (simp add: div_def mod_def divmod_def posDivAlg.simps)  
   229 
   230 
   231 text{*Basic laws about division and remainder*}
   232 
   233 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
   234 apply (case_tac "b = 0", simp)
   235 apply (cut_tac a = a and b = b in divmod_correct)
   236 apply (auto simp add: divmod_rel_def div_def mod_def)
   237 done
   238 
   239 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
   240 by(simp add: zmod_zdiv_equality[symmetric])
   241 
   242 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
   243 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
   244 
   245 text {* Tool setup *}
   246 
   247 ML {*
   248 local 
   249 
   250 structure CancelDivMod = CancelDivModFun(
   251 struct
   252   val div_name = @{const_name Divides.div};
   253   val mod_name = @{const_name Divides.mod};
   254   val mk_binop = HOLogic.mk_binop;
   255   val mk_sum = Int_Numeral_Simprocs.mk_sum HOLogic.intT;
   256   val dest_sum = Int_Numeral_Simprocs.dest_sum;
   257   val div_mod_eqs =
   258     map mk_meta_eq [@{thm zdiv_zmod_equality},
   259       @{thm zdiv_zmod_equality2}];
   260   val trans = trans;
   261   val prove_eq_sums =
   262     let
   263       val simps = @{thm diff_int_def} :: Int_Numeral_Simprocs.add_0s @ @{thms zadd_ac}
   264     in ArithData.prove_conv all_tac (ArithData.simp_all_tac simps) end;
   265 end)
   266 
   267 in
   268 
   269 val cancel_zdiv_zmod_proc = Simplifier.simproc (the_context ())
   270   "cancel_zdiv_zmod" ["(m::int) + n"] (K CancelDivMod.proc)
   271 
   272 end;
   273 
   274 Addsimprocs [cancel_zdiv_zmod_proc]
   275 *}
   276 
   277 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
   278 apply (cut_tac a = a and b = b in divmod_correct)
   279 apply (auto simp add: divmod_rel_def mod_def)
   280 done
   281 
   282 lemmas pos_mod_sign  [simp] = pos_mod_conj [THEN conjunct1, standard]
   283    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2, standard]
   284 
   285 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
   286 apply (cut_tac a = a and b = b in divmod_correct)
   287 apply (auto simp add: divmod_rel_def div_def mod_def)
   288 done
   289 
   290 lemmas neg_mod_sign  [simp] = neg_mod_conj [THEN conjunct1, standard]
   291    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2, standard]
   292 
   293 
   294 
   295 subsection{*General Properties of div and mod*}
   296 
   297 lemma divmod_rel_div_mod: "b \<noteq> 0 ==> divmod_rel a b (a div b, a mod b)"
   298 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   299 apply (force simp add: divmod_rel_def linorder_neq_iff)
   300 done
   301 
   302 lemma divmod_rel_div: "[| divmod_rel a b (q, r);  b \<noteq> 0 |] ==> a div b = q"
   303 by (simp add: divmod_rel_div_mod [THEN unique_quotient])
   304 
   305 lemma divmod_rel_mod: "[| divmod_rel a b (q, r);  b \<noteq> 0 |] ==> a mod b = r"
   306 by (simp add: divmod_rel_div_mod [THEN unique_remainder])
   307 
   308 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
   309 apply (rule divmod_rel_div)
   310 apply (auto simp add: divmod_rel_def)
   311 done
   312 
   313 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
   314 apply (rule divmod_rel_div)
   315 apply (auto simp add: divmod_rel_def)
   316 done
   317 
   318 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
   319 apply (rule divmod_rel_div)
   320 apply (auto simp add: divmod_rel_def)
   321 done
   322 
   323 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
   324 
   325 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
   326 apply (rule_tac q = 0 in divmod_rel_mod)
   327 apply (auto simp add: divmod_rel_def)
   328 done
   329 
   330 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
   331 apply (rule_tac q = 0 in divmod_rel_mod)
   332 apply (auto simp add: divmod_rel_def)
   333 done
   334 
   335 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
   336 apply (rule_tac q = "-1" in divmod_rel_mod)
   337 apply (auto simp add: divmod_rel_def)
   338 done
   339 
   340 text{*There is no @{text mod_neg_pos_trivial}.*}
   341 
   342 
   343 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
   344 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
   345 apply (case_tac "b = 0", simp)
   346 apply (simp add: divmod_rel_div_mod [THEN divmod_rel_neg, simplified, 
   347                                  THEN divmod_rel_div, THEN sym])
   348 
   349 done
   350 
   351 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
   352 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
   353 apply (case_tac "b = 0", simp)
   354 apply (subst divmod_rel_div_mod [THEN divmod_rel_neg, simplified, THEN divmod_rel_mod],
   355        auto)
   356 done
   357 
   358 
   359 subsection{*Laws for div and mod with Unary Minus*}
   360 
   361 lemma zminus1_lemma:
   362      "divmod_rel a b (q, r)
   363       ==> divmod_rel (-a) b (if r=0 then -q else -q - 1,  
   364                           if r=0 then 0 else b-r)"
   365 by (force simp add: split_ifs divmod_rel_def linorder_neq_iff right_diff_distrib)
   366 
   367 
   368 lemma zdiv_zminus1_eq_if:
   369      "b \<noteq> (0::int)  
   370       ==> (-a) div b =  
   371           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
   372 by (blast intro: divmod_rel_div_mod [THEN zminus1_lemma, THEN divmod_rel_div])
   373 
   374 lemma zmod_zminus1_eq_if:
   375      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
   376 apply (case_tac "b = 0", simp)
   377 apply (blast intro: divmod_rel_div_mod [THEN zminus1_lemma, THEN divmod_rel_mod])
   378 done
   379 
   380 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
   381 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
   382 
   383 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
   384 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
   385 
   386 lemma zdiv_zminus2_eq_if:
   387      "b \<noteq> (0::int)  
   388       ==> a div (-b) =  
   389           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
   390 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
   391 
   392 lemma zmod_zminus2_eq_if:
   393      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
   394 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
   395 
   396 
   397 subsection{*Division of a Number by Itself*}
   398 
   399 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
   400 apply (subgoal_tac "0 < a*q")
   401  apply (simp add: zero_less_mult_iff, arith)
   402 done
   403 
   404 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
   405 apply (subgoal_tac "0 \<le> a* (1-q) ")
   406  apply (simp add: zero_le_mult_iff)
   407 apply (simp add: right_diff_distrib)
   408 done
   409 
   410 lemma self_quotient: "[| divmod_rel a a (q, r);  a \<noteq> (0::int) |] ==> q = 1"
   411 apply (simp add: split_ifs divmod_rel_def linorder_neq_iff)
   412 apply (rule order_antisym, safe, simp_all)
   413 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
   414 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
   415 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
   416 done
   417 
   418 lemma self_remainder: "[| divmod_rel a a (q, r);  a \<noteq> (0::int) |] ==> r = 0"
   419 apply (frule self_quotient, assumption)
   420 apply (simp add: divmod_rel_def)
   421 done
   422 
   423 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
   424 by (simp add: divmod_rel_div_mod [THEN self_quotient])
   425 
   426 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
   427 lemma zmod_self [simp]: "a mod a = (0::int)"
   428 apply (case_tac "a = 0", simp)
   429 apply (simp add: divmod_rel_div_mod [THEN self_remainder])
   430 done
   431 
   432 
   433 subsection{*Computation of Division and Remainder*}
   434 
   435 lemma zdiv_zero [simp]: "(0::int) div b = 0"
   436 by (simp add: div_def divmod_def)
   437 
   438 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
   439 by (simp add: div_def divmod_def)
   440 
   441 lemma zmod_zero [simp]: "(0::int) mod b = 0"
   442 by (simp add: mod_def divmod_def)
   443 
   444 lemma zdiv_minus1: "(0::int) < b ==> -1 div b = -1"
   445 by (simp add: div_def divmod_def)
   446 
   447 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
   448 by (simp add: mod_def divmod_def)
   449 
   450 text{*a positive, b positive *}
   451 
   452 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
   453 by (simp add: div_def divmod_def)
   454 
   455 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
   456 by (simp add: mod_def divmod_def)
   457 
   458 text{*a negative, b positive *}
   459 
   460 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
   461 by (simp add: div_def divmod_def)
   462 
   463 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
   464 by (simp add: mod_def divmod_def)
   465 
   466 text{*a positive, b negative *}
   467 
   468 lemma div_pos_neg:
   469      "[| 0 < a;  b < 0 |] ==> a div b = fst (negateSnd (negDivAlg (-a) (-b)))"
   470 by (simp add: div_def divmod_def)
   471 
   472 lemma mod_pos_neg:
   473      "[| 0 < a;  b < 0 |] ==> a mod b = snd (negateSnd (negDivAlg (-a) (-b)))"
   474 by (simp add: mod_def divmod_def)
   475 
   476 text{*a negative, b negative *}
   477 
   478 lemma div_neg_neg:
   479      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (negateSnd (posDivAlg (-a) (-b)))"
   480 by (simp add: div_def divmod_def)
   481 
   482 lemma mod_neg_neg:
   483      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (negateSnd (posDivAlg (-a) (-b)))"
   484 by (simp add: mod_def divmod_def)
   485 
   486 text {*Simplify expresions in which div and mod combine numerical constants*}
   487 
   488 lemma divmod_relI:
   489   "\<lbrakk>a == b * q + r; if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0\<rbrakk>
   490     \<Longrightarrow> divmod_rel a b (q, r)"
   491   unfolding divmod_rel_def by simp
   492 
   493 lemmas divmod_rel_div_eq = divmod_relI [THEN divmod_rel_div, THEN eq_reflection]
   494 lemmas divmod_rel_mod_eq = divmod_relI [THEN divmod_rel_mod, THEN eq_reflection]
   495 lemmas arithmetic_simps =
   496   arith_simps
   497   add_special
   498   OrderedGroup.add_0_left
   499   OrderedGroup.add_0_right
   500   mult_zero_left
   501   mult_zero_right
   502   mult_1_left
   503   mult_1_right
   504 
   505 (* simprocs adapted from HOL/ex/Binary.thy *)
   506 ML {*
   507 local
   508   infix ==;
   509   val op == = Logic.mk_equals;
   510   fun plus m n = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"} $ m $ n;
   511   fun mult m n = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"} $ m $ n;
   512 
   513   val binary_ss = HOL_basic_ss addsimps @{thms arithmetic_simps};
   514   fun prove ctxt prop =
   515     Goal.prove ctxt [] [] prop (fn _ => ALLGOALS (full_simp_tac binary_ss));
   516 
   517   fun binary_proc proc ss ct =
   518     (case Thm.term_of ct of
   519       _ $ t $ u =>
   520       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
   521         SOME args => proc (Simplifier.the_context ss) args
   522       | NONE => NONE)
   523     | _ => NONE);
   524 in
   525 
   526 fun divmod_proc rule = binary_proc (fn ctxt => fn ((m, t), (n, u)) =>
   527   if n = 0 then NONE
   528   else
   529     let val (k, l) = Integer.div_mod m n;
   530         fun mk_num x = HOLogic.mk_number HOLogic.intT x;
   531     in SOME (rule OF [prove ctxt (t == plus (mult u (mk_num k)) (mk_num l))])
   532     end);
   533 
   534 end;
   535 *}
   536 
   537 simproc_setup binary_int_div ("number_of m div number_of n :: int") =
   538   {* K (divmod_proc (@{thm divmod_rel_div_eq})) *}
   539 
   540 simproc_setup binary_int_mod ("number_of m mod number_of n :: int") =
   541   {* K (divmod_proc (@{thm divmod_rel_mod_eq})) *}
   542 
   543 (* The following 8 lemmas are made unnecessary by the above simprocs: *)
   544 
   545 lemmas div_pos_pos_number_of =
   546     div_pos_pos [of "number_of v" "number_of w", standard]
   547 
   548 lemmas div_neg_pos_number_of =
   549     div_neg_pos [of "number_of v" "number_of w", standard]
   550 
   551 lemmas div_pos_neg_number_of =
   552     div_pos_neg [of "number_of v" "number_of w", standard]
   553 
   554 lemmas div_neg_neg_number_of =
   555     div_neg_neg [of "number_of v" "number_of w", standard]
   556 
   557 
   558 lemmas mod_pos_pos_number_of =
   559     mod_pos_pos [of "number_of v" "number_of w", standard]
   560 
   561 lemmas mod_neg_pos_number_of =
   562     mod_neg_pos [of "number_of v" "number_of w", standard]
   563 
   564 lemmas mod_pos_neg_number_of =
   565     mod_pos_neg [of "number_of v" "number_of w", standard]
   566 
   567 lemmas mod_neg_neg_number_of =
   568     mod_neg_neg [of "number_of v" "number_of w", standard]
   569 
   570 
   571 lemmas posDivAlg_eqn_number_of [simp] =
   572     posDivAlg_eqn [of "number_of v" "number_of w", standard]
   573 
   574 lemmas negDivAlg_eqn_number_of [simp] =
   575     negDivAlg_eqn [of "number_of v" "number_of w", standard]
   576 
   577 
   578 text{*Special-case simplification *}
   579 
   580 lemma zmod_1 [simp]: "a mod (1::int) = 0"
   581 apply (cut_tac a = a and b = 1 in pos_mod_sign)
   582 apply (cut_tac [2] a = a and b = 1 in pos_mod_bound)
   583 apply (auto simp del:pos_mod_bound pos_mod_sign)
   584 done
   585 
   586 lemma zdiv_1 [simp]: "a div (1::int) = a"
   587 by (cut_tac a = a and b = 1 in zmod_zdiv_equality, auto)
   588 
   589 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
   590 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
   591 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
   592 apply (auto simp del: neg_mod_sign neg_mod_bound)
   593 done
   594 
   595 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
   596 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
   597 
   598 (** The last remaining special cases for constant arithmetic:
   599     1 div z and 1 mod z **)
   600 
   601 lemmas div_pos_pos_1_number_of [simp] =
   602     div_pos_pos [OF int_0_less_1, of "number_of w", standard]
   603 
   604 lemmas div_pos_neg_1_number_of [simp] =
   605     div_pos_neg [OF int_0_less_1, of "number_of w", standard]
   606 
   607 lemmas mod_pos_pos_1_number_of [simp] =
   608     mod_pos_pos [OF int_0_less_1, of "number_of w", standard]
   609 
   610 lemmas mod_pos_neg_1_number_of [simp] =
   611     mod_pos_neg [OF int_0_less_1, of "number_of w", standard]
   612 
   613 
   614 lemmas posDivAlg_eqn_1_number_of [simp] =
   615     posDivAlg_eqn [of concl: 1 "number_of w", standard]
   616 
   617 lemmas negDivAlg_eqn_1_number_of [simp] =
   618     negDivAlg_eqn [of concl: 1 "number_of w", standard]
   619 
   620 
   621 
   622 subsection{*Monotonicity in the First Argument (Dividend)*}
   623 
   624 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
   625 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   626 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
   627 apply (rule unique_quotient_lemma)
   628 apply (erule subst)
   629 apply (erule subst, simp_all)
   630 done
   631 
   632 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
   633 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   634 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
   635 apply (rule unique_quotient_lemma_neg)
   636 apply (erule subst)
   637 apply (erule subst, simp_all)
   638 done
   639 
   640 
   641 subsection{*Monotonicity in the Second Argument (Divisor)*}
   642 
   643 lemma q_pos_lemma:
   644      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
   645 apply (subgoal_tac "0 < b'* (q' + 1) ")
   646  apply (simp add: zero_less_mult_iff)
   647 apply (simp add: right_distrib)
   648 done
   649 
   650 lemma zdiv_mono2_lemma:
   651      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
   652          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
   653       ==> q \<le> (q'::int)"
   654 apply (frule q_pos_lemma, assumption+) 
   655 apply (subgoal_tac "b*q < b* (q' + 1) ")
   656  apply (simp add: mult_less_cancel_left)
   657 apply (subgoal_tac "b*q = r' - r + b'*q'")
   658  prefer 2 apply simp
   659 apply (simp (no_asm_simp) add: right_distrib)
   660 apply (subst add_commute, rule zadd_zless_mono, arith)
   661 apply (rule mult_right_mono, auto)
   662 done
   663 
   664 lemma zdiv_mono2:
   665      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
   666 apply (subgoal_tac "b \<noteq> 0")
   667  prefer 2 apply arith
   668 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   669 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
   670 apply (rule zdiv_mono2_lemma)
   671 apply (erule subst)
   672 apply (erule subst, simp_all)
   673 done
   674 
   675 lemma q_neg_lemma:
   676      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
   677 apply (subgoal_tac "b'*q' < 0")
   678  apply (simp add: mult_less_0_iff, arith)
   679 done
   680 
   681 lemma zdiv_mono2_neg_lemma:
   682      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
   683          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
   684       ==> q' \<le> (q::int)"
   685 apply (frule q_neg_lemma, assumption+) 
   686 apply (subgoal_tac "b*q' < b* (q + 1) ")
   687  apply (simp add: mult_less_cancel_left)
   688 apply (simp add: right_distrib)
   689 apply (subgoal_tac "b*q' \<le> b'*q'")
   690  prefer 2 apply (simp add: mult_right_mono_neg, arith)
   691 done
   692 
   693 lemma zdiv_mono2_neg:
   694      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
   695 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   696 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
   697 apply (rule zdiv_mono2_neg_lemma)
   698 apply (erule subst)
   699 apply (erule subst, simp_all)
   700 done
   701 
   702 
   703 subsection{*More Algebraic Laws for div and mod*}
   704 
   705 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
   706 
   707 lemma zmult1_lemma:
   708      "[| divmod_rel b c (q, r);  c \<noteq> 0 |]  
   709       ==> divmod_rel (a * b) c (a*q + a*r div c, a*r mod c)"
   710 by (force simp add: split_ifs divmod_rel_def linorder_neq_iff right_distrib)
   711 
   712 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
   713 apply (case_tac "c = 0", simp)
   714 apply (blast intro: divmod_rel_div_mod [THEN zmult1_lemma, THEN divmod_rel_div])
   715 done
   716 
   717 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
   718 apply (case_tac "c = 0", simp)
   719 apply (blast intro: divmod_rel_div_mod [THEN zmult1_lemma, THEN divmod_rel_mod])
   720 done
   721 
   722 lemma zmod_zmult1_eq': "(a*b) mod (c::int) = ((a mod c) * b) mod c"
   723 apply (rule trans)
   724 apply (rule_tac s = "b*a mod c" in trans)
   725 apply (rule_tac [2] zmod_zmult1_eq)
   726 apply (simp_all add: mult_commute)
   727 done
   728 
   729 lemma zmod_zmult_distrib: "(a*b) mod (c::int) = ((a mod c) * (b mod c)) mod c"
   730 apply (rule zmod_zmult1_eq' [THEN trans])
   731 apply (rule zmod_zmult1_eq)
   732 done
   733 
   734 lemma zdiv_zmult_self1 [simp]: "b \<noteq> (0::int) ==> (a*b) div b = a"
   735 by (simp add: zdiv_zmult1_eq)
   736 
   737 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
   738 apply (case_tac "b = 0", simp)
   739 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
   740 done
   741 
   742 lemma zmod_zmod_trivial: "(a mod b) mod b = a mod (b::int)"
   743 apply (case_tac "b = 0", simp)
   744 apply (force simp add: linorder_neq_iff mod_pos_pos_trivial mod_neg_neg_trivial)
   745 done
   746 
   747 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
   748 
   749 lemma zadd1_lemma:
   750      "[| divmod_rel a c (aq, ar);  divmod_rel b c (bq, br);  c \<noteq> 0 |]  
   751       ==> divmod_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
   752 by (force simp add: split_ifs divmod_rel_def linorder_neq_iff right_distrib)
   753 
   754 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   755 lemma zdiv_zadd1_eq:
   756      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
   757 apply (case_tac "c = 0", simp)
   758 apply (blast intro: zadd1_lemma [OF divmod_rel_div_mod divmod_rel_div_mod] divmod_rel_div)
   759 done
   760 
   761 lemma zmod_zadd1_eq: "(a+b) mod (c::int) = (a mod c + b mod c) mod c"
   762 apply (case_tac "c = 0", simp)
   763 apply (blast intro: zadd1_lemma [OF divmod_rel_div_mod divmod_rel_div_mod] divmod_rel_mod)
   764 done
   765 
   766 instance int :: ring_div
   767 proof
   768   fix a b c :: int
   769   assume not0: "b \<noteq> 0"
   770   show "(a + c * b) div b = c + a div b"
   771     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
   772       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial)
   773 qed auto
   774 
   775 lemma posDivAlg_div_mod:
   776   assumes "k \<ge> 0"
   777   and "l \<ge> 0"
   778   shows "posDivAlg k l = (k div l, k mod l)"
   779 proof (cases "l = 0")
   780   case True then show ?thesis by (simp add: posDivAlg.simps)
   781 next
   782   case False with assms posDivAlg_correct
   783     have "divmod_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
   784     by simp
   785   from divmod_rel_div [OF this `l \<noteq> 0`] divmod_rel_mod [OF this `l \<noteq> 0`]
   786   show ?thesis by simp
   787 qed
   788 
   789 lemma negDivAlg_div_mod:
   790   assumes "k < 0"
   791   and "l > 0"
   792   shows "negDivAlg k l = (k div l, k mod l)"
   793 proof -
   794   from assms have "l \<noteq> 0" by simp
   795   from assms negDivAlg_correct
   796     have "divmod_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
   797     by simp
   798   from divmod_rel_div [OF this `l \<noteq> 0`] divmod_rel_mod [OF this `l \<noteq> 0`]
   799   show ?thesis by simp
   800 qed
   801 
   802 lemma zdiv_zadd_self1: "a \<noteq> (0::int) ==> (a+b) div a = b div a + 1"
   803 by (rule div_add_self1) (* already declared [simp] *)
   804 
   805 lemma zdiv_zadd_self2: "a \<noteq> (0::int) ==> (b+a) div a = b div a + 1"
   806 by (rule div_add_self2) (* already declared [simp] *)
   807 
   808 lemma zdiv_zmult_self2: "b \<noteq> (0::int) ==> (b*a) div b = a"
   809 by (rule div_mult_self1_is_id) (* already declared [simp] *)
   810 
   811 lemma zmod_zmult_self1: "(a*b) mod b = (0::int)"
   812 by (rule mod_mult_self2_is_0) (* already declared [simp] *)
   813 
   814 lemma zmod_zmult_self2: "(b*a) mod b = (0::int)"
   815 by (rule mod_mult_self1_is_0) (* already declared [simp] *)
   816 
   817 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
   818 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   819 
   820 (* REVISIT: should this be generalized to all semiring_div types? *)
   821 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
   822 
   823 lemma zmod_zadd_left_eq: "(a+b) mod (c::int) = ((a mod c) + b) mod c"
   824 by (rule mod_add_left_eq)
   825 
   826 lemma zmod_zadd_right_eq: "(a+b) mod (c::int) = (a + (b mod c)) mod c"
   827 by (rule mod_add_right_eq)
   828 
   829 lemma zmod_zadd_self1: "(a+b) mod a = b mod (a::int)"
   830 by (rule mod_add_self1) (* already declared [simp] *)
   831 
   832 lemma zmod_zadd_self2: "(b+a) mod a = b mod (a::int)"
   833 by (rule mod_add_self2) (* already declared [simp] *)
   834 
   835 lemma zmod_zdiff1_eq: "(a - b) mod c = (a mod c - b mod c) mod (c::int)"
   836 by (rule mod_diff_eq)
   837 
   838 subsection{*Proving  @{term "a div (b*c) = (a div b) div c"} *}
   839 
   840 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
   841   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
   842   to cause particular problems.*)
   843 
   844 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
   845 
   846 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
   847 apply (subgoal_tac "b * (c - q mod c) < r * 1")
   848  apply (simp add: algebra_simps)
   849 apply (rule order_le_less_trans)
   850  apply (erule_tac [2] mult_strict_right_mono)
   851  apply (rule mult_left_mono_neg)
   852   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps pos_mod_bound)
   853  apply (simp)
   854 apply (simp)
   855 done
   856 
   857 lemma zmult2_lemma_aux2:
   858      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
   859 apply (subgoal_tac "b * (q mod c) \<le> 0")
   860  apply arith
   861 apply (simp add: mult_le_0_iff)
   862 done
   863 
   864 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
   865 apply (subgoal_tac "0 \<le> b * (q mod c) ")
   866 apply arith
   867 apply (simp add: zero_le_mult_iff)
   868 done
   869 
   870 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
   871 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
   872  apply (simp add: right_diff_distrib)
   873 apply (rule order_less_le_trans)
   874  apply (erule mult_strict_right_mono)
   875  apply (rule_tac [2] mult_left_mono)
   876   apply simp
   877  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps pos_mod_bound)
   878 apply simp
   879 done
   880 
   881 lemma zmult2_lemma: "[| divmod_rel a b (q, r);  b \<noteq> 0;  0 < c |]  
   882       ==> divmod_rel a (b * c) (q div c, b*(q mod c) + r)"
   883 by (auto simp add: mult_ac divmod_rel_def linorder_neq_iff
   884                    zero_less_mult_iff right_distrib [symmetric] 
   885                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
   886 
   887 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
   888 apply (case_tac "b = 0", simp)
   889 apply (force simp add: divmod_rel_div_mod [THEN zmult2_lemma, THEN divmod_rel_div])
   890 done
   891 
   892 lemma zmod_zmult2_eq:
   893      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
   894 apply (case_tac "b = 0", simp)
   895 apply (force simp add: divmod_rel_div_mod [THEN zmult2_lemma, THEN divmod_rel_mod])
   896 done
   897 
   898 
   899 subsection{*Cancellation of Common Factors in div*}
   900 
   901 lemma zdiv_zmult_zmult1_aux1:
   902      "[| (0::int) < b;  c \<noteq> 0 |] ==> (c*a) div (c*b) = a div b"
   903 by (subst zdiv_zmult2_eq, auto)
   904 
   905 lemma zdiv_zmult_zmult1_aux2:
   906      "[| b < (0::int);  c \<noteq> 0 |] ==> (c*a) div (c*b) = a div b"
   907 apply (subgoal_tac " (c * (-a)) div (c * (-b)) = (-a) div (-b) ")
   908 apply (rule_tac [2] zdiv_zmult_zmult1_aux1, auto)
   909 done
   910 
   911 lemma zdiv_zmult_zmult1: "c \<noteq> (0::int) ==> (c*a) div (c*b) = a div b"
   912 apply (case_tac "b = 0", simp)
   913 apply (auto simp add: linorder_neq_iff zdiv_zmult_zmult1_aux1 zdiv_zmult_zmult1_aux2)
   914 done
   915 
   916 lemma zdiv_zmult_zmult1_if[simp]:
   917   "(k*m) div (k*n) = (if k = (0::int) then 0 else m div n)"
   918 by (simp add:zdiv_zmult_zmult1)
   919 
   920 (*
   921 lemma zdiv_zmult_zmult2: "c \<noteq> (0::int) ==> (a*c) div (b*c) = a div b"
   922 apply (drule zdiv_zmult_zmult1)
   923 apply (auto simp add: mult_commute)
   924 done
   925 *)
   926 
   927 
   928 subsection{*Distribution of Factors over mod*}
   929 
   930 lemma zmod_zmult_zmult1_aux1:
   931      "[| (0::int) < b;  c \<noteq> 0 |] ==> (c*a) mod (c*b) = c * (a mod b)"
   932 by (subst zmod_zmult2_eq, auto)
   933 
   934 lemma zmod_zmult_zmult1_aux2:
   935      "[| b < (0::int);  c \<noteq> 0 |] ==> (c*a) mod (c*b) = c * (a mod b)"
   936 apply (subgoal_tac " (c * (-a)) mod (c * (-b)) = c * ((-a) mod (-b))")
   937 apply (rule_tac [2] zmod_zmult_zmult1_aux1, auto)
   938 done
   939 
   940 lemma zmod_zmult_zmult1: "(c*a) mod (c*b) = (c::int) * (a mod b)"
   941 apply (case_tac "b = 0", simp)
   942 apply (case_tac "c = 0", simp)
   943 apply (auto simp add: linorder_neq_iff zmod_zmult_zmult1_aux1 zmod_zmult_zmult1_aux2)
   944 done
   945 
   946 lemma zmod_zmult_zmult2: "(a*c) mod (b*c) = (a mod b) * (c::int)"
   947 apply (cut_tac c = c in zmod_zmult_zmult1)
   948 apply (auto simp add: mult_commute)
   949 done
   950 
   951 lemma zmod_zmod_cancel: "n dvd m \<Longrightarrow> (k::int) mod m mod n = k mod n"
   952 by (rule mod_mod_cancel)
   953 
   954 
   955 subsection {*Splitting Rules for div and mod*}
   956 
   957 text{*The proofs of the two lemmas below are essentially identical*}
   958 
   959 lemma split_pos_lemma:
   960  "0<k ==> 
   961     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
   962 apply (rule iffI, clarify)
   963  apply (erule_tac P="P ?x ?y" in rev_mp)  
   964  apply (subst zmod_zadd1_eq) 
   965  apply (subst zdiv_zadd1_eq) 
   966  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
   967 txt{*converse direction*}
   968 apply (drule_tac x = "n div k" in spec) 
   969 apply (drule_tac x = "n mod k" in spec, simp)
   970 done
   971 
   972 lemma split_neg_lemma:
   973  "k<0 ==>
   974     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
   975 apply (rule iffI, clarify)
   976  apply (erule_tac P="P ?x ?y" in rev_mp)  
   977  apply (subst zmod_zadd1_eq) 
   978  apply (subst zdiv_zadd1_eq) 
   979  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
   980 txt{*converse direction*}
   981 apply (drule_tac x = "n div k" in spec) 
   982 apply (drule_tac x = "n mod k" in spec, simp)
   983 done
   984 
   985 lemma split_zdiv:
   986  "P(n div k :: int) =
   987   ((k = 0 --> P 0) & 
   988    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
   989    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
   990 apply (case_tac "k=0", simp)
   991 apply (simp only: linorder_neq_iff)
   992 apply (erule disjE) 
   993  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
   994                       split_neg_lemma [of concl: "%x y. P x"])
   995 done
   996 
   997 lemma split_zmod:
   998  "P(n mod k :: int) =
   999   ((k = 0 --> P n) & 
  1000    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  1001    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  1002 apply (case_tac "k=0", simp)
  1003 apply (simp only: linorder_neq_iff)
  1004 apply (erule disjE) 
  1005  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  1006                       split_neg_lemma [of concl: "%x y. P y"])
  1007 done
  1008 
  1009 (* Enable arith to deal with div 2 and mod 2: *)
  1010 declare split_zdiv [of _ _ "number_of k", simplified, standard, arith_split]
  1011 declare split_zmod [of _ _ "number_of k", simplified, standard, arith_split]
  1012 
  1013 
  1014 subsection{*Speeding up the Division Algorithm with Shifting*}
  1015 
  1016 text{*computing div by shifting *}
  1017 
  1018 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  1019 proof cases
  1020   assume "a=0"
  1021     thus ?thesis by simp
  1022 next
  1023   assume "a\<noteq>0" and le_a: "0\<le>a"   
  1024   hence a_pos: "1 \<le> a" by arith
  1025   hence one_less_a2: "1 < 2*a" by arith
  1026   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  1027     by (simp add: mult_le_cancel_left add_commute [of 1] add1_zle_eq)
  1028   with a_pos have "0 \<le> b mod a" by simp
  1029   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  1030     by (simp add: mod_pos_pos_trivial one_less_a2)
  1031   with  le_2a
  1032   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  1033     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  1034                   right_distrib) 
  1035   thus ?thesis
  1036     by (subst zdiv_zadd1_eq,
  1037         simp add: zdiv_zmult_zmult1 zmod_zmult_zmult1 one_less_a2
  1038                   div_pos_pos_trivial)
  1039 qed
  1040 
  1041 lemma neg_zdiv_mult_2: "a \<le> (0::int) ==> (1 + 2*b) div (2*a) = (b+1) div a"
  1042 apply (subgoal_tac " (1 + 2* (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a) ")
  1043 apply (rule_tac [2] pos_zdiv_mult_2)
  1044 apply (auto simp add: minus_mult_right [symmetric] right_diff_distrib)
  1045 apply (subgoal_tac " (-1 - (2 * b)) = - (1 + (2 * b))")
  1046 apply (simp only: zdiv_zminus_zminus diff_minus minus_add_distrib [symmetric],
  1047        simp) 
  1048 done
  1049 
  1050 (*Not clear why this must be proved separately; probably number_of causes
  1051   simplification problems*)
  1052 lemma not_0_le_lemma: "~ 0 \<le> x ==> x \<le> (0::int)"
  1053 by auto
  1054 
  1055 lemma zdiv_number_of_Bit0 [simp]:
  1056      "number_of (Int.Bit0 v) div number_of (Int.Bit0 w) =  
  1057           number_of v div (number_of w :: int)"
  1058 by (simp only: number_of_eq numeral_simps) simp
  1059 
  1060 lemma zdiv_number_of_Bit1 [simp]:
  1061      "number_of (Int.Bit1 v) div number_of (Int.Bit0 w) =  
  1062           (if (0::int) \<le> number_of w                    
  1063            then number_of v div (number_of w)     
  1064            else (number_of v + (1::int)) div (number_of w))"
  1065 apply (simp only: number_of_eq numeral_simps UNIV_I split: split_if) 
  1066 apply (simp add: zdiv_zmult_zmult1 pos_zdiv_mult_2 neg_zdiv_mult_2 add_ac)
  1067 done
  1068 
  1069 
  1070 subsection{*Computing mod by Shifting (proofs resemble those for div)*}
  1071 
  1072 lemma pos_zmod_mult_2:
  1073      "(0::int) \<le> a ==> (1 + 2*b) mod (2*a) = 1 + 2 * (b mod a)"
  1074 apply (case_tac "a = 0", simp)
  1075 apply (subgoal_tac "1 < a * 2")
  1076  prefer 2 apply arith
  1077 apply (subgoal_tac "2* (1 + b mod a) \<le> 2*a")
  1078  apply (rule_tac [2] mult_left_mono)
  1079 apply (auto simp add: add_commute [of 1] mult_commute add1_zle_eq 
  1080                       pos_mod_bound)
  1081 apply (subst zmod_zadd1_eq)
  1082 apply (simp add: zmod_zmult_zmult2 mod_pos_pos_trivial)
  1083 apply (rule mod_pos_pos_trivial)
  1084 apply (auto simp add: mod_pos_pos_trivial ring_distribs)
  1085 apply (subgoal_tac "0 \<le> b mod a", arith, simp)
  1086 done
  1087 
  1088 lemma neg_zmod_mult_2:
  1089      "a \<le> (0::int) ==> (1 + 2*b) mod (2*a) = 2 * ((b+1) mod a) - 1"
  1090 apply (subgoal_tac "(1 + 2* (-b - 1)) mod (2* (-a)) = 
  1091                     1 + 2* ((-b - 1) mod (-a))")
  1092 apply (rule_tac [2] pos_zmod_mult_2)
  1093 apply (auto simp add: minus_mult_right [symmetric] right_diff_distrib)
  1094 apply (subgoal_tac " (-1 - (2 * b)) = - (1 + (2 * b))")
  1095  prefer 2 apply simp 
  1096 apply (simp only: zmod_zminus_zminus diff_minus minus_add_distrib [symmetric])
  1097 done
  1098 
  1099 lemma zmod_number_of_Bit0 [simp]:
  1100      "number_of (Int.Bit0 v) mod number_of (Int.Bit0 w) =  
  1101       (2::int) * (number_of v mod number_of w)"
  1102 apply (simp only: number_of_eq numeral_simps) 
  1103 apply (simp add: zmod_zmult_zmult1 pos_zmod_mult_2 
  1104                  not_0_le_lemma neg_zmod_mult_2 add_ac)
  1105 done
  1106 
  1107 lemma zmod_number_of_Bit1 [simp]:
  1108      "number_of (Int.Bit1 v) mod number_of (Int.Bit0 w) =  
  1109       (if (0::int) \<le> number_of w  
  1110                 then 2 * (number_of v mod number_of w) + 1     
  1111                 else 2 * ((number_of v + (1::int)) mod number_of w) - 1)"
  1112 apply (simp only: number_of_eq numeral_simps) 
  1113 apply (simp add: zmod_zmult_zmult1 pos_zmod_mult_2 
  1114                  not_0_le_lemma neg_zmod_mult_2 add_ac)
  1115 done
  1116 
  1117 
  1118 subsection{*Quotients of Signs*}
  1119 
  1120 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  1121 apply (subgoal_tac "a div b \<le> -1", force)
  1122 apply (rule order_trans)
  1123 apply (rule_tac a' = "-1" in zdiv_mono1)
  1124 apply (auto simp add: zdiv_minus1)
  1125 done
  1126 
  1127 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a;  b < 0 |] ==> a div b \<le> 0"
  1128 by (drule zdiv_mono1_neg, auto)
  1129 
  1130 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  1131 apply auto
  1132 apply (drule_tac [2] zdiv_mono1)
  1133 apply (auto simp add: linorder_neq_iff)
  1134 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  1135 apply (blast intro: div_neg_pos_less0)
  1136 done
  1137 
  1138 lemma neg_imp_zdiv_nonneg_iff:
  1139      "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  1140 apply (subst zdiv_zminus_zminus [symmetric])
  1141 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  1142 done
  1143 
  1144 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  1145 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  1146 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  1147 
  1148 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  1149 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  1150 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  1151 
  1152 
  1153 subsection {* The Divides Relation *}
  1154 
  1155 lemma zdvd_iff_zmod_eq_0: "(m dvd n) = (n mod m = (0::int))"
  1156   by (rule dvd_eq_mod_eq_0)
  1157 
  1158 lemmas zdvd_iff_zmod_eq_0_number_of [simp] =
  1159   zdvd_iff_zmod_eq_0 [of "number_of x" "number_of y", standard]
  1160 
  1161 lemma zdvd_0_right: "(m::int) dvd 0"
  1162   by (rule dvd_0_right) (* already declared [iff] *)
  1163 
  1164 lemma zdvd_0_left: "(0 dvd (m::int)) = (m = 0)"
  1165   by (rule dvd_0_left_iff) (* already declared [noatp,simp] *)
  1166 
  1167 lemma zdvd_1_left: "1 dvd (m::int)"
  1168   by (rule one_dvd) (* already declared [simp] *)
  1169 
  1170 lemma zdvd_refl [simp]: "m dvd (m::int)"
  1171   by (rule dvd_refl) (* TODO: declare generic dvd_refl [simp] *)
  1172 
  1173 lemma zdvd_trans: "m dvd n ==> n dvd k ==> m dvd (k::int)"
  1174   by (rule dvd_trans)
  1175 
  1176 lemma zdvd_zminus_iff[simp]: "m dvd -n \<longleftrightarrow> m dvd (n::int)"
  1177   by (rule dvd_minus_iff)
  1178 
  1179 lemma zdvd_zminus2_iff[simp]: "-m dvd n \<longleftrightarrow> m dvd (n::int)"
  1180   by (rule minus_dvd_iff)
  1181 
  1182 lemma zdvd_abs1[simp]: "( \<bar>i::int\<bar> dvd j) = (i dvd j)" 
  1183   by (cases "i > 0") (simp_all add: zdvd_zminus2_iff)
  1184 
  1185 lemma zdvd_abs2[simp]: "( (i::int) dvd \<bar>j\<bar>) = (i dvd j)" 
  1186   by (cases "j > 0") (simp_all add: zdvd_zminus_iff)
  1187 
  1188 lemma zdvd_anti_sym:
  1189     "0 < m ==> 0 < n ==> m dvd n ==> n dvd m ==> m = (n::int)"
  1190   apply (simp add: dvd_def, auto)
  1191   apply (simp add: mult_assoc zero_less_mult_iff zmult_eq_1_iff)
  1192   done
  1193 
  1194 lemma zdvd_zadd: "k dvd m ==> k dvd n ==> k dvd (m + n :: int)"
  1195   by (rule dvd_add)
  1196 
  1197 lemma zdvd_dvd_eq: assumes anz:"a \<noteq> 0" and ab: "(a::int) dvd b" and ba:"b dvd a" 
  1198   shows "\<bar>a\<bar> = \<bar>b\<bar>"
  1199 proof-
  1200   from ab obtain k where k:"b = a*k" unfolding dvd_def by blast 
  1201   from ba obtain k' where k':"a = b*k'" unfolding dvd_def by blast 
  1202   from k k' have "a = a*k*k'" by simp
  1203   with mult_cancel_left1[where c="a" and b="k*k'"]
  1204   have kk':"k*k' = 1" using anz by (simp add: mult_assoc)
  1205   hence "k = 1 \<and> k' = 1 \<or> k = -1 \<and> k' = -1" by (simp add: zmult_eq_1_iff)
  1206   thus ?thesis using k k' by auto
  1207 qed
  1208 
  1209 lemma zdvd_zdiff: "k dvd m ==> k dvd n ==> k dvd (m - n :: int)"
  1210   by (rule Ring_and_Field.dvd_diff)
  1211 
  1212 lemma zdvd_zdiffD: "k dvd m - n ==> k dvd n ==> k dvd (m::int)"
  1213   apply (subgoal_tac "m = n + (m - n)")
  1214    apply (erule ssubst)
  1215    apply (blast intro: zdvd_zadd, simp)
  1216   done
  1217 
  1218 lemma zdvd_zmult: "k dvd (n::int) ==> k dvd m * n"
  1219   by (rule dvd_mult)
  1220 
  1221 lemma zdvd_zmult2: "k dvd (m::int) ==> k dvd m * n"
  1222   by (rule dvd_mult2)
  1223 
  1224 lemma zdvd_triv_right: "(k::int) dvd m * k"
  1225   by (rule dvd_triv_right) (* already declared [simp] *)
  1226 
  1227 lemma zdvd_triv_left: "(k::int) dvd k * m"
  1228   by (rule dvd_triv_left) (* already declared [simp] *)
  1229 
  1230 lemma zdvd_zmultD2: "j * k dvd n ==> j dvd (n::int)"
  1231   by (rule dvd_mult_left)
  1232 
  1233 lemma zdvd_zmultD: "j * k dvd n ==> k dvd (n::int)"
  1234   by (rule dvd_mult_right)
  1235 
  1236 lemma zdvd_zmult_mono: "i dvd m ==> j dvd (n::int) ==> i * j dvd m * n"
  1237   by (rule mult_dvd_mono)
  1238 
  1239 lemma zdvd_reduce: "(k dvd n + k * m) = (k dvd (n::int))"
  1240   apply (rule iffI)
  1241    apply (erule_tac [2] zdvd_zadd)
  1242    apply (subgoal_tac "n = (n + k * m) - k * m")
  1243     apply (erule ssubst)
  1244     apply (erule zdvd_zdiff, simp_all)
  1245   done
  1246 
  1247 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  1248   apply (simp add: dvd_def)
  1249   apply (auto simp add: zmod_zmult_zmult1)
  1250   done
  1251 
  1252 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  1253   apply (subgoal_tac "k dvd n * (m div n) + m mod n")
  1254    apply (simp add: zmod_zdiv_equality [symmetric])
  1255   apply (simp only: zdvd_zadd zdvd_zmult2)
  1256   done
  1257 
  1258 lemma zdvd_not_zless: "0 < m ==> m < n ==> \<not> n dvd (m::int)"
  1259   apply (auto elim!: dvdE)
  1260   apply (subgoal_tac "0 < n")
  1261    prefer 2
  1262    apply (blast intro: order_less_trans)
  1263   apply (simp add: zero_less_mult_iff)
  1264   apply (subgoal_tac "n * k < n * 1")
  1265    apply (drule mult_less_cancel_left [THEN iffD1], auto)
  1266   done
  1267 
  1268 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  1269   using zmod_zdiv_equality[where a="m" and b="n"]
  1270   by (simp add: algebra_simps)
  1271 
  1272 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  1273 apply (subgoal_tac "m mod n = 0")
  1274  apply (simp add: zmult_div_cancel)
  1275 apply (simp only: zdvd_iff_zmod_eq_0)
  1276 done
  1277 
  1278 lemma zdvd_mult_cancel: assumes d:"k * m dvd k * n" and kz:"k \<noteq> (0::int)"
  1279   shows "m dvd n"
  1280 proof-
  1281   from d obtain h where h: "k*n = k*m * h" unfolding dvd_def by blast
  1282   {assume "n \<noteq> m*h" hence "k* n \<noteq> k* (m*h)" using kz by simp
  1283     with h have False by (simp add: mult_assoc)}
  1284   hence "n = m * h" by blast
  1285   thus ?thesis by simp
  1286 qed
  1287 
  1288 lemma zdvd_zmult_cancel_disj[simp]:
  1289   "(k*m) dvd (k*n) = (k=0 | m dvd (n::int))"
  1290 by (auto simp: zdvd_zmult_mono dest: zdvd_mult_cancel)
  1291 
  1292 
  1293 theorem ex_nat: "(\<exists>x::nat. P x) = (\<exists>x::int. 0 <= x \<and> P (nat x))"
  1294 apply (simp split add: split_nat)
  1295 apply (rule iffI)
  1296 apply (erule exE)
  1297 apply (rule_tac x = "int x" in exI)
  1298 apply simp
  1299 apply (erule exE)
  1300 apply (rule_tac x = "nat x" in exI)
  1301 apply (erule conjE)
  1302 apply (erule_tac x = "nat x" in allE)
  1303 apply simp
  1304 done
  1305 
  1306 theorem zdvd_int: "(x dvd y) = (int x dvd int y)"
  1307 proof -
  1308   have "\<And>k. int y = int x * k \<Longrightarrow> x dvd y"
  1309   proof -
  1310     fix k
  1311     assume A: "int y = int x * k"
  1312     then show "x dvd y" proof (cases k)
  1313       case (1 n) with A have "y = x * n" by (simp add: zmult_int)
  1314       then show ?thesis ..
  1315     next
  1316       case (2 n) with A have "int y = int x * (- int (Suc n))" by simp
  1317       also have "\<dots> = - (int x * int (Suc n))" by (simp only: mult_minus_right)
  1318       also have "\<dots> = - int (x * Suc n)" by (simp only: zmult_int)
  1319       finally have "- int (x * Suc n) = int y" ..
  1320       then show ?thesis by (simp only: negative_eq_positive) auto
  1321     qed
  1322   qed
  1323   then show ?thesis by (auto elim!: dvdE simp only: zdvd_triv_left int_mult)
  1324 qed
  1325 
  1326 lemma zdvd1_eq[simp]: "(x::int) dvd 1 = ( \<bar>x\<bar> = 1)"
  1327 proof
  1328   assume d: "x dvd 1" hence "int (nat \<bar>x\<bar>) dvd int (nat 1)" by (simp add: zdvd_abs1)
  1329   hence "nat \<bar>x\<bar> dvd 1" by (simp add: zdvd_int)
  1330   hence "nat \<bar>x\<bar> = 1"  by simp
  1331   thus "\<bar>x\<bar> = 1" by (cases "x < 0", auto)
  1332 next
  1333   assume "\<bar>x\<bar>=1" thus "x dvd 1" 
  1334     by(cases "x < 0",simp_all add: minus_equation_iff zdvd_iff_zmod_eq_0)
  1335 qed
  1336 lemma zdvd_mult_cancel1: 
  1337   assumes mp:"m \<noteq>(0::int)" shows "(m * n dvd m) = (\<bar>n\<bar> = 1)"
  1338 proof
  1339   assume n1: "\<bar>n\<bar> = 1" thus "m * n dvd m" 
  1340     by (cases "n >0", auto simp add: zdvd_zminus2_iff minus_equation_iff)
  1341 next
  1342   assume H: "m * n dvd m" hence H2: "m * n dvd m * 1" by simp
  1343   from zdvd_mult_cancel[OF H2 mp] show "\<bar>n\<bar> = 1" by (simp only: zdvd1_eq)
  1344 qed
  1345 
  1346 lemma int_dvd_iff: "(int m dvd z) = (m dvd nat (abs z))"
  1347   unfolding zdvd_int by (cases "z \<ge> 0") (simp_all add: zdvd_zminus_iff)
  1348 
  1349 lemma dvd_int_iff: "(z dvd int m) = (nat (abs z) dvd m)"
  1350   unfolding zdvd_int by (cases "z \<ge> 0") (simp_all add: zdvd_zminus2_iff)
  1351 
  1352 lemma nat_dvd_iff: "(nat z dvd m) = (if 0 \<le> z then (z dvd int m) else m = 0)"
  1353   by (auto simp add: dvd_int_iff)
  1354 
  1355 lemma zminus_dvd_iff [iff]: "(-z dvd w) = (z dvd (w::int))"
  1356   by (rule minus_dvd_iff)
  1357 
  1358 lemma dvd_zminus_iff [iff]: "(z dvd -w) = (z dvd (w::int))"
  1359   by (rule dvd_minus_iff)
  1360 
  1361 lemma zdvd_imp_le: "[| z dvd n; 0 < n |] ==> z \<le> (n::int)"
  1362   apply (rule_tac z=n in int_cases)
  1363   apply (auto simp add: dvd_int_iff)
  1364   apply (rule_tac z=z in int_cases)
  1365   apply (auto simp add: dvd_imp_le)
  1366   done
  1367 
  1368 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  1369 apply (induct "y", auto)
  1370 apply (rule zmod_zmult1_eq [THEN trans])
  1371 apply (simp (no_asm_simp))
  1372 apply (rule zmod_zmult_distrib [symmetric])
  1373 done
  1374 
  1375 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  1376 apply (subst split_div, auto)
  1377 apply (subst split_zdiv, auto)
  1378 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in IntDiv.unique_quotient)
  1379 apply (auto simp add: IntDiv.divmod_rel_def of_nat_mult)
  1380 done
  1381 
  1382 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  1383 apply (subst split_mod, auto)
  1384 apply (subst split_zmod, auto)
  1385 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  1386        in unique_remainder)
  1387 apply (auto simp add: IntDiv.divmod_rel_def of_nat_mult)
  1388 done
  1389 
  1390 text{*Suggested by Matthias Daum*}
  1391 lemma int_power_div_base:
  1392      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  1393 apply (subgoal_tac "k ^ m = k ^ ((m - 1) + 1)")
  1394  apply (erule ssubst)
  1395  apply (simp only: power_add)
  1396  apply simp_all
  1397 done
  1398 
  1399 text {* by Brian Huffman *}
  1400 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  1401 by (rule mod_minus_eq [symmetric])
  1402 
  1403 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  1404 by (rule mod_diff_left_eq [symmetric])
  1405 
  1406 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  1407 by (rule mod_diff_right_eq [symmetric])
  1408 
  1409 lemmas zmod_simps =
  1410   IntDiv.zmod_zadd_left_eq  [symmetric]
  1411   IntDiv.zmod_zadd_right_eq [symmetric]
  1412   IntDiv.zmod_zmult1_eq     [symmetric]
  1413   IntDiv.zmod_zmult1_eq'    [symmetric]
  1414   IntDiv.zpower_zmod
  1415   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  1416 
  1417 text {* Distributive laws for function @{text nat}. *}
  1418 
  1419 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  1420 apply (rule linorder_cases [of y 0])
  1421 apply (simp add: div_nonneg_neg_le0)
  1422 apply simp
  1423 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  1424 done
  1425 
  1426 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  1427 lemma nat_mod_distrib:
  1428   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  1429 apply (case_tac "y = 0", simp add: DIVISION_BY_ZERO)
  1430 apply (simp add: nat_eq_iff zmod_int)
  1431 done
  1432 
  1433 text{*Suggested by Matthias Daum*}
  1434 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  1435 apply (subgoal_tac "nat x div nat k < nat x")
  1436  apply (simp (asm_lr) add: nat_div_distrib [symmetric])
  1437 apply (rule Divides.div_less_dividend, simp_all)
  1438 done
  1439 
  1440 text {* code generator setup *}
  1441 
  1442 context ring_1
  1443 begin
  1444 
  1445 lemma of_int_num [code]:
  1446   "of_int k = (if k = 0 then 0 else if k < 0 then
  1447      - of_int (- k) else let
  1448        (l, m) = divmod k 2;
  1449        l' = of_int l
  1450      in if m = 0 then l' + l' else l' + l' + 1)"
  1451 proof -
  1452   have aux1: "k mod (2\<Colon>int) \<noteq> (0\<Colon>int) \<Longrightarrow> 
  1453     of_int k = of_int (k div 2 * 2 + 1)"
  1454   proof -
  1455     have "k mod 2 < 2" by (auto intro: pos_mod_bound)
  1456     moreover have "0 \<le> k mod 2" by (auto intro: pos_mod_sign)
  1457     moreover assume "k mod 2 \<noteq> 0"
  1458     ultimately have "k mod 2 = 1" by arith
  1459     moreover have "of_int k = of_int (k div 2 * 2 + k mod 2)" by simp
  1460     ultimately show ?thesis by auto
  1461   qed
  1462   have aux2: "\<And>x. of_int 2 * x = x + x"
  1463   proof -
  1464     fix x
  1465     have int2: "(2::int) = 1 + 1" by arith
  1466     show "of_int 2 * x = x + x"
  1467     unfolding int2 of_int_add left_distrib by simp
  1468   qed
  1469   have aux3: "\<And>x. x * of_int 2 = x + x"
  1470   proof -
  1471     fix x
  1472     have int2: "(2::int) = 1 + 1" by arith
  1473     show "x * of_int 2 = x + x" 
  1474     unfolding int2 of_int_add right_distrib by simp
  1475   qed
  1476   from aux1 show ?thesis by (auto simp add: divmod_mod_div Let_def aux2 aux3)
  1477 qed
  1478 
  1479 end
  1480 
  1481 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  1482 proof
  1483   assume H: "x mod n = y mod n"
  1484   hence "x mod n - y mod n = 0" by simp
  1485   hence "(x mod n - y mod n) mod n = 0" by simp 
  1486   hence "(x - y) mod n = 0" by (simp add: zmod_zdiff1_eq[symmetric])
  1487   thus "n dvd x - y" by (simp add: zdvd_iff_zmod_eq_0)
  1488 next
  1489   assume H: "n dvd x - y"
  1490   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  1491   hence "x = n*k + y" by simp
  1492   hence "x mod n = (n*k + y) mod n" by simp
  1493   thus "x mod n = y mod n" by (simp add: zmod_zadd_left_eq)
  1494 qed
  1495 
  1496 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  1497   shows "\<exists>q. x = y + n * q"
  1498 proof-
  1499   from xy have th: "int x - int y = int (x - y)" by simp 
  1500   from xyn have "int x mod int n = int y mod int n" 
  1501     by (simp add: zmod_int[symmetric])
  1502   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  1503   hence "n dvd x - y" by (simp add: th zdvd_int)
  1504   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  1505 qed
  1506 
  1507 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  1508   (is "?lhs = ?rhs")
  1509 proof
  1510   assume H: "x mod n = y mod n"
  1511   {assume xy: "x \<le> y"
  1512     from H have th: "y mod n = x mod n" by simp
  1513     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  1514       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  1515   moreover
  1516   {assume xy: "y \<le> x"
  1517     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  1518       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  1519   ultimately  show ?rhs using linear[of x y] by blast  
  1520 next
  1521   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  1522   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  1523   thus  ?lhs by simp
  1524 qed
  1525 
  1526 code_modulename SML
  1527   IntDiv Integer
  1528 
  1529 code_modulename OCaml
  1530   IntDiv Integer
  1531 
  1532 code_modulename Haskell
  1533   IntDiv Integer
  1534 
  1535 end