src/HOL/Complex.thy
author wenzelm
Mon Dec 28 01:26:34 2015 +0100 (2015-12-28)
changeset 61944 5d06ecfdb472
parent 61848 9250e546ab23
child 61969 e01015e49041
permissions -rw-r--r--
prefer symbols for "abs";
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 section \<open>Complex Numbers: Rectangular and Polar Representations\<close>
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 text \<open>
    14 We use the \<open>codatatype\<close> command to define the type of complex numbers. This allows us to use
    15 \<open>primcorec\<close> to define complex functions by defining their real and imaginary result
    16 separately.
    17 \<close>
    18 
    19 codatatype complex = Complex (Re: real) (Im: real)
    20 
    21 lemma complex_surj: "Complex (Re z) (Im z) = z"
    22   by (rule complex.collapse)
    23 
    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    25   by (rule complex.expand) simp
    26 
    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    28   by (auto intro: complex.expand)
    29 
    30 subsection \<open>Addition and Subtraction\<close>
    31 
    32 instantiation complex :: ab_group_add
    33 begin
    34 
    35 primcorec zero_complex where
    36   "Re 0 = 0"
    37 | "Im 0 = 0"
    38 
    39 primcorec plus_complex where
    40   "Re (x + y) = Re x + Re y"
    41 | "Im (x + y) = Im x + Im y"
    42 
    43 primcorec uminus_complex where
    44   "Re (- x) = - Re x"
    45 | "Im (- x) = - Im x"
    46 
    47 primcorec minus_complex where
    48   "Re (x - y) = Re x - Re y"
    49 | "Im (x - y) = Im x - Im y"
    50 
    51 instance
    52   by intro_classes (simp_all add: complex_eq_iff)
    53 
    54 end
    55 
    56 subsection \<open>Multiplication and Division\<close>
    57 
    58 instantiation complex :: field
    59 begin
    60 
    61 primcorec one_complex where
    62   "Re 1 = 1"
    63 | "Im 1 = 0"
    64 
    65 primcorec times_complex where
    66   "Re (x * y) = Re x * Re y - Im x * Im y"
    67 | "Im (x * y) = Re x * Im y + Im x * Re y"
    68 
    69 primcorec inverse_complex where
    70   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    71 | "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    72 
    73 definition "x div (y::complex) = x * inverse y"
    74 
    75 instance
    76   by intro_classes
    77      (simp_all add: complex_eq_iff divide_complex_def
    78       distrib_left distrib_right right_diff_distrib left_diff_distrib
    79       power2_eq_square add_divide_distrib [symmetric])
    80 
    81 end
    82 
    83 lemma Re_divide: "Re (x / y) = (Re x * Re y + Im x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    84   unfolding divide_complex_def by (simp add: add_divide_distrib)
    85 
    86 lemma Im_divide: "Im (x / y) = (Im x * Re y - Re x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    87   unfolding divide_complex_def times_complex.sel inverse_complex.sel
    88   by (simp_all add: divide_simps)
    89 
    90 lemma Re_power2: "Re (x ^ 2) = (Re x)^2 - (Im x)^2"
    91   by (simp add: power2_eq_square)
    92 
    93 lemma Im_power2: "Im (x ^ 2) = 2 * Re x * Im x"
    94   by (simp add: power2_eq_square)
    95 
    96 lemma Re_power_real [simp]: "Im x = 0 \<Longrightarrow> Re (x ^ n) = Re x ^ n "
    97   by (induct n) simp_all
    98 
    99 lemma Im_power_real [simp]: "Im x = 0 \<Longrightarrow> Im (x ^ n) = 0"
   100   by (induct n) simp_all
   101 
   102 subsection \<open>Scalar Multiplication\<close>
   103 
   104 instantiation complex :: real_field
   105 begin
   106 
   107 primcorec scaleR_complex where
   108   "Re (scaleR r x) = r * Re x"
   109 | "Im (scaleR r x) = r * Im x"
   110 
   111 instance
   112 proof
   113   fix a b :: real and x y :: complex
   114   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   115     by (simp add: complex_eq_iff distrib_left)
   116   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   117     by (simp add: complex_eq_iff distrib_right)
   118   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   119     by (simp add: complex_eq_iff mult.assoc)
   120   show "scaleR 1 x = x"
   121     by (simp add: complex_eq_iff)
   122   show "scaleR a x * y = scaleR a (x * y)"
   123     by (simp add: complex_eq_iff algebra_simps)
   124   show "x * scaleR a y = scaleR a (x * y)"
   125     by (simp add: complex_eq_iff algebra_simps)
   126 qed
   127 
   128 end
   129 
   130 subsection \<open>Numerals, Arithmetic, and Embedding from Reals\<close>
   131 
   132 abbreviation complex_of_real :: "real \<Rightarrow> complex"
   133   where "complex_of_real \<equiv> of_real"
   134 
   135 declare [[coercion "of_real :: real \<Rightarrow> complex"]]
   136 declare [[coercion "of_rat :: rat \<Rightarrow> complex"]]
   137 declare [[coercion "of_int :: int \<Rightarrow> complex"]]
   138 declare [[coercion "of_nat :: nat \<Rightarrow> complex"]]
   139 
   140 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   141   by (induct n) simp_all
   142 
   143 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   144   by (induct n) simp_all
   145 
   146 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   147   by (cases z rule: int_diff_cases) simp
   148 
   149 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   150   by (cases z rule: int_diff_cases) simp
   151 
   152 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
   153   using complex_Re_of_int [of "numeral v"] by simp
   154 
   155 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
   156   using complex_Im_of_int [of "numeral v"] by simp
   157 
   158 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   159   by (simp add: of_real_def)
   160 
   161 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   162   by (simp add: of_real_def)
   163 
   164 lemma Re_divide_numeral [simp]: "Re (z / numeral w) = Re z / numeral w"
   165   by (simp add: Re_divide sqr_conv_mult)
   166 
   167 lemma Im_divide_numeral [simp]: "Im (z / numeral w) = Im z / numeral w"
   168   by (simp add: Im_divide sqr_conv_mult)
   169 
   170 lemma Re_divide_of_nat: "Re (z / of_nat n) = Re z / of_nat n"
   171   by (cases n) (simp_all add: Re_divide divide_simps power2_eq_square del: of_nat_Suc)
   172 
   173 lemma Im_divide_of_nat: "Im (z / of_nat n) = Im z / of_nat n"
   174   by (cases n) (simp_all add: Im_divide divide_simps power2_eq_square del: of_nat_Suc)
   175 
   176 lemma of_real_Re [simp]:
   177     "z \<in> \<real> \<Longrightarrow> of_real (Re z) = z"
   178   by (auto simp: Reals_def)
   179 
   180 lemma complex_Re_fact [simp]: "Re (fact n) = fact n"
   181 proof -
   182   have "(fact n :: complex) = of_real (fact n)" by simp
   183   also have "Re \<dots> = fact n" by (subst Re_complex_of_real) simp_all
   184   finally show ?thesis .
   185 qed
   186 
   187 lemma complex_Im_fact [simp]: "Im (fact n) = 0"
   188   by (subst of_nat_fact [symmetric]) (simp only: complex_Im_of_nat)
   189 
   190 
   191 subsection \<open>The Complex Number $i$\<close>
   192 
   193 primcorec "ii" :: complex  ("\<i>") where
   194   "Re ii = 0"
   195 | "Im ii = 1"
   196 
   197 lemma Complex_eq[simp]: "Complex a b = a + \<i> * b"
   198   by (simp add: complex_eq_iff)
   199 
   200 lemma complex_eq: "a = Re a + \<i> * Im a"
   201   by (simp add: complex_eq_iff)
   202 
   203 lemma fun_complex_eq: "f = (\<lambda>x. Re (f x) + \<i> * Im (f x))"
   204   by (simp add: fun_eq_iff complex_eq)
   205 
   206 lemma i_squared [simp]: "ii * ii = -1"
   207   by (simp add: complex_eq_iff)
   208 
   209 lemma power2_i [simp]: "ii\<^sup>2 = -1"
   210   by (simp add: power2_eq_square)
   211 
   212 lemma inverse_i [simp]: "inverse ii = - ii"
   213   by (rule inverse_unique) simp
   214 
   215 lemma divide_i [simp]: "x / ii = - ii * x"
   216   by (simp add: divide_complex_def)
   217 
   218 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   219   by (simp add: mult.assoc [symmetric])
   220 
   221 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   222   by (simp add: complex_eq_iff)
   223 
   224 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   225   by (simp add: complex_eq_iff)
   226 
   227 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
   228   by (simp add: complex_eq_iff)
   229 
   230 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"
   231   by (simp add: complex_eq_iff)
   232 
   233 lemma complex_split_polar: "\<exists>r a. z = complex_of_real r * (cos a + \<i> * sin a)"
   234   by (simp add: complex_eq_iff polar_Ex)
   235 
   236 lemma i_even_power [simp]: "\<i> ^ (n * 2) = (-1) ^ n"
   237   by (metis mult.commute power2_i power_mult)
   238 
   239 lemma Re_ii_times [simp]: "Re (ii*z) = - Im z"
   240   by simp
   241 
   242 lemma Im_ii_times [simp]: "Im (ii*z) = Re z"
   243   by simp
   244 
   245 lemma ii_times_eq_iff: "ii*w = z \<longleftrightarrow> w = -(ii*z)"
   246   by auto
   247 
   248 lemma divide_numeral_i [simp]: "z / (numeral n * ii) = -(ii*z) / numeral n"
   249   by (metis divide_divide_eq_left divide_i mult.commute mult_minus_right)
   250 
   251 subsection \<open>Vector Norm\<close>
   252 
   253 instantiation complex :: real_normed_field
   254 begin
   255 
   256 definition "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   257 
   258 abbreviation cmod :: "complex \<Rightarrow> real"
   259   where "cmod \<equiv> norm"
   260 
   261 definition complex_sgn_def:
   262   "sgn x = x /\<^sub>R cmod x"
   263 
   264 definition dist_complex_def:
   265   "dist x y = cmod (x - y)"
   266 
   267 definition open_complex_def:
   268   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   269 
   270 instance proof
   271   fix r :: real and x y :: complex and S :: "complex set"
   272   show "(norm x = 0) = (x = 0)"
   273     by (simp add: norm_complex_def complex_eq_iff)
   274   show "norm (x + y) \<le> norm x + norm y"
   275     by (simp add: norm_complex_def complex_eq_iff real_sqrt_sum_squares_triangle_ineq)
   276   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   277     by (simp add: norm_complex_def complex_eq_iff power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
   278   show "norm (x * y) = norm x * norm y"
   279     by (simp add: norm_complex_def complex_eq_iff real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   280 qed (rule complex_sgn_def dist_complex_def open_complex_def)+
   281 
   282 end
   283 
   284 lemma norm_ii [simp]: "norm ii = 1"
   285   by (simp add: norm_complex_def)
   286 
   287 lemma cmod_unit_one: "cmod (cos a + \<i> * sin a) = 1"
   288   by (simp add: norm_complex_def)
   289 
   290 lemma cmod_complex_polar: "cmod (r * (cos a + \<i> * sin a)) = \<bar>r\<bar>"
   291   by (simp add: norm_mult cmod_unit_one)
   292 
   293 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   294   unfolding norm_complex_def
   295   by (rule real_sqrt_sum_squares_ge1)
   296 
   297 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
   298   by (rule order_trans [OF _ norm_ge_zero]) simp
   299 
   300 lemma complex_mod_triangle_ineq2: "cmod (b + a) - cmod b \<le> cmod a"
   301   by (rule ord_le_eq_trans [OF norm_triangle_ineq2]) simp
   302 
   303 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   304   by (simp add: norm_complex_def)
   305 
   306 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   307   by (simp add: norm_complex_def)
   308 
   309 lemma cmod_le: "cmod z \<le> \<bar>Re z\<bar> + \<bar>Im z\<bar>"
   310   apply (subst complex_eq)
   311   apply (rule order_trans)
   312   apply (rule norm_triangle_ineq)
   313   apply (simp add: norm_mult)
   314   done
   315 
   316 lemma cmod_eq_Re: "Im z = 0 \<Longrightarrow> cmod z = \<bar>Re z\<bar>"
   317   by (simp add: norm_complex_def)
   318 
   319 lemma cmod_eq_Im: "Re z = 0 \<Longrightarrow> cmod z = \<bar>Im z\<bar>"
   320   by (simp add: norm_complex_def)
   321 
   322 lemma cmod_power2: "cmod z ^ 2 = (Re z)^2 + (Im z)^2"
   323   by (simp add: norm_complex_def)
   324 
   325 lemma cmod_plus_Re_le_0_iff: "cmod z + Re z \<le> 0 \<longleftrightarrow> Re z = - cmod z"
   326   using abs_Re_le_cmod[of z] by auto
   327 
   328 lemma Im_eq_0: "\<bar>Re z\<bar> = cmod z \<Longrightarrow> Im z = 0"
   329   by (subst (asm) power_eq_iff_eq_base[symmetric, where n=2])
   330      (auto simp add: norm_complex_def)
   331 
   332 lemma abs_sqrt_wlog:
   333   fixes x::"'a::linordered_idom"
   334   assumes "\<And>x::'a. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)" shows "P \<bar>x\<bar> (x\<^sup>2)"
   335 by (metis abs_ge_zero assms power2_abs)
   336 
   337 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"
   338   unfolding norm_complex_def
   339   apply (rule abs_sqrt_wlog [where x="Re z"])
   340   apply (rule abs_sqrt_wlog [where x="Im z"])
   341   apply (rule power2_le_imp_le)
   342   apply (simp_all add: power2_sum add.commute sum_squares_bound real_sqrt_mult [symmetric])
   343   done
   344 
   345 lemma complex_unit_circle: "z \<noteq> 0 \<Longrightarrow> (Re z / cmod z)\<^sup>2 + (Im z / cmod z)\<^sup>2 = 1"
   346   by (simp add: norm_complex_def divide_simps complex_eq_iff)
   347 
   348 
   349 text \<open>Properties of complex signum.\<close>
   350 
   351 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   352   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult.commute)
   353 
   354 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   355   by (simp add: complex_sgn_def divide_inverse)
   356 
   357 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   358   by (simp add: complex_sgn_def divide_inverse)
   359 
   360 
   361 subsection \<open>Completeness of the Complexes\<close>
   362 
   363 lemma bounded_linear_Re: "bounded_linear Re"
   364   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
   365 
   366 lemma bounded_linear_Im: "bounded_linear Im"
   367   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
   368 
   369 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   370 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   371 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]
   372 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]
   373 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   374 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   375 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]
   376 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]
   377 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]
   378 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]
   379 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]
   380 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]
   381 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]
   382 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]
   383 
   384 lemma tendsto_Complex [tendsto_intros]:
   385   "(f ---> a) F \<Longrightarrow> (g ---> b) F \<Longrightarrow> ((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
   386   by (auto intro!: tendsto_intros)
   387 
   388 lemma tendsto_complex_iff:
   389   "(f ---> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) ---> Re x) F \<and> ((\<lambda>x. Im (f x)) ---> Im x) F)"
   390 proof safe
   391   assume "((\<lambda>x. Re (f x)) ---> Re x) F" "((\<lambda>x. Im (f x)) ---> Im x) F"
   392   from tendsto_Complex[OF this] show "(f ---> x) F"
   393     unfolding complex.collapse .
   394 qed (auto intro: tendsto_intros)
   395 
   396 lemma continuous_complex_iff: "continuous F f \<longleftrightarrow>
   397     continuous F (\<lambda>x. Re (f x)) \<and> continuous F (\<lambda>x. Im (f x))"
   398   unfolding continuous_def tendsto_complex_iff ..
   399 
   400 lemma has_vector_derivative_complex_iff: "(f has_vector_derivative x) F \<longleftrightarrow>
   401     ((\<lambda>x. Re (f x)) has_field_derivative (Re x)) F \<and>
   402     ((\<lambda>x. Im (f x)) has_field_derivative (Im x)) F"
   403   unfolding has_vector_derivative_def has_field_derivative_def has_derivative_def tendsto_complex_iff
   404   by (simp add: field_simps bounded_linear_scaleR_left bounded_linear_mult_right)
   405 
   406 lemma has_field_derivative_Re[derivative_intros]:
   407   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Re (f x)) has_field_derivative (Re D)) F"
   408   unfolding has_vector_derivative_complex_iff by safe
   409 
   410 lemma has_field_derivative_Im[derivative_intros]:
   411   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Im (f x)) has_field_derivative (Im D)) F"
   412   unfolding has_vector_derivative_complex_iff by safe
   413 
   414 instance complex :: banach
   415 proof
   416   fix X :: "nat \<Rightarrow> complex"
   417   assume X: "Cauchy X"
   418   then have "(\<lambda>n. Complex (Re (X n)) (Im (X n))) ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   419     by (intro tendsto_Complex convergent_LIMSEQ_iff[THEN iffD1] Cauchy_convergent_iff[THEN iffD1] Cauchy_Re Cauchy_Im)
   420   then show "convergent X"
   421     unfolding complex.collapse by (rule convergentI)
   422 qed
   423 
   424 declare
   425   DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]
   426 
   427 subsection \<open>Complex Conjugation\<close>
   428 
   429 primcorec cnj :: "complex \<Rightarrow> complex" where
   430   "Re (cnj z) = Re z"
   431 | "Im (cnj z) = - Im z"
   432 
   433 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   434   by (simp add: complex_eq_iff)
   435 
   436 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   437   by (simp add: complex_eq_iff)
   438 
   439 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   440   by (simp add: complex_eq_iff)
   441 
   442 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   443   by (simp add: complex_eq_iff)
   444 
   445 lemma complex_cnj_add [simp]: "cnj (x + y) = cnj x + cnj y"
   446   by (simp add: complex_eq_iff)
   447 
   448 lemma cnj_setsum [simp]: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"
   449   by (induct s rule: infinite_finite_induct) auto
   450 
   451 lemma complex_cnj_diff [simp]: "cnj (x - y) = cnj x - cnj y"
   452   by (simp add: complex_eq_iff)
   453 
   454 lemma complex_cnj_minus [simp]: "cnj (- x) = - cnj x"
   455   by (simp add: complex_eq_iff)
   456 
   457 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   458   by (simp add: complex_eq_iff)
   459 
   460 lemma complex_cnj_mult [simp]: "cnj (x * y) = cnj x * cnj y"
   461   by (simp add: complex_eq_iff)
   462 
   463 lemma cnj_setprod [simp]: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"
   464   by (induct s rule: infinite_finite_induct) auto
   465 
   466 lemma complex_cnj_inverse [simp]: "cnj (inverse x) = inverse (cnj x)"
   467   by (simp add: complex_eq_iff)
   468 
   469 lemma complex_cnj_divide [simp]: "cnj (x / y) = cnj x / cnj y"
   470   by (simp add: divide_complex_def)
   471 
   472 lemma complex_cnj_power [simp]: "cnj (x ^ n) = cnj x ^ n"
   473   by (induct n) simp_all
   474 
   475 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   476   by (simp add: complex_eq_iff)
   477 
   478 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   479   by (simp add: complex_eq_iff)
   480 
   481 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
   482   by (simp add: complex_eq_iff)
   483 
   484 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
   485   by (simp add: complex_eq_iff)
   486 
   487 lemma complex_cnj_scaleR [simp]: "cnj (scaleR r x) = scaleR r (cnj x)"
   488   by (simp add: complex_eq_iff)
   489 
   490 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   491   by (simp add: norm_complex_def)
   492 
   493 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   494   by (simp add: complex_eq_iff)
   495 
   496 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   497   by (simp add: complex_eq_iff)
   498 
   499 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   500   by (simp add: complex_eq_iff)
   501 
   502 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   503   by (simp add: complex_eq_iff)
   504 
   505 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   506   by (simp add: complex_eq_iff power2_eq_square)
   507 
   508 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
   509   by (simp add: norm_mult power2_eq_square)
   510 
   511 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   512   by (simp add: norm_complex_def power2_eq_square)
   513 
   514 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   515   by simp
   516 
   517 lemma complex_cnj_fact [simp]: "cnj (fact n) = fact n"
   518   by (subst of_nat_fact [symmetric], subst complex_cnj_of_nat) simp
   519 
   520 lemma complex_cnj_pochhammer [simp]: "cnj (pochhammer z n) = pochhammer (cnj z) n"
   521   by (induction n arbitrary: z) (simp_all add: pochhammer_rec)
   522 
   523 lemma bounded_linear_cnj: "bounded_linear cnj"
   524   using complex_cnj_add complex_cnj_scaleR
   525   by (rule bounded_linear_intro [where K=1], simp)
   526 
   527 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]
   528 lemmas isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]
   529 lemmas continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]
   530 lemmas continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]
   531 lemmas has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]
   532 
   533 lemma lim_cnj: "((\<lambda>x. cnj(f x)) ---> cnj l) F \<longleftrightarrow> (f ---> l) F"
   534   by (simp add: tendsto_iff dist_complex_def complex_cnj_diff [symmetric] del: complex_cnj_diff)
   535 
   536 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"
   537   by (simp add: sums_def lim_cnj cnj_setsum [symmetric] del: cnj_setsum)
   538 
   539 
   540 subsection\<open>Basic Lemmas\<close>
   541 
   542 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
   543   by (metis zero_complex.sel complex_eqI sum_power2_eq_zero_iff)
   544 
   545 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
   546   by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
   547 
   548 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
   549 by (cases z)
   550    (auto simp: complex_eq_iff norm_complex_def power2_eq_square[symmetric] of_real_power[symmetric]
   551          simp del: of_real_power)
   552 
   553 lemma complex_div_cnj: "a / b = (a * cnj b) / (norm b)^2"
   554   using complex_norm_square by auto
   555 
   556 lemma Re_complex_div_eq_0: "Re (a / b) = 0 \<longleftrightarrow> Re (a * cnj b) = 0"
   557   by (auto simp add: Re_divide)
   558 
   559 lemma Im_complex_div_eq_0: "Im (a / b) = 0 \<longleftrightarrow> Im (a * cnj b) = 0"
   560   by (auto simp add: Im_divide)
   561 
   562 lemma complex_div_gt_0:
   563   "(Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0) \<and> (Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0)"
   564 proof cases
   565   assume "b = 0" then show ?thesis by auto
   566 next
   567   assume "b \<noteq> 0"
   568   then have "0 < (Re b)\<^sup>2 + (Im b)\<^sup>2"
   569     by (simp add: complex_eq_iff sum_power2_gt_zero_iff)
   570   then show ?thesis
   571     by (simp add: Re_divide Im_divide zero_less_divide_iff)
   572 qed
   573 
   574 lemma Re_complex_div_gt_0: "Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0"
   575   and Im_complex_div_gt_0: "Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0"
   576   using complex_div_gt_0 by auto
   577 
   578 lemma Re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"
   579   by (metis le_less Re_complex_div_eq_0 Re_complex_div_gt_0)
   580 
   581 lemma Im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"
   582   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 le_less)
   583 
   584 lemma Re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"
   585   by (metis less_asym neq_iff Re_complex_div_eq_0 Re_complex_div_gt_0)
   586 
   587 lemma Im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"
   588   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 less_asym neq_iff)
   589 
   590 lemma Re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"
   591   by (metis not_le Re_complex_div_gt_0)
   592 
   593 lemma Im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"
   594   by (metis Im_complex_div_gt_0 not_le)
   595 
   596 lemma Re_divide_of_real [simp]: "Re (z / of_real r) = Re z / r"
   597   by (simp add: Re_divide power2_eq_square)
   598 
   599 lemma Im_divide_of_real [simp]: "Im (z / of_real r) = Im z / r"
   600   by (simp add: Im_divide power2_eq_square)
   601 
   602 lemma Re_divide_Reals: "r \<in> Reals \<Longrightarrow> Re (z / r) = Re z / Re r"
   603   by (metis Re_divide_of_real of_real_Re)
   604 
   605 lemma Im_divide_Reals: "r \<in> Reals \<Longrightarrow> Im (z / r) = Im z / Re r"
   606   by (metis Im_divide_of_real of_real_Re)
   607 
   608 lemma Re_setsum[simp]: "Re (setsum f s) = (\<Sum>x\<in>s. Re (f x))"
   609   by (induct s rule: infinite_finite_induct) auto
   610 
   611 lemma Im_setsum[simp]: "Im (setsum f s) = (\<Sum>x\<in>s. Im(f x))"
   612   by (induct s rule: infinite_finite_induct) auto
   613 
   614 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"
   615   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..
   616 
   617 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"
   618   unfolding summable_def sums_complex_iff[abs_def] by (metis complex.sel)
   619 
   620 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"
   621   unfolding summable_complex_iff by simp
   622 
   623 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"
   624   unfolding summable_complex_iff by blast
   625 
   626 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"
   627   unfolding summable_complex_iff by blast
   628 
   629 lemma complex_is_Nat_iff: "z \<in> \<nat> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_nat i)"
   630   by (auto simp: Nats_def complex_eq_iff)
   631 
   632 lemma complex_is_Int_iff: "z \<in> \<int> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_int i)"
   633   by (auto simp: Ints_def complex_eq_iff)
   634 
   635 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"
   636   by (auto simp: Reals_def complex_eq_iff)
   637 
   638 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
   639   by (auto simp: complex_is_Real_iff complex_eq_iff)
   640 
   641 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm z = \<bar>Re z\<bar>"
   642   by (simp add: complex_is_Real_iff norm_complex_def)
   643 
   644 lemma series_comparison_complex:
   645   fixes f:: "nat \<Rightarrow> 'a::banach"
   646   assumes sg: "summable g"
   647      and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"
   648      and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"
   649   shows "summable f"
   650 proof -
   651   have g: "\<And>n. cmod (g n) = Re (g n)" using assms
   652     by (metis abs_of_nonneg in_Reals_norm)
   653   show ?thesis
   654     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])
   655     using sg
   656     apply (auto simp: summable_def)
   657     apply (rule_tac x="Re s" in exI)
   658     apply (auto simp: g sums_Re)
   659     apply (metis fg g)
   660     done
   661 qed
   662 
   663 subsection\<open>Polar Form for Complex Numbers\<close>
   664 
   665 lemma complex_unimodular_polar: "(norm z = 1) \<Longrightarrow> \<exists>x. z = Complex (cos x) (sin x)"
   666   using sincos_total_2pi [of "Re z" "Im z"]
   667   by auto (metis cmod_power2 complex_eq power_one)
   668 
   669 subsubsection \<open>$\cos \theta + i \sin \theta$\<close>
   670 
   671 primcorec cis :: "real \<Rightarrow> complex" where
   672   "Re (cis a) = cos a"
   673 | "Im (cis a) = sin a"
   674 
   675 lemma cis_zero [simp]: "cis 0 = 1"
   676   by (simp add: complex_eq_iff)
   677 
   678 lemma norm_cis [simp]: "norm (cis a) = 1"
   679   by (simp add: norm_complex_def)
   680 
   681 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
   682   by (simp add: sgn_div_norm)
   683 
   684 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
   685   by (metis norm_cis norm_zero zero_neq_one)
   686 
   687 lemma cis_mult: "cis a * cis b = cis (a + b)"
   688   by (simp add: complex_eq_iff cos_add sin_add)
   689 
   690 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   691   by (induct n, simp_all add: of_nat_Suc algebra_simps cis_mult)
   692 
   693 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   694   by (simp add: complex_eq_iff)
   695 
   696 lemma cis_divide: "cis a / cis b = cis (a - b)"
   697   by (simp add: divide_complex_def cis_mult)
   698 
   699 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   700   by (auto simp add: DeMoivre)
   701 
   702 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   703   by (auto simp add: DeMoivre)
   704 
   705 lemma cis_pi: "cis pi = -1"
   706   by (simp add: complex_eq_iff)
   707 
   708 subsubsection \<open>$r(\cos \theta + i \sin \theta)$\<close>
   709 
   710 definition rcis :: "real \<Rightarrow> real \<Rightarrow> complex" where
   711   "rcis r a = complex_of_real r * cis a"
   712 
   713 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   714   by (simp add: rcis_def)
   715 
   716 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   717   by (simp add: rcis_def)
   718 
   719 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   720   by (simp add: complex_eq_iff polar_Ex)
   721 
   722 lemma complex_mod_rcis [simp]: "cmod (rcis r a) = \<bar>r\<bar>"
   723   by (simp add: rcis_def norm_mult)
   724 
   725 lemma cis_rcis_eq: "cis a = rcis 1 a"
   726   by (simp add: rcis_def)
   727 
   728 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   729   by (simp add: rcis_def cis_mult)
   730 
   731 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   732   by (simp add: rcis_def)
   733 
   734 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   735   by (simp add: rcis_def)
   736 
   737 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
   738   by (simp add: rcis_def)
   739 
   740 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   741   by (simp add: rcis_def power_mult_distrib DeMoivre)
   742 
   743 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   744   by (simp add: divide_inverse rcis_def)
   745 
   746 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   747   by (simp add: rcis_def cis_divide [symmetric])
   748 
   749 subsubsection \<open>Complex exponential\<close>
   750 
   751 lemma cis_conv_exp: "cis b = exp (\<i> * b)"
   752 proof -
   753   { fix n :: nat
   754     have "\<i> ^ n = fact n *\<^sub>R (cos_coeff n + \<i> * sin_coeff n)"
   755       by (induct n)
   756          (simp_all add: sin_coeff_Suc cos_coeff_Suc complex_eq_iff Re_divide Im_divide field_simps
   757                         power2_eq_square of_nat_Suc add_nonneg_eq_0_iff)
   758     then have "(\<i> * complex_of_real b) ^ n /\<^sub>R fact n =
   759         of_real (cos_coeff n * b^n) + \<i> * of_real (sin_coeff n * b^n)"
   760       by (simp add: field_simps) }
   761   then show ?thesis using sin_converges [of b] cos_converges [of b]
   762     by (auto simp add: cis.ctr exp_def simp del: of_real_mult
   763              intro!: sums_unique sums_add sums_mult sums_of_real)
   764 qed
   765 
   766 lemma exp_eq_polar: "exp z = exp (Re z) * cis (Im z)"
   767   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by (cases z) simp
   768 
   769 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
   770   unfolding exp_eq_polar by simp
   771 
   772 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
   773   unfolding exp_eq_polar by simp
   774 
   775 lemma norm_cos_sin [simp]: "norm (Complex (cos t) (sin t)) = 1"
   776   by (simp add: norm_complex_def)
   777 
   778 lemma norm_exp_eq_Re [simp]: "norm (exp z) = exp (Re z)"
   779   by (simp add: cis.code cmod_complex_polar exp_eq_polar)
   780 
   781 lemma complex_exp_exists: "\<exists>a r. z = complex_of_real r * exp a"
   782   apply (insert rcis_Ex [of z])
   783   apply (auto simp add: exp_eq_polar rcis_def mult.assoc [symmetric])
   784   apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   785   done
   786 
   787 lemma exp_pi_i [simp]: "exp(of_real pi * ii) = -1"
   788   by (metis cis_conv_exp cis_pi mult.commute)
   789 
   790 lemma exp_two_pi_i [simp]: "exp(2 * of_real pi * ii) = 1"
   791   by (simp add: exp_eq_polar complex_eq_iff)
   792 
   793 subsubsection \<open>Complex argument\<close>
   794 
   795 definition arg :: "complex \<Rightarrow> real" where
   796   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
   797 
   798 lemma arg_zero: "arg 0 = 0"
   799   by (simp add: arg_def)
   800 
   801 lemma arg_unique:
   802   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
   803   shows "arg z = x"
   804 proof -
   805   from assms have "z \<noteq> 0" by auto
   806   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
   807   proof
   808     fix a def d \<equiv> "a - x"
   809     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
   810     from a assms have "- (2*pi) < d \<and> d < 2*pi"
   811       unfolding d_def by simp
   812     moreover from a assms have "cos a = cos x" and "sin a = sin x"
   813       by (simp_all add: complex_eq_iff)
   814     hence cos: "cos d = 1" unfolding d_def cos_diff by simp
   815     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)
   816     ultimately have "d = 0"
   817       unfolding sin_zero_iff
   818       by (auto elim!: evenE dest!: less_2_cases)
   819     thus "a = x" unfolding d_def by simp
   820   qed (simp add: assms del: Re_sgn Im_sgn)
   821   with \<open>z \<noteq> 0\<close> show "arg z = x"
   822     unfolding arg_def by simp
   823 qed
   824 
   825 lemma arg_correct:
   826   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
   827 proof (simp add: arg_def assms, rule someI_ex)
   828   obtain r a where z: "z = rcis r a" using rcis_Ex by fast
   829   with assms have "r \<noteq> 0" by auto
   830   def b \<equiv> "if 0 < r then a else a + pi"
   831   have b: "sgn z = cis b"
   832     unfolding z b_def rcis_def using \<open>r \<noteq> 0\<close>
   833     by (simp add: of_real_def sgn_scaleR sgn_if complex_eq_iff)
   834   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
   835     by (induct_tac n) (simp_all add: distrib_left cis_mult [symmetric] complex_eq_iff)
   836   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
   837     by (case_tac x rule: int_diff_cases)
   838        (simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
   839   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
   840   have "sgn z = cis c"
   841     unfolding b c_def
   842     by (simp add: cis_divide [symmetric] cis_2pi_int)
   843   moreover have "- pi < c \<and> c \<le> pi"
   844     using ceiling_correct [of "(b - pi) / (2*pi)"]
   845     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps del: le_of_int_ceiling)
   846   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
   847 qed
   848 
   849 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
   850   by (cases "z = 0") (simp_all add: arg_zero arg_correct)
   851 
   852 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
   853   by (simp add: arg_correct)
   854 
   855 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
   856   by (cases "z = 0") (simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
   857 
   858 lemma cos_arg_i_mult_zero [simp]: "y \<noteq> 0 \<Longrightarrow> Re y = 0 \<Longrightarrow> cos (arg y) = 0"
   859   using cis_arg [of y] by (simp add: complex_eq_iff)
   860 
   861 subsection \<open>Square root of complex numbers\<close>
   862 
   863 primcorec csqrt :: "complex \<Rightarrow> complex" where
   864   "Re (csqrt z) = sqrt ((cmod z + Re z) / 2)"
   865 | "Im (csqrt z) = (if Im z = 0 then 1 else sgn (Im z)) * sqrt ((cmod z - Re z) / 2)"
   866 
   867 lemma csqrt_of_real_nonneg [simp]: "Im x = 0 \<Longrightarrow> Re x \<ge> 0 \<Longrightarrow> csqrt x = sqrt (Re x)"
   868   by (simp add: complex_eq_iff norm_complex_def)
   869 
   870 lemma csqrt_of_real_nonpos [simp]: "Im x = 0 \<Longrightarrow> Re x \<le> 0 \<Longrightarrow> csqrt x = \<i> * sqrt \<bar>Re x\<bar>"
   871   by (simp add: complex_eq_iff norm_complex_def)
   872 
   873 lemma of_real_sqrt: "x \<ge> 0 \<Longrightarrow> of_real (sqrt x) = csqrt (of_real x)"
   874   by (simp add: complex_eq_iff norm_complex_def)
   875 
   876 lemma csqrt_0 [simp]: "csqrt 0 = 0"
   877   by simp
   878 
   879 lemma csqrt_1 [simp]: "csqrt 1 = 1"
   880   by simp
   881 
   882 lemma csqrt_ii [simp]: "csqrt \<i> = (1 + \<i>) / sqrt 2"
   883   by (simp add: complex_eq_iff Re_divide Im_divide real_sqrt_divide real_div_sqrt)
   884 
   885 lemma power2_csqrt[simp,algebra]: "(csqrt z)\<^sup>2 = z"
   886 proof cases
   887   assume "Im z = 0" then show ?thesis
   888     using real_sqrt_pow2[of "Re z"] real_sqrt_pow2[of "- Re z"]
   889     by (cases "0::real" "Re z" rule: linorder_cases)
   890        (simp_all add: complex_eq_iff Re_power2 Im_power2 power2_eq_square cmod_eq_Re)
   891 next
   892   assume "Im z \<noteq> 0"
   893   moreover
   894   have "cmod z * cmod z - Re z * Re z = Im z * Im z"
   895     by (simp add: norm_complex_def power2_eq_square)
   896   moreover
   897   have "\<bar>Re z\<bar> \<le> cmod z"
   898     by (simp add: norm_complex_def)
   899   ultimately show ?thesis
   900     by (simp add: Re_power2 Im_power2 complex_eq_iff real_sgn_eq
   901                   field_simps real_sqrt_mult[symmetric] real_sqrt_divide)
   902 qed
   903 
   904 lemma csqrt_eq_0 [simp]: "csqrt z = 0 \<longleftrightarrow> z = 0"
   905   by auto (metis power2_csqrt power_eq_0_iff)
   906 
   907 lemma csqrt_eq_1 [simp]: "csqrt z = 1 \<longleftrightarrow> z = 1"
   908   by auto (metis power2_csqrt power2_eq_1_iff)
   909 
   910 lemma csqrt_principal: "0 < Re (csqrt z) \<or> Re (csqrt z) = 0 \<and> 0 \<le> Im (csqrt z)"
   911   by (auto simp add: not_less cmod_plus_Re_le_0_iff Im_eq_0)
   912 
   913 lemma Re_csqrt: "0 \<le> Re (csqrt z)"
   914   by (metis csqrt_principal le_less)
   915 
   916 lemma csqrt_square:
   917   assumes "0 < Re b \<or> (Re b = 0 \<and> 0 \<le> Im b)"
   918   shows "csqrt (b^2) = b"
   919 proof -
   920   have "csqrt (b^2) = b \<or> csqrt (b^2) = - b"
   921     unfolding power2_eq_iff[symmetric] by (simp add: power2_csqrt)
   922   moreover have "csqrt (b^2) \<noteq> -b \<or> b = 0"
   923     using csqrt_principal[of "b ^ 2"] assms by (intro disjCI notI) (auto simp: complex_eq_iff)
   924   ultimately show ?thesis
   925     by auto
   926 qed
   927 
   928 lemma csqrt_unique:
   929     "w^2 = z \<Longrightarrow> (0 < Re w \<or> Re w = 0 \<and> 0 \<le> Im w) \<Longrightarrow> csqrt z = w"
   930   by (auto simp: csqrt_square)
   931 
   932 lemma csqrt_minus [simp]:
   933   assumes "Im x < 0 \<or> (Im x = 0 \<and> 0 \<le> Re x)"
   934   shows "csqrt (- x) = \<i> * csqrt x"
   935 proof -
   936   have "csqrt ((\<i> * csqrt x)^2) = \<i> * csqrt x"
   937   proof (rule csqrt_square)
   938     have "Im (csqrt x) \<le> 0"
   939       using assms by (auto simp add: cmod_eq_Re mult_le_0_iff field_simps complex_Re_le_cmod)
   940     then show "0 < Re (\<i> * csqrt x) \<or> Re (\<i> * csqrt x) = 0 \<and> 0 \<le> Im (\<i> * csqrt x)"
   941       by (auto simp add: Re_csqrt simp del: csqrt.simps)
   942   qed
   943   also have "(\<i> * csqrt x)^2 = - x"
   944     by (simp add: power_mult_distrib)
   945   finally show ?thesis .
   946 qed
   947 
   948 text \<open>Legacy theorem names\<close>
   949 
   950 lemmas expand_complex_eq = complex_eq_iff
   951 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   952 lemmas complex_equality = complex_eqI
   953 lemmas cmod_def = norm_complex_def
   954 lemmas complex_norm_def = norm_complex_def
   955 lemmas complex_divide_def = divide_complex_def
   956 
   957 lemma legacy_Complex_simps:
   958   shows Complex_eq_0: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
   959     and complex_add: "Complex a b + Complex c d = Complex (a + c) (b + d)"
   960     and complex_minus: "- (Complex a b) = Complex (- a) (- b)"
   961     and complex_diff: "Complex a b - Complex c d = Complex (a - c) (b - d)"
   962     and Complex_eq_1: "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
   963     and Complex_eq_neg_1: "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
   964     and complex_mult: "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   965     and complex_inverse: "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
   966     and Complex_eq_numeral: "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
   967     and Complex_eq_neg_numeral: "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
   968     and complex_scaleR: "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   969     and Complex_eq_i: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   970     and i_mult_Complex: "ii * Complex a b = Complex (- b) a"
   971     and Complex_mult_i: "Complex a b * ii = Complex (- b) a"
   972     and i_complex_of_real: "ii * complex_of_real r = Complex 0 r"
   973     and complex_of_real_i: "complex_of_real r * ii = Complex 0 r"
   974     and Complex_add_complex_of_real: "Complex x y + complex_of_real r = Complex (x+r) y"
   975     and complex_of_real_add_Complex: "complex_of_real r + Complex x y = Complex (r+x) y"
   976     and Complex_mult_complex_of_real: "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   977     and complex_of_real_mult_Complex: "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   978     and complex_eq_cancel_iff2: "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   979     and complex_cn: "cnj (Complex a b) = Complex a (- b)"
   980     and Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"
   981     and Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"
   982     and complex_of_real_def: "complex_of_real r = Complex r 0"
   983     and complex_norm: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
   984   by (simp_all add: norm_complex_def field_simps complex_eq_iff Re_divide Im_divide del: Complex_eq)
   985 
   986 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
   987   by (metis Reals_of_real complex_of_real_def)
   988 
   989 end