src/Pure/variable.ML
author wenzelm
Sat Dec 13 15:00:39 2008 +0100 (2008-12-13)
changeset 29091 b81fe045e799
parent 28965 1de908189869
child 29279 7456a64bc4f6
permissions -rw-r--r--
Context.display_names;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val maxidx_of: Proof.context -> int
    17   val sorts_of: Proof.context -> sort list
    18   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    19   val is_declared: Proof.context -> string -> bool
    20   val is_fixed: Proof.context -> string -> bool
    21   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    22   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    23   val default_type: Proof.context -> string -> typ option
    24   val def_type: Proof.context -> bool -> indexname -> typ option
    25   val def_sort: Proof.context -> indexname -> sort option
    26   val declare_names: term -> Proof.context -> Proof.context
    27   val declare_constraints: term -> Proof.context -> Proof.context
    28   val declare_term: term -> Proof.context -> Proof.context
    29   val declare_typ: typ -> Proof.context -> Proof.context
    30   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    31   val declare_thm: thm -> Proof.context -> Proof.context
    32   val thm_context: thm -> Proof.context
    33   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    34   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    35   val expand_binds: Proof.context -> term -> term
    36   val lookup_const: Proof.context -> string -> string option
    37   val is_const: Proof.context -> string -> bool
    38   val declare_const: string * string -> Proof.context -> Proof.context
    39   val add_fixes: string list -> Proof.context -> string list * Proof.context
    40   val add_fixes_direct: string list -> Proof.context -> Proof.context
    41   val auto_fixes: term -> Proof.context -> Proof.context
    42   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    43   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    44   val export_terms: Proof.context -> Proof.context -> term list -> term list
    45   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    46   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    47   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    48   val export: Proof.context -> Proof.context -> thm list -> thm list
    49   val export_morphism: Proof.context -> Proof.context -> morphism
    50   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    51   val import_inst: bool -> term list -> Proof.context ->
    52     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    53   val importT_terms: term list -> Proof.context -> term list * Proof.context
    54   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    55   val importT_thms: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    56   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    57   val import_thms: bool -> thm list -> Proof.context ->
    58     ((ctyp list * cterm list) * thm list) * Proof.context
    59   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    60   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    61   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    62   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    63   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    64   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    65   val polymorphic: Proof.context -> term list -> term list
    66 end;
    67 
    68 structure Variable: VARIABLE =
    69 struct
    70 
    71 (** local context data **)
    72 
    73 datatype data = Data of
    74  {is_body: bool,                        (*inner body mode*)
    75   names: Name.context,                  (*type/term variable names*)
    76   consts: string Symtab.table,          (*consts within the local scope*)
    77   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    78   binds: (typ * term) Vartab.table,     (*term bindings*)
    79   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    80   maxidx: int,                          (*maximum var index*)
    81   sorts: sort OrdList.T,                (*declared sort occurrences*)
    82   constraints:
    83     typ Vartab.table *                  (*type constraints*)
    84     sort Vartab.table};                 (*default sorts*)
    85 
    86 fun make_data (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =
    87   Data {is_body = is_body, names = names, consts = consts, fixes = fixes, binds = binds,
    88     type_occs = type_occs, maxidx = maxidx, sorts = sorts, constraints = constraints};
    89 
    90 structure Data = ProofDataFun
    91 (
    92   type T = data;
    93   fun init thy =
    94     make_data (false, Name.context, Symtab.empty, [], Vartab.empty, Symtab.empty,
    95       ~1, [], (Vartab.empty, Vartab.empty));
    96 );
    97 
    98 fun map_data f =
    99   Data.map (fn Data {is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints} =>
   100     make_data (f (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints)));
   101 
   102 fun map_names f =
   103   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   104     (is_body, f names, consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   105 
   106 fun map_consts f =
   107   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   108     (is_body, names, f consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   109 
   110 fun map_fixes f =
   111   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   112     (is_body, names, consts, f fixes, binds, type_occs, maxidx, sorts, constraints));
   113 
   114 fun map_binds f =
   115   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   116     (is_body, names, consts, fixes, f binds, type_occs, maxidx, sorts, constraints));
   117 
   118 fun map_type_occs f =
   119   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   120     (is_body, names, consts, fixes, binds, f type_occs, maxidx, sorts, constraints));
   121 
   122 fun map_maxidx f =
   123   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   124     (is_body, names, consts, fixes, binds, type_occs, f maxidx, sorts, constraints));
   125 
   126 fun map_sorts f =
   127   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   128     (is_body, names, consts, fixes, binds, type_occs, maxidx, f sorts, constraints));
   129 
   130 fun map_constraints f =
   131   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   132     (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, f constraints));
   133 
   134 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   135 
   136 val is_body = #is_body o rep_data;
   137 
   138 fun set_body b =
   139   map_data (fn (_, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   140     (b, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   141 
   142 fun restore_body ctxt = set_body (is_body ctxt);
   143 
   144 val names_of = #names o rep_data;
   145 val fixes_of = #fixes o rep_data;
   146 val binds_of = #binds o rep_data;
   147 val type_occs_of = #type_occs o rep_data;
   148 val maxidx_of = #maxidx o rep_data;
   149 val sorts_of = #sorts o rep_data;
   150 val constraints_of = #constraints o rep_data;
   151 
   152 val is_declared = Name.is_declared o names_of;
   153 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   154 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   155 
   156 fun add_fixed ctxt = Term.fold_aterms
   157   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   158 
   159 
   160 
   161 (** declarations **)
   162 
   163 (* default sorts and types *)
   164 
   165 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   166 
   167 fun def_type ctxt pattern xi =
   168   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   169     (case Vartab.lookup types xi of
   170       NONE =>
   171         if pattern then NONE
   172         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   173     | some => some)
   174   end;
   175 
   176 val def_sort = Vartab.lookup o #2 o constraints_of;
   177 
   178 
   179 (* names *)
   180 
   181 fun declare_type_names t =
   182   map_names (fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I)) t) #>
   183   map_maxidx (fold_types Term.maxidx_typ t);
   184 
   185 fun declare_names t =
   186   declare_type_names t #>
   187   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t) #>
   188   map_maxidx (Term.maxidx_term t);
   189 
   190 
   191 (* type occurrences *)
   192 
   193 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   194 
   195 val decl_type_occs = fold_term_types
   196   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   197     | _ => decl_type_occsT);
   198 
   199 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   200 val declare_type_occs = map_type_occs o decl_type_occs;
   201 
   202 
   203 (* constraints *)
   204 
   205 fun constrain_tvar (xi, S) =
   206   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   207 
   208 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   209   let
   210     val types' = fold_aterms
   211       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   212         | Var v => Vartab.update v
   213         | _ => I) t types;
   214     val sorts' = fold_types (fold_atyps
   215       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   216         | TVar v => constrain_tvar v
   217         | _ => I)) t sorts;
   218   in (types', sorts') end)
   219   #> declare_type_occsT t
   220   #> declare_type_names t;
   221 
   222 
   223 (* common declarations *)
   224 
   225 fun declare_internal t =
   226   declare_names t #>
   227   declare_type_occs t #>
   228   map_sorts (Sorts.insert_term t);
   229 
   230 fun declare_term t =
   231   declare_internal t #>
   232   declare_constraints t;
   233 
   234 val declare_typ = declare_term o Logic.mk_type;
   235 
   236 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   237 
   238 val declare_thm = Thm.fold_terms declare_internal;
   239 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   240 
   241 
   242 (* renaming term/type frees *)
   243 
   244 fun variant_frees ctxt ts frees =
   245   let
   246     val names = names_of (fold declare_names ts ctxt);
   247     val xs = fst (Name.variants (map #1 frees) names);
   248   in xs ~~ map snd frees end;
   249 
   250 
   251 
   252 (** term bindings **)
   253 
   254 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   255   | add_bind ((x, i), SOME t) =
   256       let
   257         val u = Term.close_schematic_term t;
   258         val U = Term.fastype_of u;
   259       in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   260 
   261 val add_binds = fold add_bind;
   262 
   263 fun expand_binds ctxt =
   264   let
   265     val binds = binds_of ctxt;
   266     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   267   in Envir.beta_norm o Envir.expand_term get end;
   268 
   269 
   270 
   271 (** consts **)
   272 
   273 val lookup_const = Symtab.lookup o #consts o rep_data;
   274 val is_const = is_some oo lookup_const;
   275 
   276 val declare_fixed = map_consts o Symtab.delete_safe;
   277 val declare_const = map_consts o Symtab.update;
   278 
   279 
   280 
   281 (** fixes **)
   282 
   283 local
   284 
   285 fun no_dups [] = ()
   286   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   287 
   288 fun new_fixes names' xs xs' =
   289   map_names (K names') #>
   290   fold declare_fixed xs #>
   291   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   292   fold (declare_constraints o Syntax.free) xs' #>
   293   pair xs';
   294 
   295 in
   296 
   297 fun add_fixes xs ctxt =
   298   let
   299     val _ =
   300       (case filter (can Name.dest_skolem) xs of [] => ()
   301       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   302     val _ = no_dups (duplicates (op =) xs);
   303     val (ys, zs) = split_list (fixes_of ctxt);
   304     val names = names_of ctxt;
   305     val (xs', names') =
   306       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   307       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   308         (xs, fold Name.declare xs names));
   309   in ctxt |> new_fixes names' xs xs' end;
   310 
   311 fun variant_fixes raw_xs ctxt =
   312   let
   313     val names = names_of ctxt;
   314     val xs = map (fn x => Name.clean x |> can Name.dest_internal x ? Name.internal) raw_xs;
   315     val (xs', names') = Name.variants xs names |>> (is_body ctxt ? map Name.skolem);
   316   in ctxt |> new_fixes names' xs xs' end;
   317 
   318 end;
   319 
   320 
   321 fun add_fixes_direct xs ctxt = ctxt
   322   |> set_body false
   323   |> (snd o add_fixes xs)
   324   |> restore_body ctxt;
   325 
   326 fun fix_frees t ctxt = ctxt
   327   |> add_fixes_direct
   328       (rev (fold_aterms (fn Free (x, _) =>
   329         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   330 
   331 fun auto_fixes t ctxt =
   332   (if is_body ctxt then ctxt else fix_frees t ctxt)
   333   |> declare_term t;
   334 
   335 fun invent_types Ss ctxt =
   336   let
   337     val tfrees = Name.invents (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   338     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   339   in (tfrees, ctxt') end;
   340 
   341 
   342 
   343 (** export -- generalize type/term variables (beware of closure sizes) **)
   344 
   345 fun export_inst inner outer =
   346   let
   347     val declared_outer = is_declared outer;
   348     val fixes_inner = fixes_of inner;
   349     val fixes_outer = fixes_of outer;
   350 
   351     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   352     val still_fixed = not o member (op =) gen_fixes;
   353 
   354     val type_occs_inner = type_occs_of inner;
   355     fun gen_fixesT ts =
   356       Symtab.fold (fn (a, xs) =>
   357         if declared_outer a orelse exists still_fixed xs
   358         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   359   in (gen_fixesT, gen_fixes) end;
   360 
   361 fun exportT_inst inner outer = #1 (export_inst inner outer);
   362 
   363 fun exportT_terms inner outer =
   364   let val mk_tfrees = exportT_inst inner outer in
   365     fn ts => ts |> map
   366       (TermSubst.generalize (mk_tfrees ts, [])
   367         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   368   end;
   369 
   370 fun export_terms inner outer =
   371   let val (mk_tfrees, tfrees) = export_inst inner outer in
   372     fn ts => ts |> map
   373       (TermSubst.generalize (mk_tfrees ts, tfrees)
   374         (fold Term.maxidx_term ts ~1 + 1))
   375   end;
   376 
   377 fun export_prf inner outer prf =
   378   let
   379     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   380     val tfrees = mk_tfrees [];
   381     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   382     val gen_term = TermSubst.generalize_option (tfrees, frees) idx;
   383     val gen_typ = TermSubst.generalizeT_option tfrees idx;
   384   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   385 
   386 
   387 fun gen_export (mk_tfrees, frees) ths =
   388   let
   389     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   390     val maxidx = fold Thm.maxidx_thm ths ~1;
   391   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   392 
   393 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   394 fun export inner outer = gen_export (export_inst inner outer);
   395 
   396 fun export_morphism inner outer =
   397   let
   398     val fact = export inner outer;
   399     val term = singleton (export_terms inner outer);
   400     val typ = Logic.type_map term;
   401   in Morphism.morphism {binding = I, var = I, typ = typ, term = term, fact = fact} end;
   402 
   403 
   404 
   405 (** import -- fix schematic type/term variables **)
   406 
   407 fun importT_inst ts ctxt =
   408   let
   409     val tvars = rev (fold Term.add_tvars ts []);
   410     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   411   in (tvars ~~ map TFree tfrees, ctxt') end;
   412 
   413 fun import_inst is_open ts ctxt =
   414   let
   415     val ren = Name.clean #> (if is_open then I else Name.internal);
   416     val (instT, ctxt') = importT_inst ts ctxt;
   417     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   418     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   419     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   420   in ((instT, inst), ctxt'') end;
   421 
   422 fun importT_terms ts ctxt =
   423   let val (instT, ctxt') = importT_inst ts ctxt
   424   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   425 
   426 fun import_terms is_open ts ctxt =
   427   let val (inst, ctxt') = import_inst is_open ts ctxt
   428   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   429 
   430 fun importT_thms ths ctxt =
   431   let
   432     val thy = ProofContext.theory_of ctxt;
   433     val certT = Thm.ctyp_of thy;
   434     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   435     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   436     val ths' = map (Thm.instantiate (instT', [])) ths;
   437   in ((map #2 instT', ths'), ctxt') end;
   438 
   439 fun import_prf is_open prf ctxt =
   440   let
   441     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   442     val (insts, ctxt') = import_inst is_open ts ctxt;
   443   in (Proofterm.instantiate insts prf, ctxt') end;
   444 
   445 fun import_thms is_open ths ctxt =
   446   let
   447     val thy = ProofContext.theory_of ctxt;
   448     val cert = Thm.cterm_of thy;
   449     val certT = Thm.ctyp_of thy;
   450     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   451     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   452     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   453     val ths' = map (Thm.instantiate (instT', inst')) ths;
   454   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   455 
   456 
   457 (* import/export *)
   458 
   459 fun gen_trade imp exp f ctxt ths =
   460   let val ((_, ths'), ctxt') = imp ths ctxt
   461   in exp ctxt' ctxt (f ctxt' ths') end;
   462 
   463 val tradeT = gen_trade importT_thms exportT;
   464 val trade = gen_trade (import_thms true) export;
   465 
   466 
   467 (* focus on outermost parameters *)
   468 
   469 fun forall_elim_prop t prop =
   470   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   471   |> Thm.cprop_of |> Thm.dest_arg;
   472 
   473 fun focus goal ctxt =
   474   let
   475     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   476     val t = Thm.term_of goal;
   477     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   478     val (xs, Ts) = split_list ps;
   479     val (xs', ctxt') = variant_fixes xs ctxt;
   480     val ps' = ListPair.map (cert o Free) (xs', Ts);
   481     val goal' = fold forall_elim_prop ps' goal;
   482     val ctxt'' = ctxt' |> fold (declare_constraints o Thm.term_of) ps';
   483   in ((ps', goal'), ctxt'') end;
   484 
   485 fun focus_subgoal i st =
   486   let
   487     val all_vars = Thm.fold_terms Term.add_vars st [];
   488     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   489   in
   490     add_binds no_binds #>
   491     fold (declare_constraints o Var) all_vars #>
   492     focus (Thm.cprem_of st i)
   493   end;
   494 
   495 
   496 
   497 (** implicit polymorphism **)
   498 
   499 (* warn_extra_tfrees *)
   500 
   501 fun warn_extra_tfrees ctxt1 ctxt2 =
   502   let
   503     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   504     fun occs_free a x =
   505       (case def_type ctxt1 false (x, ~1) of
   506         SOME T => if occs_typ a T then I else cons (a, x)
   507       | NONE => cons (a, x));
   508 
   509     val occs1 = type_occs_of ctxt1;
   510     val occs2 = type_occs_of ctxt2;
   511     val extras = Symtab.fold (fn (a, xs) =>
   512       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   513     val tfrees = map #1 extras |> sort_distinct string_ord;
   514     val frees = map #2 extras |> sort_distinct string_ord;
   515   in
   516     if null extras then ()
   517     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   518       space_implode " or " (map quote frees))
   519   end;
   520 
   521 
   522 (* polymorphic terms *)
   523 
   524 fun polymorphic_types ctxt ts =
   525   let
   526     val ctxt' = fold declare_term ts ctxt;
   527     val occs = type_occs_of ctxt;
   528     val occs' = type_occs_of ctxt';
   529     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   530     val idx = maxidx_of ctxt' + 1;
   531     val Ts' = (fold o fold_types o fold_atyps)
   532       (fn T as TFree _ =>
   533           (case TermSubst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   534         | _ => I) ts [];
   535     val ts' = map (TermSubst.generalize (types, []) idx) ts;
   536   in (rev Ts', ts') end;
   537 
   538 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   539 
   540 end;