src/HOL/Library/Indicator_Function.thy
author hoelzl
Tue Nov 12 19:28:50 2013 +0100 (2013-11-12)
changeset 54408 67dec4ccaabd
parent 45425 7fee7d7abf2f
child 56993 e5366291d6aa
permissions -rw-r--r--
equation when indicator function equals 0 or 1
     1 (*  Title:      HOL/Library/Indicator_Function.thy
     2     Author:     Johannes Hoelzl (TU Muenchen)
     3 *)
     4 
     5 header {* Indicator Function *}
     6 
     7 theory Indicator_Function
     8 imports Main
     9 begin
    10 
    11 definition "indicator S x = (if x \<in> S then 1 else 0)"
    12 
    13 lemma indicator_simps[simp]:
    14   "x \<in> S \<Longrightarrow> indicator S x = 1"
    15   "x \<notin> S \<Longrightarrow> indicator S x = 0"
    16   unfolding indicator_def by auto
    17 
    18 lemma indicator_pos_le[intro, simp]: "(0::'a::linordered_semidom) \<le> indicator S x"
    19   and indicator_le_1[intro, simp]: "indicator S x \<le> (1::'a::linordered_semidom)"
    20   unfolding indicator_def by auto
    21 
    22 lemma indicator_abs_le_1: "\<bar>indicator S x\<bar> \<le> (1::'a::linordered_idom)"
    23   unfolding indicator_def by auto
    24 
    25 lemma indicator_eq_0_iff: "indicator A x = (0::_::zero_neq_one) \<longleftrightarrow> x \<notin> A"
    26   by (auto simp: indicator_def)
    27 
    28 lemma indicator_eq_1_iff: "indicator A x = (1::_::zero_neq_one) \<longleftrightarrow> x \<in> A"
    29   by (auto simp: indicator_def)
    30 
    31 lemma split_indicator:
    32   "P (indicator S x) \<longleftrightarrow> ((x \<in> S \<longrightarrow> P 1) \<and> (x \<notin> S \<longrightarrow> P 0))"
    33   unfolding indicator_def by auto
    34 
    35 lemma indicator_inter_arith: "indicator (A \<inter> B) x = indicator A x * (indicator B x::'a::semiring_1)"
    36   unfolding indicator_def by (auto simp: min_def max_def)
    37 
    38 lemma indicator_union_arith: "indicator (A \<union> B) x =  indicator A x + indicator B x - indicator A x * (indicator B x::'a::ring_1)"
    39   unfolding indicator_def by (auto simp: min_def max_def)
    40 
    41 lemma indicator_inter_min: "indicator (A \<inter> B) x = min (indicator A x) (indicator B x::'a::linordered_semidom)"
    42   and indicator_union_max: "indicator (A \<union> B) x = max (indicator A x) (indicator B x::'a::linordered_semidom)"
    43   unfolding indicator_def by (auto simp: min_def max_def)
    44 
    45 lemma indicator_compl: "indicator (- A) x = 1 - (indicator A x::'a::ring_1)"
    46   and indicator_diff: "indicator (A - B) x = indicator A x * (1 - indicator B x::'a::ring_1)"
    47   unfolding indicator_def by (auto simp: min_def max_def)
    48 
    49 lemma indicator_times: "indicator (A \<times> B) x = indicator A (fst x) * (indicator B (snd x)::'a::semiring_1)"
    50   unfolding indicator_def by (cases x) auto
    51 
    52 lemma indicator_sum: "indicator (A <+> B) x = (case x of Inl x \<Rightarrow> indicator A x | Inr x \<Rightarrow> indicator B x)"
    53   unfolding indicator_def by (cases x) auto
    54 
    55 lemma
    56   fixes f :: "'a \<Rightarrow> 'b::semiring_1" assumes "finite A"
    57   shows setsum_mult_indicator[simp]: "(\<Sum>x \<in> A. f x * indicator B x) = (\<Sum>x \<in> A \<inter> B. f x)"
    58   and setsum_indicator_mult[simp]: "(\<Sum>x \<in> A. indicator B x * f x) = (\<Sum>x \<in> A \<inter> B. f x)"
    59   unfolding indicator_def
    60   using assms by (auto intro!: setsum_mono_zero_cong_right split: split_if_asm)
    61 
    62 lemma setsum_indicator_eq_card:
    63   assumes "finite A"
    64   shows "(SUM x : A. indicator B x) = card (A Int B)"
    65   using setsum_mult_indicator[OF assms, of "%x. 1::nat"]
    66   unfolding card_eq_setsum by simp
    67 
    68 end