(* Title: Pure/Isar/code.ML
Author: Florian Haftmann, TU Muenchen
Abstract executable ingredients of theory. Management of data
dependent on executable ingredients as synchronized cache; purged
on any change of underlying executable ingredients.
*)
signature CODE =
sig
(*constants*)
val check_const: theory -> term -> string
val read_bare_const: theory -> string -> string * typ
val read_const: theory -> string -> string
val string_of_const: theory -> string -> string
val cert_signature: theory -> typ -> typ
val read_signature: theory -> string -> typ
val const_typ: theory -> string -> typ
val subst_signatures: theory -> term -> term
val args_number: theory -> string -> int
(*constructor sets*)
val constrset_of_consts: theory -> (string * typ) list
-> string * ((string * sort) list * (string * typ list) list)
val abstype_cert: theory -> string * typ -> string
-> string * ((string * sort) list * ((string * typ) * (string * term)))
(*code equations and certificates*)
val mk_eqn: theory -> thm * bool -> thm * bool
val mk_eqn_warning: theory -> thm -> (thm * bool) option
val mk_eqn_liberal: theory -> thm -> (thm * bool) option
val assert_eqn: theory -> thm * bool -> thm * bool
val const_typ_eqn: theory -> thm -> string * typ
val expand_eta: theory -> int -> thm -> thm
type cert
val empty_cert: theory -> string -> cert
val cert_of_eqns: theory -> string -> (thm * bool) list -> cert
val constrain_cert: theory -> sort list -> cert -> cert
val typargs_deps_of_cert: theory -> cert -> (string * sort) list * (string * typ list) list
val equations_of_cert: theory -> cert ->
((string * sort) list * typ) * ((string option * (term list * term)) * (thm option * bool)) list
val bare_thms_of_cert: theory -> cert -> thm list
val pretty_cert: theory -> cert -> Pretty.T list
(*executable code*)
val add_type: string -> theory -> theory
val add_type_cmd: string -> theory -> theory
val add_signature: string * typ -> theory -> theory
val add_signature_cmd: string * string -> theory -> theory
val add_datatype: (string * typ) list -> theory -> theory
val add_datatype_cmd: string list -> theory -> theory
val datatype_interpretation:
(string * ((string * sort) list * (string * typ list) list)
-> theory -> theory) -> theory -> theory
val add_abstype: string * typ -> string * typ -> theory -> Proof.state
val add_abstype_cmd: string -> string -> theory -> Proof.state
val abstype_interpretation:
(string * ((string * sort) list * ((string * typ) * (string * thm)))
-> theory -> theory) -> theory -> theory
val add_eqn: thm -> theory -> theory
val add_nbe_eqn: thm -> theory -> theory
val add_default_eqn: thm -> theory -> theory
val add_default_eqn_attribute: attribute
val add_default_eqn_attrib: Attrib.src
val del_eqn: thm -> theory -> theory
val del_eqns: string -> theory -> theory
val add_case: thm -> theory -> theory
val add_undefined: string -> theory -> theory
val get_type: theory -> string -> ((string * sort) list * (string * typ list) list)
val get_type_of_constr_or_abstr: theory -> string -> (string * bool) option
val is_constr: theory -> string -> bool
val is_abstr: theory -> string -> bool
val get_cert: theory -> ((thm * bool) list -> (thm * bool) list) -> string -> cert
val get_case_scheme: theory -> string -> (int * (int * string list)) option
val undefineds: theory -> string list
val print_codesetup: theory -> unit
(*infrastructure*)
val set_code_target_attr: (string -> thm -> theory -> theory) -> theory -> theory
val purge_data: theory -> theory
end;
signature CODE_DATA_ARGS =
sig
type T
val empty: T
end;
signature CODE_DATA =
sig
type T
val change: theory -> (T -> T) -> T
val change_yield: theory -> (T -> 'a * T) -> 'a * T
end;
signature PRIVATE_CODE =
sig
include CODE
val declare_data: Object.T -> serial
val change_data: serial * ('a -> Object.T) * (Object.T -> 'a)
-> theory -> ('a -> 'a) -> 'a
val change_yield_data: serial * ('a -> Object.T) * (Object.T -> 'a)
-> theory -> ('a -> 'b * 'a) -> 'b * 'a
end;
structure Code : PRIVATE_CODE =
struct
(** auxiliary **)
(* printing *)
fun string_of_typ thy = setmp_CRITICAL show_sorts true (Syntax.string_of_typ_global thy);
fun string_of_const thy c = case AxClass.inst_of_param thy c
of SOME (c, tyco) => Sign.extern_const thy c ^ " " ^ enclose "[" "]" (Sign.extern_type thy tyco)
| NONE => Sign.extern_const thy c;
(* constants *)
fun typ_equiv tys = Type.raw_instance tys andalso Type.raw_instance (swap tys);
fun check_bare_const thy t = case try dest_Const t
of SOME c_ty => c_ty
| NONE => error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
fun check_const thy = AxClass.unoverload_const thy o check_bare_const thy;
fun read_bare_const thy = check_bare_const thy o Syntax.read_term_global thy;
fun read_const thy = AxClass.unoverload_const thy o read_bare_const thy;
(** data store **)
(* datatypes *)
datatype typ_spec = Constructors of (string * typ list) list
| Abstractor of (string * typ) * (string * thm);
fun constructors_of (Constructors cos) = (cos, false)
| constructors_of (Abstractor ((co, ty), _)) = ([(co, [ty])], true);
(* functions *)
datatype fun_spec = Default of (thm * bool) list
| Eqns of (thm * bool) list
| Proj of term * string
| Abstr of thm * string;
val empty_fun_spec = Default [];
fun is_default (Default _) = true
| is_default _ = false;
fun associated_abstype (Abstr (_, tyco)) = SOME tyco
| associated_abstype _ = NONE;
(* executable code data *)
datatype spec = Spec of {
history_concluded: bool,
signatures: int Symtab.table * typ Symtab.table,
functions: ((bool * fun_spec) * (serial * fun_spec) list) Symtab.table
(*with explicit history*),
types: ((serial * ((string * sort) list * typ_spec)) list) Symtab.table
(*with explicit history*),
cases: (int * (int * string list)) Symtab.table * unit Symtab.table
};
fun make_spec (history_concluded, ((signatures, functions), (types, cases))) =
Spec { history_concluded = history_concluded,
signatures = signatures, functions = functions, types = types, cases = cases };
fun map_spec f (Spec { history_concluded = history_concluded, signatures = signatures,
functions = functions, types = types, cases = cases }) =
make_spec (f (history_concluded, ((signatures, functions), (types, cases))));
fun merge_spec (Spec { history_concluded = _, signatures = (tycos1, sigs1), functions = functions1,
types = types1, cases = (cases1, undefs1) },
Spec { history_concluded = _, signatures = (tycos2, sigs2), functions = functions2,
types = types2, cases = (cases2, undefs2) }) =
let
val signatures = (Symtab.merge (op =) (tycos1, tycos2),
Symtab.merge typ_equiv (sigs1, sigs2));
fun merge_functions ((_, history1), (_, history2)) =
let
val raw_history = AList.merge (op = : serial * serial -> bool)
(K true) (history1, history2);
val filtered_history = filter_out (is_default o snd) raw_history;
val history = if null filtered_history
then raw_history else filtered_history;
in ((false, (snd o hd) history), history) end;
val functions = Symtab.join (K merge_functions) (functions1, functions2);
val types = Symtab.join (K (AList.merge (op =) (K true))) (types1, types2);
val cases = (Symtab.merge (K true) (cases1, cases2),
Symtab.merge (K true) (undefs1, undefs2));
in make_spec (false, ((signatures, functions), (types, cases))) end;
fun history_concluded (Spec { history_concluded, ... }) = history_concluded;
fun the_signatures (Spec { signatures, ... }) = signatures;
fun the_functions (Spec { functions, ... }) = functions;
fun the_types (Spec { types, ... }) = types;
fun the_cases (Spec { cases, ... }) = cases;
val map_history_concluded = map_spec o apfst;
val map_signatures = map_spec o apsnd o apfst o apfst;
val map_functions = map_spec o apsnd o apfst o apsnd;
val map_typs = map_spec o apsnd o apsnd o apfst;
val map_cases = map_spec o apsnd o apsnd o apsnd;
(* data slots dependent on executable code *)
(*private copy avoids potential conflict of table exceptions*)
structure Datatab = Table(type key = int val ord = int_ord);
local
type kind = { empty: Object.T };
val kinds = Unsynchronized.ref (Datatab.empty: kind Datatab.table);
fun invoke f k = case Datatab.lookup (! kinds) k
of SOME kind => f kind
| NONE => sys_error "Invalid code data identifier";
in
fun declare_data empty =
let
val k = serial ();
val kind = { empty = empty };
val _ = CRITICAL (fn () => Unsynchronized.change kinds (Datatab.update (k, kind)));
in k end;
fun invoke_init k = invoke (fn kind => #empty kind) k;
end; (*local*)
(* theory store *)
local
type data = Object.T Datatab.table;
fun empty_dataref () = Synchronized.var "code data" (NONE : (data * theory_ref) option);
structure Code_Data = Theory_Data
(
type T = spec * (data * theory_ref) option Synchronized.var;
val empty = (make_spec (false, (((Symtab.empty, Symtab.empty), Symtab.empty),
(Symtab.empty, (Symtab.empty, Symtab.empty)))), empty_dataref ());
val extend = I
fun merge ((spec1, _), (spec2, _)) =
(merge_spec (spec1, spec2), empty_dataref ());
);
in
(* access to executable code *)
val the_exec = fst o Code_Data.get;
fun map_exec_purge f = Code_Data.map (fn (exec, _) => (f exec, empty_dataref ()));
val purge_data = (Code_Data.map o apsnd) (fn _ => empty_dataref ());
fun change_fun_spec delete c f = (map_exec_purge o map_functions
o (if delete then Symtab.map_entry c else Symtab.map_default (c, ((false, empty_fun_spec), [])))
o apfst) (fn (_, spec) => (true, f spec));
(* tackling equation history *)
fun continue_history thy = if (history_concluded o the_exec) thy
then thy
|> (Code_Data.map o apfst o map_history_concluded) (K false)
|> SOME
else NONE;
fun conclude_history thy = if (history_concluded o the_exec) thy
then NONE
else thy
|> (Code_Data.map o apfst)
((map_functions o Symtab.map) (fn ((changed, current), history) =>
((false, current),
if changed then (serial (), current) :: history else history))
#> map_history_concluded (K true))
|> SOME;
val _ = Context.>> (Context.map_theory (Theory.at_begin continue_history #> Theory.at_end conclude_history));
(* access to data dependent on abstract executable code *)
fun change_yield_data (kind, mk, dest) theory f =
let
val dataref = (snd o Code_Data.get) theory;
val (datatab, thy_ref) = case Synchronized.value dataref
of SOME (datatab, thy_ref) => if Theory.eq_thy (theory, Theory.deref thy_ref)
then (datatab, thy_ref)
else (Datatab.empty, Theory.check_thy theory)
| NONE => (Datatab.empty, Theory.check_thy theory)
val data = case Datatab.lookup datatab kind
of SOME data => data
| NONE => invoke_init kind;
val result as (x, data') = f (dest data);
val _ = Synchronized.change dataref
((K o SOME) (Datatab.update (kind, mk data') datatab, thy_ref));
in result end;
fun change_data ops theory f = change_yield_data ops theory (f #> pair ()) |> snd;
end; (*local*)
(** foundation **)
(* constants *)
fun arity_number thy tyco = case Symtab.lookup ((fst o the_signatures o the_exec) thy) tyco
of SOME n => n
| NONE => Sign.arity_number thy tyco;
fun build_tsig thy =
let
val (tycos, _) = (the_signatures o the_exec) thy;
val decls = (#types o Type.rep_tsig o Sign.tsig_of) thy
|> snd
|> Symtab.fold (fn (tyco, n) =>
Symtab.update (tyco, Type.LogicalType n)) tycos;
in
Type.empty_tsig
|> Symtab.fold (fn (tyco, Type.LogicalType n) => Type.add_type Name_Space.default_naming
(Binding.qualified_name tyco, n) | _ => I) decls
end;
fun cert_signature thy = Logic.varifyT o Type.cert_typ (build_tsig thy) o Type.no_tvars;
fun read_signature thy = cert_signature thy o Type.strip_sorts
o Syntax.parse_typ (ProofContext.init thy);
fun expand_signature thy = Type.cert_typ_mode Type.mode_syntax (Sign.tsig_of thy);
fun lookup_typ thy = Symtab.lookup ((snd o the_signatures o the_exec) thy);
fun const_typ thy c = case lookup_typ thy c
of SOME ty => ty
| NONE => (Type.strip_sorts o Sign.the_const_type thy) c;
fun subst_signature thy c ty =
let
fun mk_subst (Type (tyco, tys1)) (ty2 as Type (tyco2, tys2)) =
fold2 mk_subst tys1 tys2
| mk_subst ty (TVar (v, sort)) = Vartab.update (v, ([], ty))
in case lookup_typ thy c
of SOME ty' => Envir.subst_type (mk_subst ty (expand_signature thy ty') Vartab.empty) ty'
| NONE => ty
end;
fun subst_signatures thy = map_aterms (fn Const (c, ty) => Const (c, subst_signature thy c ty) | t => t);
fun args_number thy = length o fst o strip_type o const_typ thy;
(* datatypes *)
fun no_constr thy s (c, ty) = error ("Not a datatype constructor:\n" ^ string_of_const thy c
^ " :: " ^ string_of_typ thy ty ^ "\n" ^ enclose "(" ")" s);
fun ty_sorts thy (c, raw_ty) =
let
val _ = Thm.cterm_of thy (Const (c, raw_ty));
val ty = subst_signature thy c raw_ty;
val ty_decl = (Logic.unvarifyT o const_typ thy) c;
fun last_typ c_ty ty =
let
val tfrees = Term.add_tfreesT ty [];
val (tyco, vs) = ((apsnd o map) (dest_TFree) o dest_Type o snd o strip_type) ty
handle TYPE _ => no_constr thy "bad type" c_ty
val _ = if has_duplicates (eq_fst (op =)) vs
then no_constr thy "duplicate type variables in datatype" c_ty else ();
val _ = if length tfrees <> length vs
then no_constr thy "type variables missing in datatype" c_ty else ();
in (tyco, vs) end;
val (tyco, _) = last_typ (c, ty) ty_decl;
val (_, vs) = last_typ (c, ty) ty;
in ((tyco, map snd vs), (c, (map fst vs, ty))) end;
fun constrset_of_consts thy cs =
let
val _ = map (fn (c, _) => if (is_some o AxClass.class_of_param thy) c
then error ("Is a class parameter: " ^ string_of_const thy c) else ()) cs;
fun add ((tyco', sorts'), c) ((tyco, sorts), cs) =
let
val _ = if (tyco' : string) <> tyco
then error "Different type constructors in constructor set"
else ();
val sorts'' = map2 (curry (Sorts.inter_sort (Sign.classes_of thy))) sorts' sorts
in ((tyco, sorts), c :: cs) end;
fun inst vs' (c, (vs, ty)) =
let
val the_v = the o AList.lookup (op =) (vs ~~ vs');
val ty' = map_atyps (fn TFree (v, _) => TFree (the_v v)) ty;
in (c, (fst o strip_type) ty') end;
val c' :: cs' = map (ty_sorts thy) cs;
val ((tyco, sorts), cs'') = fold add cs' (apsnd single c');
val vs = Name.names Name.context Name.aT sorts;
val cs''' = map (inst vs) cs'';
in (tyco, (vs, rev cs''')) end;
fun abstype_cert thy abs_ty rep =
let
val _ = pairself (fn c => if (is_some o AxClass.class_of_param thy) c
then error ("Is a class parameter: " ^ string_of_const thy c) else ()) (fst abs_ty, rep);
val ((tyco, sorts), (abs, (vs, ty'))) = ty_sorts thy abs_ty;
val (ty, ty_abs) = case ty'
of Type ("fun", [ty, ty_abs]) => (ty, ty_abs)
| _ => error ("Not a datatype abstractor:\n" ^ string_of_const thy abs
^ " :: " ^ string_of_typ thy ty');
val _ = Thm.cterm_of thy (Const (rep, ty_abs --> ty)) handle CTERM _ =>
error ("Not a projection:\n" ^ string_of_const thy rep);
val cert = Logic.mk_equals (Const (abs, ty --> ty_abs) $ (Const (rep, ty_abs --> ty)
$ Free ("x", ty_abs)), Free ("x", ty_abs));
in (tyco, (vs ~~ sorts, ((fst abs_ty, ty), (rep, cert)))) end;
fun get_type_entry thy tyco = case these (Symtab.lookup ((the_types o the_exec) thy) tyco)
of (_, entry) :: _ => SOME entry
| _ => NONE;
fun get_type_spec thy tyco = case get_type_entry thy tyco
of SOME (vs, spec) => apfst (pair vs) (constructors_of spec)
| NONE => arity_number thy tyco
|> Name.invents Name.context Name.aT
|> map (rpair [])
|> rpair []
|> rpair false;
fun get_abstype_spec thy tyco = case get_type_entry thy tyco
of SOME (vs, Abstractor spec) => (vs, spec)
| NONE => error ("Not an abstract type: " ^ tyco);
fun get_type thy = fst o get_type_spec thy;
fun get_type_of_constr_or_abstr thy c =
case (snd o strip_type o const_typ thy) c
of Type (tyco, _) => let val ((vs, cos), abstract) = get_type_spec thy tyco
in if member (op =) (map fst cos) c then SOME (tyco, abstract) else NONE end
| _ => NONE;
fun is_constr thy c = case get_type_of_constr_or_abstr thy c
of SOME (_, false) => true
| _ => false;
fun is_abstr thy c = case get_type_of_constr_or_abstr thy c
of SOME (_, true) => true
| _ => false;
(* bare code equations *)
(* convention for variables:
?x ?'a for free-floating theorems (e.g. in the data store)
?x 'a for certificates
x 'a for final representation of equations
*)
exception BAD_THM of string;
fun bad_thm msg = raise BAD_THM msg;
fun error_thm f thm = f thm handle BAD_THM msg => error msg;
fun warning_thm f thm = SOME (f thm) handle BAD_THM msg => (warning msg; NONE)
fun try_thm f thm = SOME (f thm) handle BAD_THM _ => NONE;
fun is_linear thm =
let val (_, args) = (strip_comb o fst o Logic.dest_equals o Thm.plain_prop_of) thm
in not (has_duplicates (op =) ((fold o fold_aterms)
(fn Var (v, _) => cons v | _ => I) args [])) end;
fun check_eqn thy { allow_nonlinear, allow_consts, allow_pats } thm (lhs, rhs) =
let
fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
fun vars_of t = fold_aterms (fn Var (v, _) => insert (op =) v
| Free _ => bad "Illegal free variable in equation"
| _ => I) t [];
fun tvars_of t = fold_term_types (fn _ =>
fold_atyps (fn TVar (v, _) => insert (op =) v
| TFree _ => bad "Illegal free type variable in equation")) t [];
val lhs_vs = vars_of lhs;
val rhs_vs = vars_of rhs;
val lhs_tvs = tvars_of lhs;
val rhs_tvs = tvars_of rhs;
val _ = if null (subtract (op =) lhs_vs rhs_vs)
then ()
else bad "Free variables on right hand side of equation";
val _ = if null (subtract (op =) lhs_tvs rhs_tvs)
then ()
else bad "Free type variables on right hand side of equation";
val (head, args) = strip_comb lhs;
val (c, ty) = case head
of Const (c_ty as (_, ty)) => (AxClass.unoverload_const thy c_ty, ty)
| _ => bad "Equation not headed by constant";
fun check _ (Abs _) = bad "Abstraction on left hand side of equation"
| check 0 (Var _) = ()
| check _ (Var _) = bad "Variable with application on left hand side of equation"
| check n (t1 $ t2) = (check (n+1) t1; check 0 t2)
| check n (Const (c_ty as (c, ty))) =
if allow_pats then let
val c' = AxClass.unoverload_const thy c_ty
in if n = (length o fst o strip_type o subst_signature thy c') ty
then if allow_consts orelse is_constr thy c'
then ()
else bad (quote c ^ " is not a constructor, on left hand side of equation")
else bad ("Partially applied constant " ^ quote c ^ " on left hand side of equation")
end else bad ("Pattern not allowed, but constant " ^ quote c ^ " encountered on left hand side")
val _ = map (check 0) args;
val _ = if allow_nonlinear orelse is_linear thm then ()
else bad "Duplicate variables on left hand side of equation";
val _ = if (is_none o AxClass.class_of_param thy) c then ()
else bad "Overloaded constant as head in equation";
val _ = if not (is_constr thy c) then ()
else bad "Constructor as head in equation";
val _ = if not (is_abstr thy c) then ()
else bad "Abstractor as head in equation";
val ty_decl = Sign.the_const_type thy c;
val _ = if Sign.typ_equiv thy (Type.strip_sorts ty_decl, Type.strip_sorts ty)
then () else bad_thm ("Type\n" ^ string_of_typ thy ty
^ "\nof equation\n"
^ Display.string_of_thm_global thy thm
^ "\nis incompatible with declared function type\n"
^ string_of_typ thy ty_decl)
in () end;
fun gen_assert_eqn thy check_patterns (thm, proper) =
let
fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
val (lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm
handle TERM _ => bad "Not an equation"
| THM _ => bad "Not a proper equation";
val _ = check_eqn thy { allow_nonlinear = not proper,
allow_consts = not (proper andalso check_patterns), allow_pats = true } thm (lhs, rhs);
in (thm, proper) end;
fun assert_abs_eqn thy some_tyco thm =
let
fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
val (full_lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm
handle TERM _ => bad "Not an equation"
| THM _ => bad "Not a proper equation";
val (rep, lhs) = dest_comb full_lhs
handle TERM _ => bad "Not an abstract equation";
val tyco = (fst o dest_Type o domain_type o snd o dest_Const) rep
handle TERM _ => bad "Not an abstract equation";
val _ = case some_tyco of SOME tyco' => if tyco = tyco' then ()
else bad ("Abstract type mismatch:" ^ quote tyco ^ " vs. " ^ quote tyco')
| NONE => ();
val (_, (_, (rep', _))) = get_abstype_spec thy tyco;
val rep_const = (fst o dest_Const) rep;
val _ = if rep_const = rep' then ()
else bad ("Projection mismatch: " ^ quote rep_const ^ " vs. " ^ quote rep');
val _ = check_eqn thy { allow_nonlinear = false,
allow_consts = false, allow_pats = false } thm (lhs, rhs);
in (thm, tyco) end;
fun assert_eqn thy = error_thm (gen_assert_eqn thy true);
fun meta_rewrite thy = LocalDefs.meta_rewrite_rule (ProofContext.init thy);
fun mk_eqn thy = error_thm (gen_assert_eqn thy false) o
apfst (meta_rewrite thy);
fun mk_eqn_warning thy = Option.map (fn (thm, _) => (thm, is_linear thm))
o warning_thm (gen_assert_eqn thy false) o rpair false o meta_rewrite thy;
fun mk_eqn_liberal thy = Option.map (fn (thm, _) => (thm, is_linear thm))
o try_thm (gen_assert_eqn thy false) o rpair false o meta_rewrite thy;
fun mk_abs_eqn thy = error_thm (assert_abs_eqn thy NONE) o meta_rewrite thy;
val head_eqn = dest_Const o fst o strip_comb o fst o Logic.dest_equals o Thm.plain_prop_of;
fun const_typ_eqn thy thm =
let
val (c, ty) = head_eqn thm;
val c' = AxClass.unoverload_const thy (c, ty);
(*permissive wrt. to overloaded constants!*)
in (c', ty) end;
fun const_eqn thy = fst o const_typ_eqn thy;
fun const_abs_eqn thy = AxClass.unoverload_const thy o dest_Const o fst o strip_comb o snd
o dest_comb o fst o Logic.dest_equals o Thm.plain_prop_of;
fun logical_typscheme thy (c, ty) =
(map dest_TFree (Sign.const_typargs thy (c, ty)), Type.strip_sorts ty);
fun typscheme thy (c, ty) = logical_typscheme thy (c, subst_signature thy c ty);
fun mk_proj tyco vs ty abs rep =
let
val ty_abs = Type (tyco, map TFree vs);
val xarg = Var (("x", 0), ty);
in Logic.mk_equals (Const (rep, ty_abs --> ty) $ (Const (abs, ty --> ty_abs) $ xarg), xarg) end;
(* technical transformations of code equations *)
fun expand_eta thy k thm =
let
val (lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm;
val (_, args) = strip_comb lhs;
val l = if k = ~1
then (length o fst o strip_abs) rhs
else Int.max (0, k - length args);
val (raw_vars, _) = Term.strip_abs_eta l rhs;
val vars = burrow_fst (Name.variant_list (map (fst o fst) (Term.add_vars lhs [])))
raw_vars;
fun expand (v, ty) thm = Drule.fun_cong_rule thm
(Thm.cterm_of thy (Var ((v, 0), ty)));
in
thm
|> fold expand vars
|> Conv.fconv_rule Drule.beta_eta_conversion
end;
fun same_arity thy thms =
let
val num_args_of = length o snd o strip_comb o fst o Logic.dest_equals;
val k = fold (Integer.max o num_args_of o Thm.prop_of) thms 0;
in map (expand_eta thy k) thms end;
fun mk_desymbolization pre post mk vs =
let
val names = map (pre o fst o fst) vs
|> map (Name.desymbolize false)
|> Name.variant_list []
|> map post;
in map_filter (fn (((v, i), x), v') =>
if v = v' andalso i = 0 then NONE
else SOME (((v, i), x), mk ((v', 0), x))) (vs ~~ names)
end;
fun desymbolize_tvars thy thms =
let
val tvs = fold (Term.add_tvars o Thm.prop_of) thms [];
val tvar_subst = mk_desymbolization (unprefix "'") (prefix "'") TVar tvs;
in map (Thm.certify_instantiate (tvar_subst, [])) thms end;
fun desymbolize_vars thy thm =
let
val vs = Term.add_vars (Thm.prop_of thm) [];
val var_subst = mk_desymbolization I I Var vs;
in Thm.certify_instantiate ([], var_subst) thm end;
fun canonize_thms thy = desymbolize_tvars thy #> same_arity thy #> map (desymbolize_vars thy);
(* code equation certificates *)
fun build_head thy (c, ty) =
Thm.cterm_of thy (Logic.mk_equals (Free ("HEAD", ty), Const (c, ty)));
fun get_head thy cert_thm =
let
val [head] = (#hyps o Thm.crep_thm) cert_thm;
val (_, Const (c, ty)) = (Logic.dest_equals o Thm.term_of) head;
in (typscheme thy (c, ty), head) end;
fun typscheme_projection thy =
typscheme thy o dest_Const o fst o dest_comb o fst o Logic.dest_equals;
fun typscheme_abs thy =
typscheme thy o dest_Const o fst o strip_comb o snd o dest_comb o fst o Logic.dest_equals o Thm.prop_of;
fun constrain_thm thy vs sorts thm =
let
val mapping = map2 (fn (v, sort) => fn sort' =>
(v, Sorts.inter_sort (Sign.classes_of thy) (sort, sort'))) vs sorts;
val inst = map2 (fn (v, sort) => fn (_, sort') =>
(((v, 0), sort), TFree (v, sort'))) vs mapping;
val subst = (map_types o map_atyps)
(fn TFree (v, _) => TFree (v, the (AList.lookup (op =) mapping v)));
in
thm
|> Thm.varifyT
|> Thm.certify_instantiate (inst, [])
|> pair subst
end;
fun concretify_abs thy tyco abs_thm =
let
val (vs, ((c, _), (_, cert))) = get_abstype_spec thy tyco;
val lhs = (fst o Logic.dest_equals o Thm.prop_of) abs_thm
val ty = fastype_of lhs;
val ty_abs = (fastype_of o snd o dest_comb) lhs;
val abs = Thm.cterm_of thy (Const (c, ty --> ty_abs));
val raw_concrete_thm = Drule.transitive_thm OF [Thm.symmetric cert, Thm.combination (Thm.reflexive abs) abs_thm];
in (c, (Thm.varifyT o zero_var_indexes) raw_concrete_thm) end;
fun add_rhss_of_eqn thy t =
let
val (args, rhs) = (apfst (snd o strip_comb) o Logic.dest_equals o subst_signatures thy) t;
fun add_const (Const (c, ty)) = insert (op =) (c, Sign.const_typargs thy (c, ty))
| add_const _ = I
in fold_aterms add_const t end;
fun dest_eqn thy = apfst (snd o strip_comb) o Logic.dest_equals o subst_signatures thy o Logic.unvarify;
abstype cert = Equations of thm * bool list
| Projection of term * string
| Abstract of thm * string
with
fun empty_cert thy c =
let
val raw_ty = const_typ thy c;
val tvars = Term.add_tvar_namesT raw_ty [];
val tvars' = case AxClass.class_of_param thy c
of SOME class => [TFree (Name.aT, [class])]
| NONE => Name.invent_list [] Name.aT (length tvars)
|> map (fn v => TFree (v, []));
val ty = typ_subst_TVars (tvars ~~ tvars') raw_ty;
val chead = build_head thy (c, ty);
in Equations (Thm.weaken chead Drule.dummy_thm, []) end;
fun cert_of_eqns thy c [] = empty_cert thy c
| cert_of_eqns thy c raw_eqns =
let
val eqns = burrow_fst (canonize_thms thy) raw_eqns;
val _ = map (assert_eqn thy) eqns;
val (thms, propers) = split_list eqns;
val _ = map (fn thm => if c = const_eqn thy thm then ()
else error ("Wrong head of code equation,\nexpected constant "
^ string_of_const thy c ^ "\n" ^ Display.string_of_thm_global thy thm)) thms;
fun tvars_of T = rev (Term.add_tvarsT T []);
val vss = map (tvars_of o snd o head_eqn) thms;
fun inter_sorts vs =
fold (curry (Sorts.inter_sort (Sign.classes_of thy)) o snd) vs [];
val sorts = map_transpose inter_sorts vss;
val vts = Name.names Name.context Name.aT sorts;
val thms as thm :: _ =
map2 (fn vs => Thm.certify_instantiate (vs ~~ map TFree vts, [])) vss thms;
val head_thm = Thm.symmetric (Thm.assume (build_head thy (head_eqn (hd thms))));
fun head_conv ct = if can Thm.dest_comb ct
then Conv.fun_conv head_conv ct
else Conv.rewr_conv head_thm ct;
val rewrite_head = Conv.fconv_rule (Conv.arg1_conv head_conv);
val cert_thm = Conjunction.intr_balanced (map rewrite_head thms);
in Equations (cert_thm, propers) end;
fun cert_of_proj thy c tyco =
let
val (vs, ((abs, ty), (rep, cert))) = get_abstype_spec thy tyco;
val _ = if c = rep then () else
error ("Wrong head of projection,\nexpected constant " ^ string_of_const thy rep);
in Projection (mk_proj tyco vs ty abs rep, tyco) end;
fun cert_of_abs thy tyco c raw_abs_thm =
let
val abs_thm = singleton (canonize_thms thy) raw_abs_thm;
val _ = assert_abs_eqn thy (SOME tyco) abs_thm;
val _ = if c = const_abs_eqn thy abs_thm then ()
else error ("Wrong head of abstract code equation,\nexpected constant "
^ string_of_const thy c ^ "\n" ^ Display.string_of_thm_global thy abs_thm);
in Abstract (Thm.freezeT abs_thm, tyco) end;
fun constrain_cert thy sorts (Equations (cert_thm, propers)) =
let
val ((vs, _), head) = get_head thy cert_thm;
val (subst, cert_thm') = cert_thm
|> Thm.implies_intr head
|> constrain_thm thy vs sorts;
val head' = Thm.term_of head
|> subst
|> Thm.cterm_of thy;
val cert_thm'' = cert_thm'
|> Thm.elim_implies (Thm.assume head');
in Equations (cert_thm'', propers) end
| constrain_cert thy _ (cert as Projection _) =
cert
| constrain_cert thy sorts (Abstract (abs_thm, tyco)) =
Abstract (snd (constrain_thm thy (fst (typscheme_abs thy abs_thm)) sorts abs_thm), tyco);
fun typscheme_of_cert thy (Equations (cert_thm, _)) =
fst (get_head thy cert_thm)
| typscheme_of_cert thy (Projection (proj, _)) =
typscheme_projection thy proj
| typscheme_of_cert thy (Abstract (abs_thm, _)) =
typscheme_abs thy abs_thm;
fun typargs_deps_of_cert thy (Equations (cert_thm, propers)) =
let
val vs = (fst o fst) (get_head thy cert_thm);
val equations = if null propers then [] else
Thm.prop_of cert_thm
|> Logic.dest_conjunction_balanced (length propers);
in (vs, fold (add_rhss_of_eqn thy) equations []) end
| typargs_deps_of_cert thy (Projection (t, tyco)) =
(fst (typscheme_projection thy t), add_rhss_of_eqn thy t [])
| typargs_deps_of_cert thy (Abstract (abs_thm, tyco)) =
let
val vs = fst (typscheme_abs thy abs_thm);
val (_, concrete_thm) = concretify_abs thy tyco abs_thm;
in (vs, add_rhss_of_eqn thy (Thm.prop_of abs_thm) []) end;
fun equations_of_cert thy (cert as Equations (cert_thm, propers)) =
let
val tyscm = typscheme_of_cert thy cert;
val thms = if null propers then [] else
cert_thm
|> LocalDefs.expand [snd (get_head thy cert_thm)]
|> Thm.varifyT
|> Conjunction.elim_balanced (length propers);
in (tyscm, map (pair NONE o dest_eqn thy o Thm.prop_of) thms ~~ (map SOME thms ~~ propers)) end
| equations_of_cert thy (Projection (t, tyco)) =
let
val (_, ((abs, _), _)) = get_abstype_spec thy tyco;
val tyscm = typscheme_projection thy t;
val t' = map_types Logic.varifyT t;
in (tyscm, [((SOME abs, dest_eqn thy t'), (NONE, true))]) end
| equations_of_cert thy (Abstract (abs_thm, tyco)) =
let
val tyscm = typscheme_abs thy abs_thm;
val (abs, concrete_thm) = concretify_abs thy tyco abs_thm;
val _ = fold_aterms (fn Const (c, _) => if c = abs
then error ("Abstraction violation in abstract code equation\n" ^ Display.string_of_thm_global thy abs_thm)
else I | _ => I) (Thm.prop_of abs_thm);
in (tyscm, [((SOME abs, dest_eqn thy (Thm.prop_of concrete_thm)), (SOME (Thm.varifyT abs_thm), true))]) end;
fun pretty_cert thy (cert as Equations _) =
(map_filter (Option.map (Display.pretty_thm_global thy o AxClass.overload thy) o fst o snd)
o snd o equations_of_cert thy) cert
| pretty_cert thy (Projection (t, _)) =
[Syntax.pretty_term_global thy (map_types Logic.varifyT t)]
| pretty_cert thy (Abstract (abs_thm, tyco)) =
[(Display.pretty_thm_global thy o AxClass.overload thy o Thm.varifyT) abs_thm];
fun bare_thms_of_cert thy (cert as Equations _) =
(map_filter (fn (_, (some_thm, proper)) => if proper then some_thm else NONE)
o snd o equations_of_cert thy) cert
| bare_thms_of_cert thy _ = [];
end;
(* code certificate access *)
fun retrieve_raw thy c =
Symtab.lookup ((the_functions o the_exec) thy) c
|> Option.map (snd o fst)
|> the_default (Default [])
fun get_cert thy f c = case retrieve_raw thy c
of Default eqns => eqns
|> (map o apfst) (Thm.transfer thy)
|> f
|> (map o apfst) (AxClass.unoverload thy)
|> cert_of_eqns thy c
| Eqns eqns => eqns
|> (map o apfst) (Thm.transfer thy)
|> f
|> (map o apfst) (AxClass.unoverload thy)
|> cert_of_eqns thy c
| Proj (_, tyco) =>
cert_of_proj thy c tyco
| Abstr (abs_thm, tyco) => abs_thm
|> Thm.transfer thy
|> AxClass.unoverload thy
|> cert_of_abs thy tyco c;
(* cases *)
fun case_certificate thm =
let
val ((head, raw_case_expr), cases) = (apfst Logic.dest_equals
o apsnd Logic.dest_conjunctions o Logic.dest_implies o Thm.plain_prop_of) thm;
val _ = case head of Free _ => true
| Var _ => true
| _ => raise TERM ("case_cert", []);
val ([(case_var, _)], case_expr) = Term.strip_abs_eta 1 raw_case_expr;
val (Const (case_const, _), raw_params) = strip_comb case_expr;
val n = find_index (fn Free (v, _) => v = case_var | _ => false) raw_params;
val _ = if n = ~1 then raise TERM ("case_cert", []) else ();
val params = map (fst o dest_Var) (nth_drop n raw_params);
fun dest_case t =
let
val (head' $ t_co, rhs) = Logic.dest_equals t;
val _ = if head' = head then () else raise TERM ("case_cert", []);
val (Const (co, _), args) = strip_comb t_co;
val (Var (param, _), args') = strip_comb rhs;
val _ = if args' = args then () else raise TERM ("case_cert", []);
in (param, co) end;
fun analyze_cases cases =
let
val co_list = fold (AList.update (op =) o dest_case) cases [];
in map (the o AList.lookup (op =) co_list) params end;
fun analyze_let t =
let
val (head' $ arg, Var (param', _) $ arg') = Logic.dest_equals t;
val _ = if head' = head then () else raise TERM ("case_cert", []);
val _ = if arg' = arg then () else raise TERM ("case_cert", []);
val _ = if [param'] = params then () else raise TERM ("case_cert", []);
in [] end;
fun analyze (cases as [let_case]) =
(analyze_cases cases handle Bind => analyze_let let_case)
| analyze cases = analyze_cases cases;
in (case_const, (n, analyze cases)) end;
fun case_cert thm = case_certificate thm
handle Bind => error "bad case certificate"
| TERM _ => error "bad case certificate";
fun get_case_scheme thy = Symtab.lookup ((fst o the_cases o the_exec) thy);
val undefineds = Symtab.keys o snd o the_cases o the_exec;
(* diagnostic *)
fun print_codesetup thy =
let
val ctxt = ProofContext.init thy;
val exec = the_exec thy;
fun pretty_equations const thms =
(Pretty.block o Pretty.fbreaks) (
Pretty.str (string_of_const thy const) :: map (Display.pretty_thm ctxt) thms
);
fun pretty_function (const, Default eqns) = pretty_equations const (map fst eqns)
| pretty_function (const, Eqns eqns) = pretty_equations const (map fst eqns)
| pretty_function (const, Proj (proj, _)) = Pretty.block
[Pretty.str (string_of_const thy const), Pretty.fbrk, Syntax.pretty_term ctxt proj]
| pretty_function (const, Abstr (thm, _)) = pretty_equations const [thm];
fun pretty_typ (tyco, vs) = Pretty.str
(string_of_typ thy (Type (tyco, map TFree vs)));
fun pretty_typspec (typ, (cos, abstract)) = if null cos
then pretty_typ typ
else (Pretty.block o Pretty.breaks) (
pretty_typ typ
:: Pretty.str "="
:: (if abstract then [Pretty.str "(abstract)"] else [])
@ separate (Pretty.str "|") (map (fn (c, []) => Pretty.str (string_of_const thy c)
| (c, tys) =>
(Pretty.block o Pretty.breaks)
(Pretty.str (string_of_const thy c)
:: Pretty.str "of"
:: map (Pretty.quote o Syntax.pretty_typ_global thy) tys)) cos)
);
fun pretty_case (const, (_, (_, []))) = Pretty.str (string_of_const thy const)
| pretty_case (const, (_, (_, cos))) = (Pretty.block o Pretty.breaks) [
Pretty.str (string_of_const thy const), Pretty.str "with",
(Pretty.block o Pretty.commas o map (Pretty.str o string_of_const thy)) cos];
val functions = the_functions exec
|> Symtab.dest
|> (map o apsnd) (snd o fst)
|> sort (string_ord o pairself fst);
val datatypes = the_types exec
|> Symtab.dest
|> map (fn (tyco, (_, (vs, spec)) :: _) =>
((tyco, vs), constructors_of spec))
|> sort (string_ord o pairself (fst o fst));
val cases = Symtab.dest ((fst o the_cases o the_exec) thy);
val undefineds = Symtab.keys ((snd o the_cases o the_exec) thy);
in
(Pretty.writeln o Pretty.chunks) [
Pretty.block (
Pretty.str "code equations:" :: Pretty.fbrk
:: (Pretty.fbreaks o map pretty_function) functions
),
Pretty.block (
Pretty.str "datatypes:" :: Pretty.fbrk
:: (Pretty.fbreaks o map pretty_typspec) datatypes
),
Pretty.block (
Pretty.str "cases:" :: Pretty.fbrk
:: (Pretty.fbreaks o map pretty_case) cases
),
Pretty.block (
Pretty.str "undefined:" :: Pretty.fbrk
:: (Pretty.commas o map (Pretty.str o string_of_const thy)) undefineds
)
]
end;
(** declaring executable ingredients **)
(* constant signatures *)
fun add_type tyco thy =
case Symtab.lookup ((snd o #types o Type.rep_tsig o Sign.tsig_of) thy) tyco
of SOME (Type.Abbreviation (vs, _, _)) =>
(map_exec_purge o map_signatures o apfst)
(Symtab.update (tyco, length vs)) thy
| _ => error ("No such type abbreviation: " ^ quote tyco);
fun add_type_cmd s thy = add_type (Sign.intern_type thy s) thy;
fun gen_add_signature prep_const prep_signature (raw_c, raw_ty) thy =
let
val c = prep_const thy raw_c;
val ty = prep_signature thy raw_ty;
val ty' = expand_signature thy ty;
val ty'' = Sign.the_const_type thy c;
val _ = if typ_equiv (ty', ty'') then () else
error ("Illegal constant signature: " ^ Syntax.string_of_typ_global thy ty);
in
thy
|> (map_exec_purge o map_signatures o apsnd) (Symtab.update (c, ty))
end;
val add_signature = gen_add_signature (K I) cert_signature;
val add_signature_cmd = gen_add_signature read_const read_signature;
(* code equations *)
fun gen_add_eqn default (raw_thm, proper) thy =
let
val thm = Thm.close_derivation raw_thm;
val c = const_eqn thy thm;
fun add_eqn' true (Default eqns) = Default (eqns @ [(thm, proper)])
| add_eqn' _ (Eqns eqns) =
let
val args_of = snd o strip_comb o map_types Type.strip_sorts
o fst o Logic.dest_equals o Thm.plain_prop_of;
val args = args_of thm;
val incr_idx = Logic.incr_indexes ([], Thm.maxidx_of thm + 1);
fun matches_args args' = length args <= length args' andalso
Pattern.matchess thy (args, (map incr_idx o take (length args)) args');
fun drop (thm', proper') = if (proper orelse not proper')
andalso matches_args (args_of thm') then
(warning ("Code generator: dropping redundant code equation\n" ^
Display.string_of_thm_global thy thm'); true)
else false;
in Eqns ((thm, proper) :: filter_out drop eqns) end
| add_eqn' false _ = Eqns [(thm, proper)];
in change_fun_spec false c (add_eqn' default) thy end;
fun add_eqn thm thy =
gen_add_eqn false (mk_eqn thy (thm, true)) thy;
fun add_warning_eqn thm thy =
case mk_eqn_warning thy thm
of SOME eqn => gen_add_eqn false eqn thy
| NONE => thy;
fun add_default_eqn thm thy =
case mk_eqn_liberal thy thm
of SOME eqn => gen_add_eqn true eqn thy
| NONE => thy;
fun add_nbe_eqn thm thy =
gen_add_eqn false (mk_eqn thy (thm, false)) thy;
val add_default_eqn_attribute = Thm.declaration_attribute
(fn thm => Context.mapping (add_default_eqn thm) I);
val add_default_eqn_attrib = Attrib.internal (K add_default_eqn_attribute);
fun add_abs_eqn raw_thm thy =
let
val (abs_thm, tyco) = (apfst Thm.close_derivation o mk_abs_eqn thy) raw_thm;
val c = const_abs_eqn thy abs_thm;
in change_fun_spec false c (K (Abstr (abs_thm, tyco))) thy end;
fun del_eqn thm thy = case mk_eqn_liberal thy thm
of SOME (thm, _) => let
fun del_eqn' (Default eqns) = empty_fun_spec
| del_eqn' (Eqns eqns) =
Eqns (filter_out (fn (thm', _) => Thm.eq_thm_prop (thm, thm')) eqns)
| del_eqn' spec = spec
in change_fun_spec true (const_eqn thy thm) del_eqn' thy end
| NONE => thy;
fun del_eqns c = change_fun_spec true c (K empty_fun_spec);
(* cases *)
fun add_case thm thy =
let
val (c, (k, case_pats)) = case_cert thm;
val _ = case filter_out (is_constr thy) case_pats
of [] => ()
| cs => error ("Non-constructor(s) in case certificate: " ^ commas (map quote cs));
val entry = (1 + Int.max (1, length case_pats), (k, case_pats))
in (map_exec_purge o map_cases o apfst) (Symtab.update (c, entry)) thy end;
fun add_undefined c thy =
(map_exec_purge o map_cases o apsnd) (Symtab.update (c, ())) thy;
(* types *)
fun register_type (tyco, vs_spec) thy =
let
val (old_constrs, some_old_proj) =
case these (Symtab.lookup ((the_types o the_exec) thy) tyco)
of (_, (_, Constructors cos)) :: _ => (map fst cos, NONE)
| (_, (_, Abstractor (_, (co, _)))) :: _ => ([], SOME co)
| [] => ([], NONE)
val outdated_funs = case some_old_proj
of NONE => []
| SOME old_proj => Symtab.fold
(fn (c, ((_, spec), _)) => if member (op =) (the_list (associated_abstype spec)) tyco
then insert (op =) c else I)
((the_functions o the_exec) thy) [old_proj];
fun drop_outdated_cases cases = fold Symtab.delete_safe
(Symtab.fold (fn (c, (_, (_, cos))) =>
if exists (member (op =) old_constrs) cos
then insert (op =) c else I) cases []) cases;
in
thy
|> fold del_eqns outdated_funs
|> map_exec_purge
((map_typs o Symtab.map_default (tyco, [])) (cons (serial (), vs_spec))
#> (map_cases o apfst) drop_outdated_cases)
end;
fun unoverload_const_typ thy (c, ty) = (AxClass.unoverload_const thy (c, ty), ty);
structure Datatype_Interpretation =
Interpretation(type T = string * serial val eq = eq_snd (op =) : T * T -> bool);
fun datatype_interpretation f = Datatype_Interpretation.interpretation
(fn (tyco, _) => fn thy => f (tyco, get_type thy tyco) thy);
fun add_datatype proto_constrs thy =
let
val constrs = map (unoverload_const_typ thy) proto_constrs;
val (tyco, (vs, cos)) = constrset_of_consts thy constrs;
in
thy
|> fold (del_eqns o fst) constrs
|> register_type (tyco, (vs, Constructors cos))
|> Datatype_Interpretation.data (tyco, serial ())
end;
fun add_datatype_cmd raw_constrs thy =
add_datatype (map (read_bare_const thy) raw_constrs) thy;
structure Abstype_Interpretation =
Interpretation(type T = string * serial val eq = eq_snd (op =) : T * T -> bool);
fun abstype_interpretation f = Abstype_Interpretation.interpretation
(fn (tyco, _) => fn thy => f (tyco, get_abstype_spec thy tyco) thy);
fun add_abstype proto_abs proto_rep thy =
let
val (abs, rep) = pairself (unoverload_const_typ thy) (proto_abs, proto_rep);
val (tyco, (vs, (abs_ty as (abs, ty), (rep, cert_prop)))) = abstype_cert thy abs (fst rep);
fun after_qed [[cert]] = ProofContext.theory
(register_type (tyco, (vs, Abstractor (abs_ty, (rep, cert))))
#> change_fun_spec false rep ((K o Proj)
(map_types Logic.varifyT (mk_proj tyco vs ty abs rep), tyco))
#> Abstype_Interpretation.data (tyco, serial ()));
in
thy
|> ProofContext.init
|> Proof.theorem_i NONE after_qed [[(cert_prop, [])]]
end;
fun add_abstype_cmd raw_abs raw_rep thy =
add_abstype (read_bare_const thy raw_abs) (read_bare_const thy raw_rep) thy;
(** infrastructure **)
(* c.f. src/HOL/Tools/recfun_codegen.ML *)
structure Code_Target_Attr = Theory_Data
(
type T = (string -> thm -> theory -> theory) option;
val empty = NONE;
val extend = I;
fun merge (f1, f2) = if is_some f1 then f1 else f2;
);
fun set_code_target_attr f = Code_Target_Attr.map (K (SOME f));
fun code_target_attr prefix thm thy =
let
val attr = the_default ((K o K) I) (Code_Target_Attr.get thy);
in thy |> add_warning_eqn thm |> attr prefix thm end;
(* setup *)
val _ = Context.>> (Context.map_theory
(let
fun mk_attribute f = Thm.declaration_attribute (fn thm => Context.mapping (f thm) I);
val code_attribute_parser =
Args.del |-- Scan.succeed (mk_attribute del_eqn)
|| Args.$$$ "nbe" |-- Scan.succeed (mk_attribute add_nbe_eqn)
|| Args.$$$ "abstract" |-- Scan.succeed (mk_attribute add_abs_eqn)
|| (Args.$$$ "target" |-- Args.colon |-- Args.name >>
(mk_attribute o code_target_attr))
|| Scan.succeed (mk_attribute add_warning_eqn);
in
Datatype_Interpretation.init
#> Attrib.setup (Binding.name "code") (Scan.lift code_attribute_parser)
"declare theorems for code generation"
end));
end; (*struct*)
(* type-safe interfaces for data dependent on executable code *)
functor Code_Data(Data: CODE_DATA_ARGS): CODE_DATA =
struct
type T = Data.T;
exception Data of T;
fun dest (Data x) = x
val kind = Code.declare_data (Data Data.empty);
val data_op = (kind, Data, dest);
val change = Code.change_data data_op;
fun change_yield thy = Code.change_yield_data data_op thy;
end;
structure Code : CODE = struct open Code; end;