src/HOL/RealVector.thy
author hoelzl
Thu Jan 31 17:42:12 2013 +0100 (2013-01-31)
changeset 51002 496013a6eb38
parent 50999 3de230ed0547
child 51022 78de6c7e8a58
permissions -rw-r--r--
remove unnecessary assumption from real_normed_vector
     1 (*  Title:      HOL/RealVector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Vector Spaces and Algebras over the Reals *}
     6 
     7 theory RealVector
     8 imports RComplete
     9 begin
    10 
    11 subsection {* Locale for additive functions *}
    12 
    13 locale additive =
    14   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    15   assumes add: "f (x + y) = f x + f y"
    16 begin
    17 
    18 lemma zero: "f 0 = 0"
    19 proof -
    20   have "f 0 = f (0 + 0)" by simp
    21   also have "\<dots> = f 0 + f 0" by (rule add)
    22   finally show "f 0 = 0" by simp
    23 qed
    24 
    25 lemma minus: "f (- x) = - f x"
    26 proof -
    27   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    28   also have "\<dots> = - f x + f x" by (simp add: zero)
    29   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    30 qed
    31 
    32 lemma diff: "f (x - y) = f x - f y"
    33 by (simp add: add minus diff_minus)
    34 
    35 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    36 apply (cases "finite A")
    37 apply (induct set: finite)
    38 apply (simp add: zero)
    39 apply (simp add: add)
    40 apply (simp add: zero)
    41 done
    42 
    43 end
    44 
    45 subsection {* Vector spaces *}
    46 
    47 locale vector_space =
    48   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    49   assumes scale_right_distrib [algebra_simps]:
    50     "scale a (x + y) = scale a x + scale a y"
    51   and scale_left_distrib [algebra_simps]:
    52     "scale (a + b) x = scale a x + scale b x"
    53   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    54   and scale_one [simp]: "scale 1 x = x"
    55 begin
    56 
    57 lemma scale_left_commute:
    58   "scale a (scale b x) = scale b (scale a x)"
    59 by (simp add: mult_commute)
    60 
    61 lemma scale_zero_left [simp]: "scale 0 x = 0"
    62   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    63   and scale_left_diff_distrib [algebra_simps]:
    64         "scale (a - b) x = scale a x - scale b x"
    65   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    66 proof -
    67   interpret s: additive "\<lambda>a. scale a x"
    68     proof qed (rule scale_left_distrib)
    69   show "scale 0 x = 0" by (rule s.zero)
    70   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    71   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    72   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    73 qed
    74 
    75 lemma scale_zero_right [simp]: "scale a 0 = 0"
    76   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    77   and scale_right_diff_distrib [algebra_simps]:
    78         "scale a (x - y) = scale a x - scale a y"
    79   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    80 proof -
    81   interpret s: additive "\<lambda>x. scale a x"
    82     proof qed (rule scale_right_distrib)
    83   show "scale a 0 = 0" by (rule s.zero)
    84   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    85   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    86   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    87 qed
    88 
    89 lemma scale_eq_0_iff [simp]:
    90   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    91 proof cases
    92   assume "a = 0" thus ?thesis by simp
    93 next
    94   assume anz [simp]: "a \<noteq> 0"
    95   { assume "scale a x = 0"
    96     hence "scale (inverse a) (scale a x) = 0" by simp
    97     hence "x = 0" by simp }
    98   thus ?thesis by force
    99 qed
   100 
   101 lemma scale_left_imp_eq:
   102   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   103 proof -
   104   assume nonzero: "a \<noteq> 0"
   105   assume "scale a x = scale a y"
   106   hence "scale a (x - y) = 0"
   107      by (simp add: scale_right_diff_distrib)
   108   hence "x - y = 0" by (simp add: nonzero)
   109   thus "x = y" by (simp only: right_minus_eq)
   110 qed
   111 
   112 lemma scale_right_imp_eq:
   113   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   114 proof -
   115   assume nonzero: "x \<noteq> 0"
   116   assume "scale a x = scale b x"
   117   hence "scale (a - b) x = 0"
   118      by (simp add: scale_left_diff_distrib)
   119   hence "a - b = 0" by (simp add: nonzero)
   120   thus "a = b" by (simp only: right_minus_eq)
   121 qed
   122 
   123 lemma scale_cancel_left [simp]:
   124   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   125 by (auto intro: scale_left_imp_eq)
   126 
   127 lemma scale_cancel_right [simp]:
   128   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   129 by (auto intro: scale_right_imp_eq)
   130 
   131 end
   132 
   133 subsection {* Real vector spaces *}
   134 
   135 class scaleR =
   136   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   137 begin
   138 
   139 abbreviation
   140   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   141 where
   142   "x /\<^sub>R r == scaleR (inverse r) x"
   143 
   144 end
   145 
   146 class real_vector = scaleR + ab_group_add +
   147   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   148   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   149   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   150   and scaleR_one: "scaleR 1 x = x"
   151 
   152 interpretation real_vector:
   153   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   154 apply unfold_locales
   155 apply (rule scaleR_add_right)
   156 apply (rule scaleR_add_left)
   157 apply (rule scaleR_scaleR)
   158 apply (rule scaleR_one)
   159 done
   160 
   161 text {* Recover original theorem names *}
   162 
   163 lemmas scaleR_left_commute = real_vector.scale_left_commute
   164 lemmas scaleR_zero_left = real_vector.scale_zero_left
   165 lemmas scaleR_minus_left = real_vector.scale_minus_left
   166 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   167 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   168 lemmas scaleR_zero_right = real_vector.scale_zero_right
   169 lemmas scaleR_minus_right = real_vector.scale_minus_right
   170 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   171 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   172 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   173 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   174 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   175 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   176 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   177 
   178 text {* Legacy names *}
   179 
   180 lemmas scaleR_left_distrib = scaleR_add_left
   181 lemmas scaleR_right_distrib = scaleR_add_right
   182 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   183 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   184 
   185 lemma scaleR_minus1_left [simp]:
   186   fixes x :: "'a::real_vector"
   187   shows "scaleR (-1) x = - x"
   188   using scaleR_minus_left [of 1 x] by simp
   189 
   190 class real_algebra = real_vector + ring +
   191   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   192   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   193 
   194 class real_algebra_1 = real_algebra + ring_1
   195 
   196 class real_div_algebra = real_algebra_1 + division_ring
   197 
   198 class real_field = real_div_algebra + field
   199 
   200 instantiation real :: real_field
   201 begin
   202 
   203 definition
   204   real_scaleR_def [simp]: "scaleR a x = a * x"
   205 
   206 instance proof
   207 qed (simp_all add: algebra_simps)
   208 
   209 end
   210 
   211 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   212 proof qed (rule scaleR_left_distrib)
   213 
   214 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   215 proof qed (rule scaleR_right_distrib)
   216 
   217 lemma nonzero_inverse_scaleR_distrib:
   218   fixes x :: "'a::real_div_algebra" shows
   219   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   220 by (rule inverse_unique, simp)
   221 
   222 lemma inverse_scaleR_distrib:
   223   fixes x :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   224   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   225 apply (case_tac "a = 0", simp)
   226 apply (case_tac "x = 0", simp)
   227 apply (erule (1) nonzero_inverse_scaleR_distrib)
   228 done
   229 
   230 
   231 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   232 @{term of_real} *}
   233 
   234 definition
   235   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   236   "of_real r = scaleR r 1"
   237 
   238 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   239 by (simp add: of_real_def)
   240 
   241 lemma of_real_0 [simp]: "of_real 0 = 0"
   242 by (simp add: of_real_def)
   243 
   244 lemma of_real_1 [simp]: "of_real 1 = 1"
   245 by (simp add: of_real_def)
   246 
   247 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   248 by (simp add: of_real_def scaleR_left_distrib)
   249 
   250 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   251 by (simp add: of_real_def)
   252 
   253 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   254 by (simp add: of_real_def scaleR_left_diff_distrib)
   255 
   256 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   257 by (simp add: of_real_def mult_commute)
   258 
   259 lemma nonzero_of_real_inverse:
   260   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   261    inverse (of_real x :: 'a::real_div_algebra)"
   262 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   263 
   264 lemma of_real_inverse [simp]:
   265   "of_real (inverse x) =
   266    inverse (of_real x :: 'a::{real_div_algebra, division_ring_inverse_zero})"
   267 by (simp add: of_real_def inverse_scaleR_distrib)
   268 
   269 lemma nonzero_of_real_divide:
   270   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   271    (of_real x / of_real y :: 'a::real_field)"
   272 by (simp add: divide_inverse nonzero_of_real_inverse)
   273 
   274 lemma of_real_divide [simp]:
   275   "of_real (x / y) =
   276    (of_real x / of_real y :: 'a::{real_field, field_inverse_zero})"
   277 by (simp add: divide_inverse)
   278 
   279 lemma of_real_power [simp]:
   280   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   281 by (induct n) simp_all
   282 
   283 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   284 by (simp add: of_real_def)
   285 
   286 lemma inj_of_real:
   287   "inj of_real"
   288   by (auto intro: injI)
   289 
   290 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   291 
   292 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   293 proof
   294   fix r
   295   show "of_real r = id r"
   296     by (simp add: of_real_def)
   297 qed
   298 
   299 text{*Collapse nested embeddings*}
   300 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   301 by (induct n) auto
   302 
   303 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   304 by (cases z rule: int_diff_cases, simp)
   305 
   306 lemma of_real_numeral: "of_real (numeral w) = numeral w"
   307 using of_real_of_int_eq [of "numeral w"] by simp
   308 
   309 lemma of_real_neg_numeral: "of_real (neg_numeral w) = neg_numeral w"
   310 using of_real_of_int_eq [of "neg_numeral w"] by simp
   311 
   312 text{*Every real algebra has characteristic zero*}
   313 
   314 instance real_algebra_1 < ring_char_0
   315 proof
   316   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   317   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   318 qed
   319 
   320 instance real_field < field_char_0 ..
   321 
   322 
   323 subsection {* The Set of Real Numbers *}
   324 
   325 definition Reals :: "'a::real_algebra_1 set" where
   326   "Reals = range of_real"
   327 
   328 notation (xsymbols)
   329   Reals  ("\<real>")
   330 
   331 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   332 by (simp add: Reals_def)
   333 
   334 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   335 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   336 
   337 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   338 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   339 
   340 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   341 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   342 
   343 lemma Reals_neg_numeral [simp]: "neg_numeral w \<in> Reals"
   344 by (subst of_real_neg_numeral [symmetric], rule Reals_of_real)
   345 
   346 lemma Reals_0 [simp]: "0 \<in> Reals"
   347 apply (unfold Reals_def)
   348 apply (rule range_eqI)
   349 apply (rule of_real_0 [symmetric])
   350 done
   351 
   352 lemma Reals_1 [simp]: "1 \<in> Reals"
   353 apply (unfold Reals_def)
   354 apply (rule range_eqI)
   355 apply (rule of_real_1 [symmetric])
   356 done
   357 
   358 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   359 apply (auto simp add: Reals_def)
   360 apply (rule range_eqI)
   361 apply (rule of_real_add [symmetric])
   362 done
   363 
   364 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   365 apply (auto simp add: Reals_def)
   366 apply (rule range_eqI)
   367 apply (rule of_real_minus [symmetric])
   368 done
   369 
   370 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   371 apply (auto simp add: Reals_def)
   372 apply (rule range_eqI)
   373 apply (rule of_real_diff [symmetric])
   374 done
   375 
   376 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   377 apply (auto simp add: Reals_def)
   378 apply (rule range_eqI)
   379 apply (rule of_real_mult [symmetric])
   380 done
   381 
   382 lemma nonzero_Reals_inverse:
   383   fixes a :: "'a::real_div_algebra"
   384   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   385 apply (auto simp add: Reals_def)
   386 apply (rule range_eqI)
   387 apply (erule nonzero_of_real_inverse [symmetric])
   388 done
   389 
   390 lemma Reals_inverse [simp]:
   391   fixes a :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   392   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   393 apply (auto simp add: Reals_def)
   394 apply (rule range_eqI)
   395 apply (rule of_real_inverse [symmetric])
   396 done
   397 
   398 lemma nonzero_Reals_divide:
   399   fixes a b :: "'a::real_field"
   400   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   401 apply (auto simp add: Reals_def)
   402 apply (rule range_eqI)
   403 apply (erule nonzero_of_real_divide [symmetric])
   404 done
   405 
   406 lemma Reals_divide [simp]:
   407   fixes a b :: "'a::{real_field, field_inverse_zero}"
   408   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   409 apply (auto simp add: Reals_def)
   410 apply (rule range_eqI)
   411 apply (rule of_real_divide [symmetric])
   412 done
   413 
   414 lemma Reals_power [simp]:
   415   fixes a :: "'a::{real_algebra_1}"
   416   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   417 apply (auto simp add: Reals_def)
   418 apply (rule range_eqI)
   419 apply (rule of_real_power [symmetric])
   420 done
   421 
   422 lemma Reals_cases [cases set: Reals]:
   423   assumes "q \<in> \<real>"
   424   obtains (of_real) r where "q = of_real r"
   425   unfolding Reals_def
   426 proof -
   427   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   428   then obtain r where "q = of_real r" ..
   429   then show thesis ..
   430 qed
   431 
   432 lemma Reals_induct [case_names of_real, induct set: Reals]:
   433   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   434   by (rule Reals_cases) auto
   435 
   436 
   437 subsection {* Topological spaces *}
   438 
   439 class "open" =
   440   fixes "open" :: "'a set \<Rightarrow> bool"
   441 
   442 class topological_space = "open" +
   443   assumes open_UNIV [simp, intro]: "open UNIV"
   444   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
   445   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
   446 begin
   447 
   448 definition
   449   closed :: "'a set \<Rightarrow> bool" where
   450   "closed S \<longleftrightarrow> open (- S)"
   451 
   452 lemma open_empty [intro, simp]: "open {}"
   453   using open_Union [of "{}"] by simp
   454 
   455 lemma open_Un [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
   456   using open_Union [of "{S, T}"] by simp
   457 
   458 lemma open_UN [intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
   459   unfolding SUP_def by (rule open_Union) auto
   460 
   461 lemma open_Inter [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
   462   by (induct set: finite) auto
   463 
   464 lemma open_INT [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
   465   unfolding INF_def by (rule open_Inter) auto
   466 
   467 lemma closed_empty [intro, simp]:  "closed {}"
   468   unfolding closed_def by simp
   469 
   470 lemma closed_Un [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
   471   unfolding closed_def by auto
   472 
   473 lemma closed_UNIV [intro, simp]: "closed UNIV"
   474   unfolding closed_def by simp
   475 
   476 lemma closed_Int [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
   477   unfolding closed_def by auto
   478 
   479 lemma closed_INT [intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
   480   unfolding closed_def by auto
   481 
   482 lemma closed_Inter [intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
   483   unfolding closed_def uminus_Inf by auto
   484 
   485 lemma closed_Union [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
   486   by (induct set: finite) auto
   487 
   488 lemma closed_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
   489   unfolding SUP_def by (rule closed_Union) auto
   490 
   491 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
   492   unfolding closed_def by simp
   493 
   494 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
   495   unfolding closed_def by simp
   496 
   497 lemma open_Diff [intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
   498   unfolding closed_open Diff_eq by (rule open_Int)
   499 
   500 lemma closed_Diff [intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
   501   unfolding open_closed Diff_eq by (rule closed_Int)
   502 
   503 lemma open_Compl [intro]: "closed S \<Longrightarrow> open (- S)"
   504   unfolding closed_open .
   505 
   506 lemma closed_Compl [intro]: "open S \<Longrightarrow> closed (- S)"
   507   unfolding open_closed .
   508 
   509 end
   510 
   511 inductive generate_topology for S where
   512   UNIV: "generate_topology S UNIV"
   513 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   514 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   515 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   516 
   517 hide_fact (open) UNIV Int UN Basis 
   518 
   519 lemma generate_topology_Union: 
   520   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   521   unfolding SUP_def by (intro generate_topology.UN) auto
   522 
   523 lemma topological_space_generate_topology:
   524   "class.topological_space (generate_topology S)"
   525   by default (auto intro: generate_topology.intros)
   526 
   527 class order_topology = order + "open" +
   528   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   529 begin
   530 
   531 subclass topological_space
   532   unfolding open_generated_order
   533   by (rule topological_space_generate_topology)
   534 
   535 lemma open_greaterThan [simp]: "open {a <..}"
   536   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   537 
   538 lemma open_lessThan [simp]: "open {..< a}"
   539   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   540 
   541 lemma open_greaterThanLessThan [simp]: "open {a <..< b}"
   542    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   543 
   544 end
   545 
   546 class linorder_topology = linorder + order_topology
   547 
   548 lemma closed_atMost [simp]: "closed {.. a::'a::linorder_topology}"
   549   by (simp add: closed_open)
   550 
   551 lemma closed_atLeast [simp]: "closed {a::'a::linorder_topology ..}"
   552   by (simp add: closed_open)
   553 
   554 lemma closed_atLeastAtMost [simp]: "closed {a::'a::linorder_topology .. b}"
   555 proof -
   556   have "{a .. b} = {a ..} \<inter> {.. b}"
   557     by auto
   558   then show ?thesis
   559     by (simp add: closed_Int)
   560 qed
   561 
   562 inductive open_interval :: "'a::order set \<Rightarrow> bool" where
   563   empty[intro]: "open_interval {}" |
   564   UNIV[intro]: "open_interval UNIV" |
   565   greaterThan[intro]: "open_interval {a <..}" |
   566   lessThan[intro]: "open_interval {..< b}" |
   567   greaterThanLessThan[intro]: "open_interval {a <..< b}"
   568 hide_fact (open) empty UNIV greaterThan lessThan greaterThanLessThan
   569 
   570 lemma open_intervalD:
   571   "open_interval S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> S"
   572   by (cases rule: open_interval.cases) auto
   573 
   574 lemma open_interval_Int[intro]:
   575   fixes S T :: "'a :: linorder set"
   576   assumes S: "open_interval S" and T: "open_interval T"
   577   shows "open_interval (S \<inter> T)"
   578 proof -
   579   { fix a b :: 'a have "{..<b} \<inter> {a<..} = { a <..} \<inter> {..< b }" by auto } note this[simp]
   580   { fix a b :: 'a and A have "{a <..} \<inter> ({b <..} \<inter> A) = {max a b <..} \<inter> A" by auto } note this[simp]
   581   { fix a b :: 'a and A have "{..<b} \<inter> (A \<inter> {..<a}) = A \<inter> {..<min a b}" by auto } note this[simp]
   582   { fix a b :: 'a have "open_interval ({ a <..} \<inter> {..< b})"
   583       unfolding greaterThanLessThan_eq[symmetric] by auto } note this[simp]
   584   show ?thesis
   585     by (cases rule: open_interval.cases[OF S, case_product open_interval.cases[OF T]])
   586        (auto simp: greaterThanLessThan_eq lessThan_Int_lessThan greaterThan_Int_greaterThan Int_assoc)
   587 qed
   588 
   589 lemma open_interval_imp_open: "open_interval S \<Longrightarrow> open (S::'a::order_topology set)"
   590   by (cases S rule: open_interval.cases) auto
   591 
   592 lemma open_orderD:
   593   "open (S::'a::linorder_topology set) \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>T. open_interval T \<and> T \<subseteq> S \<and> x \<in> T"
   594   unfolding open_generated_order
   595 proof (induct rule: generate_topology.induct)
   596   case (UN K) then obtain k where "k \<in> K" "x \<in> k" by auto
   597   with UN(2)[of k] show ?case by auto
   598 qed auto
   599 
   600 lemma open_order_induct[consumes 2, case_names subset UNIV lessThan greaterThan greaterThanLessThan]:
   601   fixes S :: "'a::linorder_topology set"
   602   assumes S: "open S" "x \<in> S"
   603   assumes subset: "\<And>S T. P S \<Longrightarrow> S \<subseteq> T \<Longrightarrow> P T"
   604   assumes univ: "P UNIV"
   605   assumes lt: "\<And>a. x < a \<Longrightarrow> P {..< a}"
   606   assumes gt: "\<And>a. a < x \<Longrightarrow> P {a <..}"
   607   assumes lgt: "\<And>a b. a < x \<Longrightarrow> x < b \<Longrightarrow> P {a <..< b}"
   608   shows "P S"
   609 proof -
   610   from open_orderD[OF S] obtain T where "open_interval T" "T \<subseteq> S" "x \<in> T"
   611     by auto
   612   then show "P S"
   613     by induct (auto intro: univ subset lt gt lgt)
   614 qed
   615 
   616 subsection {* Metric spaces *}
   617 
   618 class dist =
   619   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   620 
   621 class open_dist = "open" + dist +
   622   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   623 
   624 class metric_space = open_dist +
   625   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   626   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   627 begin
   628 
   629 lemma dist_self [simp]: "dist x x = 0"
   630 by simp
   631 
   632 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   633 using dist_triangle2 [of x x y] by simp
   634 
   635 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   636 by (simp add: less_le)
   637 
   638 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   639 by (simp add: not_less)
   640 
   641 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   642 by (simp add: le_less)
   643 
   644 lemma dist_commute: "dist x y = dist y x"
   645 proof (rule order_antisym)
   646   show "dist x y \<le> dist y x"
   647     using dist_triangle2 [of x y x] by simp
   648   show "dist y x \<le> dist x y"
   649     using dist_triangle2 [of y x y] by simp
   650 qed
   651 
   652 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   653 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   654 
   655 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   656 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   657 
   658 lemma dist_triangle_alt:
   659   shows "dist y z <= dist x y + dist x z"
   660 by (rule dist_triangle3)
   661 
   662 lemma dist_pos_lt:
   663   shows "x \<noteq> y ==> 0 < dist x y"
   664 by (simp add: zero_less_dist_iff)
   665 
   666 lemma dist_nz:
   667   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   668 by (simp add: zero_less_dist_iff)
   669 
   670 lemma dist_triangle_le:
   671   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   672 by (rule order_trans [OF dist_triangle2])
   673 
   674 lemma dist_triangle_lt:
   675   shows "dist x z + dist y z < e ==> dist x y < e"
   676 by (rule le_less_trans [OF dist_triangle2])
   677 
   678 lemma dist_triangle_half_l:
   679   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   680 by (rule dist_triangle_lt [where z=y], simp)
   681 
   682 lemma dist_triangle_half_r:
   683   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   684 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   685 
   686 subclass topological_space
   687 proof
   688   have "\<exists>e::real. 0 < e"
   689     by (fast intro: zero_less_one)
   690   then show "open UNIV"
   691     unfolding open_dist by simp
   692 next
   693   fix S T assume "open S" "open T"
   694   then show "open (S \<inter> T)"
   695     unfolding open_dist
   696     apply clarify
   697     apply (drule (1) bspec)+
   698     apply (clarify, rename_tac r s)
   699     apply (rule_tac x="min r s" in exI, simp)
   700     done
   701 next
   702   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   703     unfolding open_dist by fast
   704 qed
   705 
   706 lemma (in metric_space) open_ball: "open {y. dist x y < d}"
   707 proof (unfold open_dist, intro ballI)
   708   fix y assume *: "y \<in> {y. dist x y < d}"
   709   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
   710     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
   711 qed
   712 
   713 end
   714 
   715 
   716 subsection {* Real normed vector spaces *}
   717 
   718 class norm =
   719   fixes norm :: "'a \<Rightarrow> real"
   720 
   721 class sgn_div_norm = scaleR + norm + sgn +
   722   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   723 
   724 class dist_norm = dist + norm + minus +
   725   assumes dist_norm: "dist x y = norm (x - y)"
   726 
   727 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   728   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   729   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   730   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   731 begin
   732 
   733 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   734 proof -
   735   have "0 = norm (x + -1 *\<^sub>R x)" 
   736     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   737   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   738   finally show ?thesis by simp
   739 qed
   740 
   741 end
   742 
   743 class real_normed_algebra = real_algebra + real_normed_vector +
   744   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   745 
   746 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   747   assumes norm_one [simp]: "norm 1 = 1"
   748 
   749 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   750   assumes norm_mult: "norm (x * y) = norm x * norm y"
   751 
   752 class real_normed_field = real_field + real_normed_div_algebra
   753 
   754 instance real_normed_div_algebra < real_normed_algebra_1
   755 proof
   756   fix x y :: 'a
   757   show "norm (x * y) \<le> norm x * norm y"
   758     by (simp add: norm_mult)
   759 next
   760   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   761     by (rule norm_mult)
   762   thus "norm (1::'a) = 1" by simp
   763 qed
   764 
   765 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   766 by simp
   767 
   768 lemma zero_less_norm_iff [simp]:
   769   fixes x :: "'a::real_normed_vector"
   770   shows "(0 < norm x) = (x \<noteq> 0)"
   771 by (simp add: order_less_le)
   772 
   773 lemma norm_not_less_zero [simp]:
   774   fixes x :: "'a::real_normed_vector"
   775   shows "\<not> norm x < 0"
   776 by (simp add: linorder_not_less)
   777 
   778 lemma norm_le_zero_iff [simp]:
   779   fixes x :: "'a::real_normed_vector"
   780   shows "(norm x \<le> 0) = (x = 0)"
   781 by (simp add: order_le_less)
   782 
   783 lemma norm_minus_cancel [simp]:
   784   fixes x :: "'a::real_normed_vector"
   785   shows "norm (- x) = norm x"
   786 proof -
   787   have "norm (- x) = norm (scaleR (- 1) x)"
   788     by (simp only: scaleR_minus_left scaleR_one)
   789   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   790     by (rule norm_scaleR)
   791   finally show ?thesis by simp
   792 qed
   793 
   794 lemma norm_minus_commute:
   795   fixes a b :: "'a::real_normed_vector"
   796   shows "norm (a - b) = norm (b - a)"
   797 proof -
   798   have "norm (- (b - a)) = norm (b - a)"
   799     by (rule norm_minus_cancel)
   800   thus ?thesis by simp
   801 qed
   802 
   803 lemma norm_triangle_ineq2:
   804   fixes a b :: "'a::real_normed_vector"
   805   shows "norm a - norm b \<le> norm (a - b)"
   806 proof -
   807   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   808     by (rule norm_triangle_ineq)
   809   thus ?thesis by simp
   810 qed
   811 
   812 lemma norm_triangle_ineq3:
   813   fixes a b :: "'a::real_normed_vector"
   814   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   815 apply (subst abs_le_iff)
   816 apply auto
   817 apply (rule norm_triangle_ineq2)
   818 apply (subst norm_minus_commute)
   819 apply (rule norm_triangle_ineq2)
   820 done
   821 
   822 lemma norm_triangle_ineq4:
   823   fixes a b :: "'a::real_normed_vector"
   824   shows "norm (a - b) \<le> norm a + norm b"
   825 proof -
   826   have "norm (a + - b) \<le> norm a + norm (- b)"
   827     by (rule norm_triangle_ineq)
   828   thus ?thesis
   829     by (simp only: diff_minus norm_minus_cancel)
   830 qed
   831 
   832 lemma norm_diff_ineq:
   833   fixes a b :: "'a::real_normed_vector"
   834   shows "norm a - norm b \<le> norm (a + b)"
   835 proof -
   836   have "norm a - norm (- b) \<le> norm (a - - b)"
   837     by (rule norm_triangle_ineq2)
   838   thus ?thesis by simp
   839 qed
   840 
   841 lemma norm_diff_triangle_ineq:
   842   fixes a b c d :: "'a::real_normed_vector"
   843   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   844 proof -
   845   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   846     by (simp add: diff_minus add_ac)
   847   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   848     by (rule norm_triangle_ineq)
   849   finally show ?thesis .
   850 qed
   851 
   852 lemma abs_norm_cancel [simp]:
   853   fixes a :: "'a::real_normed_vector"
   854   shows "\<bar>norm a\<bar> = norm a"
   855 by (rule abs_of_nonneg [OF norm_ge_zero])
   856 
   857 lemma norm_add_less:
   858   fixes x y :: "'a::real_normed_vector"
   859   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   860 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   861 
   862 lemma norm_mult_less:
   863   fixes x y :: "'a::real_normed_algebra"
   864   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   865 apply (rule order_le_less_trans [OF norm_mult_ineq])
   866 apply (simp add: mult_strict_mono')
   867 done
   868 
   869 lemma norm_of_real [simp]:
   870   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   871 unfolding of_real_def by simp
   872 
   873 lemma norm_numeral [simp]:
   874   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   875 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   876 
   877 lemma norm_neg_numeral [simp]:
   878   "norm (neg_numeral w::'a::real_normed_algebra_1) = numeral w"
   879 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   880 
   881 lemma norm_of_int [simp]:
   882   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   883 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   884 
   885 lemma norm_of_nat [simp]:
   886   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   887 apply (subst of_real_of_nat_eq [symmetric])
   888 apply (subst norm_of_real, simp)
   889 done
   890 
   891 lemma nonzero_norm_inverse:
   892   fixes a :: "'a::real_normed_div_algebra"
   893   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   894 apply (rule inverse_unique [symmetric])
   895 apply (simp add: norm_mult [symmetric])
   896 done
   897 
   898 lemma norm_inverse:
   899   fixes a :: "'a::{real_normed_div_algebra, division_ring_inverse_zero}"
   900   shows "norm (inverse a) = inverse (norm a)"
   901 apply (case_tac "a = 0", simp)
   902 apply (erule nonzero_norm_inverse)
   903 done
   904 
   905 lemma nonzero_norm_divide:
   906   fixes a b :: "'a::real_normed_field"
   907   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   908 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   909 
   910 lemma norm_divide:
   911   fixes a b :: "'a::{real_normed_field, field_inverse_zero}"
   912   shows "norm (a / b) = norm a / norm b"
   913 by (simp add: divide_inverse norm_mult norm_inverse)
   914 
   915 lemma norm_power_ineq:
   916   fixes x :: "'a::{real_normed_algebra_1}"
   917   shows "norm (x ^ n) \<le> norm x ^ n"
   918 proof (induct n)
   919   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   920 next
   921   case (Suc n)
   922   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   923     by (rule norm_mult_ineq)
   924   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   925     using norm_ge_zero by (rule mult_left_mono)
   926   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   927     by simp
   928 qed
   929 
   930 lemma norm_power:
   931   fixes x :: "'a::{real_normed_div_algebra}"
   932   shows "norm (x ^ n) = norm x ^ n"
   933 by (induct n) (simp_all add: norm_mult)
   934 
   935 text {* Every normed vector space is a metric space. *}
   936 
   937 instance real_normed_vector < metric_space
   938 proof
   939   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
   940     unfolding dist_norm by simp
   941 next
   942   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
   943     unfolding dist_norm
   944     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
   945 qed
   946 
   947 
   948 subsection {* Class instances for real numbers *}
   949 
   950 instantiation real :: real_normed_field
   951 begin
   952 
   953 definition real_norm_def [simp]:
   954   "norm r = \<bar>r\<bar>"
   955 
   956 definition dist_real_def:
   957   "dist x y = \<bar>x - y\<bar>"
   958 
   959 definition open_real_def:
   960   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   961 
   962 instance
   963 apply (intro_classes, unfold real_norm_def real_scaleR_def)
   964 apply (rule dist_real_def)
   965 apply (rule open_real_def)
   966 apply (simp add: sgn_real_def)
   967 apply (rule abs_eq_0)
   968 apply (rule abs_triangle_ineq)
   969 apply (rule abs_mult)
   970 apply (rule abs_mult)
   971 done
   972 
   973 end
   974 
   975 instance real :: linorder_topology
   976 proof
   977   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
   978   proof (rule ext, safe)
   979     fix S :: "real set" assume "open S"
   980     then guess f unfolding open_real_def bchoice_iff ..
   981     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
   982       by (fastforce simp: dist_real_def)
   983     show "generate_topology (range lessThan \<union> range greaterThan) S"
   984       apply (subst *)
   985       apply (intro generate_topology_Union generate_topology.Int)
   986       apply (auto intro: generate_topology.Basis)
   987       done
   988   next
   989     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
   990     moreover have "\<And>a::real. open {..<a}"
   991       unfolding open_real_def dist_real_def
   992     proof clarify
   993       fix x a :: real assume "x < a"
   994       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
   995       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
   996     qed
   997     moreover have "\<And>a::real. open {a <..}"
   998       unfolding open_real_def dist_real_def
   999     proof clarify
  1000       fix x a :: real assume "a < x"
  1001       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1002       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1003     qed
  1004     ultimately show "open S"
  1005       by induct auto
  1006   qed
  1007 qed
  1008 
  1009 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1010 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1011 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1012 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1013 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1014 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1015 
  1016 subsection {* Extra type constraints *}
  1017 
  1018 text {* Only allow @{term "open"} in class @{text topological_space}. *}
  1019 
  1020 setup {* Sign.add_const_constraint
  1021   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
  1022 
  1023 text {* Only allow @{term dist} in class @{text metric_space}. *}
  1024 
  1025 setup {* Sign.add_const_constraint
  1026   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
  1027 
  1028 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
  1029 
  1030 setup {* Sign.add_const_constraint
  1031   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
  1032 
  1033 
  1034 subsection {* Sign function *}
  1035 
  1036 lemma norm_sgn:
  1037   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
  1038 by (simp add: sgn_div_norm)
  1039 
  1040 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
  1041 by (simp add: sgn_div_norm)
  1042 
  1043 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
  1044 by (simp add: sgn_div_norm)
  1045 
  1046 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
  1047 by (simp add: sgn_div_norm)
  1048 
  1049 lemma sgn_scaleR:
  1050   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
  1051 by (simp add: sgn_div_norm mult_ac)
  1052 
  1053 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1054 by (simp add: sgn_div_norm)
  1055 
  1056 lemma sgn_of_real:
  1057   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
  1058 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1059 
  1060 lemma sgn_mult:
  1061   fixes x y :: "'a::real_normed_div_algebra"
  1062   shows "sgn (x * y) = sgn x * sgn y"
  1063 by (simp add: sgn_div_norm norm_mult mult_commute)
  1064 
  1065 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
  1066 by (simp add: sgn_div_norm divide_inverse)
  1067 
  1068 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
  1069 unfolding real_sgn_eq by simp
  1070 
  1071 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
  1072 unfolding real_sgn_eq by simp
  1073 
  1074 
  1075 subsection {* Bounded Linear and Bilinear Operators *}
  1076 
  1077 locale bounded_linear = additive f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1078   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1079   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1080 begin
  1081 
  1082 lemma pos_bounded:
  1083   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1084 proof -
  1085   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1086     using bounded by fast
  1087   show ?thesis
  1088   proof (intro exI impI conjI allI)
  1089     show "0 < max 1 K"
  1090       by (rule order_less_le_trans [OF zero_less_one le_maxI1])
  1091   next
  1092     fix x
  1093     have "norm (f x) \<le> norm x * K" using K .
  1094     also have "\<dots> \<le> norm x * max 1 K"
  1095       by (rule mult_left_mono [OF le_maxI2 norm_ge_zero])
  1096     finally show "norm (f x) \<le> norm x * max 1 K" .
  1097   qed
  1098 qed
  1099 
  1100 lemma nonneg_bounded:
  1101   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1102 proof -
  1103   from pos_bounded
  1104   show ?thesis by (auto intro: order_less_imp_le)
  1105 qed
  1106 
  1107 end
  1108 
  1109 lemma bounded_linear_intro:
  1110   assumes "\<And>x y. f (x + y) = f x + f y"
  1111   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1112   assumes "\<And>x. norm (f x) \<le> norm x * K"
  1113   shows "bounded_linear f"
  1114   by default (fast intro: assms)+
  1115 
  1116 locale bounded_bilinear =
  1117   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
  1118                  \<Rightarrow> 'c::real_normed_vector"
  1119     (infixl "**" 70)
  1120   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1121   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1122   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1123   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1124   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1125 begin
  1126 
  1127 lemma pos_bounded:
  1128   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1129 apply (cut_tac bounded, erule exE)
  1130 apply (rule_tac x="max 1 K" in exI, safe)
  1131 apply (rule order_less_le_trans [OF zero_less_one le_maxI1])
  1132 apply (drule spec, drule spec, erule order_trans)
  1133 apply (rule mult_left_mono [OF le_maxI2])
  1134 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1135 done
  1136 
  1137 lemma nonneg_bounded:
  1138   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1139 proof -
  1140   from pos_bounded
  1141   show ?thesis by (auto intro: order_less_imp_le)
  1142 qed
  1143 
  1144 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1145 by (rule additive.intro, rule add_right)
  1146 
  1147 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1148 by (rule additive.intro, rule add_left)
  1149 
  1150 lemma zero_left: "prod 0 b = 0"
  1151 by (rule additive.zero [OF additive_left])
  1152 
  1153 lemma zero_right: "prod a 0 = 0"
  1154 by (rule additive.zero [OF additive_right])
  1155 
  1156 lemma minus_left: "prod (- a) b = - prod a b"
  1157 by (rule additive.minus [OF additive_left])
  1158 
  1159 lemma minus_right: "prod a (- b) = - prod a b"
  1160 by (rule additive.minus [OF additive_right])
  1161 
  1162 lemma diff_left:
  1163   "prod (a - a') b = prod a b - prod a' b"
  1164 by (rule additive.diff [OF additive_left])
  1165 
  1166 lemma diff_right:
  1167   "prod a (b - b') = prod a b - prod a b'"
  1168 by (rule additive.diff [OF additive_right])
  1169 
  1170 lemma bounded_linear_left:
  1171   "bounded_linear (\<lambda>a. a ** b)"
  1172 apply (cut_tac bounded, safe)
  1173 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1174 apply (rule add_left)
  1175 apply (rule scaleR_left)
  1176 apply (simp add: mult_ac)
  1177 done
  1178 
  1179 lemma bounded_linear_right:
  1180   "bounded_linear (\<lambda>b. a ** b)"
  1181 apply (cut_tac bounded, safe)
  1182 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1183 apply (rule add_right)
  1184 apply (rule scaleR_right)
  1185 apply (simp add: mult_ac)
  1186 done
  1187 
  1188 lemma prod_diff_prod:
  1189   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1190 by (simp add: diff_left diff_right)
  1191 
  1192 end
  1193 
  1194 lemma bounded_bilinear_mult:
  1195   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1196 apply (rule bounded_bilinear.intro)
  1197 apply (rule distrib_right)
  1198 apply (rule distrib_left)
  1199 apply (rule mult_scaleR_left)
  1200 apply (rule mult_scaleR_right)
  1201 apply (rule_tac x="1" in exI)
  1202 apply (simp add: norm_mult_ineq)
  1203 done
  1204 
  1205 lemma bounded_linear_mult_left:
  1206   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1207   using bounded_bilinear_mult
  1208   by (rule bounded_bilinear.bounded_linear_left)
  1209 
  1210 lemma bounded_linear_mult_right:
  1211   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1212   using bounded_bilinear_mult
  1213   by (rule bounded_bilinear.bounded_linear_right)
  1214 
  1215 lemma bounded_linear_divide:
  1216   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1217   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1218 
  1219 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1220 apply (rule bounded_bilinear.intro)
  1221 apply (rule scaleR_left_distrib)
  1222 apply (rule scaleR_right_distrib)
  1223 apply simp
  1224 apply (rule scaleR_left_commute)
  1225 apply (rule_tac x="1" in exI, simp)
  1226 done
  1227 
  1228 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1229   using bounded_bilinear_scaleR
  1230   by (rule bounded_bilinear.bounded_linear_left)
  1231 
  1232 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1233   using bounded_bilinear_scaleR
  1234   by (rule bounded_bilinear.bounded_linear_right)
  1235 
  1236 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1237   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1238 
  1239 subsection{* Hausdorff and other separation properties *}
  1240 
  1241 class t0_space = topological_space +
  1242   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
  1243 
  1244 class t1_space = topological_space +
  1245   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
  1246 
  1247 instance t1_space \<subseteq> t0_space
  1248 proof qed (fast dest: t1_space)
  1249 
  1250 lemma separation_t1:
  1251   fixes x y :: "'a::t1_space"
  1252   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
  1253   using t1_space[of x y] by blast
  1254 
  1255 lemma closed_singleton:
  1256   fixes a :: "'a::t1_space"
  1257   shows "closed {a}"
  1258 proof -
  1259   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
  1260   have "open ?T" by (simp add: open_Union)
  1261   also have "?T = - {a}"
  1262     by (simp add: set_eq_iff separation_t1, auto)
  1263   finally show "closed {a}" unfolding closed_def .
  1264 qed
  1265 
  1266 lemma closed_insert [simp]:
  1267   fixes a :: "'a::t1_space"
  1268   assumes "closed S" shows "closed (insert a S)"
  1269 proof -
  1270   from closed_singleton assms
  1271   have "closed ({a} \<union> S)" by (rule closed_Un)
  1272   thus "closed (insert a S)" by simp
  1273 qed
  1274 
  1275 lemma finite_imp_closed:
  1276   fixes S :: "'a::t1_space set"
  1277   shows "finite S \<Longrightarrow> closed S"
  1278 by (induct set: finite, simp_all)
  1279 
  1280 text {* T2 spaces are also known as Hausdorff spaces. *}
  1281 
  1282 class t2_space = topological_space +
  1283   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1284 
  1285 instance t2_space \<subseteq> t1_space
  1286 proof qed (fast dest: hausdorff)
  1287 
  1288 lemma (in linorder) less_separate:
  1289   assumes "x < y"
  1290   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
  1291 proof cases
  1292   assume "\<exists>z. x < z \<and> z < y"
  1293   then guess z ..
  1294   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
  1295     by auto
  1296   then show ?thesis by blast
  1297 next
  1298   assume "\<not> (\<exists>z. x < z \<and> z < y)"
  1299   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
  1300     by auto
  1301   then show ?thesis by blast
  1302 qed
  1303 
  1304 instance linorder_topology \<subseteq> t2_space
  1305 proof
  1306   fix x y :: 'a
  1307   from less_separate[of x y] less_separate[of y x]
  1308   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1309     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
  1310 qed
  1311 
  1312 instance metric_space \<subseteq> t2_space
  1313 proof
  1314   fix x y :: "'a::metric_space"
  1315   assume xy: "x \<noteq> y"
  1316   let ?U = "{y'. dist x y' < dist x y / 2}"
  1317   let ?V = "{x'. dist y x' < dist x y / 2}"
  1318   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
  1319                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
  1320   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
  1321     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
  1322     using open_ball[of _ "dist x y / 2"] by auto
  1323   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1324     by blast
  1325 qed
  1326 
  1327 lemma separation_t2:
  1328   fixes x y :: "'a::t2_space"
  1329   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
  1330   using hausdorff[of x y] by blast
  1331 
  1332 lemma separation_t0:
  1333   fixes x y :: "'a::t0_space"
  1334   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
  1335   using t0_space[of x y] by blast
  1336 
  1337 text {* A perfect space is a topological space with no isolated points. *}
  1338 
  1339 class perfect_space = topological_space +
  1340   assumes not_open_singleton: "\<not> open {x}"
  1341 
  1342 instance real_normed_algebra_1 \<subseteq> perfect_space
  1343 proof
  1344   fix x::'a
  1345   show "\<not> open {x}"
  1346     unfolding open_dist dist_norm
  1347     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1348 qed
  1349 
  1350 end