src/HOL/Complex.thy
author haftmann
Sat Jul 05 11:01:53 2014 +0200 (2014-07-05)
changeset 57514 bdc2c6b40bf2
parent 57512 cc97b347b301
child 58146 d91c1e50b36e
permissions -rw-r--r--
prefer ac_simps collections over separate name bindings for add and mult
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 text {*
    14 
    15 We use the @{text codatatype}-command to define the type of complex numbers. This might look strange
    16 at first, but allows us to use @{text primcorec} to define complex-functions by defining their
    17 real and imaginary result separate.
    18 
    19 *}
    20 
    21 codatatype complex = Complex (Re: real) (Im: real)
    22 
    23 lemma complex_surj: "Complex (Re z) (Im z) = z"
    24   by (rule complex.collapse)
    25 
    26 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    27   by (rule complex.expand) simp
    28 
    29 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    30   by (auto intro: complex.expand)
    31 
    32 subsection {* Addition and Subtraction *}
    33 
    34 instantiation complex :: ab_group_add
    35 begin
    36 
    37 primcorec zero_complex where
    38   "Re 0 = 0"
    39 | "Im 0 = 0"
    40 
    41 primcorec plus_complex where
    42   "Re (x + y) = Re x + Re y"
    43 | "Im (x + y) = Im x + Im y"
    44 
    45 primcorec uminus_complex where
    46   "Re (- x) = - Re x"
    47 | "Im (- x) = - Im x"
    48 
    49 primcorec minus_complex where
    50   "Re (x - y) = Re x - Re y"
    51 | "Im (x - y) = Im x - Im y"
    52 
    53 instance
    54   by intro_classes (simp_all add: complex_eq_iff)
    55 
    56 end
    57 
    58 subsection {* Multiplication and Division *}
    59 
    60 instantiation complex :: field_inverse_zero
    61 begin
    62 
    63 primcorec one_complex where
    64   "Re 1 = 1"
    65 | "Im 1 = 0"
    66 
    67 primcorec times_complex where
    68   "Re (x * y) = Re x * Re y - Im x * Im y"
    69 | "Im (x * y) = Re x * Im y + Im x * Re y"
    70 
    71 primcorec inverse_complex where
    72   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    73 | "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    74 
    75 definition "x / (y\<Colon>complex) = x * inverse y"
    76 
    77 instance
    78   by intro_classes 
    79      (simp_all add: complex_eq_iff divide_complex_def
    80       distrib_left distrib_right right_diff_distrib left_diff_distrib
    81       power2_eq_square add_divide_distrib [symmetric])
    82 
    83 end
    84 
    85 lemma Re_divide: "Re (x / y) = (Re x * Re y + Im x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    86   unfolding divide_complex_def by (simp add: add_divide_distrib)
    87 
    88 lemma Im_divide: "Im (x / y) = (Im x * Re y - Re x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    89   unfolding divide_complex_def times_complex.sel inverse_complex.sel
    90   by (simp_all add: divide_simps)
    91 
    92 lemma Re_power2: "Re (x ^ 2) = (Re x)^2 - (Im x)^2"
    93   by (simp add: power2_eq_square)
    94 
    95 lemma Im_power2: "Im (x ^ 2) = 2 * Re x * Im x"
    96   by (simp add: power2_eq_square)
    97 
    98 lemma Re_power_real: "Im x = 0 \<Longrightarrow> Re (x ^ n) = Re x ^ n "
    99   by (induct n) simp_all
   100 
   101 lemma Im_power_real: "Im x = 0 \<Longrightarrow> Im (x ^ n) = 0"
   102   by (induct n) simp_all
   103 
   104 subsection {* Scalar Multiplication *}
   105 
   106 instantiation complex :: real_field
   107 begin
   108 
   109 primcorec scaleR_complex where
   110   "Re (scaleR r x) = r * Re x"
   111 | "Im (scaleR r x) = r * Im x"
   112 
   113 instance
   114 proof
   115   fix a b :: real and x y :: complex
   116   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   117     by (simp add: complex_eq_iff distrib_left)
   118   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   119     by (simp add: complex_eq_iff distrib_right)
   120   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   121     by (simp add: complex_eq_iff mult.assoc)
   122   show "scaleR 1 x = x"
   123     by (simp add: complex_eq_iff)
   124   show "scaleR a x * y = scaleR a (x * y)"
   125     by (simp add: complex_eq_iff algebra_simps)
   126   show "x * scaleR a y = scaleR a (x * y)"
   127     by (simp add: complex_eq_iff algebra_simps)
   128 qed
   129 
   130 end
   131 
   132 subsection {* Numerals, Arithmetic, and Embedding from Reals *}
   133 
   134 abbreviation complex_of_real :: "real \<Rightarrow> complex"
   135   where "complex_of_real \<equiv> of_real"
   136 
   137 declare [[coercion complex_of_real]]
   138 declare [[coercion "of_int :: int \<Rightarrow> complex"]]
   139 declare [[coercion "of_nat :: nat \<Rightarrow> complex"]]
   140 
   141 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   142   by (induct n) simp_all
   143 
   144 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   145   by (induct n) simp_all
   146 
   147 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   148   by (cases z rule: int_diff_cases) simp
   149 
   150 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   151   by (cases z rule: int_diff_cases) simp
   152 
   153 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
   154   using complex_Re_of_int [of "numeral v"] by simp
   155 
   156 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
   157   using complex_Im_of_int [of "numeral v"] by simp
   158 
   159 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   160   by (simp add: of_real_def)
   161 
   162 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   163   by (simp add: of_real_def)
   164 
   165 subsection {* The Complex Number $i$ *}
   166 
   167 primcorec "ii" :: complex  ("\<i>") where
   168   "Re ii = 0"
   169 | "Im ii = 1"
   170 
   171 lemma Complex_eq[simp]: "Complex a b = a + \<i> * b"
   172   by (simp add: complex_eq_iff)
   173 
   174 lemma complex_eq: "a = Re a + \<i> * Im a"
   175   by (simp add: complex_eq_iff)
   176 
   177 lemma fun_complex_eq: "f = (\<lambda>x. Re (f x) + \<i> * Im (f x))"
   178   by (simp add: fun_eq_iff complex_eq)
   179 
   180 lemma i_squared [simp]: "ii * ii = -1"
   181   by (simp add: complex_eq_iff)
   182 
   183 lemma power2_i [simp]: "ii\<^sup>2 = -1"
   184   by (simp add: power2_eq_square)
   185 
   186 lemma inverse_i [simp]: "inverse ii = - ii"
   187   by (rule inverse_unique) simp
   188 
   189 lemma divide_i [simp]: "x / ii = - ii * x"
   190   by (simp add: divide_complex_def)
   191 
   192 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   193   by (simp add: mult.assoc [symmetric])
   194 
   195 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   196   by (simp add: complex_eq_iff)
   197 
   198 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   199   by (simp add: complex_eq_iff)
   200 
   201 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
   202   by (simp add: complex_eq_iff)
   203 
   204 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"
   205   by (simp add: complex_eq_iff)
   206 
   207 lemma complex_split_polar: "\<exists>r a. z = complex_of_real r * (cos a + \<i> * sin a)"
   208   by (simp add: complex_eq_iff polar_Ex)
   209 
   210 subsection {* Vector Norm *}
   211 
   212 instantiation complex :: real_normed_field
   213 begin
   214 
   215 definition "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   216 
   217 abbreviation cmod :: "complex \<Rightarrow> real"
   218   where "cmod \<equiv> norm"
   219 
   220 definition complex_sgn_def:
   221   "sgn x = x /\<^sub>R cmod x"
   222 
   223 definition dist_complex_def:
   224   "dist x y = cmod (x - y)"
   225 
   226 definition open_complex_def:
   227   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   228 
   229 instance proof
   230   fix r :: real and x y :: complex and S :: "complex set"
   231   show "(norm x = 0) = (x = 0)"
   232     by (simp add: norm_complex_def complex_eq_iff)
   233   show "norm (x + y) \<le> norm x + norm y"
   234     by (simp add: norm_complex_def complex_eq_iff real_sqrt_sum_squares_triangle_ineq)
   235   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   236     by (simp add: norm_complex_def complex_eq_iff power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
   237   show "norm (x * y) = norm x * norm y"
   238     by (simp add: norm_complex_def complex_eq_iff real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   239 qed (rule complex_sgn_def dist_complex_def open_complex_def)+
   240 
   241 end
   242 
   243 lemma norm_ii [simp]: "norm ii = 1"
   244   by (simp add: norm_complex_def)
   245 
   246 lemma cmod_unit_one: "cmod (cos a + \<i> * sin a) = 1"
   247   by (simp add: norm_complex_def)
   248 
   249 lemma cmod_complex_polar: "cmod (r * (cos a + \<i> * sin a)) = \<bar>r\<bar>"
   250   by (simp add: norm_mult cmod_unit_one)
   251 
   252 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   253   unfolding norm_complex_def
   254   by (rule real_sqrt_sum_squares_ge1)
   255 
   256 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
   257   by (rule order_trans [OF _ norm_ge_zero]) simp
   258 
   259 lemma complex_mod_triangle_ineq2: "cmod (b + a) - cmod b \<le> cmod a"
   260   by (rule ord_le_eq_trans [OF norm_triangle_ineq2]) simp
   261 
   262 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   263   by (simp add: norm_complex_def)
   264 
   265 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   266   by (simp add: norm_complex_def)
   267 
   268 lemma cmod_le: "cmod z \<le> \<bar>Re z\<bar> + \<bar>Im z\<bar>"
   269   apply (subst complex_eq)
   270   apply (rule order_trans)
   271   apply (rule norm_triangle_ineq)
   272   apply (simp add: norm_mult)
   273   done
   274 
   275 lemma cmod_eq_Re: "Im z = 0 \<Longrightarrow> cmod z = \<bar>Re z\<bar>"
   276   by (simp add: norm_complex_def)
   277 
   278 lemma cmod_eq_Im: "Re z = 0 \<Longrightarrow> cmod z = \<bar>Im z\<bar>"
   279   by (simp add: norm_complex_def)
   280 
   281 lemma cmod_power2: "cmod z ^ 2 = (Re z)^2 + (Im z)^2"
   282   by (simp add: norm_complex_def)
   283 
   284 lemma cmod_plus_Re_le_0_iff: "cmod z + Re z \<le> 0 \<longleftrightarrow> Re z = - cmod z"
   285   using abs_Re_le_cmod[of z] by auto
   286 
   287 lemma Im_eq_0: "\<bar>Re z\<bar> = cmod z \<Longrightarrow> Im z = 0"
   288   by (subst (asm) power_eq_iff_eq_base[symmetric, where n=2])
   289      (auto simp add: norm_complex_def)
   290 
   291 lemma abs_sqrt_wlog:
   292   fixes x::"'a::linordered_idom"
   293   assumes "\<And>x::'a. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)" shows "P \<bar>x\<bar> (x\<^sup>2)"
   294 by (metis abs_ge_zero assms power2_abs)
   295 
   296 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"
   297   unfolding norm_complex_def
   298   apply (rule abs_sqrt_wlog [where x="Re z"])
   299   apply (rule abs_sqrt_wlog [where x="Im z"])
   300   apply (rule power2_le_imp_le)
   301   apply (simp_all add: power2_sum add.commute sum_squares_bound real_sqrt_mult [symmetric])
   302   done
   303 
   304 
   305 text {* Properties of complex signum. *}
   306 
   307 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   308   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult.commute)
   309 
   310 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   311   by (simp add: complex_sgn_def divide_inverse)
   312 
   313 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   314   by (simp add: complex_sgn_def divide_inverse)
   315 
   316 
   317 subsection {* Completeness of the Complexes *}
   318 
   319 lemma bounded_linear_Re: "bounded_linear Re"
   320   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
   321 
   322 lemma bounded_linear_Im: "bounded_linear Im"
   323   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
   324 
   325 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   326 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   327 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]
   328 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]
   329 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   330 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   331 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]
   332 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]
   333 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]
   334 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]
   335 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]
   336 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]
   337 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]
   338 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]
   339 
   340 lemma tendsto_Complex [tendsto_intros]:
   341   "(f ---> a) F \<Longrightarrow> (g ---> b) F \<Longrightarrow> ((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
   342   by (auto intro!: tendsto_intros)
   343 
   344 lemma tendsto_complex_iff:
   345   "(f ---> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) ---> Re x) F \<and> ((\<lambda>x. Im (f x)) ---> Im x) F)"
   346 proof safe
   347   assume "((\<lambda>x. Re (f x)) ---> Re x) F" "((\<lambda>x. Im (f x)) ---> Im x) F"
   348   from tendsto_Complex[OF this] show "(f ---> x) F"
   349     unfolding complex.collapse .
   350 qed (auto intro: tendsto_intros)
   351 
   352 lemma continuous_complex_iff: "continuous F f \<longleftrightarrow>
   353     continuous F (\<lambda>x. Re (f x)) \<and> continuous F (\<lambda>x. Im (f x))"
   354   unfolding continuous_def tendsto_complex_iff ..
   355 
   356 lemma has_vector_derivative_complex_iff: "(f has_vector_derivative x) F \<longleftrightarrow>
   357     ((\<lambda>x. Re (f x)) has_field_derivative (Re x)) F \<and>
   358     ((\<lambda>x. Im (f x)) has_field_derivative (Im x)) F"
   359   unfolding has_vector_derivative_def has_field_derivative_def has_derivative_def tendsto_complex_iff
   360   by (simp add: field_simps bounded_linear_scaleR_left bounded_linear_mult_right)
   361 
   362 lemma has_field_derivative_Re[derivative_intros]:
   363   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Re (f x)) has_field_derivative (Re D)) F"
   364   unfolding has_vector_derivative_complex_iff by safe
   365 
   366 lemma has_field_derivative_Im[derivative_intros]:
   367   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Im (f x)) has_field_derivative (Im D)) F"
   368   unfolding has_vector_derivative_complex_iff by safe
   369 
   370 instance complex :: banach
   371 proof
   372   fix X :: "nat \<Rightarrow> complex"
   373   assume X: "Cauchy X"
   374   then have "(\<lambda>n. Complex (Re (X n)) (Im (X n))) ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   375     by (intro tendsto_Complex convergent_LIMSEQ_iff[THEN iffD1] Cauchy_convergent_iff[THEN iffD1] Cauchy_Re Cauchy_Im)
   376   then show "convergent X"
   377     unfolding complex.collapse by (rule convergentI)
   378 qed
   379 
   380 declare
   381   DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]
   382 
   383 subsection {* Complex Conjugation *}
   384 
   385 primcorec cnj :: "complex \<Rightarrow> complex" where
   386   "Re (cnj z) = Re z"
   387 | "Im (cnj z) = - Im z"
   388 
   389 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   390   by (simp add: complex_eq_iff)
   391 
   392 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   393   by (simp add: complex_eq_iff)
   394 
   395 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   396   by (simp add: complex_eq_iff)
   397 
   398 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   399   by (simp add: complex_eq_iff)
   400 
   401 lemma complex_cnj_add [simp]: "cnj (x + y) = cnj x + cnj y"
   402   by (simp add: complex_eq_iff)
   403 
   404 lemma cnj_setsum [simp]: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"
   405   by (induct s rule: infinite_finite_induct) auto
   406 
   407 lemma complex_cnj_diff [simp]: "cnj (x - y) = cnj x - cnj y"
   408   by (simp add: complex_eq_iff)
   409 
   410 lemma complex_cnj_minus [simp]: "cnj (- x) = - cnj x"
   411   by (simp add: complex_eq_iff)
   412 
   413 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   414   by (simp add: complex_eq_iff)
   415 
   416 lemma complex_cnj_mult [simp]: "cnj (x * y) = cnj x * cnj y"
   417   by (simp add: complex_eq_iff)
   418 
   419 lemma cnj_setprod [simp]: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"
   420   by (induct s rule: infinite_finite_induct) auto
   421 
   422 lemma complex_cnj_inverse [simp]: "cnj (inverse x) = inverse (cnj x)"
   423   by (simp add: complex_eq_iff)
   424 
   425 lemma complex_cnj_divide [simp]: "cnj (x / y) = cnj x / cnj y"
   426   by (simp add: divide_complex_def)
   427 
   428 lemma complex_cnj_power [simp]: "cnj (x ^ n) = cnj x ^ n"
   429   by (induct n) simp_all
   430 
   431 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   432   by (simp add: complex_eq_iff)
   433 
   434 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   435   by (simp add: complex_eq_iff)
   436 
   437 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
   438   by (simp add: complex_eq_iff)
   439 
   440 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
   441   by (simp add: complex_eq_iff)
   442 
   443 lemma complex_cnj_scaleR [simp]: "cnj (scaleR r x) = scaleR r (cnj x)"
   444   by (simp add: complex_eq_iff)
   445 
   446 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   447   by (simp add: norm_complex_def)
   448 
   449 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   450   by (simp add: complex_eq_iff)
   451 
   452 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   453   by (simp add: complex_eq_iff)
   454 
   455 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   456   by (simp add: complex_eq_iff)
   457 
   458 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   459   by (simp add: complex_eq_iff)
   460 
   461 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   462   by (simp add: complex_eq_iff power2_eq_square)
   463 
   464 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
   465   by (simp add: norm_mult power2_eq_square)
   466 
   467 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   468   by (simp add: norm_complex_def power2_eq_square)
   469 
   470 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   471   by simp
   472 
   473 lemma bounded_linear_cnj: "bounded_linear cnj"
   474   using complex_cnj_add complex_cnj_scaleR
   475   by (rule bounded_linear_intro [where K=1], simp)
   476 
   477 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]
   478 lemmas isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]
   479 lemmas continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]
   480 lemmas continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]
   481 lemmas has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]
   482 
   483 lemma lim_cnj: "((\<lambda>x. cnj(f x)) ---> cnj l) F \<longleftrightarrow> (f ---> l) F"
   484   by (simp add: tendsto_iff dist_complex_def complex_cnj_diff [symmetric] del: complex_cnj_diff)
   485 
   486 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"
   487   by (simp add: sums_def lim_cnj cnj_setsum [symmetric] del: cnj_setsum)
   488 
   489 
   490 subsection{*Basic Lemmas*}
   491 
   492 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
   493   by (metis zero_complex.sel complex_eqI sum_power2_eq_zero_iff)
   494 
   495 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
   496   by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
   497 
   498 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
   499 by (cases z)
   500    (auto simp: complex_eq_iff norm_complex_def power2_eq_square[symmetric] of_real_power[symmetric]
   501          simp del: of_real_power)
   502 
   503 lemma re_complex_div_eq_0: "Re (a / b) = 0 \<longleftrightarrow> Re (a * cnj b) = 0"
   504   by (auto simp add: Re_divide)
   505   
   506 lemma im_complex_div_eq_0: "Im (a / b) = 0 \<longleftrightarrow> Im (a * cnj b) = 0"
   507   by (auto simp add: Im_divide)
   508 
   509 lemma complex_div_gt_0: 
   510   "(Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0) \<and> (Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0)"
   511 proof cases
   512   assume "b = 0" then show ?thesis by auto
   513 next
   514   assume "b \<noteq> 0"
   515   then have "0 < (Re b)\<^sup>2 + (Im b)\<^sup>2"
   516     by (simp add: complex_eq_iff sum_power2_gt_zero_iff)
   517   then show ?thesis
   518     by (simp add: Re_divide Im_divide zero_less_divide_iff)
   519 qed
   520 
   521 lemma re_complex_div_gt_0: "Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0"
   522   and im_complex_div_gt_0: "Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0"
   523   using complex_div_gt_0 by auto
   524 
   525 lemma re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"
   526   by (metis le_less re_complex_div_eq_0 re_complex_div_gt_0)
   527 
   528 lemma im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"
   529   by (metis im_complex_div_eq_0 im_complex_div_gt_0 le_less)
   530 
   531 lemma re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"
   532   by (metis less_asym neq_iff re_complex_div_eq_0 re_complex_div_gt_0)
   533 
   534 lemma im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"
   535   by (metis im_complex_div_eq_0 im_complex_div_gt_0 less_asym neq_iff)
   536 
   537 lemma re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"
   538   by (metis not_le re_complex_div_gt_0)
   539 
   540 lemma im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"
   541   by (metis im_complex_div_gt_0 not_le)
   542 
   543 lemma Re_setsum[simp]: "Re (setsum f s) = (\<Sum>x\<in>s. Re (f x))"
   544   by (induct s rule: infinite_finite_induct) auto
   545 
   546 lemma Im_setsum[simp]: "Im (setsum f s) = (\<Sum>x\<in>s. Im(f x))"
   547   by (induct s rule: infinite_finite_induct) auto
   548 
   549 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"
   550   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..
   551   
   552 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"
   553   unfolding summable_def sums_complex_iff[abs_def] by (metis complex.sel)
   554 
   555 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"
   556   unfolding summable_complex_iff by simp
   557 
   558 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"
   559   unfolding summable_complex_iff by blast
   560 
   561 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"
   562   unfolding summable_complex_iff by blast
   563 
   564 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"
   565   by (auto simp: Reals_def complex_eq_iff)
   566 
   567 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
   568   by (auto simp: complex_is_Real_iff complex_eq_iff)
   569 
   570 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm(z) = abs(Re z)"
   571   by (simp add: complex_is_Real_iff norm_complex_def)
   572 
   573 lemma series_comparison_complex:
   574   fixes f:: "nat \<Rightarrow> 'a::banach"
   575   assumes sg: "summable g"
   576      and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"
   577      and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"
   578   shows "summable f"
   579 proof -
   580   have g: "\<And>n. cmod (g n) = Re (g n)" using assms
   581     by (metis abs_of_nonneg in_Reals_norm)
   582   show ?thesis
   583     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])
   584     using sg
   585     apply (auto simp: summable_def)
   586     apply (rule_tac x="Re s" in exI)
   587     apply (auto simp: g sums_Re)
   588     apply (metis fg g)
   589     done
   590 qed
   591 
   592 subsection{*Finally! Polar Form for Complex Numbers*}
   593 
   594 subsubsection {* $\cos \theta + i \sin \theta$ *}
   595 
   596 primcorec cis :: "real \<Rightarrow> complex" where
   597   "Re (cis a) = cos a"
   598 | "Im (cis a) = sin a"
   599 
   600 lemma cis_zero [simp]: "cis 0 = 1"
   601   by (simp add: complex_eq_iff)
   602 
   603 lemma norm_cis [simp]: "norm (cis a) = 1"
   604   by (simp add: norm_complex_def)
   605 
   606 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
   607   by (simp add: sgn_div_norm)
   608 
   609 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
   610   by (metis norm_cis norm_zero zero_neq_one)
   611 
   612 lemma cis_mult: "cis a * cis b = cis (a + b)"
   613   by (simp add: complex_eq_iff cos_add sin_add)
   614 
   615 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   616   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)
   617 
   618 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   619   by (simp add: complex_eq_iff)
   620 
   621 lemma cis_divide: "cis a / cis b = cis (a - b)"
   622   by (simp add: divide_complex_def cis_mult)
   623 
   624 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   625   by (auto simp add: DeMoivre)
   626 
   627 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   628   by (auto simp add: DeMoivre)
   629 
   630 lemma cis_pi: "cis pi = -1"
   631   by (simp add: complex_eq_iff)
   632 
   633 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}
   634 
   635 definition rcis :: "real \<Rightarrow> real \<Rightarrow> complex" where
   636   "rcis r a = complex_of_real r * cis a"
   637 
   638 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   639   by (simp add: rcis_def)
   640 
   641 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   642   by (simp add: rcis_def)
   643 
   644 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   645   by (simp add: complex_eq_iff polar_Ex)
   646 
   647 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   648   by (simp add: rcis_def norm_mult)
   649 
   650 lemma cis_rcis_eq: "cis a = rcis 1 a"
   651   by (simp add: rcis_def)
   652 
   653 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   654   by (simp add: rcis_def cis_mult)
   655 
   656 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   657   by (simp add: rcis_def)
   658 
   659 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   660   by (simp add: rcis_def)
   661 
   662 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
   663   by (simp add: rcis_def)
   664 
   665 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   666   by (simp add: rcis_def power_mult_distrib DeMoivre)
   667 
   668 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   669   by (simp add: divide_inverse rcis_def)
   670 
   671 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   672   by (simp add: rcis_def cis_divide [symmetric])
   673 
   674 subsubsection {* Complex exponential *}
   675 
   676 abbreviation expi :: "complex \<Rightarrow> complex"
   677   where "expi \<equiv> exp"
   678 
   679 lemma cis_conv_exp: "cis b = exp (\<i> * b)"
   680 proof -
   681   { fix n :: nat
   682     have "\<i> ^ n = fact n *\<^sub>R (cos_coeff n + \<i> * sin_coeff n)"
   683       by (induct n)
   684          (simp_all add: sin_coeff_Suc cos_coeff_Suc complex_eq_iff Re_divide Im_divide field_simps
   685                         power2_eq_square real_of_nat_Suc add_nonneg_eq_0_iff
   686                         real_of_nat_def[symmetric])
   687     then have "(\<i> * complex_of_real b) ^ n /\<^sub>R fact n =
   688         of_real (cos_coeff n * b^n) + \<i> * of_real (sin_coeff n * b^n)"
   689       by (simp add: field_simps) }
   690   then show ?thesis
   691     by (auto simp add: cis.ctr exp_def simp del: of_real_mult
   692              intro!: sums_unique sums_add sums_mult sums_of_real sin_converges cos_converges)
   693 qed
   694 
   695 lemma expi_def: "expi z = exp (Re z) * cis (Im z)"
   696   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by (cases z) simp
   697 
   698 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
   699   unfolding expi_def by simp
   700 
   701 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
   702   unfolding expi_def by simp
   703 
   704 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   705 apply (insert rcis_Ex [of z])
   706 apply (auto simp add: expi_def rcis_def mult.assoc [symmetric])
   707 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   708 done
   709 
   710 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   711   by (simp add: expi_def complex_eq_iff)
   712 
   713 subsubsection {* Complex argument *}
   714 
   715 definition arg :: "complex \<Rightarrow> real" where
   716   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
   717 
   718 lemma arg_zero: "arg 0 = 0"
   719   by (simp add: arg_def)
   720 
   721 lemma arg_unique:
   722   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
   723   shows "arg z = x"
   724 proof -
   725   from assms have "z \<noteq> 0" by auto
   726   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
   727   proof
   728     fix a def d \<equiv> "a - x"
   729     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
   730     from a assms have "- (2*pi) < d \<and> d < 2*pi"
   731       unfolding d_def by simp
   732     moreover from a assms have "cos a = cos x" and "sin a = sin x"
   733       by (simp_all add: complex_eq_iff)
   734     hence cos: "cos d = 1" unfolding d_def cos_diff by simp
   735     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)
   736     ultimately have "d = 0"
   737       unfolding sin_zero_iff even_mult_two_ex
   738       by (auto simp add: numeral_2_eq_2 less_Suc_eq)
   739     thus "a = x" unfolding d_def by simp
   740   qed (simp add: assms del: Re_sgn Im_sgn)
   741   with `z \<noteq> 0` show "arg z = x"
   742     unfolding arg_def by simp
   743 qed
   744 
   745 lemma arg_correct:
   746   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
   747 proof (simp add: arg_def assms, rule someI_ex)
   748   obtain r a where z: "z = rcis r a" using rcis_Ex by fast
   749   with assms have "r \<noteq> 0" by auto
   750   def b \<equiv> "if 0 < r then a else a + pi"
   751   have b: "sgn z = cis b"
   752     unfolding z b_def rcis_def using `r \<noteq> 0`
   753     by (simp add: of_real_def sgn_scaleR sgn_if complex_eq_iff)
   754   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
   755     by (induct_tac n) (simp_all add: distrib_left cis_mult [symmetric] complex_eq_iff)
   756   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
   757     by (case_tac x rule: int_diff_cases)
   758        (simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
   759   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
   760   have "sgn z = cis c"
   761     unfolding b c_def
   762     by (simp add: cis_divide [symmetric] cis_2pi_int)
   763   moreover have "- pi < c \<and> c \<le> pi"
   764     using ceiling_correct [of "(b - pi) / (2*pi)"]
   765     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)
   766   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
   767 qed
   768 
   769 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
   770   by (cases "z = 0") (simp_all add: arg_zero arg_correct)
   771 
   772 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
   773   by (simp add: arg_correct)
   774 
   775 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
   776   by (cases "z = 0") (simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
   777 
   778 lemma cos_arg_i_mult_zero [simp]: "y \<noteq> 0 \<Longrightarrow> Re y = 0 \<Longrightarrow> cos (arg y) = 0"
   779   using cis_arg [of y] by (simp add: complex_eq_iff)
   780 
   781 subsection {* Square root of complex numbers *}
   782 
   783 primcorec csqrt :: "complex \<Rightarrow> complex" where
   784   "Re (csqrt z) = sqrt ((cmod z + Re z) / 2)"
   785 | "Im (csqrt z) = (if Im z = 0 then 1 else sgn (Im z)) * sqrt ((cmod z - Re z) / 2)"
   786 
   787 lemma csqrt_of_real_nonneg [simp]: "Im x = 0 \<Longrightarrow> Re x \<ge> 0 \<Longrightarrow> csqrt x = sqrt (Re x)"
   788   by (simp add: complex_eq_iff norm_complex_def)
   789 
   790 lemma csqrt_of_real_nonpos [simp]: "Im x = 0 \<Longrightarrow> Re x \<le> 0 \<Longrightarrow> csqrt x = \<i> * sqrt \<bar>Re x\<bar>"
   791   by (simp add: complex_eq_iff norm_complex_def)
   792 
   793 lemma csqrt_0 [simp]: "csqrt 0 = 0"
   794   by simp
   795 
   796 lemma csqrt_1 [simp]: "csqrt 1 = 1"
   797   by simp
   798 
   799 lemma csqrt_ii [simp]: "csqrt \<i> = (1 + \<i>) / sqrt 2"
   800   by (simp add: complex_eq_iff Re_divide Im_divide real_sqrt_divide real_div_sqrt)
   801 
   802 lemma power2_csqrt[algebra]: "(csqrt z)\<^sup>2 = z"
   803 proof cases
   804   assume "Im z = 0" then show ?thesis
   805     using real_sqrt_pow2[of "Re z"] real_sqrt_pow2[of "- Re z"]
   806     by (cases "0::real" "Re z" rule: linorder_cases)
   807        (simp_all add: complex_eq_iff Re_power2 Im_power2 power2_eq_square cmod_eq_Re)
   808 next
   809   assume "Im z \<noteq> 0"
   810   moreover
   811   have "cmod z * cmod z - Re z * Re z = Im z * Im z"
   812     by (simp add: norm_complex_def power2_eq_square)
   813   moreover
   814   have "\<bar>Re z\<bar> \<le> cmod z"
   815     by (simp add: norm_complex_def)
   816   ultimately show ?thesis
   817     by (simp add: Re_power2 Im_power2 complex_eq_iff real_sgn_eq
   818                   field_simps real_sqrt_mult[symmetric] real_sqrt_divide)
   819 qed
   820 
   821 lemma csqrt_eq_0 [simp]: "csqrt z = 0 \<longleftrightarrow> z = 0"
   822   by auto (metis power2_csqrt power_eq_0_iff)
   823 
   824 lemma csqrt_eq_1 [simp]: "csqrt z = 1 \<longleftrightarrow> z = 1"
   825   by auto (metis power2_csqrt power2_eq_1_iff)
   826 
   827 lemma csqrt_principal: "0 < Re (csqrt z) \<or> Re (csqrt z) = 0 \<and> 0 \<le> Im (csqrt z)"
   828   by (auto simp add: not_less cmod_plus_Re_le_0_iff Im_eq_0)
   829 
   830 lemma Re_csqrt: "0 \<le> Re (csqrt z)"
   831   by (metis csqrt_principal le_less)
   832 
   833 lemma csqrt_square:
   834   assumes "0 < Re b \<or> (Re b = 0 \<and> 0 \<le> Im b)"
   835   shows "csqrt (b^2) = b"
   836 proof -
   837   have "csqrt (b^2) = b \<or> csqrt (b^2) = - b"
   838     unfolding power2_eq_iff[symmetric] by (simp add: power2_csqrt)
   839   moreover have "csqrt (b^2) \<noteq> -b \<or> b = 0"
   840     using csqrt_principal[of "b ^ 2"] assms by (intro disjCI notI) (auto simp: complex_eq_iff)
   841   ultimately show ?thesis
   842     by auto
   843 qed
   844 
   845 lemma csqrt_minus [simp]: 
   846   assumes "Im x < 0 \<or> (Im x = 0 \<and> 0 \<le> Re x)"
   847   shows "csqrt (- x) = \<i> * csqrt x"
   848 proof -
   849   have "csqrt ((\<i> * csqrt x)^2) = \<i> * csqrt x"
   850   proof (rule csqrt_square)
   851     have "Im (csqrt x) \<le> 0"
   852       using assms by (auto simp add: cmod_eq_Re mult_le_0_iff field_simps complex_Re_le_cmod)
   853     then show "0 < Re (\<i> * csqrt x) \<or> Re (\<i> * csqrt x) = 0 \<and> 0 \<le> Im (\<i> * csqrt x)"
   854       by (auto simp add: Re_csqrt simp del: csqrt.simps)
   855   qed
   856   also have "(\<i> * csqrt x)^2 = - x"
   857     by (simp add: power2_csqrt power_mult_distrib)
   858   finally show ?thesis .
   859 qed
   860 
   861 text {* Legacy theorem names *}
   862 
   863 lemmas expand_complex_eq = complex_eq_iff
   864 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   865 lemmas complex_equality = complex_eqI
   866 lemmas cmod_def = norm_complex_def
   867 lemmas complex_norm_def = norm_complex_def
   868 lemmas complex_divide_def = divide_complex_def
   869 
   870 lemma legacy_Complex_simps:
   871   shows Complex_eq_0: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
   872     and complex_add: "Complex a b + Complex c d = Complex (a + c) (b + d)"
   873     and complex_minus: "- (Complex a b) = Complex (- a) (- b)"
   874     and complex_diff: "Complex a b - Complex c d = Complex (a - c) (b - d)"
   875     and Complex_eq_1: "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
   876     and Complex_eq_neg_1: "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
   877     and complex_mult: "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   878     and complex_inverse: "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
   879     and Complex_eq_numeral: "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
   880     and Complex_eq_neg_numeral: "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
   881     and complex_scaleR: "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   882     and Complex_eq_i: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   883     and i_mult_Complex: "ii * Complex a b = Complex (- b) a"
   884     and Complex_mult_i: "Complex a b * ii = Complex (- b) a"
   885     and i_complex_of_real: "ii * complex_of_real r = Complex 0 r"
   886     and complex_of_real_i: "complex_of_real r * ii = Complex 0 r"
   887     and Complex_add_complex_of_real: "Complex x y + complex_of_real r = Complex (x+r) y"
   888     and complex_of_real_add_Complex: "complex_of_real r + Complex x y = Complex (r+x) y"
   889     and Complex_mult_complex_of_real: "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   890     and complex_of_real_mult_Complex: "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   891     and complex_eq_cancel_iff2: "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   892     and complex_cn: "cnj (Complex a b) = Complex a (- b)"
   893     and Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"
   894     and Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"
   895     and complex_of_real_def: "complex_of_real r = Complex r 0"
   896     and complex_norm: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
   897   by (simp_all add: norm_complex_def field_simps complex_eq_iff Re_divide Im_divide del: Complex_eq)
   898 
   899 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
   900   by (metis Reals_of_real complex_of_real_def)
   901 
   902 end