src/Pure/Isar/calculation.ML
author wenzelm
Tue Oct 16 21:26:36 2012 +0200 (2012-10-16)
changeset 49868 3039922ffd8d
parent 45375 7fe19930dfc9
child 51580 64ef8260dc60
permissions -rw-r--r--
more informative errors for 'also' and 'finally';
     1 (*  Title:      Pure/Isar/calculation.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Generic calculational proofs.
     5 *)
     6 
     7 signature CALCULATION =
     8 sig
     9   val print_rules: Proof.context -> unit
    10   val get_calculation: Proof.state -> thm list option
    11   val trans_add: attribute
    12   val trans_del: attribute
    13   val sym_add: attribute
    14   val sym_del: attribute
    15   val symmetric: attribute
    16   val also: thm list option -> bool -> Proof.state -> Proof.state Seq.result Seq.seq
    17   val also_cmd: (Facts.ref * Attrib.src list) list option ->
    18     bool -> Proof.state -> Proof.state Seq.result Seq.seq
    19   val finally: thm list option -> bool -> Proof.state -> Proof.state Seq.result Seq.seq
    20   val finally_cmd: (Facts.ref * Attrib.src list) list option -> bool ->
    21     Proof.state -> Proof.state Seq.result Seq.seq
    22   val moreover: bool -> Proof.state -> Proof.state
    23   val ultimately: bool -> Proof.state -> Proof.state
    24 end;
    25 
    26 structure Calculation: CALCULATION =
    27 struct
    28 
    29 (** calculation data **)
    30 
    31 structure Data = Generic_Data
    32 (
    33   type T = (thm Item_Net.T * thm list) * (thm list * int) option;
    34   val empty = ((Thm.elim_rules, []), NONE);
    35   val extend = I;
    36   fun merge (((trans1, sym1), _), ((trans2, sym2), _)) =
    37     ((Item_Net.merge (trans1, trans2), Thm.merge_thms (sym1, sym2)), NONE);
    38 );
    39 
    40 val get_rules = #1 o Data.get o Context.Proof;
    41 
    42 fun print_rules ctxt =
    43   let val (trans, sym) = get_rules ctxt in
    44     [Pretty.big_list "transitivity rules:"
    45         (map (Display.pretty_thm ctxt) (Item_Net.content trans)),
    46       Pretty.big_list "symmetry rules:" (map (Display.pretty_thm ctxt) sym)]
    47     |> Pretty.chunks |> Pretty.writeln
    48   end;
    49 
    50 
    51 (* access calculation *)
    52 
    53 fun get_calculation state =
    54   (case #2 (Data.get (Context.Proof (Proof.context_of state))) of
    55     NONE => NONE
    56   | SOME (thms, lev) => if lev = Proof.level state then SOME thms else NONE);
    57 
    58 val calculationN = "calculation";
    59 
    60 fun put_calculation calc =
    61   `Proof.level #-> (fn lev => Proof.map_context (Context.proof_map
    62      (Data.map (apsnd (K (Option.map (rpair lev) calc))))))
    63   #> Proof.put_thms false (calculationN, calc);
    64 
    65 
    66 
    67 (** attributes **)
    68 
    69 (* add/del rules *)
    70 
    71 val trans_add = Thm.declaration_attribute (Data.map o apfst o apfst o Item_Net.update);
    72 val trans_del = Thm.declaration_attribute (Data.map o apfst o apfst o Item_Net.remove);
    73 
    74 val sym_add =
    75   Thm.declaration_attribute (fn th =>
    76     (Data.map o apfst o apsnd) (Thm.add_thm th) #>
    77     Thm.attribute_declaration (Context_Rules.elim_query NONE) th);
    78 
    79 val sym_del =
    80   Thm.declaration_attribute (fn th =>
    81     (Data.map o apfst o apsnd) (Thm.del_thm th) #>
    82     Thm.attribute_declaration Context_Rules.rule_del th);
    83 
    84 
    85 (* symmetric *)
    86 
    87 val symmetric = Thm.rule_attribute (fn x => fn th =>
    88   (case Seq.chop 2 (Drule.multi_resolves [th] (#2 (#1 (Data.get x)))) of
    89     ([th'], _) => Drule.zero_var_indexes th'
    90   | ([], _) => raise THM ("symmetric: no unifiers", 1, [th])
    91   | _ => raise THM ("symmetric: multiple unifiers", 1, [th])));
    92 
    93 
    94 (* concrete syntax *)
    95 
    96 val _ = Context.>> (Context.map_theory
    97  (Attrib.setup (Binding.name "trans") (Attrib.add_del trans_add trans_del)
    98     "declaration of transitivity rule" #>
    99   Attrib.setup (Binding.name "sym") (Attrib.add_del sym_add sym_del)
   100     "declaration of symmetry rule" #>
   101   Attrib.setup (Binding.name "symmetric") (Scan.succeed symmetric)
   102     "resolution with symmetry rule" #>
   103   Global_Theory.add_thms
   104    [((Binding.empty, transitive_thm), [trans_add]),
   105     ((Binding.empty, symmetric_thm), [sym_add])] #> snd));
   106 
   107 
   108 
   109 (** proof commands **)
   110 
   111 fun assert_sane final =
   112   if final then Proof.assert_forward else Proof.assert_forward_or_chain;
   113 
   114 fun maintain_calculation int final calc state =
   115   let
   116     val state' = put_calculation (SOME calc) state;
   117     val ctxt' = Proof.context_of state';
   118     val _ =
   119       if int then
   120         Pretty.writeln
   121           (Proof_Context.pretty_fact ctxt'
   122             (Proof_Context.full_name ctxt' (Binding.name calculationN), calc))
   123       else ();
   124   in state' |> final ? (put_calculation NONE #> Proof.chain_facts calc) end;
   125 
   126 
   127 (* also and finally *)
   128 
   129 fun calculate prep_rules final raw_rules int state =
   130   let
   131     val ctxt = Proof.context_of state;
   132     val pretty_thm = Display.pretty_thm ctxt;
   133 
   134     val strip_assums_concl = Logic.strip_assums_concl o Thm.prop_of;
   135     val eq_prop = op aconv o pairself (Envir.beta_eta_contract o strip_assums_concl);
   136     fun check_projection ths th =
   137       (case find_index (curry eq_prop th) ths of
   138         ~1 => Seq.Result [th]
   139       | i =>
   140           Seq.Error (fn () =>
   141             (Pretty.string_of o Pretty.chunks)
   142              [Pretty.block [Pretty.str "Vacuous calculation result:", Pretty.brk 1, pretty_thm th],
   143               (Pretty.block o Pretty.fbreaks)
   144                 (Pretty.str ("derived as projection (" ^ string_of_int (i + 1) ^ ") from:") ::
   145                   map pretty_thm ths)]));
   146 
   147     val opt_rules = Option.map (prep_rules ctxt) raw_rules;
   148     fun combine ths =
   149       Seq.append
   150         ((case opt_rules of
   151           SOME rules => rules
   152         | NONE =>
   153             (case ths of
   154               [] => Item_Net.content (#1 (get_rules ctxt))
   155             | th :: _ => Item_Net.retrieve (#1 (get_rules ctxt)) (strip_assums_concl th)))
   156         |> Seq.of_list |> Seq.maps (Drule.multi_resolve ths)
   157         |> Seq.map (check_projection ths))
   158         (Seq.single (Seq.Error (fn () =>
   159           (Pretty.string_of o Pretty.block o Pretty.fbreaks)
   160             (Pretty.str "No matching trans rules for calculation:" ::
   161               map pretty_thm ths))));
   162 
   163     val facts = Proof.the_facts (assert_sane final state);
   164     val (initial, calculations) =
   165       (case get_calculation state of
   166         NONE => (true, Seq.single (Seq.Result facts))
   167       | SOME calc => (false, combine (calc @ facts)));
   168 
   169     val _ = initial andalso final andalso error "No calculation yet";
   170     val _ = initial andalso is_some opt_rules andalso
   171       error "Initial calculation -- no rules to be given";
   172   in
   173     calculations |> Seq.map_result (fn calc => maintain_calculation int final calc state)
   174   end;
   175 
   176 val also = calculate (K I) false;
   177 val also_cmd = calculate Attrib.eval_thms false;
   178 val finally = calculate (K I) true;
   179 val finally_cmd = calculate Attrib.eval_thms true;
   180 
   181 
   182 (* moreover and ultimately *)
   183 
   184 fun collect final int state =
   185   let
   186     val facts = Proof.the_facts (assert_sane final state);
   187     val (initial, thms) =
   188       (case get_calculation state of
   189         NONE => (true, [])
   190       | SOME thms => (false, thms));
   191     val calc = thms @ facts;
   192     val _ = initial andalso final andalso error "No calculation yet";
   193   in maintain_calculation int final calc state end;
   194 
   195 val moreover = collect false;
   196 val ultimately = collect true;
   197 
   198 end;