src/Pure/library.ML
author wenzelm
Thu Jan 03 00:15:39 2008 +0100 (2008-01-03)
changeset 25797 b293e3ed3cad
parent 25752 374446e93558
child 25943 d431d65346a1
permissions -rw-r--r--
added setmp_thread_data;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    67   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    69 
    70   (*lists*)
    71   exception UnequalLengths
    72   val single: 'a -> 'a list
    73   val the_single: 'a list -> 'a
    74   val singleton: ('a list -> 'b list) -> 'a -> 'b
    75   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    76   val apply: ('a -> 'a) list -> 'a -> 'a
    77   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    78   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    79   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    80   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    81   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    82   val flat: 'a list list -> 'a list
    83   val unflat: 'a list list -> 'b list -> 'b list list
    84   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    85   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    86   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    87   val maps: ('a -> 'b list) -> 'a list -> 'b list
    88   val filter: ('a -> bool) -> 'a list -> 'a list
    89   val filter_out: ('a -> bool) -> 'a list -> 'a list
    90   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    91   val chop: int -> 'a list -> 'a list * 'a list
    92   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    93   val nth: 'a list -> int -> 'a
    94   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val nth_drop: int -> 'a list -> 'a list
    96   val nth_list: 'a list list -> int -> 'a list
    97   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    98   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    99   val split_last: 'a list -> 'a list * 'a
   100   val find_index: ('a -> bool) -> 'a list -> int
   101   val find_index_eq: ''a -> ''a list -> int
   102   val find_first: ('a -> bool) -> 'a list -> 'a option
   103   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   104   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   105   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   106   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   107   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   108   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   109   val ~~ : 'a list * 'b list -> ('a * 'b) list
   110   val split_list: ('a * 'b) list -> 'a list * 'b list
   111   val separate: 'a -> 'a list -> 'a list
   112   val replicate: int -> 'a -> 'a list
   113   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   116   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   117   val prefixes1: 'a list -> 'a list list
   118   val prefixes: 'a list -> 'a list list
   119   val suffixes1: 'a list -> 'a list list
   120   val suffixes: 'a list -> 'a list list
   121 
   122   (*integers*)
   123   val inc: int ref -> int
   124   val dec: int ref -> int
   125   val upto: int * int -> int list
   126   val downto: int * int -> int list
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val signed_string_of_int: int -> string
   131   val string_of_indexname: string * int -> string
   132   val read_radix_int: int -> string list -> int * string list
   133   val read_int: string list -> int * string list
   134   val oct_char: string -> string
   135 
   136   (*strings*)
   137   val nth_string: string -> int -> string
   138   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   139   val exists_string: (string -> bool) -> string -> bool
   140   val forall_string: (string -> bool) -> string -> bool
   141   val enclose: string -> string -> string -> string
   142   val unenclose: string -> string
   143   val quote: string -> string
   144   val space_implode: string -> string list -> string
   145   val commas: string list -> string
   146   val commas_quote: string list -> string
   147   val cat_lines: string list -> string
   148   val space_explode: string -> string -> string list
   149   val split_lines: string -> string list
   150   val prefix_lines: string -> string -> string
   151   val untabify: string list -> string list
   152   val prefix: string -> string -> string
   153   val suffix: string -> string -> string
   154   val unprefix: string -> string -> string
   155   val unsuffix: string -> string -> string
   156   val replicate_string: int -> string -> string
   157   val translate_string: (string -> string) -> string -> string
   158   val multiply: 'a list -> 'a list list -> 'a list list
   159   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   160   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   161 
   162   (*lists as sets -- see also Pure/General/ord_list.ML*)
   163   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   164   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   165   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   166   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   167   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   168   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   169   val mem: ''a * ''a list -> bool
   170   val mem_int: int * int list -> bool
   171   val mem_string: string * string list -> bool
   172   val union: ''a list * ''a list -> ''a list
   173   val union_int: int list * int list -> int list
   174   val union_string: string list * string list -> string list
   175   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   176   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   177   val inter: ''a list * ''a list -> ''a list
   178   val inter_int: int list * int list -> int list
   179   val inter_string: string list * string list -> string list
   180   val subset: ''a list * ''a list -> bool
   181   val subset_int: int list * int list -> bool
   182   val subset_string: string list * string list -> bool
   183   val eq_set: ''a list * ''a list -> bool
   184   val eq_set_string: string list * string list -> bool
   185   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   186   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   187   val \ : ''a list * ''a -> ''a list
   188   val \\ : ''a list * ''a list -> ''a list
   189   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   190   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   191   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   192 
   193   (*lists as multisets*)
   194   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   195   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   196 
   197   (*orders*)
   198   val is_equal: order -> bool
   199   val rev_order: order -> order
   200   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   201   val bool_ord: bool * bool -> order
   202   val int_ord: int * int -> order
   203   val string_ord: string * string -> order
   204   val fast_string_ord: string * string -> order
   205   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   206   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   207   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   208   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   209   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   210   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   211   val sort_strings: string list -> string list
   212   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   213 
   214   (*random numbers*)
   215   exception RANDOM
   216   val random: unit -> real
   217   val random_range: int -> int -> int
   218   val one_of: 'a list -> 'a
   219   val frequency: (int * 'a) list -> 'a
   220 
   221   (*misc*)
   222   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   223   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   224   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   225   val gensym: string -> string
   226   type stamp
   227   val stamp: unit -> stamp
   228   type serial
   229   val serial: unit -> serial
   230   val serial_string: unit -> string
   231   structure Object: sig type T end
   232 end;
   233 
   234 signature LIBRARY =
   235 sig
   236   include BASIC_LIBRARY
   237   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   238   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   239   val take: int * 'a list -> 'a list
   240   val drop: int * 'a list -> 'a list
   241   val last_elem: 'a list -> 'a
   242 end;
   243 
   244 structure Library: LIBRARY =
   245 struct
   246 
   247 (* functions *)
   248 
   249 fun undefined _ = raise Match;
   250 
   251 fun I x = x;
   252 fun K x = fn _ => x;
   253 fun curry f x y = f (x, y);
   254 fun uncurry f (x, y) = f x y;
   255 
   256 (*application and structured results -- old version*)
   257 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   258 
   259 (*conditional application*)
   260 fun b ? f = fn x => if b then f x else x;
   261 
   262 (*composition with multiple args*)
   263 fun (f oo g) x y = f (g x y);
   264 fun (f ooo g) x y z = f (g x y z);
   265 fun (f oooo g) x y z w = f (g x y z w);
   266 
   267 (*function exponentiation: f(...(f x)...) with n applications of f*)
   268 fun funpow (0: int) _ x = x
   269   | funpow n f x = funpow (n - 1) f (f x);
   270 
   271 
   272 (* errors *)
   273 
   274 exception SYS_ERROR of string;
   275 fun sys_error msg = raise SYS_ERROR msg;
   276 
   277 exception ERROR of string;
   278 fun error msg = raise ERROR msg;
   279 
   280 fun cat_error "" msg = error msg
   281   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   282 
   283 fun assert_all pred list msg =
   284   let
   285     fun ass [] = ()
   286       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   287   in ass list end;
   288 
   289 
   290 (* pairs *)
   291 
   292 fun pair x y = (x, y);
   293 fun rpair x y = (y, x);
   294 
   295 fun fst (x, y) = x;
   296 fun snd (x, y) = y;
   297 
   298 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   299 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   300 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   301 
   302 fun swap (x, y) = (y, x);
   303 
   304 fun apfst f (x, y) = (f x, y);
   305 fun apsnd f (x, y) = (x, f y);
   306 fun pairself f (x, y) = (f x, f y);
   307 
   308 
   309 (* booleans *)
   310 
   311 (*polymorphic equality*)
   312 fun equal x y = x = y;
   313 fun not_equal x y = x <> y;
   314 
   315 (*combining predicates*)
   316 fun p orf q = fn x => p x orelse q x;
   317 fun p andf q = fn x => p x andalso q x;
   318 
   319 val exists = List.exists;
   320 val forall = List.all;
   321 
   322 
   323 (* flags *)
   324 
   325 fun set flag = (flag := true; true);
   326 fun reset flag = (flag := false; false);
   327 fun toggle flag = (flag := not (! flag); ! flag);
   328 
   329 fun change r f = r := f (! r);
   330 
   331 (*temporarily set flag during execution*)
   332 fun setmp_noncritical flag value f x =
   333   let
   334     val orig_value = ! flag;
   335     val _ = flag := value;
   336     val result = Exn.capture f x;
   337     val _ = flag := orig_value;
   338   in Exn.release result end;
   339 
   340 fun setmp flag value f x = NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   341 
   342 fun setmp_thread_data tag orig_data data f x =
   343   let
   344     val _ = Multithreading.put_data (tag, data);
   345     val result = Exn.capture f x;
   346     val _ = Multithreading.put_data (tag, orig_data);
   347   in Exn.release result end;
   348 
   349 
   350 
   351 (** lists **)
   352 
   353 exception UnequalLengths;
   354 
   355 fun single x = [x];
   356 
   357 fun the_single [x] = x
   358   | the_single _ = raise Empty;
   359 
   360 fun singleton f x = the_single (f [x]);
   361 
   362 fun yield_singleton f x = f [x] #>> the_single;
   363 
   364 fun apply [] x = x
   365   | apply (f :: fs) x = apply fs (f x);
   366 
   367 fun perhaps_apply funs arg =
   368   let
   369     fun app [] res = res
   370       | app (f :: fs) (changed, x) =
   371           (case f x of
   372             NONE => app fs (changed, x)
   373           | SOME x' => app fs (true, x'));
   374   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   375 
   376 fun perhaps_loop f arg =
   377   let
   378     fun loop (changed, x) =
   379       (case f x of
   380         NONE => (changed, x)
   381       | SOME x' => loop (true, x'));
   382   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   383 
   384 
   385 (* fold -- old versions *)
   386 
   387 (*the following versions of fold are designed to fit nicely with infixes*)
   388 
   389 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   390     for operators that associate to the left (TAIL RECURSIVE)*)
   391 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   392   let fun itl (e, [])  = e
   393         | itl (e, a::l) = itl (f(e, a), l)
   394   in  itl end;
   395 
   396 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   397     for operators that associate to the right (not tail recursive)*)
   398 fun foldr f (l, e) =
   399   let fun itr [] = e
   400         | itr (a::l) = f(a, itr l)
   401   in  itr l  end;
   402 
   403 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   404     for operators that associate to the left (TAIL RECURSIVE)*)
   405 fun foldl1 f [] = raise Empty
   406   | foldl1 f (x :: xs) = foldl f (x, xs);
   407 
   408 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   409     for n > 0, operators that associate to the right (not tail recursive)*)
   410 fun foldr1 f [] = raise Empty
   411   | foldr1 f l =
   412       let fun itr [x] = x
   413             | itr (x::l) = f(x, itr l)
   414       in  itr l  end;
   415 
   416 fun foldl_map f =
   417   let
   418     fun fold_aux (x, []) = (x, [])
   419       | fold_aux (x, y :: ys) =
   420           let
   421             val (x', y') = f (x, y);
   422             val (x'', ys') = fold_aux (x', ys);
   423           in (x'', y' :: ys') end;
   424   in fold_aux end;
   425 
   426 
   427 (* basic list functions *)
   428 
   429 fun eq_list eq (list1, list2) =
   430   let
   431     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   432       | eq_lst _ = true;
   433   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   434 
   435 fun maps f [] = []
   436   | maps f (x :: xs) = f x @ maps f xs;
   437 
   438 val filter = List.filter;
   439 fun filter_out f = filter (not o f);
   440 val map_filter = List.mapPartial;
   441 
   442 fun chop (0: int) xs = ([], xs)
   443   | chop _ [] = ([], [])
   444   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   445 
   446 (*take the first n elements from a list*)
   447 fun take (n: int, []) = []
   448   | take (n, x :: xs) =
   449       if n > 0 then x :: take (n - 1, xs) else [];
   450 
   451 (*drop the first n elements from a list*)
   452 fun drop (n: int, []) = []
   453   | drop (n, x :: xs) =
   454       if n > 0 then drop (n - 1, xs) else x :: xs;
   455 
   456 fun dropwhile P [] = []
   457   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   458 
   459 (*return nth element of a list, where 0 designates the first element;
   460   raise Subscript if list too short*)
   461 fun nth xs i = List.nth (xs, i);
   462 
   463 fun nth_list xss i = nth xss i handle Subscript => [];
   464 
   465 fun nth_map 0 f (x :: xs) = f x :: xs
   466   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   467   | nth_map (_: int) _ [] = raise Subscript;
   468 
   469 fun nth_drop n xs =
   470   List.take (xs, n) @ List.drop (xs, n + 1);
   471 
   472 fun map_index f =
   473   let
   474     fun mapp (_: int) [] = []
   475       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   476   in mapp 0 end;
   477 
   478 fun fold_index f =
   479   let
   480     fun fold_aux (_: int) [] y = y
   481       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   482   in fold_aux 0 end;
   483 
   484 val last_elem = List.last;
   485 
   486 (*rear decomposition*)
   487 fun split_last [] = raise Empty
   488   | split_last [x] = ([], x)
   489   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   490 
   491 (*find the position of an element in a list*)
   492 fun find_index pred =
   493   let fun find (_: int) [] = ~1
   494         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   495   in find 0 end;
   496 
   497 fun find_index_eq x = find_index (equal x);
   498 
   499 (*find first element satisfying predicate*)
   500 val find_first = List.find;
   501 
   502 (*get first element by lookup function*)
   503 fun get_first _ [] = NONE
   504   | get_first f (x :: xs) =
   505       (case f x of
   506         NONE => get_first f xs
   507       | some => some);
   508 
   509 fun get_index f =
   510   let
   511     fun get (_: int) [] = NONE
   512       | get i (x :: xs) =
   513           case f x
   514            of NONE => get (i + 1) xs
   515             | SOME y => SOME (i, y)
   516   in get 0 end;
   517 
   518 val flat = List.concat;
   519 
   520 fun unflat (xs :: xss) ys =
   521       let val (ps, qs) = chop (length xs) ys
   522       in ps :: unflat xss qs end
   523   | unflat [] [] = []
   524   | unflat _ _ = raise UnequalLengths;
   525 
   526 fun burrow f xss = unflat xss (f (flat xss));
   527 
   528 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   529 
   530 fun fold_burrow f xss s =
   531   apfst (unflat xss) (f (flat xss) s);
   532 
   533 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   534 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   535   | separate _ xs = xs;
   536 
   537 (*make the list [x, x, ..., x] of length n*)
   538 fun replicate (n: int) x =
   539   let fun rep (0, xs) = xs
   540         | rep (n, xs) = rep (n - 1, x :: xs)
   541   in
   542     if n < 0 then raise Subscript
   543     else rep (n, [])
   544   end;
   545 
   546 fun translate_string f = String.translate (f o String.str);
   547 
   548 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   549 fun multiply [] _ = []
   550   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   551 
   552 
   553 (* direct product *)
   554 
   555 fun map_product f _ [] = []
   556   | map_product f [] _ = []
   557   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   558 
   559 fun fold_product f _ [] z = z
   560   | fold_product f [] _ z = z
   561   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   562 
   563 
   564 (* lists of pairs *)
   565 
   566 exception UnequalLengths;
   567 
   568 fun map2 _ [] [] = []
   569   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   570   | map2 _ _ _ = raise UnequalLengths;
   571 
   572 fun fold2 f [] [] z = z
   573   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   574   | fold2 f _ _ _ = raise UnequalLengths;
   575 
   576 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   577   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   578   | zip_options _ [] = []
   579   | zip_options [] _ = raise UnequalLengths;
   580 
   581 (*combine two lists forming a list of pairs:
   582   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   583 fun [] ~~ [] = []
   584   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   585   | _ ~~ _ = raise UnequalLengths;
   586 
   587 (*inverse of ~~; the old 'split':
   588   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   589 val split_list = ListPair.unzip;
   590 
   591 
   592 (* prefixes, suffixes *)
   593 
   594 fun is_prefix _ [] _ = true
   595   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   596   | is_prefix eq _ _ = false;
   597 
   598 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   599    where xi is the first element that does not satisfy the predicate*)
   600 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   601   let fun take (rxs, []) = (rev rxs, [])
   602         | take (rxs, x :: xs) =
   603             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   604   in  take([], xs)  end;
   605 
   606 fun chop_prefix eq ([], ys) = ([], ([], ys))
   607   | chop_prefix eq (xs, []) = ([], (xs, []))
   608   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   609       if eq (x, y) then
   610         let val (ps', xys'') = chop_prefix eq (xs', ys')
   611         in (x :: ps', xys'') end
   612       else ([], (xs, ys));
   613 
   614 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   615    where xi is the last element that does not satisfy the predicate*)
   616 fun take_suffix _ [] = ([], [])
   617   | take_suffix pred (x :: xs) =
   618       (case take_suffix pred xs of
   619         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   620       | (prfx, sffx) => (x :: prfx, sffx));
   621 
   622 fun prefixes1 [] = []
   623   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   624 
   625 fun prefixes xs = [] :: prefixes1 xs;
   626 
   627 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   628 fun suffixes xs = [] :: suffixes1 xs;
   629 
   630 
   631 
   632 (** integers **)
   633 
   634 fun inc i = (i := ! i + (1: int); ! i);
   635 fun dec i = (i := ! i - (1: int); ! i);
   636 
   637 
   638 (* lists of integers *)
   639 
   640 (*make the list [from, from + 1, ..., to]*)
   641 fun ((i: int) upto j) =
   642   if i > j then [] else i :: (i + 1 upto j);
   643 
   644 (*make the list [from, from - 1, ..., to]*)
   645 fun ((i: int) downto j) =
   646   if i < j then [] else i :: (i - 1 downto j);
   647 
   648 
   649 (* convert integers to strings *)
   650 
   651 (*expand the number in the given base;
   652   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   653 fun radixpand (base, num) : int list =
   654   let
   655     fun radix (n, tail) =
   656       if n < base then n :: tail
   657       else radix (n div base, (n mod base) :: tail)
   658   in radix (num, []) end;
   659 
   660 (*expands a number into a string of characters starting from "zerochar";
   661   example: radixstring (2, "0", 8) gives "1000"*)
   662 fun radixstring (base, zerochar, num) =
   663   let val offset = ord zerochar;
   664       fun chrof n = chr (offset + n)
   665   in implode (map chrof (radixpand (base, num))) end;
   666 
   667 
   668 val string_of_int = Int.toString;
   669 
   670 fun signed_string_of_int i =
   671   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   672 
   673 fun string_of_indexname (a, 0) = a
   674   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   675 
   676 
   677 (* read integers *)
   678 
   679 fun read_radix_int radix cs =
   680   let
   681     val zero = ord "0";
   682     val limit = zero + radix;
   683     fun scan (num, []) = (num, [])
   684       | scan (num, c :: cs) =
   685         if zero <= ord c andalso ord c < limit then
   686           scan (radix * num + (ord c - zero), cs)
   687         else (num, c :: cs);
   688   in scan (0, cs) end;
   689 
   690 val read_int = read_radix_int 10;
   691 
   692 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   693 
   694 
   695 
   696 (** strings **)
   697 
   698 (* functions tuned for strings, avoiding explode *)
   699 
   700 fun nth_string str i =
   701   (case try String.substring (str, i, 1) of
   702     SOME s => s
   703   | NONE => raise Subscript);
   704 
   705 fun fold_string f str x0 =
   706   let
   707     val n = size str;
   708     fun iter (x, i) =
   709       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   710   in iter (x0, 0) end;
   711 
   712 fun exists_string pred str =
   713   let
   714     val n = size str;
   715     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   716   in ex 0 end;
   717 
   718 fun forall_string pred = not o exists_string (not o pred);
   719 
   720 (*enclose in brackets*)
   721 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   722 fun unenclose str = String.substring (str, 1, size str - 2);
   723 
   724 (*simple quoting (does not escape special chars)*)
   725 val quote = enclose "\"" "\"";
   726 
   727 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   728 fun space_implode a bs = implode (separate a bs);
   729 
   730 val commas = space_implode ", ";
   731 val commas_quote = commas o map quote;
   732 
   733 (*concatenate messages, one per line, into a string*)
   734 val cat_lines = space_implode "\n";
   735 
   736 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   737 fun space_explode _ "" = []
   738   | space_explode sep s = String.fields (fn c => str c = sep) s;
   739 
   740 val split_lines = space_explode "\n";
   741 
   742 fun prefix_lines "" txt = txt
   743   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   744 
   745 fun untabify chs =
   746   let
   747     val tab_width = 8;
   748 
   749     fun untab pos [] ys = rev ys
   750       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   751       | untab pos ("\t" :: xs) ys =
   752           let val d = tab_width - (pos mod tab_width)
   753           in untab (pos + d) xs (funpow d (cons " ") ys) end
   754       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   755   in
   756     if not (exists (fn c => c = "\t") chs) then chs
   757     else untab 0 chs []
   758   end;
   759 
   760 fun prefix prfx s = prfx ^ s;
   761 fun suffix sffx s = s ^ sffx;
   762 
   763 fun unprefix prfx s =
   764   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   765   else raise Fail "unprefix";
   766 
   767 fun unsuffix sffx s =
   768   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   769   else raise Fail "unsuffix";
   770 
   771 fun replicate_string (0: int) _ = ""
   772   | replicate_string 1 a = a
   773   | replicate_string k a =
   774       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   775       else replicate_string (k div 2) (a ^ a) ^ a;
   776 
   777 
   778 
   779 (** lists as sets -- see also Pure/General/ord_list.ML **)
   780 
   781 (*canonical member, insert, remove*)
   782 fun member eq list x =
   783   let
   784     fun memb [] = false
   785       | memb (y :: ys) = eq (x, y) orelse memb ys;
   786   in memb list end;
   787 
   788 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   789 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   790 fun update eq x xs = cons x (remove eq x xs);
   791 
   792 fun subtract eq = fold (remove eq);
   793 
   794 fun merge _ ([], ys) = ys
   795   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   796 
   797 (*old-style infixes*)
   798 fun x mem xs = member (op =) xs x;
   799 fun (x: int) mem_int xs = member (op =) xs x;
   800 fun (x: string) mem_string xs = member (op =) xs x;
   801 
   802 
   803 (*union of sets represented as lists: no repetitions*)
   804 fun xs union [] = xs
   805   | [] union ys = ys
   806   | (x :: xs) union ys = xs union (insert (op =) x ys);
   807 
   808 (*union of sets, optimized version for ints*)
   809 fun (xs:int list) union_int [] = xs
   810   | [] union_int ys = ys
   811   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   812 
   813 (*union of sets, optimized version for strings*)
   814 fun (xs:string list) union_string [] = xs
   815   | [] union_string ys = ys
   816   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   817 
   818 (*generalized union*)
   819 fun gen_union eq (xs, []) = xs
   820   | gen_union eq ([], ys) = ys
   821   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   822 
   823 
   824 (*intersection*)
   825 fun [] inter ys = []
   826   | (x :: xs) inter ys =
   827       if x mem ys then x :: (xs inter ys) else xs inter ys;
   828 
   829 (*intersection, optimized version for ints*)
   830 fun ([]:int list) inter_int ys = []
   831   | (x :: xs) inter_int ys =
   832       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   833 
   834 (*intersection, optimized version for strings *)
   835 fun ([]:string list) inter_string ys = []
   836   | (x :: xs) inter_string ys =
   837       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   838 
   839 (*generalized intersection*)
   840 fun gen_inter eq ([], ys) = []
   841   | gen_inter eq (x::xs, ys) =
   842       if member eq ys x then x :: gen_inter eq (xs, ys)
   843       else gen_inter eq (xs, ys);
   844 
   845 
   846 (*subset*)
   847 fun [] subset ys = true
   848   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   849 
   850 (*subset, optimized version for ints*)
   851 fun ([]: int list) subset_int ys = true
   852   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   853 
   854 (*subset, optimized version for strings*)
   855 fun ([]: string list) subset_string ys = true
   856   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   857 
   858 (*set equality*)
   859 fun eq_set (xs, ys) =
   860   xs = ys orelse (xs subset ys andalso ys subset xs);
   861 
   862 (*set equality for strings*)
   863 fun eq_set_string ((xs: string list), ys) =
   864   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   865 
   866 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   867 
   868 fun gen_eq_set eq (xs, ys) =
   869   eq_list eq (xs, ys) orelse
   870     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   871 
   872 
   873 (*removing an element from a list WITHOUT duplicates*)
   874 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   875   | [] \ x = [];
   876 fun ys \\ xs = foldl (op \) (ys,xs);
   877 
   878 
   879 (*makes a list of the distinct members of the input; preserves order, takes
   880   first of equal elements*)
   881 fun distinct eq lst =
   882   let
   883     fun dist (rev_seen, []) = rev rev_seen
   884       | dist (rev_seen, x :: xs) =
   885           if member eq rev_seen x then dist (rev_seen, xs)
   886           else dist (x :: rev_seen, xs);
   887   in dist ([], lst) end;
   888 
   889 (*returns a list containing all repeated elements exactly once; preserves
   890   order, takes first of equal elements*)
   891 fun duplicates eq lst =
   892   let
   893     fun dups (rev_dups, []) = rev rev_dups
   894       | dups (rev_dups, x :: xs) =
   895           if member eq rev_dups x orelse not (member eq xs x) then
   896             dups (rev_dups, xs)
   897           else dups (x :: rev_dups, xs);
   898   in dups ([], lst) end;
   899 
   900 fun has_duplicates eq =
   901   let
   902     fun dups [] = false
   903       | dups (x :: xs) = member eq xs x orelse dups xs;
   904   in dups end;
   905 
   906 
   907 
   908 (** lists as multisets **)
   909 
   910 fun remove1 _ _ [] = raise Empty
   911   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   912 
   913 fun submultiset _ ([], _)  = true
   914   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   915 
   916 
   917 
   918 (** orders **)
   919 
   920 fun is_equal EQUAL = true
   921   | is_equal _ = false;
   922 
   923 fun rev_order LESS = GREATER
   924   | rev_order EQUAL = EQUAL
   925   | rev_order GREATER = LESS;
   926 
   927 (*assume rel is a linear strict order*)
   928 fun make_ord rel (x, y) =
   929   if rel (x, y) then LESS
   930   else if rel (y, x) then GREATER
   931   else EQUAL;
   932 
   933 fun bool_ord (false, true) = LESS
   934   | bool_ord (true, false) = GREATER
   935   | bool_ord _ = EQUAL;
   936 
   937 val int_ord = Int.compare;
   938 val string_ord = String.compare;
   939 
   940 fun fast_string_ord (s1, s2) =
   941   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   942 
   943 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   944   | option_ord _ (NONE, NONE) = EQUAL
   945   | option_ord _ (NONE, SOME _) = LESS
   946   | option_ord _ (SOME _, NONE) = GREATER;
   947 
   948 (*lexicographic product*)
   949 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   950   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   951 
   952 (*dictionary order -- in general NOT well-founded!*)
   953 fun dict_ord elem_ord (x :: xs, y :: ys) =
   954       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   955   | dict_ord _ ([], []) = EQUAL
   956   | dict_ord _ ([], _ :: _) = LESS
   957   | dict_ord _ (_ :: _, []) = GREATER;
   958 
   959 (*lexicographic product of lists*)
   960 fun list_ord elem_ord (xs, ys) =
   961   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   962 
   963 
   964 (* sorting *)
   965 
   966 (*quicksort -- stable, i.e. does not reorder equal elements*)
   967 fun quicksort unique ord =
   968   let
   969     fun qsort [] = []
   970       | qsort (xs as [_]) = xs
   971       | qsort (xs as [x, y]) =
   972           (case ord (x, y) of
   973             LESS => xs
   974           | EQUAL => if unique then [x] else xs
   975           | GREATER => [y, x])
   976       | qsort xs =
   977           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   978           in qsort lts @ eqs @ qsort gts end
   979     and part _ [] = ([], [], [])
   980       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   981     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   982       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   983       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   984       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   985   in qsort end;
   986 
   987 fun sort ord = quicksort false ord;
   988 fun sort_distinct ord = quicksort true ord;
   989 
   990 val sort_strings = sort string_ord;
   991 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   992 
   993 
   994 
   995 (** random numbers **)
   996 
   997 exception RANDOM;
   998 
   999 fun rmod x y = x - y * Real.realFloor (x / y);
  1000 
  1001 local
  1002   val a = 16807.0;
  1003   val m = 2147483647.0;
  1004   val random_seed = ref 1.0;
  1005 in
  1006 
  1007 fun random () = CRITICAL (fn () =>
  1008   let val r = rmod (a * ! random_seed) m
  1009   in (random_seed := r; r) end);
  1010 
  1011 end;
  1012 
  1013 fun random_range l h =
  1014   if h < l orelse l < 0 then raise RANDOM
  1015   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1016 
  1017 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1018 
  1019 fun frequency xs =
  1020   let
  1021     val sum = foldl op + (0, map fst xs);
  1022     fun pick n ((k: int, x) :: xs) =
  1023       if n <= k then x else pick (n - k) xs
  1024   in pick (random_range 1 sum) xs end;
  1025 
  1026 
  1027 
  1028 (** misc **)
  1029 
  1030 fun divide_and_conquer decomp x =
  1031   let val (ys, recomb) = decomp x
  1032   in recomb (map (divide_and_conquer decomp) ys) end;
  1033 
  1034 
  1035 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1036    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1037 fun partition_list p i j =
  1038   let fun part k xs =
  1039             if k>j then
  1040               (case xs of [] => []
  1041                          | _ => raise Fail "partition_list")
  1042             else
  1043             let val (ns, rest) = List.partition (p k) xs;
  1044             in  ns :: part(k+1)rest  end
  1045   in  part (i: int) end;
  1046 
  1047 fun partition_eq (eq:'a * 'a -> bool) =
  1048   let
  1049     fun part [] = []
  1050       | part (x :: ys) =
  1051           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1052           in (x::xs)::(part xs') end
  1053   in part end;
  1054 
  1055 
  1056 
  1057 (* generating identifiers *)
  1058 
  1059 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1060 local
  1061 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1062 fun gensym_char i =
  1063   if i<26 then chr (ord "A" + i)
  1064   else if i<52 then chr (ord "a" + i - 26)
  1065   else chr (ord "0" + i - 52);
  1066 
  1067 val char_vec = Vector.tabulate (62, gensym_char);
  1068 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1069 
  1070 val gensym_seed = ref (0: int);
  1071 
  1072 in
  1073   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1074 end;
  1075 
  1076 
  1077 (* stamps and serial numbers *)
  1078 
  1079 type stamp = unit ref;
  1080 val stamp: unit -> stamp = ref;
  1081 
  1082 type serial = int;
  1083 val serial = Multithreading.serial;
  1084 val serial_string = string_of_int o serial;
  1085 
  1086 
  1087 (* generic objects *)
  1088 
  1089 (*note that the builtin exception datatype may be extended by new
  1090   constructors at any time*)
  1091 structure Object = struct type T = exn end;
  1092 
  1093 end;
  1094 
  1095 structure BasicLibrary: BASIC_LIBRARY = Library;
  1096 open BasicLibrary;