src/HOL/Product_Type.thy
author haftmann
Tue Aug 07 09:38:44 2007 +0200 (2007-08-07)
changeset 24162 8dfd5dd65d82
parent 23247 b99dce43d252
child 24286 7619080e49f0
permissions -rw-r--r--
split off theory Option for benefit of code generator
     1 (*  Title:      HOL/Product_Type.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Cartesian products *}
     8 
     9 theory Product_Type
    10 imports Typedef Fun
    11 uses ("Tools/split_rule.ML")
    12 begin
    13 
    14 subsection {* Unit *}
    15 
    16 typedef unit = "{True}"
    17 proof
    18   show "True : ?unit" ..
    19 qed
    20 
    21 constdefs
    22   Unity :: unit    ("'(')")
    23   "() == Abs_unit True"
    24 
    25 lemma unit_eq: "u = ()"
    26   by (induct u) (simp add: unit_def Unity_def)
    27 
    28 text {*
    29   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    30   this rule directly --- it loops!
    31 *}
    32 
    33 ML_setup {*
    34   val unit_eq_proc =
    35     let val unit_meta_eq = mk_meta_eq (thm "unit_eq") in
    36       Simplifier.simproc (the_context ()) "unit_eq" ["x::unit"]
    37       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    38     end;
    39 
    40   Addsimprocs [unit_eq_proc];
    41 *}
    42 
    43 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    44   by simp
    45 
    46 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    47   by (rule triv_forall_equality)
    48 
    49 lemma unit_induct [induct type: unit]: "P () ==> P x"
    50   by simp
    51 
    52 text {*
    53   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    54   [source] "%u::unit. f u"}, replacing it by @{term [source]
    55   f} rather than by @{term [source] "%u. f ()"}.
    56 *}
    57 
    58 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
    59   by (rule ext) simp
    60 
    61 
    62 subsection {* Pairs *}
    63 
    64 subsubsection {* Type definition *}
    65 
    66 constdefs
    67   Pair_Rep :: "['a, 'b] => ['a, 'b] => bool"
    68   "Pair_Rep == (%a b. %x y. x=a & y=b)"
    69 
    70 global
    71 
    72 typedef (Prod)
    73   ('a, 'b) "*"    (infixr "*" 20)
    74     = "{f. EX a b. f = Pair_Rep (a::'a) (b::'b)}"
    75 proof
    76   fix a b show "Pair_Rep a b : ?Prod"
    77     by blast
    78 qed
    79 
    80 syntax (xsymbols)
    81   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
    82 syntax (HTML output)
    83   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
    84 
    85 local
    86 
    87 
    88 subsubsection {* Definitions *}
    89 
    90 global
    91 
    92 consts
    93   fst      :: "'a * 'b => 'a"
    94   snd      :: "'a * 'b => 'b"
    95   split    :: "[['a, 'b] => 'c, 'a * 'b] => 'c"
    96   curry    :: "['a * 'b => 'c, 'a, 'b] => 'c"
    97   prod_fun :: "['a => 'b, 'c => 'd, 'a * 'c] => 'b * 'd"
    98   Pair     :: "['a, 'b] => 'a * 'b"
    99   Sigma    :: "['a set, 'a => 'b set] => ('a * 'b) set"
   100 
   101 local
   102 
   103 defs
   104   Pair_def:     "Pair a b == Abs_Prod (Pair_Rep a b)"
   105   fst_def:      "fst p == THE a. EX b. p = Pair a b"
   106   snd_def:      "snd p == THE b. EX a. p = Pair a b"
   107   split_def:    "split == (%c p. c (fst p) (snd p))"
   108   curry_def:    "curry == (%c x y. c (Pair x y))"
   109   prod_fun_def: "prod_fun f g == split (%x y. Pair (f x) (g y))"
   110   Sigma_def [code func]:    "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   111 
   112 abbreviation
   113   Times :: "['a set, 'b set] => ('a * 'b) set"
   114     (infixr "<*>" 80) where
   115   "A <*> B == Sigma A (%_. B)"
   116 
   117 notation (xsymbols)
   118   Times  (infixr "\<times>" 80)
   119 
   120 notation (HTML output)
   121   Times  (infixr "\<times>" 80)
   122 
   123 
   124 subsubsection {* Concrete syntax *}
   125 
   126 text {*
   127   Patterns -- extends pre-defined type @{typ pttrn} used in
   128   abstractions.
   129 *}
   130 
   131 nonterminals
   132   tuple_args patterns
   133 
   134 syntax
   135   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   136   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   137   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   138   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   139   ""            :: "pttrn => patterns"                  ("_")
   140   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   141   "@Sigma" ::"[pttrn, 'a set, 'b set] => ('a * 'b) set" ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   142 
   143 translations
   144   "(x, y)"       == "Pair x y"
   145   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   146   "%(x,y,zs).b"  == "split(%x (y,zs).b)"
   147   "%(x,y).b"     == "split(%x y. b)"
   148   "_abs (Pair x y) t" => "%(x,y).t"
   149   (* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   150      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *)
   151   "SIGMA x:A. B" == "Sigma A (%x. B)"
   152 
   153 (* reconstructs pattern from (nested) splits, avoiding eta-contraction of body*)
   154 (* works best with enclosing "let", if "let" does not avoid eta-contraction   *)
   155 print_translation {*
   156 let fun split_tr' [Abs (x,T,t as (Abs abs))] =
   157       (* split (%x y. t) => %(x,y) t *)
   158       let val (y,t') = atomic_abs_tr' abs;
   159           val (x',t'') = atomic_abs_tr' (x,T,t');
   160     
   161       in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end
   162     | split_tr' [Abs (x,T,(s as Const ("split",_)$t))] =
   163        (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   164        let val (Const ("_abs",_)$(Const ("_pattern",_)$y$z)$t') = split_tr' [t];
   165            val (x',t'') = atomic_abs_tr' (x,T,t');
   166        in Syntax.const "_abs"$ 
   167            (Syntax.const "_pattern"$x'$(Syntax.const "_patterns"$y$z))$t'' end
   168     | split_tr' [Const ("split",_)$t] =
   169        (* split (split (%x y z. t)) => %((x,y),z). t *)   
   170        split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   171     | split_tr' [Const ("_abs",_)$x_y$(Abs abs)] =
   172        (* split (%pttrn z. t) => %(pttrn,z). t *)
   173        let val (z,t) = atomic_abs_tr' abs;
   174        in Syntax.const "_abs" $ (Syntax.const "_pattern" $x_y$z) $ t end
   175     | split_tr' _ =  raise Match;
   176 in [("split", split_tr')]
   177 end
   178 *}
   179 
   180 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   181 typed_print_translation {*
   182 let
   183   fun split_guess_names_tr' _ T [Abs (x,_,Abs _)] = raise Match
   184     | split_guess_names_tr' _ T  [Abs (x,xT,t)] =
   185         (case (head_of t) of
   186            Const ("split",_) => raise Match
   187          | _ => let 
   188                   val (_::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   189                   val (y,t') = atomic_abs_tr' ("y",yT,(incr_boundvars 1 t)$Bound 0); 
   190                   val (x',t'') = atomic_abs_tr' (x,xT,t');
   191                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   192     | split_guess_names_tr' _ T [t] =
   193        (case (head_of t) of
   194            Const ("split",_) => raise Match 
   195          | _ => let 
   196                   val (xT::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   197                   val (y,t') = 
   198                         atomic_abs_tr' ("y",yT,(incr_boundvars 2 t)$Bound 1$Bound 0); 
   199                   val (x',t'') = atomic_abs_tr' ("x",xT,t');
   200                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   201     | split_guess_names_tr' _ _ _ = raise Match;
   202 in [("split", split_guess_names_tr')]
   203 end 
   204 *}
   205 
   206 
   207 subsubsection {* Lemmas and proof tool setup *}
   208 
   209 lemma ProdI: "Pair_Rep a b : Prod"
   210   unfolding Prod_def by blast
   211 
   212 lemma Pair_Rep_inject: "Pair_Rep a b = Pair_Rep a' b' ==> a = a' & b = b'"
   213   apply (unfold Pair_Rep_def)
   214   apply (drule fun_cong [THEN fun_cong], blast)
   215   done
   216 
   217 lemma inj_on_Abs_Prod: "inj_on Abs_Prod Prod"
   218   apply (rule inj_on_inverseI)
   219   apply (erule Abs_Prod_inverse)
   220   done
   221 
   222 lemma Pair_inject:
   223   assumes "(a, b) = (a', b')"
   224     and "a = a' ==> b = b' ==> R"
   225   shows R
   226   apply (insert prems [unfolded Pair_def])
   227   apply (rule inj_on_Abs_Prod [THEN inj_onD, THEN Pair_Rep_inject, THEN conjE])
   228   apply (assumption | rule ProdI)+
   229   done
   230 
   231 lemma Pair_eq [iff]: "((a, b) = (a', b')) = (a = a' & b = b')"
   232   by (blast elim!: Pair_inject)
   233 
   234 lemma fst_conv [simp, code]: "fst (a, b) = a"
   235   unfolding fst_def by blast
   236 
   237 lemma snd_conv [simp, code]: "snd (a, b) = b"
   238   unfolding snd_def by blast
   239 
   240 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   241   by simp
   242 
   243 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   244   by simp
   245 
   246 lemma PairE_lemma: "EX x y. p = (x, y)"
   247   apply (unfold Pair_def)
   248   apply (rule Rep_Prod [unfolded Prod_def, THEN CollectE])
   249   apply (erule exE, erule exE, rule exI, rule exI)
   250   apply (rule Rep_Prod_inverse [symmetric, THEN trans])
   251   apply (erule arg_cong)
   252   done
   253 
   254 lemma PairE [cases type: *]: "(!!x y. p = (x, y) ==> Q) ==> Q"
   255   using PairE_lemma [of p] by blast
   256 
   257 ML {*
   258   local val PairE = thm "PairE" in
   259     fun pair_tac s =
   260       EVERY' [res_inst_tac [("p", s)] PairE, hyp_subst_tac, K prune_params_tac];
   261   end;
   262 *}
   263 
   264 lemma surjective_pairing: "p = (fst p, snd p)"
   265   -- {* Do not add as rewrite rule: invalidates some proofs in IMP *}
   266   by (cases p) simp
   267 
   268 lemmas pair_collapse = surjective_pairing [symmetric]
   269 declare pair_collapse [simp]
   270 
   271 lemma surj_pair [simp]: "EX x y. z = (x, y)"
   272   apply (rule exI)
   273   apply (rule exI)
   274   apply (rule surjective_pairing)
   275   done
   276 
   277 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   278 proof
   279   fix a b
   280   assume "!!x. PROP P x"
   281   then show "PROP P (a, b)" .
   282 next
   283   fix x
   284   assume "!!a b. PROP P (a, b)"
   285   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   286 qed
   287 
   288 lemmas split_tupled_all = split_paired_all unit_all_eq2
   289 
   290 text {*
   291   The rule @{thm [source] split_paired_all} does not work with the
   292   Simplifier because it also affects premises in congrence rules,
   293   where this can lead to premises of the form @{text "!!a b. ... =
   294   ?P(a, b)"} which cannot be solved by reflexivity.
   295 *}
   296 
   297 ML_setup {*
   298   (* replace parameters of product type by individual component parameters *)
   299   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   300   local (* filtering with exists_paired_all is an essential optimization *)
   301     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   302           can HOLogic.dest_prodT T orelse exists_paired_all t
   303       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   304       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   305       | exists_paired_all _ = false;
   306     val ss = HOL_basic_ss
   307       addsimps [thm "split_paired_all", thm "unit_all_eq2", thm "unit_abs_eta_conv"]
   308       addsimprocs [unit_eq_proc];
   309   in
   310     val split_all_tac = SUBGOAL (fn (t, i) =>
   311       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   312     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   313       if exists_paired_all t then full_simp_tac ss i else no_tac);
   314     fun split_all th =
   315    if exists_paired_all (#prop (Thm.rep_thm th)) then full_simplify ss th else th;
   316   end;
   317 
   318 change_claset (fn cs => cs addSbefore ("split_all_tac", split_all_tac));
   319 *}
   320 
   321 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   322   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   323   by fast
   324 
   325 lemma curry_split [simp]: "curry (split f) = f"
   326   by (simp add: curry_def split_def)
   327 
   328 lemma split_curry [simp]: "split (curry f) = f"
   329   by (simp add: curry_def split_def)
   330 
   331 lemma curryI [intro!]: "f (a,b) ==> curry f a b"
   332   by (simp add: curry_def)
   333 
   334 lemma curryD [dest!]: "curry f a b ==> f (a,b)"
   335   by (simp add: curry_def)
   336 
   337 lemma curryE: "[| curry f a b ; f (a,b) ==> Q |] ==> Q"
   338   by (simp add: curry_def)
   339 
   340 lemma curry_conv [simp, code func]: "curry f a b = f (a,b)"
   341   by (simp add: curry_def)
   342 
   343 lemma prod_induct [induct type: *]: "!!x. (!!a b. P (a, b)) ==> P x"
   344   by fast
   345 
   346 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   347   by fast
   348 
   349 lemma split_conv [simp, code func]: "split c (a, b) = c a b"
   350   by (simp add: split_def)
   351 
   352 lemmas split = split_conv  -- {* for backwards compatibility *}
   353 
   354 lemmas splitI = split_conv [THEN iffD2, standard]
   355 lemmas splitD = split_conv [THEN iffD1, standard]
   356 
   357 lemma split_Pair_apply: "split (%x y. f (x, y)) = f"
   358   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   359   apply (rule ext)
   360   apply (tactic {* pair_tac "x" 1 *}, simp)
   361   done
   362 
   363 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   364   -- {* Can't be added to simpset: loops! *}
   365   by (simp add: split_Pair_apply)
   366 
   367 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   368   by (simp add: split_def)
   369 
   370 lemma Pair_fst_snd_eq: "!!s t. (s = t) = (fst s = fst t & snd s = snd t)"
   371 by (simp only: split_tupled_all, simp)
   372 
   373 lemma prod_eqI [intro?]: "fst p = fst q ==> snd p = snd q ==> p = q"
   374   by (simp add: Pair_fst_snd_eq)
   375 
   376 lemma split_weak_cong: "p = q ==> split c p = split c q"
   377   -- {* Prevents simplification of @{term c}: much faster *}
   378   by (erule arg_cong)
   379 
   380 lemma split_eta: "(%(x, y). f (x, y)) = f"
   381   apply (rule ext)
   382   apply (simp only: split_tupled_all)
   383   apply (rule split_conv)
   384   done
   385 
   386 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   387   by (simp add: split_eta)
   388 
   389 text {*
   390   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   391   @{thm [source] split_eta} as a rewrite rule is not general enough,
   392   and using @{thm [source] cond_split_eta} directly would render some
   393   existing proofs very inefficient; similarly for @{text
   394   split_beta}. *}
   395 
   396 ML_setup {*
   397 
   398 local
   399   val cond_split_eta_ss = HOL_basic_ss addsimps [thm "cond_split_eta"]
   400   fun  Pair_pat k 0 (Bound m) = (m = k)
   401   |    Pair_pat k i (Const ("Pair",  _) $ Bound m $ t) = i > 0 andalso
   402                         m = k+i andalso Pair_pat k (i-1) t
   403   |    Pair_pat _ _ _ = false;
   404   fun no_args k i (Abs (_, _, t)) = no_args (k+1) i t
   405   |   no_args k i (t $ u) = no_args k i t andalso no_args k i u
   406   |   no_args k i (Bound m) = m < k orelse m > k+i
   407   |   no_args _ _ _ = true;
   408   fun split_pat tp i (Abs  (_,_,t)) = if tp 0 i t then SOME (i,t) else NONE
   409   |   split_pat tp i (Const ("split", _) $ Abs (_, _, t)) = split_pat tp (i+1) t
   410   |   split_pat tp i _ = NONE;
   411   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   412         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs,rhs)))
   413         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   414 
   415   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k+1) i t
   416   |   beta_term_pat k i (t $ u) = Pair_pat k i (t $ u) orelse
   417                         (beta_term_pat k i t andalso beta_term_pat k i u)
   418   |   beta_term_pat k i t = no_args k i t;
   419   fun  eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   420   |    eta_term_pat _ _ _ = false;
   421   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   422   |   subst arg k i (t $ u) = if Pair_pat k i (t $ u) then incr_boundvars k arg
   423                               else (subst arg k i t $ subst arg k i u)
   424   |   subst arg k i t = t;
   425   fun beta_proc ss (s as Const ("split", _) $ Abs (_, _, t) $ arg) =
   426         (case split_pat beta_term_pat 1 t of
   427         SOME (i,f) => SOME (metaeq ss s (subst arg 0 i f))
   428         | NONE => NONE)
   429   |   beta_proc _ _ = NONE;
   430   fun eta_proc ss (s as Const ("split", _) $ Abs (_, _, t)) =
   431         (case split_pat eta_term_pat 1 t of
   432           SOME (_,ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   433         | NONE => NONE)
   434   |   eta_proc _ _ = NONE;
   435 in
   436   val split_beta_proc = Simplifier.simproc @{theory} "split_beta" ["split f z"] (K beta_proc);
   437   val split_eta_proc = Simplifier.simproc @{theory} "split_eta" ["split f"] (K eta_proc);
   438 end;
   439 
   440 Addsimprocs [split_beta_proc, split_eta_proc];
   441 *}
   442 
   443 lemma split_beta: "(%(x, y). P x y) z = P (fst z) (snd z)"
   444   by (subst surjective_pairing, rule split_conv)
   445 
   446 lemma split_split: "R (split c p) = (ALL x y. p = (x, y) --> R (c x y))"
   447   -- {* For use with @{text split} and the Simplifier. *}
   448   by (insert surj_pair [of p], clarify, simp)
   449 
   450 text {*
   451   @{thm [source] split_split} could be declared as @{text "[split]"}
   452   done after the Splitter has been speeded up significantly;
   453   precompute the constants involved and don't do anything unless the
   454   current goal contains one of those constants.
   455 *}
   456 
   457 lemma split_split_asm: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   458 by (subst split_split, simp)
   459 
   460 
   461 text {*
   462   \medskip @{term split} used as a logical connective or set former.
   463 
   464   \medskip These rules are for use with @{text blast}; could instead
   465   call @{text simp} using @{thm [source] split} as rewrite. *}
   466 
   467 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   468   apply (simp only: split_tupled_all)
   469   apply (simp (no_asm_simp))
   470   done
   471 
   472 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   473   apply (simp only: split_tupled_all)
   474   apply (simp (no_asm_simp))
   475   done
   476 
   477 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   478   by (induct p) (auto simp add: split_def)
   479 
   480 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   481   by (induct p) (auto simp add: split_def)
   482 
   483 lemma splitE2:
   484   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   485 proof -
   486   assume q: "Q (split P z)"
   487   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   488   show R
   489     apply (rule r surjective_pairing)+
   490     apply (rule split_beta [THEN subst], rule q)
   491     done
   492 qed
   493 
   494 lemma splitD': "split R (a,b) c ==> R a b c"
   495   by simp
   496 
   497 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   498   by simp
   499 
   500 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   501 by (simp only: split_tupled_all, simp)
   502 
   503 lemma mem_splitE:
   504   assumes major: "z: split c p"
   505     and cases: "!!x y. [| p = (x,y); z: c x y |] ==> Q"
   506   shows Q
   507   by (rule major [unfolded split_def] cases surjective_pairing)+
   508 
   509 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   510 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   511 
   512 ML_setup {*
   513 local (* filtering with exists_p_split is an essential optimization *)
   514   fun exists_p_split (Const ("split",_) $ _ $ (Const ("Pair",_)$_$_)) = true
   515     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   516     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   517     | exists_p_split _ = false;
   518   val ss = HOL_basic_ss addsimps [thm "split_conv"];
   519 in
   520 val split_conv_tac = SUBGOAL (fn (t, i) =>
   521     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   522 end;
   523 (* This prevents applications of splitE for already splitted arguments leading
   524    to quite time-consuming computations (in particular for nested tuples) *)
   525 change_claset (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac));
   526 *}
   527 
   528 lemma split_eta_SetCompr [simp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   529   by (rule ext) fast
   530 
   531 lemma split_eta_SetCompr2 [simp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   532   by (rule ext) fast
   533 
   534 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   535   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   536   by (rule ext) blast
   537 
   538 (* Do NOT make this a simp rule as it
   539    a) only helps in special situations
   540    b) can lead to nontermination in the presence of split_def
   541 *)
   542 lemma split_comp_eq: 
   543   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   544   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   545   by (rule ext) auto
   546 
   547 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   548   by blast
   549 
   550 (*
   551 the following  would be slightly more general,
   552 but cannot be used as rewrite rule:
   553 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   554 ### ?y = .x
   555 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   556 by (rtac some_equality 1)
   557 by ( Simp_tac 1)
   558 by (split_all_tac 1)
   559 by (Asm_full_simp_tac 1)
   560 qed "The_split_eq";
   561 *)
   562 
   563 lemma injective_fst_snd: "!!x y. [|fst x = fst y; snd x = snd y|] ==> x = y"
   564   by auto
   565 
   566 
   567 text {*
   568   \bigskip @{term prod_fun} --- action of the product functor upon
   569   functions.
   570 *}
   571 
   572 lemma prod_fun [simp, code func]: "prod_fun f g (a, b) = (f a, g b)"
   573   by (simp add: prod_fun_def)
   574 
   575 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   576   apply (rule ext)
   577   apply (tactic {* pair_tac "x" 1 *}, simp)
   578   done
   579 
   580 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   581   apply (rule ext)
   582   apply (tactic {* pair_tac "z" 1 *}, simp)
   583   done
   584 
   585 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   586   apply (rule image_eqI)
   587   apply (rule prod_fun [symmetric], assumption)
   588   done
   589 
   590 lemma prod_fun_imageE [elim!]:
   591   assumes major: "c: (prod_fun f g)`r"
   592     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   593   shows P
   594   apply (rule major [THEN imageE])
   595   apply (rule_tac p = x in PairE)
   596   apply (rule cases)
   597    apply (blast intro: prod_fun)
   598   apply blast
   599   done
   600 
   601 
   602 definition
   603   upd_fst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b"
   604 where
   605   [code func del]: "upd_fst f = prod_fun f id"
   606 
   607 definition
   608   upd_snd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c"
   609 where
   610   [code func del]: "upd_snd f = prod_fun id f"
   611 
   612 lemma upd_fst_conv [simp, code]:
   613   "upd_fst f (x, y) = (f x, y)" 
   614   by (simp add: upd_fst_def)
   615 
   616 lemma upd_snd_conv [simp, code]:
   617   "upd_snd f (x, y) = (x, f y)" 
   618   by (simp add: upd_snd_def)
   619 
   620 text {*
   621   \bigskip Disjoint union of a family of sets -- Sigma.
   622 *}
   623 
   624 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   625   by (unfold Sigma_def) blast
   626 
   627 lemma SigmaE [elim!]:
   628     "[| c: Sigma A B;
   629         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   630      |] ==> P"
   631   -- {* The general elimination rule. *}
   632   by (unfold Sigma_def) blast
   633 
   634 text {*
   635   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   636   eigenvariables.
   637 *}
   638 
   639 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   640   by blast
   641 
   642 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   643   by blast
   644 
   645 lemma SigmaE2:
   646     "[| (a, b) : Sigma A B;
   647         [| a:A;  b:B(a) |] ==> P
   648      |] ==> P"
   649   by blast
   650 
   651 lemma Sigma_cong:
   652      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   653       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   654   by auto
   655 
   656 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   657   by blast
   658 
   659 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   660   by blast
   661 
   662 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   663   by blast
   664 
   665 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   666   by auto
   667 
   668 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   669   by auto
   670 
   671 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   672   by auto
   673 
   674 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   675   by blast
   676 
   677 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   678   by blast
   679 
   680 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   681   by (blast elim: equalityE)
   682 
   683 lemma SetCompr_Sigma_eq:
   684     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   685   by blast
   686 
   687 text {*
   688   \bigskip Complex rules for Sigma.
   689 *}
   690 
   691 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   692   by blast
   693 
   694 lemma UN_Times_distrib:
   695   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   696   -- {* Suggested by Pierre Chartier *}
   697   by blast
   698 
   699 lemma split_paired_Ball_Sigma [simp]:
   700     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   701   by blast
   702 
   703 lemma split_paired_Bex_Sigma [simp]:
   704     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   705   by blast
   706 
   707 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   708   by blast
   709 
   710 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   711   by blast
   712 
   713 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   714   by blast
   715 
   716 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   717   by blast
   718 
   719 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   720   by blast
   721 
   722 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   723   by blast
   724 
   725 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   726   by blast
   727 
   728 text {*
   729   Non-dependent versions are needed to avoid the need for higher-order
   730   matching, especially when the rules are re-oriented.
   731 *}
   732 
   733 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
   734   by blast
   735 
   736 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
   737   by blast
   738 
   739 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
   740   by blast
   741 
   742 
   743 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   744   apply (rule_tac x = "(a, b)" in image_eqI)
   745    apply auto
   746   done
   747 
   748 
   749 text {*
   750   Setup of internal @{text split_rule}.
   751 *}
   752 
   753 constdefs
   754   internal_split :: "('a => 'b => 'c) => 'a * 'b => 'c"
   755   "internal_split == split"
   756 
   757 lemmas [code func del] = internal_split_def
   758 
   759 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   760   by (simp only: internal_split_def split_conv)
   761 
   762 hide const internal_split
   763 
   764 use "Tools/split_rule.ML"
   765 setup SplitRule.setup
   766 
   767 
   768 subsection {* Further lemmas *}
   769 
   770 lemma
   771   split_Pair: "split Pair x = x"
   772   unfolding split_def by auto
   773 
   774 lemma
   775   split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   776   by (cases x, simp)
   777 
   778 
   779 subsection {* Code generator setup *}
   780 
   781 instance unit :: eq ..
   782 
   783 lemma [code func]:
   784   "(u\<Colon>unit) = v \<longleftrightarrow> True" unfolding unit_eq [of u] unit_eq [of v] by rule+
   785 
   786 code_type unit
   787   (SML "unit")
   788   (OCaml "unit")
   789   (Haskell "()")
   790 
   791 code_instance unit :: eq
   792   (Haskell -)
   793 
   794 code_const "op = \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   795   (Haskell infixl 4 "==")
   796 
   797 code_const Unity
   798   (SML "()")
   799   (OCaml "()")
   800   (Haskell "()")
   801 
   802 code_reserved SML
   803   unit
   804 
   805 code_reserved OCaml
   806   unit
   807 
   808 instance * :: (eq, eq) eq ..
   809 
   810 lemma [code func]:
   811   "(x1\<Colon>'a\<Colon>eq, y1\<Colon>'b\<Colon>eq) = (x2, y2) \<longleftrightarrow> x1 = x2 \<and> y1 = y2" by auto
   812 
   813 code_type *
   814   (SML infix 2 "*")
   815   (OCaml infix 2 "*")
   816   (Haskell "!((_),/ (_))")
   817 
   818 code_instance * :: eq
   819   (Haskell -)
   820 
   821 code_const "op = \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   822   (Haskell infixl 4 "==")
   823 
   824 code_const Pair
   825   (SML "!((_),/ (_))")
   826   (OCaml "!((_),/ (_))")
   827   (Haskell "!((_),/ (_))")
   828 
   829 code_const fst and snd
   830   (Haskell "fst" and "snd")
   831 
   832 types_code
   833   "*"     ("(_ */ _)")
   834 attach (term_of) {*
   835 fun term_of_id_42 f T g U (x, y) = HOLogic.pair_const T U $ f x $ g y;
   836 *}
   837 attach (test) {*
   838 fun gen_id_42 aG bG i = (aG i, bG i);
   839 *}
   840 
   841 consts_code
   842   "Pair"    ("(_,/ _)")
   843 
   844 setup {*
   845 
   846 let
   847 
   848 fun strip_abs_split 0 t = ([], t)
   849   | strip_abs_split i (Abs (s, T, t)) =
   850       let
   851         val s' = Codegen.new_name t s;
   852         val v = Free (s', T)
   853       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   854   | strip_abs_split i (u as Const ("split", _) $ t) = (case strip_abs_split (i+1) t of
   855         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   856       | _ => ([], u))
   857   | strip_abs_split i t = ([], t);
   858 
   859 fun let_codegen thy defs gr dep thyname brack t = (case strip_comb t of
   860     (t1 as Const ("Let", _), t2 :: t3 :: ts) =>
   861     let
   862       fun dest_let (l as Const ("Let", _) $ t $ u) =
   863           (case strip_abs_split 1 u of
   864              ([p], u') => apfst (cons (p, t)) (dest_let u')
   865            | _ => ([], l))
   866         | dest_let t = ([], t);
   867       fun mk_code (gr, (l, r)) =
   868         let
   869           val (gr1, pl) = Codegen.invoke_codegen thy defs dep thyname false (gr, l);
   870           val (gr2, pr) = Codegen.invoke_codegen thy defs dep thyname false (gr1, r);
   871         in (gr2, (pl, pr)) end
   872     in case dest_let (t1 $ t2 $ t3) of
   873         ([], _) => NONE
   874       | (ps, u) =>
   875           let
   876             val (gr1, qs) = foldl_map mk_code (gr, ps);
   877             val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
   878             val (gr3, pargs) = foldl_map
   879               (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
   880           in
   881             SOME (gr3, Codegen.mk_app brack
   882               (Pretty.blk (0, [Pretty.str "let ", Pretty.blk (0, List.concat
   883                   (separate [Pretty.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   884                     [Pretty.block [Pretty.str "val ", pl, Pretty.str " =",
   885                        Pretty.brk 1, pr]]) qs))),
   886                 Pretty.brk 1, Pretty.str "in ", pu,
   887                 Pretty.brk 1, Pretty.str "end"])) pargs)
   888           end
   889     end
   890   | _ => NONE);
   891 
   892 fun split_codegen thy defs gr dep thyname brack t = (case strip_comb t of
   893     (t1 as Const ("split", _), t2 :: ts) =>
   894       (case strip_abs_split 1 (t1 $ t2) of
   895          ([p], u) =>
   896            let
   897              val (gr1, q) = Codegen.invoke_codegen thy defs dep thyname false (gr, p);
   898              val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
   899              val (gr3, pargs) = foldl_map
   900                (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
   901            in
   902              SOME (gr2, Codegen.mk_app brack
   903                (Pretty.block [Pretty.str "(fn ", q, Pretty.str " =>",
   904                  Pretty.brk 1, pu, Pretty.str ")"]) pargs)
   905            end
   906        | _ => NONE)
   907   | _ => NONE);
   908 
   909 in
   910 
   911   Codegen.add_codegen "let_codegen" let_codegen
   912   #> Codegen.add_codegen "split_codegen" split_codegen
   913 
   914 end
   915 *}
   916 
   917 ML {*
   918 val Collect_split = thm "Collect_split";
   919 val Compl_Times_UNIV1 = thm "Compl_Times_UNIV1";
   920 val Compl_Times_UNIV2 = thm "Compl_Times_UNIV2";
   921 val PairE = thm "PairE";
   922 val PairE_lemma = thm "PairE_lemma";
   923 val Pair_Rep_inject = thm "Pair_Rep_inject";
   924 val Pair_def = thm "Pair_def";
   925 val Pair_eq = thm "Pair_eq";
   926 val Pair_fst_snd_eq = thm "Pair_fst_snd_eq";
   927 val Pair_inject = thm "Pair_inject";
   928 val ProdI = thm "ProdI";
   929 val SetCompr_Sigma_eq = thm "SetCompr_Sigma_eq";
   930 val SigmaD1 = thm "SigmaD1";
   931 val SigmaD2 = thm "SigmaD2";
   932 val SigmaE = thm "SigmaE";
   933 val SigmaE2 = thm "SigmaE2";
   934 val SigmaI = thm "SigmaI";
   935 val Sigma_Diff_distrib1 = thm "Sigma_Diff_distrib1";
   936 val Sigma_Diff_distrib2 = thm "Sigma_Diff_distrib2";
   937 val Sigma_Int_distrib1 = thm "Sigma_Int_distrib1";
   938 val Sigma_Int_distrib2 = thm "Sigma_Int_distrib2";
   939 val Sigma_Un_distrib1 = thm "Sigma_Un_distrib1";
   940 val Sigma_Un_distrib2 = thm "Sigma_Un_distrib2";
   941 val Sigma_Union = thm "Sigma_Union";
   942 val Sigma_def = thm "Sigma_def";
   943 val Sigma_empty1 = thm "Sigma_empty1";
   944 val Sigma_empty2 = thm "Sigma_empty2";
   945 val Sigma_mono = thm "Sigma_mono";
   946 val The_split = thm "The_split";
   947 val The_split_eq = thm "The_split_eq";
   948 val The_split_eq = thm "The_split_eq";
   949 val Times_Diff_distrib1 = thm "Times_Diff_distrib1";
   950 val Times_Int_distrib1 = thm "Times_Int_distrib1";
   951 val Times_Un_distrib1 = thm "Times_Un_distrib1";
   952 val Times_eq_cancel2 = thm "Times_eq_cancel2";
   953 val Times_subset_cancel2 = thm "Times_subset_cancel2";
   954 val UNIV_Times_UNIV = thm "UNIV_Times_UNIV";
   955 val UN_Times_distrib = thm "UN_Times_distrib";
   956 val Unity_def = thm "Unity_def";
   957 val cond_split_eta = thm "cond_split_eta";
   958 val fst_conv = thm "fst_conv";
   959 val fst_def = thm "fst_def";
   960 val fst_eqD = thm "fst_eqD";
   961 val inj_on_Abs_Prod = thm "inj_on_Abs_Prod";
   962 val injective_fst_snd = thm "injective_fst_snd";
   963 val mem_Sigma_iff = thm "mem_Sigma_iff";
   964 val mem_splitE = thm "mem_splitE";
   965 val mem_splitI = thm "mem_splitI";
   966 val mem_splitI2 = thm "mem_splitI2";
   967 val prod_eqI = thm "prod_eqI";
   968 val prod_fun = thm "prod_fun";
   969 val prod_fun_compose = thm "prod_fun_compose";
   970 val prod_fun_def = thm "prod_fun_def";
   971 val prod_fun_ident = thm "prod_fun_ident";
   972 val prod_fun_imageE = thm "prod_fun_imageE";
   973 val prod_fun_imageI = thm "prod_fun_imageI";
   974 val prod_induct = thm "prod_induct";
   975 val snd_conv = thm "snd_conv";
   976 val snd_def = thm "snd_def";
   977 val snd_eqD = thm "snd_eqD";
   978 val split = thm "split";
   979 val splitD = thm "splitD";
   980 val splitD' = thm "splitD'";
   981 val splitE = thm "splitE";
   982 val splitE' = thm "splitE'";
   983 val splitE2 = thm "splitE2";
   984 val splitI = thm "splitI";
   985 val splitI2 = thm "splitI2";
   986 val splitI2' = thm "splitI2'";
   987 val split_Pair_apply = thm "split_Pair_apply";
   988 val split_beta = thm "split_beta";
   989 val split_conv = thm "split_conv";
   990 val split_def = thm "split_def";
   991 val split_eta = thm "split_eta";
   992 val split_eta_SetCompr = thm "split_eta_SetCompr";
   993 val split_eta_SetCompr2 = thm "split_eta_SetCompr2";
   994 val split_paired_All = thm "split_paired_All";
   995 val split_paired_Ball_Sigma = thm "split_paired_Ball_Sigma";
   996 val split_paired_Bex_Sigma = thm "split_paired_Bex_Sigma";
   997 val split_paired_Ex = thm "split_paired_Ex";
   998 val split_paired_The = thm "split_paired_The";
   999 val split_paired_all = thm "split_paired_all";
  1000 val split_part = thm "split_part";
  1001 val split_split = thm "split_split";
  1002 val split_split_asm = thm "split_split_asm";
  1003 val split_tupled_all = thms "split_tupled_all";
  1004 val split_weak_cong = thm "split_weak_cong";
  1005 val surj_pair = thm "surj_pair";
  1006 val surjective_pairing = thm "surjective_pairing";
  1007 val unit_abs_eta_conv = thm "unit_abs_eta_conv";
  1008 val unit_all_eq1 = thm "unit_all_eq1";
  1009 val unit_all_eq2 = thm "unit_all_eq2";
  1010 val unit_eq = thm "unit_eq";
  1011 val unit_induct = thm "unit_induct";
  1012 *}
  1013 
  1014 end