src/Pure/Proof/proofchecker.ML
author wenzelm
Mon Aug 08 17:23:15 2011 +0200 (2011-08-08)
changeset 44058 ae85c5d64913
parent 44057 fda143b5c2f5
child 44061 9f17ede679e9
permissions -rw-r--r--
misc tuning -- eliminated old-fashioned rep_thm;
     1 (*  Title:      Pure/Proof/proofchecker.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Simple proof checker based only on the core inference rules
     5 of Isabelle/Pure.
     6 *)
     7 
     8 signature PROOF_CHECKER =
     9 sig
    10   val thm_of_proof : theory -> Proofterm.proof -> thm
    11 end;
    12 
    13 structure Proof_Checker : PROOF_CHECKER =
    14 struct
    15 
    16 (***** construct a theorem out of a proof term *****)
    17 
    18 fun lookup_thm thy =
    19   let val tab = fold_rev Symtab.update (Global_Theory.all_thms_of thy) Symtab.empty in
    20     fn s =>
    21       (case Symtab.lookup tab s of
    22         NONE => error ("Unknown theorem " ^ quote s)
    23       | SOME thm => thm)
    24   end;
    25 
    26 val beta_eta_convert =
    27   Conv.fconv_rule Drule.beta_eta_conversion;
    28 
    29 (* equality modulo renaming of type variables *)
    30 fun is_equal t t' =
    31   let
    32     val atoms = fold_types (fold_atyps (insert (op =))) t [];
    33     val atoms' = fold_types (fold_atyps (insert (op =))) t' []
    34   in
    35     length atoms = length atoms' andalso
    36     map_types (map_atyps (the o AList.lookup (op =) (atoms ~~ atoms'))) t aconv t'
    37   end;
    38 
    39 fun pretty_prf thy vs Hs prf =
    40   let val prf' = prf |> Proofterm.prf_subst_bounds (map Free vs) |>
    41     Proofterm.prf_subst_pbounds (map (Hyp o prop_of) Hs)
    42   in
    43     (Proof_Syntax.pretty_proof (Syntax.init_pretty_global thy) prf',
    44      Syntax.pretty_term_global thy (Reconstruct.prop_of prf'))
    45   end;
    46 
    47 fun pretty_term thy vs _ t =
    48   let val t' = subst_bounds (map Free vs, t)
    49   in
    50     (Syntax.pretty_term_global thy t',
    51      Syntax.pretty_typ_global thy (fastype_of t'))
    52   end;
    53 
    54 fun appl_error thy prt vs Hs s f a =
    55   let
    56     val (pp_f, pp_fT) = pretty_prf thy vs Hs f;
    57     val (pp_a, pp_aT) = prt thy vs Hs a
    58   in
    59     error (cat_lines
    60       [s,
    61        "",
    62        Pretty.string_of (Pretty.block
    63          [Pretty.str "Operator:", Pretty.brk 2, pp_f,
    64            Pretty.str " ::", Pretty.brk 1, pp_fT]),
    65        Pretty.string_of (Pretty.block
    66          [Pretty.str "Operand:", Pretty.brk 3, pp_a,
    67            Pretty.str " ::", Pretty.brk 1, pp_aT]),
    68        ""])
    69   end;
    70 
    71 fun thm_of_proof thy prf =
    72   let
    73     val prf_names = Proofterm.fold_proof_terms Term.declare_term_frees (K I) prf Name.context;
    74     val lookup = lookup_thm thy;
    75 
    76     fun thm_of_atom thm Ts =
    77       let
    78         val tvars = Term.add_tvars (Thm.full_prop_of thm) [] |> rev;
    79         val (fmap, thm') = Thm.varifyT_global' [] thm;
    80         val ctye = map (pairself (Thm.ctyp_of thy))
    81           (map TVar tvars @ map (fn ((_, S), ixn) => TVar (ixn, S)) fmap ~~ Ts)
    82       in
    83         Thm.instantiate (ctye, []) (forall_intr_vars (Thm.forall_intr_frees thm'))
    84       end;
    85 
    86     fun thm_of _ _ (PThm (_, ((name, prop', SOME Ts), _))) =
    87           let
    88             val thm = Thm.unconstrainT (Drule.implies_intr_hyps (lookup name));
    89             val prop = Thm.prop_of thm;
    90             val _ =
    91               if is_equal prop prop' then ()
    92               else
    93                 error ("Duplicate use of theorem name " ^ quote name ^ "\n" ^
    94                   Syntax.string_of_term_global thy prop ^ "\n\n" ^
    95                   Syntax.string_of_term_global thy prop');
    96           in thm_of_atom thm Ts end
    97 
    98       | thm_of _ _ (PAxm (name, _, SOME Ts)) =
    99           thm_of_atom (Thm.axiom thy name) Ts
   100 
   101       | thm_of _ Hs (PBound i) = nth Hs i
   102 
   103       | thm_of (vs, names) Hs (Abst (s, SOME T, prf)) =
   104           let
   105             val (x, names') = Name.variant s names;
   106             val thm = thm_of ((x, T) :: vs, names') Hs prf
   107           in
   108             Thm.forall_intr (Thm.cterm_of thy (Free (x, T))) thm
   109           end
   110 
   111       | thm_of (vs, names) Hs (prf % SOME t) =
   112           let
   113             val thm = thm_of (vs, names) Hs prf;
   114             val ct = Thm.cterm_of thy (Term.subst_bounds (map Free vs, t));
   115           in
   116             Thm.forall_elim ct thm
   117             handle THM (s, _, _) => appl_error thy pretty_term vs Hs s prf t
   118           end
   119 
   120       | thm_of (vs, names) Hs (AbsP (s, SOME t, prf)) =
   121           let
   122             val ct = Thm.cterm_of thy (Term.subst_bounds (map Free vs, t));
   123             val thm = thm_of (vs, names) (Thm.assume ct :: Hs) prf;
   124           in
   125             Thm.implies_intr ct thm
   126           end
   127 
   128       | thm_of vars Hs (prf %% prf') =
   129           let
   130             val thm = beta_eta_convert (thm_of vars Hs prf);
   131             val thm' = beta_eta_convert (thm_of vars Hs prf');
   132           in
   133             Thm.implies_elim thm thm'
   134             handle THM (s, _, _) => appl_error thy pretty_prf (fst vars) Hs s prf prf'
   135           end
   136 
   137       | thm_of _ _ (Hyp t) = Thm.assume (Thm.cterm_of thy t)
   138 
   139       | thm_of _ _ _ = error "thm_of_proof: partial proof term";
   140 
   141   in beta_eta_convert (thm_of ([], prf_names) [] prf) end;
   142 
   143 end;