src/HOL/Filter.thy
author wenzelm
Fri Oct 09 20:26:03 2015 +0200 (2015-10-09)
changeset 61378 3e04c9ca001a
parent 61245 b77bf45efe21
child 61531 ab2e862263e7
permissions -rw-r--r--
discontinued specific HTML syntax;
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Filters on predicates\<close>
     7 
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    11 
    12 subsection \<open>Filters\<close>
    13 
    14 text \<open>
    15   This definition also allows non-proper filters.
    16 \<close>
    17 
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    23 
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    28 
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    31 
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    35 
    36 
    37 subsubsection \<open>Eventually\<close>
    38 
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    41 
    42 syntax (xsymbols)
    43   "_eventually"  :: "pttrn => 'a filter => bool => bool"      ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 
    45 translations
    46   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    47 
    48 lemma eventually_Abs_filter:
    49   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    50   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    51 
    52 lemma filter_eq_iff:
    53   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    54   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    55 
    56 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    57   unfolding eventually_def
    58   by (rule is_filter.True [OF is_filter_Rep_filter])
    59 
    60 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    61 proof -
    62   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    63   thus "eventually P F" by simp
    64 qed
    65 
    66 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    67   by (auto intro: always_eventually)
    68 
    69 lemma eventually_mono:
    70   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    71   unfolding eventually_def
    72   by (rule is_filter.mono [OF is_filter_Rep_filter])
    73 
    74 lemma eventually_conj:
    75   assumes P: "eventually (\<lambda>x. P x) F"
    76   assumes Q: "eventually (\<lambda>x. Q x) F"
    77   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    78   using assms unfolding eventually_def
    79   by (rule is_filter.conj [OF is_filter_Rep_filter])
    80 
    81 lemma eventually_mp:
    82   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    83   assumes "eventually (\<lambda>x. P x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 proof (rule eventually_mono)
    86   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    87   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    88     using assms by (rule eventually_conj)
    89 qed
    90 
    91 lemma eventually_rev_mp:
    92   assumes "eventually (\<lambda>x. P x) F"
    93   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    94   shows "eventually (\<lambda>x. Q x) F"
    95 using assms(2) assms(1) by (rule eventually_mp)
    96 
    97 lemma eventually_conj_iff:
    98   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    99   by (auto intro: eventually_conj elim: eventually_rev_mp)
   100 
   101 lemma eventually_elim1:
   102   assumes "eventually (\<lambda>i. P i) F"
   103   assumes "\<And>i. P i \<Longrightarrow> Q i"
   104   shows "eventually (\<lambda>i. Q i) F"
   105   using assms by (auto elim!: eventually_rev_mp)
   106 
   107 lemma eventually_elim2:
   108   assumes "eventually (\<lambda>i. P i) F"
   109   assumes "eventually (\<lambda>i. Q i) F"
   110   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   111   shows "eventually (\<lambda>i. R i) F"
   112   using assms by (auto elim!: eventually_rev_mp)
   113 
   114 lemma eventually_ball_finite_distrib:
   115   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   116   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   117 
   118 lemma eventually_ball_finite:
   119   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   120   by (auto simp: eventually_ball_finite_distrib)
   121 
   122 lemma eventually_all_finite:
   123   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   124   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   125   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   126 using eventually_ball_finite [of UNIV P] assms by simp
   127 
   128 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   129 proof
   130   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   131   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   132     by (auto intro: someI_ex eventually_elim1)
   133   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   134     by auto
   135 qed (auto intro: eventually_elim1)
   136 
   137 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   138   by (auto intro: eventually_mp)
   139 
   140 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   141   by (metis always_eventually)
   142 
   143 lemma eventually_subst:
   144   assumes "eventually (\<lambda>n. P n = Q n) F"
   145   shows "eventually P F = eventually Q F" (is "?L = ?R")
   146 proof -
   147   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   148       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   149     by (auto elim: eventually_elim1)
   150   then show ?thesis by (auto elim: eventually_elim2)
   151 qed
   152 
   153 subsection \<open> Frequently as dual to eventually \<close>
   154 
   155 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   156   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   157 
   158 syntax (xsymbols)
   159   "_frequently"  :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   160 
   161 translations
   162   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   163 
   164 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   165   by (simp add: frequently_def)
   166 
   167 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   168   by (auto simp: frequently_def dest: not_eventuallyD)
   169 
   170 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   171   using frequently_ex[OF assms] by auto
   172 
   173 lemma frequently_mp:
   174   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   175 proof - 
   176   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   177     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   178   from eventually_mp[OF this] P show ?thesis
   179     by (auto simp: frequently_def)
   180 qed
   181 
   182 lemma frequently_rev_mp:
   183   assumes "\<exists>\<^sub>Fx in F. P x"
   184   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   185   shows "\<exists>\<^sub>Fx in F. Q x"
   186 using assms(2) assms(1) by (rule frequently_mp)
   187 
   188 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   189   using frequently_mp[of P Q] by (simp add: always_eventually)
   190 
   191 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   192   by (metis frequently_mono)
   193 
   194 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   195   by (simp add: frequently_def eventually_conj_iff)
   196 
   197 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   198   by (simp add: frequently_disj_iff)
   199 
   200 lemma frequently_bex_finite_distrib:
   201   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   202   using assms by induction (auto simp: frequently_disj_iff)
   203 
   204 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   205   by (simp add: frequently_bex_finite_distrib)
   206 
   207 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   208   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   209 
   210 lemma
   211   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   212     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   213   by (auto simp: frequently_def)
   214 
   215 lemma frequently_imp_iff:
   216   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   217   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   218 
   219 lemma eventually_frequently_const_simps:
   220   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   221   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   222   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   223   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   224   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   225   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   226   by (cases C; simp add: not_frequently)+
   227 
   228 lemmas eventually_frequently_simps = 
   229   eventually_frequently_const_simps
   230   not_eventually
   231   eventually_conj_iff
   232   eventually_ball_finite_distrib
   233   eventually_ex
   234   not_frequently
   235   frequently_disj_iff
   236   frequently_bex_finite_distrib
   237   frequently_all
   238   frequently_imp_iff
   239 
   240 ML \<open>
   241   fun eventually_elim_tac ctxt facts = SUBGOAL_CASES (fn (goal, i) =>
   242     let
   243       val mp_thms = facts RL @{thms eventually_rev_mp}
   244       val raw_elim_thm =
   245         (@{thm allI} RS @{thm always_eventually})
   246         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   247         |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   248       val cases_prop =
   249         Thm.prop_of
   250           (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
   251       val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   252     in
   253       CASES cases (resolve_tac ctxt [raw_elim_thm] i)
   254     end)
   255 \<close>
   256 
   257 method_setup eventually_elim = \<open>
   258   Scan.succeed (fn ctxt => METHOD_CASES (HEADGOAL o eventually_elim_tac ctxt))
   259 \<close> "elimination of eventually quantifiers"
   260 
   261 subsubsection \<open>Finer-than relation\<close>
   262 
   263 text \<open>@{term "F \<le> F'"} means that filter @{term F} is finer than
   264 filter @{term F'}.\<close>
   265 
   266 instantiation filter :: (type) complete_lattice
   267 begin
   268 
   269 definition le_filter_def:
   270   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   271 
   272 definition
   273   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   274 
   275 definition
   276   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   277 
   278 definition
   279   "bot = Abs_filter (\<lambda>P. True)"
   280 
   281 definition
   282   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   283 
   284 definition
   285   "inf F F' = Abs_filter
   286       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   287 
   288 definition
   289   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   290 
   291 definition
   292   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   293 
   294 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   295   unfolding top_filter_def
   296   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   297 
   298 lemma eventually_bot [simp]: "eventually P bot"
   299   unfolding bot_filter_def
   300   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   301 
   302 lemma eventually_sup:
   303   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   304   unfolding sup_filter_def
   305   by (rule eventually_Abs_filter, rule is_filter.intro)
   306      (auto elim!: eventually_rev_mp)
   307 
   308 lemma eventually_inf:
   309   "eventually P (inf F F') \<longleftrightarrow>
   310    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   311   unfolding inf_filter_def
   312   apply (rule eventually_Abs_filter, rule is_filter.intro)
   313   apply (fast intro: eventually_True)
   314   apply clarify
   315   apply (intro exI conjI)
   316   apply (erule (1) eventually_conj)
   317   apply (erule (1) eventually_conj)
   318   apply simp
   319   apply auto
   320   done
   321 
   322 lemma eventually_Sup:
   323   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   324   unfolding Sup_filter_def
   325   apply (rule eventually_Abs_filter, rule is_filter.intro)
   326   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   327   done
   328 
   329 instance proof
   330   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   331   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   332     by (rule less_filter_def) }
   333   { show "F \<le> F"
   334     unfolding le_filter_def by simp }
   335   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   336     unfolding le_filter_def by simp }
   337   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   338     unfolding le_filter_def filter_eq_iff by fast }
   339   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   340     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   341   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   342     unfolding le_filter_def eventually_inf
   343     by (auto elim!: eventually_mono intro: eventually_conj) }
   344   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   345     unfolding le_filter_def eventually_sup by simp_all }
   346   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   347     unfolding le_filter_def eventually_sup by simp }
   348   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   349     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   350   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   351     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   352   { assume "F \<in> S" thus "F \<le> Sup S"
   353     unfolding le_filter_def eventually_Sup by simp }
   354   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   355     unfolding le_filter_def eventually_Sup by simp }
   356   { show "Inf {} = (top::'a filter)"
   357     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   358       (metis (full_types) top_filter_def always_eventually eventually_top) }
   359   { show "Sup {} = (bot::'a filter)"
   360     by (auto simp: bot_filter_def Sup_filter_def) }
   361 qed
   362 
   363 end
   364 
   365 lemma filter_leD:
   366   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   367   unfolding le_filter_def by simp
   368 
   369 lemma filter_leI:
   370   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   371   unfolding le_filter_def by simp
   372 
   373 lemma eventually_False:
   374   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   375   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   376 
   377 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   378   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   379   by (auto simp add: frequently_def eventually_False)
   380 
   381 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   382   by (cases P) (auto simp: eventually_False)
   383 
   384 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   385   by (simp add: eventually_const_iff)
   386 
   387 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   388   by (simp add: frequently_def eventually_const_iff)
   389 
   390 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   391   by (simp add: frequently_const_iff)
   392 
   393 lemma eventually_happens: "eventually P net \<Longrightarrow> net = bot \<or> (\<exists>x. P x)"
   394   by (metis frequentlyE eventually_frequently)
   395 
   396 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   397   where "trivial_limit F \<equiv> F = bot"
   398 
   399 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   400   by (rule eventually_False [symmetric])
   401 
   402 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   403 proof -
   404   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   405   
   406   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   407     proof (rule eventually_Abs_filter is_filter.intro)+
   408       show "?F (\<lambda>x. True)"
   409         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   410     next
   411       fix P Q
   412       assume "?F P" then guess X ..
   413       moreover
   414       assume "?F Q" then guess Y ..
   415       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   416         by (intro exI[of _ "X \<union> Y"])
   417            (auto simp: Inf_union_distrib eventually_inf)
   418     next
   419       fix P Q
   420       assume "?F P" then guess X ..
   421       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   422       ultimately show "?F Q"
   423         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   424     qed }
   425   note eventually_F = this
   426 
   427   have "Inf B = Abs_filter ?F"
   428   proof (intro antisym Inf_greatest)
   429     show "Inf B \<le> Abs_filter ?F"
   430       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   431   next
   432     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   433       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   434   qed
   435   then show ?thesis
   436     by (simp add: eventually_F)
   437 qed
   438 
   439 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   440   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   441   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   442 
   443 lemma Inf_filter_not_bot:
   444   fixes B :: "'a filter set"
   445   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   446   unfolding trivial_limit_def eventually_Inf[of _ B]
   447     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   448 
   449 lemma INF_filter_not_bot:
   450   fixes F :: "'i \<Rightarrow> 'a filter"
   451   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   452   unfolding trivial_limit_def eventually_INF[of _ B]
   453     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   454 
   455 lemma eventually_Inf_base:
   456   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   457   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   458 proof (subst eventually_Inf, safe)
   459   fix X assume "finite X" "X \<subseteq> B"
   460   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   461   proof induct
   462     case empty then show ?case
   463       using \<open>B \<noteq> {}\<close> by auto
   464   next
   465     case (insert x X)
   466     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   467       by auto
   468     with \<open>insert x X \<subseteq> B\<close> base[of b x] show ?case
   469       by (auto intro: order_trans)
   470   qed
   471   then obtain b where "b \<in> B" "b \<le> Inf X"
   472     by (auto simp: le_Inf_iff)
   473   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   474     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   475 qed (auto intro!: exI[of _ "{x}" for x])
   476 
   477 lemma eventually_INF_base:
   478   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   479     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   480   unfolding INF_def by (subst eventually_Inf_base) auto
   481 
   482 
   483 subsubsection \<open>Map function for filters\<close>
   484 
   485 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   486   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   487 
   488 lemma eventually_filtermap:
   489   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   490   unfolding filtermap_def
   491   apply (rule eventually_Abs_filter)
   492   apply (rule is_filter.intro)
   493   apply (auto elim!: eventually_rev_mp)
   494   done
   495 
   496 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   497   by (simp add: filter_eq_iff eventually_filtermap)
   498 
   499 lemma filtermap_filtermap:
   500   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   501   by (simp add: filter_eq_iff eventually_filtermap)
   502 
   503 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   504   unfolding le_filter_def eventually_filtermap by simp
   505 
   506 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   507   by (simp add: filter_eq_iff eventually_filtermap)
   508 
   509 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   510   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   511 
   512 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   513   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   514 
   515 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   516 proof -
   517   { fix X :: "'c set" assume "finite X"
   518     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   519     proof induct
   520       case (insert x X)
   521       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   522         by (rule order_trans[OF _ filtermap_inf]) simp
   523       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   524         by (intro inf_mono insert order_refl)
   525       finally show ?case
   526         by simp
   527     qed simp }
   528   then show ?thesis
   529     unfolding le_filter_def eventually_filtermap
   530     by (subst (1 2) eventually_INF) auto
   531 qed
   532 subsubsection \<open>Standard filters\<close>
   533 
   534 definition principal :: "'a set \<Rightarrow> 'a filter" where
   535   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   536 
   537 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   538   unfolding principal_def
   539   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   540 
   541 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   542   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   543 
   544 lemma principal_UNIV[simp]: "principal UNIV = top"
   545   by (auto simp: filter_eq_iff eventually_principal)
   546 
   547 lemma principal_empty[simp]: "principal {} = bot"
   548   by (auto simp: filter_eq_iff eventually_principal)
   549 
   550 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   551   by (auto simp add: filter_eq_iff eventually_principal)
   552 
   553 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   554   by (auto simp: le_filter_def eventually_principal)
   555 
   556 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   557   unfolding le_filter_def eventually_principal
   558   apply safe
   559   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   560   apply (auto elim: eventually_elim1)
   561   done
   562 
   563 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   564   unfolding eq_iff by simp
   565 
   566 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   567   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   568 
   569 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   570   unfolding filter_eq_iff eventually_inf eventually_principal
   571   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   572 
   573 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   574   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   575 
   576 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   577   by (induct X rule: finite_induct) auto
   578 
   579 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   580   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   581 
   582 subsubsection \<open>Order filters\<close>
   583 
   584 definition at_top :: "('a::order) filter"
   585   where "at_top = (INF k. principal {k ..})"
   586 
   587 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   588   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   589 
   590 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   591   unfolding at_top_def
   592   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   593 
   594 lemma eventually_ge_at_top:
   595   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   596   unfolding eventually_at_top_linorder by auto
   597 
   598 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   599 proof -
   600   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   601     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   602   also have "(INF k. principal {k::'a <..}) = at_top"
   603     unfolding at_top_def 
   604     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   605   finally show ?thesis .
   606 qed
   607 
   608 lemma eventually_at_top_not_equal: "eventually (\<lambda>x::'a::{no_top, linorder}. x \<noteq> c) at_top"
   609   unfolding eventually_at_top_dense by auto
   610 
   611 lemma eventually_gt_at_top: "eventually (\<lambda>x. (c::_::{no_top, linorder}) < x) at_top"
   612   unfolding eventually_at_top_dense by auto
   613 
   614 definition at_bot :: "('a::order) filter"
   615   where "at_bot = (INF k. principal {.. k})"
   616 
   617 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   618   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   619 
   620 lemma eventually_at_bot_linorder:
   621   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   622   unfolding at_bot_def
   623   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   624 
   625 lemma eventually_le_at_bot:
   626   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   627   unfolding eventually_at_bot_linorder by auto
   628 
   629 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   630 proof -
   631   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   632     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   633   also have "(INF k. principal {..< k::'a}) = at_bot"
   634     unfolding at_bot_def 
   635     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   636   finally show ?thesis .
   637 qed
   638 
   639 lemma eventually_at_bot_not_equal: "eventually (\<lambda>x::'a::{no_bot, linorder}. x \<noteq> c) at_bot"
   640   unfolding eventually_at_bot_dense by auto
   641 
   642 lemma eventually_gt_at_bot:
   643   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   644   unfolding eventually_at_bot_dense by auto
   645 
   646 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   647   unfolding trivial_limit_def
   648   by (metis eventually_at_bot_linorder order_refl)
   649 
   650 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   651   unfolding trivial_limit_def
   652   by (metis eventually_at_top_linorder order_refl)
   653 
   654 subsection \<open>Sequentially\<close>
   655 
   656 abbreviation sequentially :: "nat filter"
   657   where "sequentially \<equiv> at_top"
   658 
   659 lemma eventually_sequentially:
   660   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   661   by (rule eventually_at_top_linorder)
   662 
   663 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   664   unfolding filter_eq_iff eventually_sequentially by auto
   665 
   666 lemmas trivial_limit_sequentially = sequentially_bot
   667 
   668 lemma eventually_False_sequentially [simp]:
   669   "\<not> eventually (\<lambda>n. False) sequentially"
   670   by (simp add: eventually_False)
   671 
   672 lemma le_sequentially:
   673   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   674   by (simp add: at_top_def le_INF_iff le_principal)
   675 
   676 lemma eventually_sequentiallyI [intro?]:
   677   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   678   shows "eventually P sequentially"
   679 using assms by (auto simp: eventually_sequentially)
   680 
   681 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   682   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   683 
   684 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   685   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   686 
   687 subsection \<open> The cofinite filter \<close>
   688 
   689 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   690 
   691 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "INFM " 10) where
   692   "Inf_many P \<equiv> frequently P cofinite"
   693 
   694 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "MOST " 10) where
   695   "Alm_all P \<equiv> eventually P cofinite"
   696 
   697 notation (xsymbols)
   698   Inf_many  (binder "\<exists>\<^sub>\<infinity>" 10) and
   699   Alm_all  (binder "\<forall>\<^sub>\<infinity>" 10)
   700 
   701 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   702   unfolding cofinite_def
   703 proof (rule eventually_Abs_filter, rule is_filter.intro)
   704   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   705   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   706     by (rule rev_finite_subset) auto
   707 next
   708   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   709   from * show "finite {x. \<not> Q x}"
   710     by (intro finite_subset[OF _ P]) auto
   711 qed simp
   712 
   713 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   714   by (simp add: frequently_def eventually_cofinite)
   715 
   716 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   717   unfolding trivial_limit_def eventually_cofinite by simp
   718 
   719 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   720   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   721 proof safe
   722   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   723   show "\<exists>N. \<forall>n\<ge>N. P n"
   724   proof cases
   725     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   726       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   727   qed auto
   728 next
   729   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   730   then have "{x. \<not> P x} \<subseteq> {..< N}"
   731     by (auto simp: not_le)
   732   then show "finite {x. \<not> P x}"
   733     by (blast intro: finite_subset)
   734 qed
   735 
   736 subsection \<open>Limits\<close>
   737 
   738 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   739   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   740 
   741 syntax
   742   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   743 
   744 translations
   745   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   746 
   747 lemma filterlim_iff:
   748   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   749   unfolding filterlim_def le_filter_def eventually_filtermap ..
   750 
   751 lemma filterlim_compose:
   752   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   753   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   754 
   755 lemma filterlim_mono:
   756   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   757   unfolding filterlim_def by (metis filtermap_mono order_trans)
   758 
   759 lemma filterlim_ident: "LIM x F. x :> F"
   760   by (simp add: filterlim_def filtermap_ident)
   761 
   762 lemma filterlim_cong:
   763   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   764   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   765 
   766 lemma filterlim_mono_eventually:
   767   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
   768   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
   769   shows "filterlim f' F' G'"
   770   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
   771   apply (rule filterlim_mono[OF _ ord])
   772   apply fact
   773   done
   774 
   775 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
   776   apply (auto intro!: filtermap_mono) []
   777   apply (auto simp: le_filter_def eventually_filtermap)
   778   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
   779   apply auto
   780   done
   781 
   782 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
   783   by (simp add: filtermap_mono_strong eq_iff)
   784 
   785 lemma filtermap_fun_inverse:
   786   assumes g: "filterlim g F G"
   787   assumes f: "filterlim f G F"
   788   assumes ev: "eventually (\<lambda>x. f (g x) = x) G"
   789   shows "filtermap f F = G"
   790 proof (rule antisym)
   791   show "filtermap f F \<le> G"
   792     using f unfolding filterlim_def .
   793   have "G = filtermap f (filtermap g G)"
   794     using ev by (auto elim: eventually_elim2 simp: filter_eq_iff eventually_filtermap)
   795   also have "\<dots> \<le> filtermap f F"
   796     using g by (intro filtermap_mono) (simp add: filterlim_def)
   797   finally show "G \<le> filtermap f F" .
   798 qed
   799 
   800 lemma filterlim_principal:
   801   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   802   unfolding filterlim_def eventually_filtermap le_principal ..
   803 
   804 lemma filterlim_inf:
   805   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   806   unfolding filterlim_def by simp
   807 
   808 lemma filterlim_INF:
   809   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
   810   unfolding filterlim_def le_INF_iff ..
   811 
   812 lemma filterlim_INF_INF:
   813   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
   814   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
   815 
   816 lemma filterlim_base:
   817   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow> 
   818     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
   819   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
   820 
   821 lemma filterlim_base_iff: 
   822   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
   823   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
   824     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
   825   unfolding filterlim_INF filterlim_principal
   826 proof (subst eventually_INF_base)
   827   fix i j assume "i \<in> I" "j \<in> I"
   828   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
   829     by auto
   830 qed (auto simp: eventually_principal \<open>I \<noteq> {}\<close>)
   831 
   832 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   833   unfolding filterlim_def filtermap_filtermap ..
   834 
   835 lemma filterlim_sup:
   836   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   837   unfolding filterlim_def filtermap_sup by auto
   838 
   839 lemma filterlim_sequentially_Suc:
   840   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
   841   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
   842 
   843 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   844   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   845 
   846 lemma filterlim_If:
   847   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
   848     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
   849     LIM x F. if P x then f x else g x :> G"
   850   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
   851 
   852 subsection \<open>Limits to @{const at_top} and @{const at_bot}\<close>
   853 
   854 lemma filterlim_at_top:
   855   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   856   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
   857   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
   858 
   859 lemma filterlim_at_top_mono:
   860   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
   861     LIM x F. g x :> at_top"
   862   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
   863 
   864 lemma filterlim_at_top_dense:
   865   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
   866   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
   867   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
   868             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
   869 
   870 lemma filterlim_at_top_ge:
   871   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   872   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
   873   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
   874 
   875 lemma filterlim_at_top_at_top:
   876   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
   877   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   878   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   879   assumes Q: "eventually Q at_top"
   880   assumes P: "eventually P at_top"
   881   shows "filterlim f at_top at_top"
   882 proof -
   883   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   884     unfolding eventually_at_top_linorder by auto
   885   show ?thesis
   886   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   887     fix z assume "x \<le> z"
   888     with x have "P z" by auto
   889     have "eventually (\<lambda>x. g z \<le> x) at_top"
   890       by (rule eventually_ge_at_top)
   891     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
   892       by eventually_elim (metis mono bij \<open>P z\<close>)
   893   qed
   894 qed
   895 
   896 lemma filterlim_at_top_gt:
   897   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   898   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
   899   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
   900 
   901 lemma filterlim_at_bot: 
   902   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   903   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
   904   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
   905 
   906 lemma filterlim_at_bot_dense:
   907   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
   908   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
   909 proof (auto simp add: filterlim_at_bot[of f F])
   910   fix Z :: 'b
   911   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
   912   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
   913   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
   914   thus "eventually (\<lambda>x. f x < Z) F"
   915     apply (rule eventually_mono[rotated])
   916     using 1 by auto
   917   next 
   918     fix Z :: 'b 
   919     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
   920       by (drule spec [of _ Z], erule eventually_mono[rotated], auto simp add: less_imp_le)
   921 qed
   922 
   923 lemma filterlim_at_bot_le:
   924   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   925   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
   926   unfolding filterlim_at_bot
   927 proof safe
   928   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
   929   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
   930     by (auto elim!: eventually_elim1)
   931 qed simp
   932 
   933 lemma filterlim_at_bot_lt:
   934   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   935   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
   936   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
   937 
   938 
   939 subsection \<open>Setup @{typ "'a filter"} for lifting and transfer\<close>
   940 
   941 context begin interpretation lifting_syntax .
   942 
   943 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
   944 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
   945 
   946 lemma rel_filter_eventually:
   947   "rel_filter R F G \<longleftrightarrow> 
   948   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
   949 by(simp add: rel_filter_def eventually_def)
   950 
   951 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
   952 by(simp add: fun_eq_iff id_def filtermap_ident)
   953 
   954 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
   955 using filtermap_id unfolding id_def .
   956 
   957 lemma Quotient_filter [quot_map]:
   958   assumes Q: "Quotient R Abs Rep T"
   959   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
   960 unfolding Quotient_alt_def
   961 proof(intro conjI strip)
   962   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
   963     unfolding Quotient_alt_def by blast
   964 
   965   fix F G
   966   assume "rel_filter T F G"
   967   thus "filtermap Abs F = G" unfolding filter_eq_iff
   968     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
   969 next
   970   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
   971 
   972   fix F
   973   show "rel_filter T (filtermap Rep F) F" 
   974     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
   975             del: iffI simp add: eventually_filtermap rel_filter_eventually)
   976 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
   977          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
   978 
   979 lemma eventually_parametric [transfer_rule]:
   980   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
   981 by(simp add: rel_fun_def rel_filter_eventually)
   982 
   983 lemma frequently_parametric [transfer_rule]:
   984   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
   985   unfolding frequently_def[abs_def] by transfer_prover
   986 
   987 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
   988 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
   989 
   990 lemma rel_filter_mono [relator_mono]:
   991   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
   992 unfolding rel_filter_eventually[abs_def]
   993 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
   994 
   995 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
   996 apply (simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
   997 apply (safe; metis)
   998 done
   999 
  1000 lemma is_filter_parametric_aux:
  1001   assumes "is_filter F"
  1002   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1003   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  1004   shows "is_filter G"
  1005 proof -
  1006   interpret is_filter F by fact
  1007   show ?thesis
  1008   proof
  1009     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  1010     thus "G (\<lambda>x. True)" by(simp add: True)
  1011   next
  1012     fix P' Q'
  1013     assume "G P'" "G Q'"
  1014     moreover
  1015     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1016     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1017     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  1018     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  1019     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  1020     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  1021   next
  1022     fix P' Q'
  1023     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  1024     moreover
  1025     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1026     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1027     have "F P = G P'" by transfer_prover
  1028     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1029     ultimately have "F Q" by(simp add: mono)
  1030     moreover have "F Q = G Q'" by transfer_prover
  1031     ultimately show "G Q'" by simp
  1032   qed
  1033 qed
  1034 
  1035 lemma is_filter_parametric [transfer_rule]:
  1036   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1037   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1038 apply(rule rel_funI)
  1039 apply(rule iffI)
  1040  apply(erule (3) is_filter_parametric_aux)
  1041 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1042 apply (simp_all add: rel_fun_def)
  1043 apply metis
  1044 done
  1045 
  1046 lemma left_total_rel_filter [transfer_rule]:
  1047   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1048   shows "left_total (rel_filter A)"
  1049 proof(rule left_totalI)
  1050   fix F :: "'a filter"
  1051   from bi_total_fun[OF bi_unique_fun[OF \<open>bi_total A\<close> bi_unique_eq] bi_total_eq]
  1052   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  1053     unfolding  bi_total_def by blast
  1054   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1055   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1056   ultimately have "rel_filter A F (Abs_filter G)"
  1057     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1058   thus "\<exists>G. rel_filter A F G" ..
  1059 qed
  1060 
  1061 lemma right_total_rel_filter [transfer_rule]:
  1062   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1063 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1064 
  1065 lemma bi_total_rel_filter [transfer_rule]:
  1066   assumes "bi_total A" "bi_unique A"
  1067   shows "bi_total (rel_filter A)"
  1068 unfolding bi_total_alt_def using assms
  1069 by(simp add: left_total_rel_filter right_total_rel_filter)
  1070 
  1071 lemma left_unique_rel_filter [transfer_rule]:
  1072   assumes "left_unique A"
  1073   shows "left_unique (rel_filter A)"
  1074 proof(rule left_uniqueI)
  1075   fix F F' G
  1076   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1077   show "F = F'"
  1078     unfolding filter_eq_iff
  1079   proof
  1080     fix P :: "'a \<Rightarrow> bool"
  1081     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1082       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1083     have "eventually P F = eventually P' G" 
  1084       and "eventually P F' = eventually P' G" by transfer_prover+
  1085     thus "eventually P F = eventually P F'" by simp
  1086   qed
  1087 qed
  1088 
  1089 lemma right_unique_rel_filter [transfer_rule]:
  1090   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1091 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1092 
  1093 lemma bi_unique_rel_filter [transfer_rule]:
  1094   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1095 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1096 
  1097 lemma top_filter_parametric [transfer_rule]:
  1098   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1099 by(simp add: rel_filter_eventually All_transfer)
  1100 
  1101 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1102 by(simp add: rel_filter_eventually rel_fun_def)
  1103 
  1104 lemma sup_filter_parametric [transfer_rule]:
  1105   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1106 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1107 
  1108 lemma Sup_filter_parametric [transfer_rule]:
  1109   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1110 proof(rule rel_funI)
  1111   fix S T
  1112   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1113   show "rel_filter A (Sup S) (Sup T)"
  1114     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1115 qed
  1116 
  1117 lemma principal_parametric [transfer_rule]:
  1118   "(rel_set A ===> rel_filter A) principal principal"
  1119 proof(rule rel_funI)
  1120   fix S S'
  1121   assume [transfer_rule]: "rel_set A S S'"
  1122   show "rel_filter A (principal S) (principal S')"
  1123     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1124 qed
  1125 
  1126 context
  1127   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1128   assumes [transfer_rule]: "bi_unique A" 
  1129 begin
  1130 
  1131 lemma le_filter_parametric [transfer_rule]:
  1132   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1133 unfolding le_filter_def[abs_def] by transfer_prover
  1134 
  1135 lemma less_filter_parametric [transfer_rule]:
  1136   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1137 unfolding less_filter_def[abs_def] by transfer_prover
  1138 
  1139 context
  1140   assumes [transfer_rule]: "bi_total A"
  1141 begin
  1142 
  1143 lemma Inf_filter_parametric [transfer_rule]:
  1144   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1145 unfolding Inf_filter_def[abs_def] by transfer_prover
  1146 
  1147 lemma inf_filter_parametric [transfer_rule]:
  1148   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1149 proof(intro rel_funI)+
  1150   fix F F' G G'
  1151   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1152   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1153   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1154 qed
  1155 
  1156 end
  1157 
  1158 end
  1159 
  1160 end
  1161 
  1162 end