src/Pure/Isar/specification.ML
author haftmann
Tue Sep 18 07:36:15 2007 +0200 (2007-09-18)
changeset 24624 b8383b1bbae3
parent 24557 57e2a5fbde86
child 24676 63eaef3207e1
permissions -rw-r--r--
distinction between regular and default code theorems
     1 (*  Title:      Pure/Isar/specification.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Derived local theory specifications --- with type-inference and
     6 toplevel polymorphism.
     7 *)
     8 
     9 signature SPECIFICATION =
    10 sig
    11   val quiet_mode: bool ref
    12   val print_consts: local_theory -> (string * typ -> bool) -> (string * typ) list -> unit
    13   val read_specification: (string * string option * mixfix) list ->
    14     ((string * Attrib.src list) * string list) list -> local_theory ->
    15     (((string * typ) * mixfix) list * ((string * Attrib.src list) * term list) list) *
    16     local_theory
    17   val cert_specification: (string * typ option * mixfix) list ->
    18     ((string * Attrib.src list) * term list) list -> local_theory ->
    19     (((string * typ) * mixfix) list * ((string * Attrib.src list) * term list) list) *
    20     local_theory
    21   val axiomatization: (string * string option * mixfix) list ->
    22     ((bstring * Attrib.src list) * string list) list -> local_theory ->
    23     (term list * (bstring * thm list) list) * local_theory
    24   val axiomatization_i: (string * typ option * mixfix) list ->
    25     ((bstring * Attrib.src list) * term list) list -> local_theory ->
    26     (term list * (bstring * thm list) list) * local_theory
    27   val definition:
    28     (string * string option * mixfix) option * ((string * Attrib.src list) * string) ->
    29     local_theory -> (term * (bstring * thm)) * local_theory
    30   val definition_i:
    31     (string * typ option * mixfix) option * ((string * Attrib.src list) * term) ->
    32     local_theory -> (term * (bstring * thm)) * local_theory
    33   val abbreviation: Syntax.mode -> (string * string option * mixfix) option * string ->
    34     local_theory -> local_theory
    35   val abbreviation_i: Syntax.mode -> (string * typ option * mixfix) option * term ->
    36     local_theory -> local_theory
    37   val notation: Syntax.mode -> (string * mixfix) list -> local_theory -> local_theory
    38   val notation_i: Syntax.mode -> (term * mixfix) list -> local_theory -> local_theory
    39   val theorems: string -> ((bstring * Attrib.src list) * (thmref * Attrib.src list) list) list
    40     -> local_theory -> (bstring * thm list) list * local_theory
    41   val theorems_i: string -> ((bstring * Attrib.src list) * (thm list * Attrib.src list) list) list
    42     -> local_theory -> (bstring * thm list) list * local_theory
    43   val theorem: string -> Method.text option -> (thm list list -> local_theory -> local_theory) ->
    44     string * Attrib.src list -> Element.context Locale.element list -> Element.statement ->
    45     bool -> local_theory -> Proof.state
    46   val theorem_i: string -> Method.text option -> (thm list list -> local_theory -> local_theory) ->
    47     string * Attrib.src list -> Element.context_i Locale.element list -> Element.statement_i ->
    48     bool -> local_theory -> Proof.state
    49   val add_theorem_hook: (bool -> Proof.state -> Proof.state) -> Context.generic -> Context.generic
    50 end;
    51 
    52 structure Specification: SPECIFICATION =
    53 struct
    54 
    55 
    56 (* diagnostics *)
    57 
    58 val quiet_mode = ref false;
    59 
    60 fun print_consts _ _ [] = ()
    61   | print_consts ctxt pred cs =
    62       if ! quiet_mode then () else Pretty.writeln (ProofDisplay.pretty_consts ctxt pred cs);
    63 
    64 fun present_results ctxt res =
    65   if ! quiet_mode then () else ProofDisplay.present_results ctxt res;
    66 
    67 fun present_results' ctxt kind res = present_results ctxt ((kind, ""), res);
    68 
    69 
    70 (* prepare specification *)
    71 
    72 fun prep_specification prep_vars prep_propp prep_att raw_vars raw_specs ctxt =
    73   let
    74     val thy = ProofContext.theory_of ctxt;
    75 
    76     val (vars, vars_ctxt) = ctxt |> prep_vars raw_vars;
    77     val (xs, params_ctxt) = vars_ctxt |> ProofContext.add_fixes_i vars;
    78     val ((specs, vs), specs_ctxt) =
    79       prep_propp (params_ctxt, map (map (rpair []) o snd) raw_specs)
    80       |> swap |>> map (map fst)
    81       ||>> fold_map ProofContext.inferred_param xs;
    82 
    83     val params = vs ~~ map #3 vars;
    84     val names = map (fst o fst) raw_specs;
    85     val atts = map (map (prep_att thy) o snd o fst) raw_specs;
    86   in ((params, (names ~~ atts) ~~ specs), specs_ctxt) end;
    87 
    88 fun read_specification x =
    89   prep_specification ProofContext.read_vars ProofContext.read_propp Attrib.intern_src x;
    90 
    91 fun cert_specification x =
    92   prep_specification ProofContext.cert_vars ProofContext.cert_propp (K I) x;
    93 
    94 
    95 (* axiomatization *)
    96 
    97 fun gen_axioms prep raw_vars raw_specs lthy =
    98   let
    99     val (vars, specs) = fst (prep raw_vars raw_specs lthy);
   100     val cs = map fst vars;
   101     val spec_frees = member (op =) (fold (fold Term.add_frees o snd) specs []);
   102 
   103     val ((consts, axioms), lthy') = lthy
   104       |> LocalTheory.consts spec_frees vars
   105       ||> fold (fold Variable.auto_fixes o snd) specs   (* FIXME !? *)
   106       ||>> LocalTheory.axioms Thm.axiomK specs;
   107 
   108     (* FIXME generic target!? *)
   109     val hs = map (Term.head_of o #2 o Logic.dest_equals o Thm.prop_of o #2) consts;
   110     val lthy'' = lthy' |> LocalTheory.theory (Theory.add_finals_i false hs);
   111 
   112     val _ = print_consts lthy' spec_frees cs;
   113   in ((map #1 consts, axioms), lthy'') end;
   114 
   115 val axiomatization = gen_axioms read_specification;
   116 val axiomatization_i = gen_axioms cert_specification;
   117 
   118 
   119 (* definition *)
   120 
   121 fun gen_def prep (raw_var, (raw_a, raw_prop)) lthy =
   122   let
   123     val (vars, [((raw_name, atts), [prop])]) =
   124       fst (prep (the_list raw_var) [(raw_a, [raw_prop])] lthy);
   125     val (((x, T), rhs), prove) = LocalDefs.derived_def lthy true prop;
   126     val name = Thm.def_name_optional x raw_name;
   127     val mx = (case vars of [] => NoSyn | [((x', _), mx)] =>
   128       if x = x' then mx
   129       else error ("Head of definition " ^ quote x ^ " differs from declaration " ^ quote x'));
   130     val ((lhs, (_, th)), lthy2) = lthy
   131       |> LocalTheory.def Thm.definitionK ((x, mx), ((name ^ "_raw", []), rhs));
   132     val ((b, [th']), lthy3) = lthy2
   133       |> LocalTheory.note Thm.definitionK
   134           ((name, Code.add_default_func_attr :: atts), [prove lthy2 th]);
   135 
   136     val lhs' = Morphism.term (LocalTheory.target_morphism lthy3) lhs;
   137     val _ = print_consts lthy3 (member (op =) (Term.add_frees lhs' [])) [(x, T)];
   138   in ((lhs, (b, th')), lthy3) end;
   139 
   140 val definition = gen_def read_specification;
   141 val definition_i = gen_def cert_specification;
   142 
   143 
   144 (* abbreviation *)
   145 
   146 fun gen_abbrev prep mode (raw_var, raw_prop) lthy =
   147   let
   148     val ((vars, [(_, [prop])]), _) =
   149       prep (the_list raw_var) [(("", []), [raw_prop])]
   150         (lthy |> ProofContext.set_expand_abbrevs false);
   151     val ((x, T), rhs) = LocalDefs.abs_def (#2 (LocalDefs.cert_def lthy prop));
   152     val mx = (case vars of [] => NoSyn | [((y, _), mx)] =>
   153       if x = y then mx
   154       else error ("Head of abbreviation " ^ quote x ^ " differs from declaration " ^ quote y));
   155     val lthy' = lthy
   156       |> ProofContext.set_syntax_mode mode    (* FIXME !? *)
   157       |> LocalTheory.abbrev mode ((x, mx), rhs) |> snd
   158       |> ProofContext.restore_syntax_mode lthy;
   159     val _ = print_consts lthy' (K false) [(x, T)]
   160   in lthy' end;
   161 
   162 val abbreviation = gen_abbrev read_specification;
   163 val abbreviation_i = gen_abbrev cert_specification;
   164 
   165 
   166 (* notation *)
   167 
   168 fun gen_notation prep_const mode args lthy =
   169   lthy |> LocalTheory.notation mode (map (apfst (prep_const lthy)) args);
   170 
   171 val notation = gen_notation ProofContext.read_const;
   172 val notation_i = gen_notation (K I);
   173 
   174 
   175 (* fact statements *)
   176 
   177 fun gen_theorems prep_thms prep_att kind raw_facts lthy =
   178   let
   179     val attrib = prep_att (ProofContext.theory_of lthy);
   180     val facts = raw_facts |> map (fn ((name, atts), bs) =>
   181       ((name, map attrib atts),
   182         bs |> map (fn (b, more_atts) => (prep_thms lthy b, map attrib more_atts))));
   183     val (res, lthy') = lthy |> LocalTheory.notes kind facts;
   184     val _ = present_results' lthy' kind res;
   185   in (res, lthy') end;
   186 
   187 val theorems = gen_theorems ProofContext.get_thms Attrib.intern_src;
   188 val theorems_i = gen_theorems (K I) (K I);
   189 
   190 
   191 (* complex goal statements *)
   192 
   193 local
   194 
   195 fun subtract_prems ctxt1 ctxt2 =
   196   Library.drop (length (Assumption.prems_of ctxt1), Assumption.prems_of ctxt2);
   197 
   198 fun prep_statement prep_att prep_stmt elems concl ctxt =
   199   (case concl of
   200     Element.Shows shows =>
   201       let
   202         val (_, loc_ctxt, elems_ctxt, propp) = prep_stmt elems (map snd shows) ctxt;
   203         val prems = subtract_prems loc_ctxt elems_ctxt;
   204         val stmt = Attrib.map_specs prep_att (map fst shows ~~ propp);
   205         val goal_ctxt = fold (fold (Variable.auto_fixes o fst)) propp elems_ctxt;
   206       in ((prems, stmt, []), goal_ctxt) end
   207   | Element.Obtains obtains =>
   208       let
   209         val case_names = obtains |> map_index
   210           (fn (i, ("", _)) => string_of_int (i + 1) | (_, (name, _)) => name);
   211         val constraints = obtains |> map (fn (_, (vars, _)) =>
   212           Locale.Elem (Element.Constrains
   213             (vars |> map_filter (fn (x, SOME T) => SOME (x, T) | _ => NONE))));
   214 
   215         val raw_propp = obtains |> map (fn (_, (_, props)) => map (rpair []) props);
   216         val (_, loc_ctxt, elems_ctxt, propp) = prep_stmt (elems @ constraints) raw_propp ctxt;
   217 
   218         val thesis = ObjectLogic.fixed_judgment (ProofContext.theory_of ctxt) AutoBind.thesisN;
   219 
   220         fun assume_case ((name, (vars, _)), asms) ctxt' =
   221           let
   222             val xs = map fst vars;
   223             val props = map fst asms;
   224             val (parms, _) = ctxt'
   225               |> fold Variable.declare_term props
   226               |> fold_map ProofContext.inferred_param xs;
   227             val asm = Term.list_all_free (parms, Logic.list_implies (props, thesis));
   228           in
   229             ctxt' |> (snd o ProofContext.add_fixes_i (map (fn x => (x, NONE, NoSyn)) xs));
   230             ctxt' |> Variable.auto_fixes asm
   231             |> ProofContext.add_assms_i Assumption.assume_export
   232               [((name, [ContextRules.intro_query NONE]), [(asm, [])])]
   233             |>> (fn [(_, [th])] => th)
   234           end;
   235 
   236         val atts = map (Attrib.internal o K)
   237           [RuleCases.consumes (~ (length obtains)), RuleCases.case_names case_names];
   238         val prems = subtract_prems loc_ctxt elems_ctxt;
   239         val stmt = [(("", atts), [(thesis, [])])];
   240 
   241         val (facts, goal_ctxt) = elems_ctxt
   242           |> (snd o ProofContext.add_fixes_i [(AutoBind.thesisN, NONE, NoSyn)])
   243           |> fold_map assume_case (obtains ~~ propp)
   244           |-> (fn ths => ProofContext.note_thmss_i Thm.assumptionK
   245                 [((Obtain.thatN, []), [(ths, [])])] #> #2 #> pair ths);
   246       in ((prems, stmt, facts), goal_ctxt) end);
   247 
   248 structure TheoremHook = GenericDataFun
   249 (
   250   type T = ((bool -> Proof.state -> Proof.state) * stamp) list;
   251   val empty = [];
   252   val extend = I;
   253   fun merge _ hooks : T = Library.merge (eq_snd op =) hooks;
   254 );
   255 
   256 fun gen_theorem prep_att prep_stmt
   257     kind before_qed after_qed (name, raw_atts) raw_elems raw_concl int lthy0 =
   258   let
   259     val _ = LocalTheory.affirm lthy0;
   260     val thy = ProofContext.theory_of lthy0;
   261 
   262     val (loc, ctxt, lthy) =
   263       (case (TheoryTarget.peek lthy0, exists (fn Locale.Expr _ => true | _ => false) raw_elems) of
   264         (SOME loc, true) => (* workaround non-modularity of in/includes *)  (* FIXME *)
   265           (SOME loc, ProofContext.init thy, LocalTheory.restore lthy0)
   266       | _ => (NONE, lthy0, lthy0));
   267 
   268     val attrib = prep_att thy;
   269     val atts = map attrib raw_atts;
   270 
   271     val elems = raw_elems |> map (Locale.map_elem (Element.map_ctxt_attrib attrib));
   272     val ((prems, stmt, facts), goal_ctxt) =
   273       prep_statement attrib (prep_stmt loc) elems raw_concl ctxt;
   274 
   275     fun after_qed' results goal_ctxt' =
   276       let val results' =
   277         burrow (map Goal.norm_result o ProofContext.export goal_ctxt' lthy) results
   278       in
   279         lthy
   280         |> LocalTheory.notes kind (map2 (fn (a, _) => fn ths => (a, [(ths, [])])) stmt results')
   281         |> (fn (res, lthy') =>
   282           (present_results lthy' ((kind, name), res);
   283             if name = "" andalso null atts then lthy'
   284             else #2 (LocalTheory.notes kind [((name, atts), [(maps #2 res, [])])] lthy')))
   285         |> after_qed results'
   286       end;
   287   in
   288     goal_ctxt
   289     |> ProofContext.note_thmss_i Thm.assumptionK [((AutoBind.assmsN, []), [(prems, [])])]
   290     |> snd
   291     |> Proof.theorem_i before_qed after_qed' (map snd stmt)
   292     |> Proof.refine_insert facts
   293     |> Library.apply (map (fn (f, _) => f int) (rev (TheoremHook.get (Context.Proof goal_ctxt))))
   294   end;
   295 
   296 in
   297 
   298 val theorem = gen_theorem Attrib.intern_src Locale.read_context_statement_i;
   299 val theorem_i = gen_theorem (K I) Locale.cert_context_statement;
   300 
   301 fun add_theorem_hook f = TheoremHook.map (cons (f, stamp ()));
   302 
   303 end;
   304 
   305 end;