src/Tools/Code/code_namespace.ML
author haftmann
Mon Feb 03 08:23:21 2014 +0100 (2014-02-03)
changeset 55293 42cf5802d36a
parent 55292 1e973b665b98
child 55605 b1b363e81c87
permissions -rw-r--r--
code generation: explicitly declared identifiers gain predence over implicit ones
     1 (*  Title:      Tools/Code/code_namespace.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Mastering target language namespaces.
     5 *)
     6 
     7 signature CODE_NAMESPACE =
     8 sig
     9   type flat_program
    10   val flat_program: Proof.context
    11     -> { module_prefix: string, module_name: string,
    12     reserved: Name.context, identifiers: Code_Target.identifier_data, empty_nsp: 'a,
    13     namify_stmt: Code_Thingol.stmt -> string -> 'a -> string * 'a,
    14     modify_stmt: Code_Thingol.stmt -> Code_Thingol.stmt option }
    15       -> Code_Thingol.program
    16       -> { deresolver: string -> Code_Symbol.T -> string,
    17            flat_program: flat_program }
    18 
    19   datatype ('a, 'b) node =
    20       Dummy
    21     | Stmt of 'a
    22     | Module of ('b * (string * ('a, 'b) node) Code_Symbol.Graph.T)
    23   type ('a, 'b) hierarchical_program
    24   val hierarchical_program: Proof.context
    25     -> { module_name: string,
    26     reserved: Name.context, identifiers: Code_Target.identifier_data,
    27     empty_nsp: 'c, namify_module: string -> 'c -> string * 'c,
    28     namify_stmt: Code_Thingol.stmt -> string -> 'c -> string * 'c,
    29     cyclic_modules: bool, empty_data: 'b, memorize_data: Code_Symbol.T -> 'b -> 'b,
    30     modify_stmts: (Code_Symbol.T * Code_Thingol.stmt) list -> 'a option list }
    31       -> Code_Thingol.program
    32       -> { deresolver: string list -> Code_Symbol.T -> string,
    33            hierarchical_program: ('a, 'b) hierarchical_program }
    34   val print_hierarchical: { print_module: string list -> string -> 'b -> 'c list -> 'c,
    35     print_stmt: string list -> Code_Symbol.T * 'a -> 'c,
    36     lift_markup: (Pretty.T -> Pretty.T) -> 'c -> 'c }
    37       -> ('a, 'b) hierarchical_program -> 'c list
    38 end;
    39 
    40 structure Code_Namespace : CODE_NAMESPACE =
    41 struct
    42 
    43 (** fundamental module name hierarchy **)
    44 
    45 fun module_fragments' { identifiers, reserved } name =
    46   case Code_Symbol.lookup_module_data identifiers name of
    47       SOME (fragments, _) => fragments
    48     | NONE => map (fn fragment => fst (Name.variant fragment reserved)) (Long_Name.explode name);
    49 
    50 fun module_fragments { module_name, identifiers, reserved } =
    51   if module_name = ""
    52   then module_fragments' { identifiers = identifiers, reserved = reserved }
    53   else K (Long_Name.explode module_name);
    54 
    55 fun build_module_namespace ctxt { module_prefix, module_name, identifiers, reserved } program =
    56   let
    57     val module_names = Code_Symbol.Graph.fold (insert (op =) o Code_Symbol.default_prefix ctxt o fst) program [];
    58     val module_fragments' = module_fragments
    59       { module_name = module_name, identifiers = identifiers, reserved = reserved };
    60   in
    61     fold (fn name => Symtab.update (name, Long_Name.explode module_prefix @ module_fragments' name))
    62       module_names Symtab.empty
    63   end;
    64 
    65 fun prep_symbol ctxt { module_namespace, force_module, identifiers } sym =
    66   case Code_Symbol.lookup identifiers sym of
    67       NONE => ((the o Symtab.lookup module_namespace o Code_Symbol.default_prefix ctxt) sym,
    68         Code_Symbol.default_base sym)
    69     | SOME prefix_name => if null force_module then prefix_name
    70         else (force_module, snd prefix_name);
    71 
    72 fun has_priority identifiers = is_some o Code_Symbol.lookup identifiers;
    73 
    74 fun build_proto_program { empty, add_stmt, add_dep } program =
    75   empty
    76   |> Code_Symbol.Graph.fold (fn (sym, (stmt, _)) => add_stmt sym stmt) program
    77   |> Code_Symbol.Graph.fold (fn (sym, (_, (_, syms))) =>
    78       Code_Symbol.Graph.Keys.fold (add_dep sym) syms) program;
    79 
    80 fun prioritize has_priority = uncurry append o List.partition has_priority;
    81 
    82 
    83 (** flat program structure **)
    84 
    85 type flat_program = ((string * Code_Thingol.stmt option) Code_Symbol.Graph.T * (string * Code_Symbol.T list) list) Graph.T;
    86 
    87 fun flat_program ctxt { module_prefix, module_name, reserved,
    88     identifiers, empty_nsp, namify_stmt, modify_stmt } program =
    89   let
    90 
    91     (* building module name hierarchy *)
    92     val module_namespace = build_module_namespace ctxt { module_prefix = module_prefix,
    93       module_name = module_name, identifiers = identifiers, reserved = reserved } program;
    94     val prep_sym = prep_symbol ctxt { module_namespace = module_namespace,
    95       force_module = Long_Name.explode module_name, identifiers = identifiers }
    96       #>> Long_Name.implode;
    97     val sym_priority = has_priority identifiers;
    98 
    99     (* distribute statements over hierarchy *)
   100     fun add_stmt sym stmt =
   101       let
   102         val (module_name, base) = prep_sym sym;
   103       in
   104         Graph.default_node (module_name, (Code_Symbol.Graph.empty, []))
   105         #> (Graph.map_node module_name o apfst) (Code_Symbol.Graph.new_node (sym, (base, stmt)))
   106       end;
   107     fun add_dep sym sym' =
   108       let
   109         val (module_name, _) = prep_sym sym;
   110         val (module_name', _) = prep_sym sym';
   111       in if module_name = module_name'
   112         then (Graph.map_node module_name o apfst) (Code_Symbol.Graph.add_edge (sym, sym'))
   113         else (Graph.map_node module_name o apsnd) (AList.map_default (op =) (module_name', []) (insert (op =) sym'))
   114       end;
   115     val proto_program = build_proto_program
   116       { empty = Graph.empty, add_stmt = add_stmt, add_dep = add_dep } program;
   117 
   118     (* name declarations and statement modifications *)
   119     fun declare sym (base, stmt) (gr, nsp) = 
   120       let
   121         val (base', nsp') = namify_stmt stmt base nsp;
   122         val gr' = (Code_Symbol.Graph.map_node sym o apfst) (K base') gr;
   123       in (gr', nsp') end;
   124     fun declarations gr = (gr, empty_nsp)
   125       |> fold (fn sym => declare sym (Code_Symbol.Graph.get_node gr sym))
   126           (prioritize sym_priority (Code_Symbol.Graph.keys gr))
   127       |> fst
   128       |> (Code_Symbol.Graph.map o K o apsnd) modify_stmt;
   129     val flat_program = proto_program
   130       |> (Graph.map o K o apfst) declarations;
   131 
   132     (* qualified and unqualified imports, deresolving *)
   133     fun base_deresolver sym = fst (Code_Symbol.Graph.get_node
   134       (fst (Graph.get_node flat_program (fst (prep_sym sym)))) sym);
   135     fun classify_names gr imports =
   136       let
   137         val import_tab = maps
   138           (fn (module_name, syms) => map (rpair module_name) syms) imports;
   139         val imported_syms = map fst import_tab;
   140         val here_syms = Code_Symbol.Graph.keys gr;
   141       in
   142         Code_Symbol.Table.empty
   143         |> fold (fn sym => Code_Symbol.Table.update (sym, base_deresolver sym)) here_syms
   144         |> fold (fn sym => Code_Symbol.Table.update (sym,
   145             Long_Name.append (the (AList.lookup (op =) import_tab sym))
   146               (base_deresolver sym))) imported_syms
   147       end;
   148     val deresolver_tab = Symtab.make (AList.make
   149       (uncurry classify_names o Graph.get_node flat_program)
   150         (Graph.keys flat_program));
   151     fun deresolver "" sym =
   152           Long_Name.append (fst (prep_sym sym)) (base_deresolver sym)
   153       | deresolver module_name sym =
   154           the (Code_Symbol.Table.lookup (the (Symtab.lookup deresolver_tab module_name)) sym)
   155           handle Option.Option => error ("Unknown statement name: "
   156             ^ Code_Symbol.quote ctxt sym);
   157 
   158   in { deresolver = deresolver, flat_program = flat_program } end;
   159 
   160 
   161 (** hierarchical program structure **)
   162 
   163 datatype ('a, 'b) node =
   164     Dummy
   165   | Stmt of 'a
   166   | Module of ('b * (string * ('a, 'b) node) Code_Symbol.Graph.T);
   167 
   168 type ('a, 'b) hierarchical_program = (string * ('a, 'b) node) Code_Symbol.Graph.T;
   169 
   170 fun map_module_content f (Module content) = Module (f content);
   171 
   172 fun map_module [] = I
   173   | map_module (name_fragment :: name_fragments) =
   174       apsnd o Code_Symbol.Graph.map_node (Code_Symbol.Module name_fragment) o apsnd o map_module_content
   175         o map_module name_fragments;
   176 
   177 fun hierarchical_program ctxt { module_name, reserved, identifiers, empty_nsp,
   178       namify_module, namify_stmt, cyclic_modules, empty_data, memorize_data, modify_stmts } program =
   179   let
   180 
   181     (* building module name hierarchy *)
   182     val module_namespace = build_module_namespace ctxt { module_prefix = "",
   183       module_name = module_name, identifiers = identifiers, reserved = reserved } program;
   184     val prep_sym = prep_symbol ctxt { module_namespace = module_namespace,
   185       force_module = Long_Name.explode module_name, identifiers = identifiers }
   186     val sym_priority = has_priority identifiers;
   187 
   188     (* building empty module hierarchy *)
   189     val empty_module = (empty_data, Code_Symbol.Graph.empty);
   190     fun ensure_module name_fragment (data, nodes) =
   191       if can (Code_Symbol.Graph.get_node nodes) (Code_Symbol.Module name_fragment) then (data, nodes)
   192       else (data,
   193         nodes |> Code_Symbol.Graph.new_node (Code_Symbol.Module name_fragment, (name_fragment, Module empty_module)));
   194     fun allocate_module [] = I
   195       | allocate_module (name_fragment :: name_fragments) =
   196           ensure_module name_fragment
   197           #> (apsnd o Code_Symbol.Graph.map_node (Code_Symbol.Module name_fragment) o apsnd o map_module_content o allocate_module) name_fragments;
   198     val empty_program =
   199       empty_module
   200       |> Symtab.fold (fn (_, fragments) => allocate_module fragments) module_namespace
   201       |> Code_Symbol.Graph.fold (allocate_module o these o Option.map fst
   202           o Code_Symbol.lookup identifiers o fst) program;
   203 
   204     (* distribute statements over hierarchy *)
   205     fun add_stmt sym stmt =
   206       let
   207         val (name_fragments, base) = prep_sym sym;
   208       in
   209         (map_module name_fragments o apsnd) (Code_Symbol.Graph.new_node (sym, (base, Stmt stmt)))
   210       end;
   211     fun add_dep sym sym' =
   212       let
   213         val (name_fragments, _) = prep_sym sym;
   214         val (name_fragments', _) = prep_sym sym';
   215         val (name_fragments_common, (diff, diff')) =
   216           chop_prefix (op =) (name_fragments, name_fragments');
   217         val is_module = not (null diff andalso null diff');
   218         val dep = pairself hd (map Code_Symbol.Module diff @ [sym], map Code_Symbol.Module diff' @ [sym']);
   219         val add_edge = if is_module andalso not cyclic_modules
   220           then (fn node => Code_Symbol.Graph.add_edge_acyclic dep node
   221             handle Graph.CYCLES _ => error ("Dependency "
   222               ^ Code_Symbol.quote ctxt sym ^ " -> "
   223               ^ Code_Symbol.quote ctxt sym'
   224               ^ " would result in module dependency cycle"))
   225           else Code_Symbol.Graph.add_edge dep
   226       in (map_module name_fragments_common o apsnd) add_edge end;
   227     val proto_program = build_proto_program
   228       { empty = empty_program, add_stmt = add_stmt, add_dep = add_dep } program;
   229 
   230     (* name declarations, data and statement modifications *)
   231     fun make_declarations nsps (data, nodes) =
   232       let
   233         val (module_fragments, stmt_syms) =
   234           Code_Symbol.Graph.keys nodes
   235           |> List.partition
   236               (fn sym => case Code_Symbol.Graph.get_node nodes sym
   237                 of (_, Module _) => true | _ => false)
   238           |> pairself (prioritize sym_priority)
   239         fun declare namify sym (nsps, nodes) =
   240           let
   241             val (base, node) = Code_Symbol.Graph.get_node nodes sym;
   242             val (base', nsps') = namify node base nsps;
   243             val nodes' = Code_Symbol.Graph.map_node sym (K (base', node)) nodes;
   244           in (nsps', nodes') end;
   245         val (nsps', nodes') = (nsps, nodes)
   246           |> fold (declare (K namify_module)) module_fragments
   247           |> fold (declare (namify_stmt o (fn Stmt stmt => stmt))) stmt_syms;
   248         fun zip_fillup xs ys = xs ~~ ys @ replicate (length xs - length ys) NONE;
   249         fun select_syms syms = case filter (member (op =) stmt_syms) syms
   250          of [] => NONE
   251           | syms => SOME syms;
   252         val modify_stmts' = AList.make (snd o Code_Symbol.Graph.get_node nodes)
   253           #> split_list
   254           ##> map (fn Stmt stmt => stmt)
   255           #> (fn (syms, stmts) => zip_fillup syms (modify_stmts (syms ~~ stmts)));
   256         val stmtss' = (maps modify_stmts' o map_filter select_syms o Code_Symbol.Graph.strong_conn) nodes;
   257         val nodes'' = Code_Symbol.Graph.map (fn sym => apsnd (fn Module content => Module (make_declarations nsps' content)
   258             | _ => case AList.lookup (op =) stmtss' sym of SOME (SOME stmt) => Stmt stmt | _ => Dummy)) nodes';
   259         val data' = fold memorize_data stmt_syms data;
   260       in (data', nodes'') end;
   261     val (_, hierarchical_program) = make_declarations empty_nsp proto_program;
   262 
   263     (* deresolving *)
   264     fun deresolver prefix_fragments sym =
   265       let
   266         val (name_fragments, _) = prep_sym sym;
   267         val (_, (_, remainder)) = chop_prefix (op =) (prefix_fragments, name_fragments);
   268         val nodes = fold (fn name_fragment => fn nodes => case Code_Symbol.Graph.get_node nodes (Code_Symbol.Module name_fragment)
   269          of (_, Module (_, nodes)) => nodes) name_fragments hierarchical_program;
   270         val (base', _) = Code_Symbol.Graph.get_node nodes sym;
   271       in Long_Name.implode (remainder @ [base']) end
   272         handle Code_Symbol.Graph.UNDEF _ => error ("Unknown statement name: "
   273           ^ Code_Symbol.quote ctxt sym);
   274 
   275   in { deresolver = deresolver, hierarchical_program = hierarchical_program } end;
   276 
   277 fun print_hierarchical { print_module, print_stmt, lift_markup } =
   278   let
   279     fun print_node _ (_, Dummy) =
   280           NONE
   281       | print_node prefix_fragments (sym, Stmt stmt) =
   282           SOME (lift_markup (Code_Printer.markup_stmt sym)
   283             (print_stmt prefix_fragments (sym, stmt)))
   284       | print_node prefix_fragments (Code_Symbol.Module name_fragment, Module (data, nodes)) =
   285           let
   286             val prefix_fragments' = prefix_fragments @ [name_fragment]
   287           in
   288             Option.map (print_module prefix_fragments'
   289               name_fragment data) (print_nodes prefix_fragments' nodes)
   290           end
   291     and print_nodes prefix_fragments nodes =
   292       let
   293         val xs = (map_filter (fn sym => print_node prefix_fragments
   294           (sym, snd (Code_Symbol.Graph.get_node nodes sym))) o rev o flat o Code_Symbol.Graph.strong_conn) nodes
   295       in if null xs then NONE else SOME xs end;
   296   in these o print_nodes [] end;
   297 
   298 end;