src/Pure/library.ML
author wenzelm
Mon Nov 05 15:00:22 2018 +0100 (7 months ago)
changeset 69237 76696742fd30
parent 68149 9a4a6adb95b5
child 69468 54a95e1199cb
permissions -rw-r--r--
tuned (see map_index);
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*pairs*)
    32   val pair: 'a -> 'b -> 'a * 'b
    33   val rpair: 'a -> 'b -> 'b * 'a
    34   val fst: 'a * 'b -> 'a
    35   val snd: 'a * 'b -> 'b
    36   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    37   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    38   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    39   val swap: 'a * 'b -> 'b * 'a
    40   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    41   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    42   val apply2: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    43 
    44   (*booleans*)
    45   val equal: ''a -> ''a -> bool
    46   val not_equal: ''a -> ''a -> bool
    47   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    48   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    49   val exists: ('a -> bool) -> 'a list -> bool
    50   val forall: ('a -> bool) -> 'a list -> bool
    51 
    52   (*lists*)
    53   val single: 'a -> 'a list
    54   val the_single: 'a list -> 'a
    55   val singleton: ('a list -> 'b list) -> 'a -> 'b
    56   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    57   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    58   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    59   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    60   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    61   val eq_list: ('a * 'a -> bool) -> 'a list * 'a list -> bool
    62   val maps: ('a -> 'b list) -> 'a list -> 'b list
    63   val filter: ('a -> bool) -> 'a list -> 'a list
    64   val filter_out: ('a -> bool) -> 'a list -> 'a list
    65   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    66   val take: int -> 'a list -> 'a list
    67   val drop: int -> 'a list -> 'a list
    68   val chop: int -> 'a list -> 'a list * 'a list
    69   val chop_groups: int -> 'a list -> 'a list list
    70   val nth: 'a list -> int -> 'a
    71   val nth_list: 'a list list -> int -> 'a list
    72   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    73   val nth_drop: int -> 'a list -> 'a list
    74   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    75   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    76   val map_range: (int -> 'a) -> int -> 'a list
    77   val fold_range: (int -> 'a -> 'a) -> int -> 'a -> 'a
    78   val split_last: 'a list -> 'a list * 'a
    79   val find_first: ('a -> bool) -> 'a list -> 'a option
    80   val find_index: ('a -> bool) -> 'a list -> int
    81   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    82   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    83   val flat: 'a list list -> 'a list
    84   val unflat: 'a list list -> 'b list -> 'b list list
    85   val grouped: int -> (('a list -> 'b list) -> 'c list list -> 'd list list) ->
    86     ('a -> 'b) -> 'c list -> 'd list
    87   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    88   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    89   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    90   val separate: 'a -> 'a list -> 'a list
    91   val surround: 'a -> 'a list -> 'a list
    92   val replicate: int -> 'a -> 'a list
    93   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    94   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    95   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    96   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    97   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
    98   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
    99   val ~~ : 'a list * 'b list -> ('a * 'b) list
   100   val split_list: ('a * 'b) list -> 'a list * 'b list
   101   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
   102   val take_prefix: ('a -> bool) -> 'a list -> 'a list
   103   val drop_prefix: ('a -> bool) -> 'a list -> 'a list
   104   val chop_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   105   val take_suffix: ('a -> bool) -> 'a list -> 'a list
   106   val drop_suffix: ('a -> bool) -> 'a list -> 'a list
   107   val chop_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   108   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   109   val chop_common_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   110   val prefixes1: 'a list -> 'a list list
   111   val prefixes: 'a list -> 'a list list
   112   val suffixes1: 'a list -> 'a list list
   113   val suffixes: 'a list -> 'a list list
   114   val trim: ('a -> bool) -> 'a list -> 'a list
   115 
   116   (*integers*)
   117   val upto: int * int -> int list
   118   val downto: int * int -> int list
   119   val hex_digit: int -> string
   120   val radixpand: int * int -> int list
   121   val radixstring: int * string * int -> string
   122   val string_of_int: int -> string
   123   val signed_string_of_int: int -> string
   124   val string_of_indexname: string * int -> string
   125   val read_radix_int: int -> string list -> int * string list
   126   val read_int: string list -> int * string list
   127   val oct_char: string -> string
   128 
   129   (*strings*)
   130   val nth_string: string -> int -> string
   131   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   132   val exists_string: (string -> bool) -> string -> bool
   133   val forall_string: (string -> bool) -> string -> bool
   134   val first_field: string -> string -> (string * string) option
   135   val enclose: string -> string -> string -> string
   136   val unenclose: string -> string
   137   val quote: string -> string
   138   val cartouche: string -> string
   139   val space_implode: string -> string list -> string
   140   val commas: string list -> string
   141   val commas_quote: string list -> string
   142   val cat_lines: string list -> string
   143   val space_explode: string -> string -> string list
   144   val split_lines: string -> string list
   145   val plain_words: string -> string
   146   val prefix_lines: string -> string -> string
   147   val prefix: string -> string -> string
   148   val suffix: string -> string -> string
   149   val unprefix: string -> string -> string
   150   val unsuffix: string -> string -> string
   151   val trim_line: string -> string
   152   val trim_split_lines: string -> string list
   153   val normalize_lines: string -> string
   154   val replicate_string: int -> string -> string
   155   val translate_string: (string -> string) -> string -> string
   156   val encode_lines: string -> string
   157   val decode_lines: string -> string
   158   val align_right: string -> int -> string -> string
   159   val match_string: string -> string -> bool
   160 
   161   (*reals*)
   162   val string_of_real: real -> string
   163   val signed_string_of_real: real -> string
   164 
   165   (*lists as sets -- see also Pure/General/ord_list.ML*)
   166   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   167   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   168   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   169   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   170   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   171   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   172   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   173   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   174   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   175   val eq_set: ('a * 'a -> bool) -> 'a list * 'a list -> bool
   176   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   177   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   178   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   179   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   180 
   181   (*lists as multisets*)
   182   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   183   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   184   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   185 
   186   (*orders*)
   187   val is_equal: order -> bool
   188   val is_less: order -> bool
   189   val is_less_equal: order -> bool
   190   val is_greater: order -> bool
   191   val is_greater_equal: order -> bool
   192   val rev_order: order -> order
   193   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   194   val bool_ord: bool * bool -> order
   195   val int_ord: int * int -> order
   196   val string_ord: string * string -> order
   197   val fast_string_ord: string * string -> order
   198   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   199   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   200   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   201   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   202   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   203   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   204   val sort_strings: string list -> string list
   205   val sort_by: ('a -> string) -> 'a list -> 'a list
   206   val tag_list: int -> 'a list -> (int * 'a) list
   207   val untag_list: (int * 'a) list -> 'a list
   208   val order_list: (int * 'a) list -> 'a list
   209 
   210   (*misc*)
   211   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   212   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   213     'a -> 'b -> 'c * 'b
   214   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   215   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   216   type serial = int
   217   val serial: unit -> serial
   218   val serial_string: unit -> string
   219   eqtype stamp
   220   val stamp: unit -> stamp
   221   structure Any: sig type T = exn end
   222   val getenv: string -> string
   223   val getenv_strict: string -> string
   224 end;
   225 
   226 signature LIBRARY =
   227 sig
   228   include BASIC_LIBRARY
   229   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   230   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   231 end;
   232 
   233 structure Library: LIBRARY =
   234 struct
   235 
   236 (* functions *)
   237 
   238 fun undefined _ = raise Match;
   239 
   240 fun I x = x;
   241 fun K x = fn _ => x;
   242 fun curry f x y = f (x, y);
   243 fun uncurry f (x, y) = f x y;
   244 
   245 (*conditional application*)
   246 fun b ? f = fn x => if b then f x else x;
   247 
   248 (*composition with multiple args*)
   249 fun (f oo g) x y = f (g x y);
   250 fun (f ooo g) x y z = f (g x y z);
   251 fun (f oooo g) x y z w = f (g x y z w);
   252 
   253 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   254 fun funpow (0 : int) _ = I
   255   | funpow n f = f #> funpow (n - 1) f;
   256 
   257 fun funpow_yield (0 : int) _ x = ([], x)
   258   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   259 
   260 
   261 (* pairs *)
   262 
   263 fun pair x y = (x, y);
   264 fun rpair x y = (y, x);
   265 
   266 fun fst (x, y) = x;
   267 fun snd (x, y) = y;
   268 
   269 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   270 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   271 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   272 
   273 fun swap (x, y) = (y, x);
   274 
   275 fun apfst f (x, y) = (f x, y);
   276 fun apsnd f (x, y) = (x, f y);
   277 fun apply2 f (x, y) = (f x, f y);
   278 
   279 
   280 (* booleans *)
   281 
   282 (*polymorphic equality*)
   283 fun equal x y = x = y;
   284 fun not_equal x y = x <> y;
   285 
   286 (*combining predicates*)
   287 fun p orf q = fn x => p x orelse q x;
   288 fun p andf q = fn x => p x andalso q x;
   289 
   290 val exists = List.exists;
   291 val forall = List.all;
   292 
   293 
   294 
   295 (** lists **)
   296 
   297 fun single x = [x];
   298 
   299 fun the_single [x] = x
   300   | the_single _ = raise List.Empty;
   301 
   302 fun singleton f x = the_single (f [x]);
   303 
   304 fun yield_singleton f x = f [x] #>> the_single;
   305 
   306 fun perhaps_apply funs arg =
   307   let
   308     fun app [] res = res
   309       | app (f :: fs) (changed, x) =
   310           (case f x of
   311             NONE => app fs (changed, x)
   312           | SOME x' => app fs (true, x'));
   313   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   314 
   315 fun perhaps_loop f arg =
   316   let
   317     fun loop (changed, x) =
   318       (case f x of
   319         NONE => (changed, x)
   320       | SOME x' => loop (true, x'));
   321   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   322 
   323 
   324 (* fold -- old versions *)
   325 
   326 (*the following versions of fold are designed to fit nicely with infixes*)
   327 
   328 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   329     for operators that associate to the left (TAIL RECURSIVE)*)
   330 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   331   let fun itl (e, [])  = e
   332         | itl (e, a::l) = itl (f(e, a), l)
   333   in  itl end;
   334 
   335 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   336     for operators that associate to the right (not tail recursive)*)
   337 fun foldr f (l, e) =
   338   let fun itr [] = e
   339         | itr (a::l) = f(a, itr l)
   340   in  itr l  end;
   341 
   342 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   343     for operators that associate to the left (TAIL RECURSIVE)*)
   344 fun foldl1 f [] = raise List.Empty
   345   | foldl1 f (x :: xs) = foldl f (x, xs);
   346 
   347 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   348     for n > 0, operators that associate to the right (not tail recursive)*)
   349 fun foldr1 f [] = raise List.Empty
   350   | foldr1 f l =
   351       let fun itr [x] = x
   352             | itr (x::l) = f(x, itr l)
   353       in  itr l  end;
   354 
   355 
   356 (* basic list functions *)
   357 
   358 fun eq_list eq (list1, list2) =
   359   pointer_eq (list1, list2) orelse
   360     let
   361       fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   362         | eq_lst _ = true;
   363     in length list1 = length list2 andalso eq_lst (list1, list2) end;
   364 
   365 fun maps f [] = []
   366   | maps f (x :: xs) = f x @ maps f xs;
   367 
   368 val filter = List.filter;
   369 fun filter_out f = filter (not o f);
   370 val map_filter = List.mapPartial;
   371 
   372 fun take (0: int) xs = []
   373   | take _ [] = []
   374   | take n (x :: xs) = x :: take (n - 1) xs;
   375 
   376 fun drop (0: int) xs = xs
   377   | drop _ [] = []
   378   | drop n (x :: xs) = drop (n - 1) xs;
   379 
   380 fun chop (0: int) xs = ([], xs)
   381   | chop _ [] = ([], [])
   382   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   383 
   384 fun chop_groups n list =
   385   (case chop (Int.max (n, 1)) list of
   386     ([], _) => []
   387   | (g, rest) => g :: chop_groups n rest);
   388 
   389 
   390 (*return nth element of a list, where 0 designates the first element;
   391   raise Subscript if list too short*)
   392 fun nth xs i = List.nth (xs, i);
   393 
   394 fun nth_list xss i = nth xss i handle General.Subscript => [];
   395 
   396 fun nth_map 0 f (x :: xs) = f x :: xs
   397   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   398   | nth_map (_: int) _ [] = raise Subscript;
   399 
   400 fun nth_drop n xs =
   401   List.take (xs, n) @ List.drop (xs, n + 1);
   402 
   403 fun map_index f =
   404   let
   405     fun map_aux (_: int) [] = []
   406       | map_aux i (x :: xs) = f (i, x) :: map_aux (i + 1) xs
   407   in map_aux 0 end;
   408 
   409 fun fold_index f =
   410   let
   411     fun fold_aux (_: int) [] y = y
   412       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y)
   413   in fold_aux 0 end;
   414 
   415 fun map_range f i =
   416   let
   417     fun map_aux (k: int) =
   418       if k < i then f k :: map_aux (k + 1) else []
   419   in map_aux 0 end;
   420 
   421 fun fold_range f i =
   422   let
   423     fun fold_aux (k: int) y =
   424       if k < i then fold_aux (k + 1) (f k y) else y
   425   in fold_aux 0 end;
   426 
   427 
   428 (*rear decomposition*)
   429 fun split_last [] = raise List.Empty
   430   | split_last [x] = ([], x)
   431   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   432 
   433 (*find first element satisfying predicate*)
   434 val find_first = List.find;
   435 
   436 (*find position of first element satisfying a predicate*)
   437 fun find_index pred =
   438   let fun find (_: int) [] = ~1
   439         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   440   in find 0 end;
   441 
   442 (*get first element by lookup function*)
   443 fun get_first _ [] = NONE
   444   | get_first f (x :: xs) =
   445       (case f x of
   446         NONE => get_first f xs
   447       | some => some);
   448 
   449 fun get_index f =
   450   let
   451     fun get_aux (_: int) [] = NONE
   452       | get_aux i (x :: xs) =
   453           (case f x of
   454             NONE => get_aux (i + 1) xs
   455           | SOME y => SOME (i, y))
   456   in get_aux 0 end;
   457 
   458 val flat = List.concat;
   459 
   460 fun unflat (xs :: xss) ys =
   461       let val (ps, qs) = chop (length xs) ys
   462       in ps :: unflat xss qs end
   463   | unflat [] [] = []
   464   | unflat _ _ = raise ListPair.UnequalLengths;
   465 
   466 fun grouped n comb f = chop_groups n #> comb (map f) #> flat;
   467 
   468 fun burrow f xss = unflat xss (f (flat xss));
   469 
   470 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   471 
   472 fun fold_burrow f xss s =
   473   apfst (unflat xss) (f (flat xss) s);
   474 
   475 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   476 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   477   | separate _ xs = xs;
   478 
   479 fun surround s (x :: xs) = s :: x :: surround s xs
   480   | surround s [] = [s];
   481 
   482 (*make the list [x, x, ..., x] of length n*)
   483 fun replicate (n: int) x =
   484   let fun rep (0, xs) = xs
   485         | rep (n, xs) = rep (n - 1, x :: xs)
   486   in
   487     if n < 0 then raise Subscript
   488     else rep (n, [])
   489   end;
   490 
   491 
   492 (* direct product *)
   493 
   494 fun map_product f _ [] = []
   495   | map_product f [] _ = []
   496   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   497 
   498 fun fold_product f _ [] z = z
   499   | fold_product f [] _ z = z
   500   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   501 
   502 
   503 (* lists of pairs *)
   504 
   505 fun map2 _ [] [] = []
   506   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   507   | map2 _ _ _ = raise ListPair.UnequalLengths;
   508 
   509 fun fold2 _ [] [] z = z
   510   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   511   | fold2 _ _ _ _ = raise ListPair.UnequalLengths;
   512 
   513 fun map_split _ [] = ([], [])
   514   | map_split f (x :: xs) =
   515       let
   516         val (y, w) = f x;
   517         val (ys, ws) = map_split f xs;
   518       in (y :: ys, w :: ws) end;
   519 
   520 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   521   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   522   | zip_options _ [] = []
   523   | zip_options [] _ = raise ListPair.UnequalLengths;
   524 
   525 (*combine two lists forming a list of pairs:
   526   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   527 fun [] ~~ [] = []
   528   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   529   | _ ~~ _ = raise ListPair.UnequalLengths;
   530 
   531 (*inverse of ~~; the old 'split':
   532   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   533 val split_list = ListPair.unzip;
   534 
   535 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   536 
   537 
   538 (* take, drop, chop, trim according to predicate *)
   539 
   540 fun take_prefix pred list =
   541   let
   542     fun take res (x :: xs) = if pred x then take (x :: res) xs else rev res
   543       | take res [] = rev res;
   544   in take [] list end;
   545 
   546 fun drop_prefix pred list =
   547   let
   548     fun drop (x :: xs) = if pred x then drop xs else x :: xs
   549       | drop [] = [];
   550   in drop list end;
   551 
   552 fun chop_prefix pred list =
   553   let
   554     val prfx = take_prefix pred list;
   555     val sffx = drop (length prfx) list;
   556   in (prfx, sffx) end;
   557 
   558 fun take_suffix pred list =
   559   let
   560     fun take res (x :: xs) = if pred x then take (x :: res) xs else res
   561       | take res [] = res;
   562   in take [] (rev list) end;
   563 
   564 fun drop_suffix pred list =
   565   let
   566     fun drop (x :: xs) = if pred x then drop xs else rev (x :: xs)
   567       | drop [] = [];
   568   in drop (rev list) end;
   569 
   570 fun chop_suffix pred list =
   571   let
   572     val prfx = drop_suffix pred list;
   573     val sffx = drop (length prfx) list;
   574   in (prfx, sffx) end;
   575 
   576 fun trim pred = drop_prefix pred #> drop_suffix pred;
   577 
   578 
   579 (* prefixes, suffixes *)
   580 
   581 fun is_prefix _ [] _ = true
   582   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   583   | is_prefix eq _ _ = false;
   584 
   585 fun chop_common_prefix eq ([], ys) = ([], ([], ys))
   586   | chop_common_prefix eq (xs, []) = ([], (xs, []))
   587   | chop_common_prefix eq (xs as x :: xs', ys as y :: ys') =
   588       if eq (x, y) then
   589         let val (ps', xys'') = chop_common_prefix eq (xs', ys')
   590         in (x :: ps', xys'') end
   591       else ([], (xs, ys));
   592 
   593 fun prefixes1 [] = []
   594   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   595 
   596 fun prefixes xs = [] :: prefixes1 xs;
   597 
   598 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   599 fun suffixes xs = [] :: suffixes1 xs;
   600 
   601 
   602 (** integers **)
   603 
   604 (* lists of integers *)
   605 
   606 (*make the list [from, from + 1, ..., to]*)
   607 fun ((i: int) upto j) =
   608   if i > j then [] else i :: (i + 1 upto j);
   609 
   610 (*make the list [from, from - 1, ..., to]*)
   611 fun ((i: int) downto j) =
   612   if i < j then [] else i :: (i - 1 downto j);
   613 
   614 
   615 (* convert integers to strings *)
   616 
   617 (*hexadecimal*)
   618 fun hex_digit i =
   619   if i < 10 then chr (Char.ord #"0" + i) else chr (Char.ord #"a" + i - 10);
   620 
   621 (*expand the number in the given base;
   622   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   623 fun radixpand (base, num) : int list =
   624   let
   625     fun radix (n, tail) =
   626       if n < base then n :: tail
   627       else radix (n div base, (n mod base) :: tail)
   628   in radix (num, []) end;
   629 
   630 (*expands a number into a string of characters starting from "zerochar";
   631   example: radixstring (2, "0", 8) gives "1000"*)
   632 fun radixstring (base, zerochar, num) =
   633   let val offset = ord zerochar;
   634       fun chrof n = chr (offset + n)
   635   in implode (map chrof (radixpand (base, num))) end;
   636 
   637 
   638 local
   639   val zero = Char.ord #"0";
   640   val small_int = 10000: int;
   641   val small_int_table = Vector.tabulate (small_int, Int.toString);
   642 in
   643 
   644 fun string_of_int i =
   645   if i < 0 then Int.toString i
   646   else if i < 10 then chr (zero + i)
   647   else if i < small_int then Vector.sub (small_int_table, i)
   648   else Int.toString i;
   649 
   650 end;
   651 
   652 fun signed_string_of_int i =
   653   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   654 
   655 fun string_of_indexname (a, 0) = a
   656   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   657 
   658 
   659 (* read integers *)
   660 
   661 fun read_radix_int radix cs =
   662   let
   663     val zero = Char.ord #"0";
   664     val limit = zero + radix;
   665     fun scan (num, []) = (num, [])
   666       | scan (num, c :: cs) =
   667           if zero <= ord c andalso ord c < limit then
   668             scan (radix * num + (ord c - zero), cs)
   669           else (num, c :: cs);
   670   in scan (0, cs) end;
   671 
   672 val read_int = read_radix_int 10;
   673 
   674 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   675 
   676 
   677 
   678 (** strings **)
   679 
   680 (* functions tuned for strings, avoiding explode *)
   681 
   682 fun nth_string str i =
   683   (case try String.substring (str, i, 1) of
   684     SOME s => s
   685   | NONE => raise Subscript);
   686 
   687 fun fold_string f str x0 =
   688   let
   689     val n = size str;
   690     fun iter (x, i) =
   691       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   692   in iter (x0, 0) end;
   693 
   694 fun exists_string pred str =
   695   let
   696     val n = size str;
   697     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   698   in ex 0 end;
   699 
   700 fun forall_string pred = not o exists_string (not o pred);
   701 
   702 fun first_field sep str =
   703   let
   704     val n = size sep;
   705     val len = size str;
   706     fun find i =
   707       if i + n > len then NONE
   708       else if String.substring (str, i, n) = sep then SOME i
   709       else find (i + 1);
   710   in
   711     (case find 0 of
   712       NONE => NONE
   713     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   714   end;
   715 
   716 (*enclose in brackets*)
   717 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   718 fun unenclose str = String.substring (str, 1, size str - 2);
   719 
   720 (*simple quoting (does not escape special chars)*)
   721 val quote = enclose "\"" "\"";
   722 
   723 val cartouche = enclose "\<open>" "\<close>";
   724 
   725 val space_implode = String.concatWith;
   726 
   727 val commas = space_implode ", ";
   728 val commas_quote = commas o map quote;
   729 
   730 val cat_lines = space_implode "\n";
   731 
   732 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   733 fun space_explode _ "" = []
   734   | space_explode sep s = String.fields (fn c => str c = sep) s;
   735 
   736 val split_lines = space_explode "\n";
   737 
   738 fun plain_words s = space_explode "_" s |> space_implode " ";
   739 
   740 fun prefix_lines "" txt = txt
   741   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   742 
   743 fun prefix prfx s = prfx ^ s;
   744 fun suffix sffx s = s ^ sffx;
   745 
   746 fun unprefix prfx s =
   747   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   748   else raise Fail "unprefix";
   749 
   750 fun unsuffix sffx s =
   751   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   752   else raise Fail "unsuffix";
   753 
   754 fun trim_line s =
   755   if String.isSuffix "\r\n" s
   756   then String.substring (s, 0, size s - 2)
   757   else if String.isSuffix "\r" s orelse String.isSuffix "\n" s
   758   then String.substring (s, 0, size s - 1)
   759   else s;
   760 
   761 val trim_split_lines = trim_line #> split_lines #> map trim_line;
   762 
   763 fun normalize_lines str =
   764   if exists_string (fn s => s = "\r") str then
   765     split_lines str |> map trim_line |> cat_lines
   766   else str;
   767 
   768 fun replicate_string (0: int) _ = ""
   769   | replicate_string 1 a = a
   770   | replicate_string k a =
   771       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   772       else replicate_string (k div 2) (a ^ a) ^ a;
   773 
   774 fun translate_string f = String.translate (f o String.str);
   775 
   776 val encode_lines = translate_string (fn "\n" => "\v" | c => c);
   777 val decode_lines = translate_string (fn "\v" => "\n" | c => c);
   778 
   779 fun align_right c k s =
   780   let
   781     val _ = if size c <> 1 orelse size s > k
   782       then raise Fail "align_right" else ()
   783   in replicate_string (k - size s) c ^ s end;
   784 
   785 (*crude matching of str against simple glob pat*)
   786 fun match_string pat str =
   787   let
   788     fun match [] _ = true
   789       | match (p :: ps) s =
   790           size p <= size s andalso
   791             (case try (unprefix p) s of
   792               SOME s' => match ps s'
   793             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   794   in match (space_explode "*" pat) str end;
   795 
   796 
   797 (** reals **)
   798 
   799 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   800 
   801 fun signed_string_of_real x =
   802   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   803 
   804 
   805 
   806 (** lists as sets -- see also Pure/General/ord_list.ML **)
   807 
   808 (* canonical operations *)
   809 
   810 fun member eq list x =
   811   let
   812     fun memb [] = false
   813       | memb (y :: ys) = eq (x, y) orelse memb ys;
   814   in memb list end;
   815 
   816 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   817 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   818 fun update eq x xs = cons x (remove eq x xs);
   819 
   820 fun inter eq xs = filter (member eq xs);
   821 
   822 fun union eq = fold (insert eq);
   823 fun subtract eq = fold (remove eq);
   824 
   825 fun merge eq (xs, ys) =
   826   if pointer_eq (xs, ys) then xs
   827   else if null xs then ys
   828   else fold_rev (insert eq) ys xs;
   829 
   830 
   831 (* subset and set equality *)
   832 
   833 fun subset eq (xs, ys) = forall (member eq ys) xs;
   834 
   835 fun eq_set eq (xs, ys) =
   836   eq_list eq (xs, ys) orelse
   837     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   838 
   839 
   840 (*makes a list of the distinct members of the input; preserves order, takes
   841   first of equal elements*)
   842 fun distinct eq lst =
   843   let
   844     fun dist (rev_seen, []) = rev rev_seen
   845       | dist (rev_seen, x :: xs) =
   846           if member eq rev_seen x then dist (rev_seen, xs)
   847           else dist (x :: rev_seen, xs);
   848   in dist ([], lst) end;
   849 
   850 (*returns a list containing all repeated elements exactly once; preserves
   851   order, takes first of equal elements*)
   852 fun duplicates eq lst =
   853   let
   854     fun dups (rev_dups, []) = rev rev_dups
   855       | dups (rev_dups, x :: xs) =
   856           if member eq rev_dups x orelse not (member eq xs x) then
   857             dups (rev_dups, xs)
   858           else dups (x :: rev_dups, xs);
   859   in dups ([], lst) end;
   860 
   861 fun has_duplicates eq =
   862   let
   863     fun dups [] = false
   864       | dups (x :: xs) = member eq xs x orelse dups xs;
   865   in dups end;
   866 
   867 
   868 (* matrices *)
   869 
   870 fun map_transpose f xss =
   871   let
   872     val n =
   873       (case distinct (op =) (map length xss) of
   874         [] => 0
   875       | [n] => n
   876       | _ => raise ListPair.UnequalLengths);
   877   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   878 
   879 
   880 
   881 (** lists as multisets **)
   882 
   883 fun remove1 eq x [] = []
   884   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   885 
   886 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   887 
   888 fun submultiset _ ([], _)  = true
   889   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   890 
   891 
   892 
   893 (** orders **)
   894 
   895 fun is_equal ord = ord = EQUAL;
   896 fun is_less ord = ord = LESS;
   897 fun is_less_equal ord = ord = LESS orelse ord = EQUAL;
   898 fun is_greater ord = ord = GREATER;
   899 fun is_greater_equal ord = ord = GREATER orelse ord = EQUAL;
   900 
   901 fun rev_order LESS = GREATER
   902   | rev_order EQUAL = EQUAL
   903   | rev_order GREATER = LESS;
   904 
   905 (*assume rel is a linear strict order*)
   906 fun make_ord rel (x, y) =
   907   if rel (x, y) then LESS
   908   else if rel (y, x) then GREATER
   909   else EQUAL;
   910 
   911 fun bool_ord (false, true) = LESS
   912   | bool_ord (true, false) = GREATER
   913   | bool_ord _ = EQUAL;
   914 
   915 val int_ord = Int.compare;
   916 val string_ord = String.compare;
   917 
   918 fun fast_string_ord (s1, s2) =
   919   if pointer_eq (s1, s2) then EQUAL
   920   else (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   921 
   922 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   923   | option_ord _ (NONE, NONE) = EQUAL
   924   | option_ord _ (NONE, SOME _) = LESS
   925   | option_ord _ (SOME _, NONE) = GREATER;
   926 
   927 (*lexicographic product*)
   928 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   929   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   930 
   931 (*dictionary order -- in general NOT well-founded!*)
   932 fun dict_ord elem_ord (x :: xs, y :: ys) =
   933       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   934   | dict_ord _ ([], []) = EQUAL
   935   | dict_ord _ ([], _ :: _) = LESS
   936   | dict_ord _ (_ :: _, []) = GREATER;
   937 
   938 (*lexicographic product of lists*)
   939 fun list_ord elem_ord (xs, ys) =
   940   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   941 
   942 
   943 (* sorting *)
   944 
   945 (*stable mergesort -- preserves order of equal elements*)
   946 fun mergesort unique ord =
   947   let
   948     fun merge (xs as x :: xs') (ys as y :: ys') =
   949           (case ord (x, y) of
   950             LESS => x :: merge xs' ys
   951           | EQUAL =>
   952               if unique then merge xs ys'
   953               else x :: merge xs' ys
   954           | GREATER => y :: merge xs ys')
   955       | merge [] ys = ys
   956       | merge xs [] = xs;
   957 
   958     fun merge_all [xs] = xs
   959       | merge_all xss = merge_all (merge_pairs xss)
   960     and merge_pairs (xs :: ys :: xss) = merge xs ys :: merge_pairs xss
   961       | merge_pairs xss = xss;
   962 
   963     fun runs (x :: y :: xs) =
   964           (case ord (x, y) of
   965              LESS => ascending y [x] xs
   966            | EQUAL =>
   967                if unique then runs (x :: xs)
   968                else ascending y [x] xs
   969            | GREATER => descending y [x] xs)
   970       | runs xs = [xs]
   971 
   972     and ascending x xs (zs as y :: ys) =
   973           (case ord (x, y) of
   974              LESS => ascending y (x :: xs) ys
   975            | EQUAL =>
   976                if unique then ascending x xs ys
   977                else ascending y (x :: xs) ys
   978            | GREATER => rev (x :: xs) :: runs zs)
   979       | ascending x xs [] = [rev (x :: xs)]
   980 
   981     and descending x xs (zs as y :: ys) =
   982           (case ord (x, y) of
   983              GREATER => descending y (x :: xs) ys
   984            | EQUAL =>
   985                if unique then descending x xs ys
   986                else (x :: xs) :: runs zs
   987            | LESS => (x :: xs) :: runs zs)
   988       | descending x xs [] = [x :: xs];
   989 
   990   in merge_all o runs end;
   991 
   992 fun sort ord = mergesort false ord;
   993 fun sort_distinct ord = mergesort true ord;
   994 
   995 val sort_strings = sort string_ord;
   996 fun sort_by key xs = sort (string_ord o apply2 key) xs;
   997 
   998 
   999 (* items tagged by integer index *)
  1000 
  1001 (*insert tags*)
  1002 fun tag_list k [] = []
  1003   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
  1004 
  1005 (*remove tags and suppress duplicates -- list is assumed sorted!*)
  1006 fun untag_list [] = []
  1007   | untag_list [(k: int, x)] = [x]
  1008   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
  1009       if k = k' then untag_list rest
  1010       else x :: untag_list rest;
  1011 
  1012 (*return list elements in original order*)
  1013 fun order_list list = untag_list (sort (int_ord o apply2 fst) list);
  1014 
  1015 
  1016 
  1017 (** misc **)
  1018 
  1019 fun divide_and_conquer decomp x =
  1020   let val (ys, recomb) = decomp x
  1021   in recomb (map (divide_and_conquer decomp) ys) end;
  1022 
  1023 fun divide_and_conquer' decomp x s =
  1024   let val ((ys, recomb), s') = decomp x s
  1025   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1026 
  1027 
  1028 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1029    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1030 fun partition_list p i j =
  1031   let
  1032     fun part (k: int) xs =
  1033       if k > j then
  1034         (case xs of
  1035           [] => []
  1036         | _ => raise Fail "partition_list")
  1037       else
  1038         let val (ns, rest) = List.partition (p k) xs
  1039         in ns :: part (k + 1) rest end;
  1040   in part (i: int) end;
  1041 
  1042 fun partition_eq (eq: 'a * 'a -> bool) =
  1043   let
  1044     fun part [] = []
  1045       | part (x :: ys) =
  1046           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1047           in (x :: xs) :: part xs' end;
  1048   in part end;
  1049 
  1050 
  1051 (* serial numbers and abstract stamps *)
  1052 
  1053 type serial = int;
  1054 val serial = Counter.make ();
  1055 val serial_string = string_of_int o serial;
  1056 
  1057 datatype stamp = Stamp of serial;
  1058 fun stamp () = Stamp (serial ());
  1059 
  1060 
  1061 (* values of any type *)
  1062 
  1063 (*note that the builtin exception datatype may be extended by new
  1064   constructors at any time*)
  1065 structure Any = struct type T = exn end;
  1066 
  1067 
  1068 (* getenv *)
  1069 
  1070 fun getenv x =
  1071   (case OS.Process.getEnv x of
  1072     NONE => ""
  1073   | SOME y => y);
  1074 
  1075 fun getenv_strict x =
  1076   (case getenv x of
  1077     "" => error ("Undefined Isabelle environment variable: " ^ quote x)
  1078   | y => y);
  1079 
  1080 end;
  1081 
  1082 structure Basic_Library: BASIC_LIBRARY = Library;
  1083 open Basic_Library;