src/HOL/Real/PReal.thy
author haftmann
Fri Dec 07 15:07:59 2007 +0100 (2007-12-07)
changeset 25571 c9e39eafc7a0
parent 25502 9200b36280c0
child 26511 dba7125d0fef
permissions -rw-r--r--
instantiation target rather than legacy instance
     1 (*  Title       : PReal.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Description : The positive reals as Dedekind sections of positive
     6          rationals. Fundamentals of Abstract Analysis [Gleason- p. 121]
     7                   provides some of the definitions.
     8 *)
     9 
    10 header {* Positive real numbers *}
    11 
    12 theory PReal
    13 imports Rational
    14 begin
    15 
    16 text{*Could be generalized and moved to @{text Ring_and_Field}*}
    17 lemma add_eq_exists: "\<exists>x. a+x = (b::rat)"
    18 by (rule_tac x="b-a" in exI, simp)
    19 
    20 definition
    21   cut :: "rat set => bool" where
    22   "cut A = ({} \<subset> A &
    23             A < {r. 0 < r} &
    24             (\<forall>y \<in> A. ((\<forall>z. 0<z & z < y --> z \<in> A) & (\<exists>u \<in> A. y < u))))"
    25 
    26 lemma cut_of_rat: 
    27   assumes q: "0 < q" shows "cut {r::rat. 0 < r & r < q}" (is "cut ?A")
    28 proof -
    29   from q have pos: "?A < {r. 0 < r}" by force
    30   have nonempty: "{} \<subset> ?A"
    31   proof
    32     show "{} \<subseteq> ?A" by simp
    33     show "{} \<noteq> ?A"
    34       by (force simp only: q eq_commute [of "{}"] interval_empty_iff)
    35   qed
    36   show ?thesis
    37     by (simp add: cut_def pos nonempty,
    38         blast dest: dense intro: order_less_trans)
    39 qed
    40 
    41 
    42 typedef preal = "{A. cut A}"
    43   by (blast intro: cut_of_rat [OF zero_less_one])
    44 
    45 instance preal :: "{ord, plus, minus, times, inverse, one}" ..
    46 
    47 definition
    48   preal_of_rat :: "rat => preal" where
    49   "preal_of_rat q = Abs_preal {x::rat. 0 < x & x < q}"
    50 
    51 definition
    52   psup :: "preal set => preal" where
    53   "psup P = Abs_preal (\<Union>X \<in> P. Rep_preal X)"
    54 
    55 definition
    56   add_set :: "[rat set,rat set] => rat set" where
    57   "add_set A B = {w. \<exists>x \<in> A. \<exists>y \<in> B. w = x + y}"
    58 
    59 definition
    60   diff_set :: "[rat set,rat set] => rat set" where
    61   "diff_set A B = {w. \<exists>x. 0 < w & 0 < x & x \<notin> B & x + w \<in> A}"
    62 
    63 definition
    64   mult_set :: "[rat set,rat set] => rat set" where
    65   "mult_set A B = {w. \<exists>x \<in> A. \<exists>y \<in> B. w = x * y}"
    66 
    67 definition
    68   inverse_set :: "rat set => rat set" where
    69   "inverse_set A = {x. \<exists>y. 0 < x & x < y & inverse y \<notin> A}"
    70 
    71 
    72 defs (overloaded)
    73 
    74   preal_less_def:
    75     "R < S == Rep_preal R < Rep_preal S"
    76 
    77   preal_le_def:
    78     "R \<le> S == Rep_preal R \<subseteq> Rep_preal S"
    79 
    80   preal_add_def:
    81     "R + S == Abs_preal (add_set (Rep_preal R) (Rep_preal S))"
    82 
    83   preal_diff_def:
    84     "R - S == Abs_preal (diff_set (Rep_preal R) (Rep_preal S))"
    85 
    86   preal_mult_def:
    87     "R * S == Abs_preal (mult_set (Rep_preal R) (Rep_preal S))"
    88 
    89   preal_inverse_def:
    90     "inverse R == Abs_preal (inverse_set (Rep_preal R))"
    91 
    92   preal_one_def:
    93     "1 == preal_of_rat 1"
    94 
    95 
    96 text{*Reduces equality on abstractions to equality on representatives*}
    97 declare Abs_preal_inject [simp]
    98 declare Abs_preal_inverse [simp]
    99 
   100 lemma rat_mem_preal: "0 < q ==> {r::rat. 0 < r & r < q} \<in> preal"
   101 by (simp add: preal_def cut_of_rat)
   102 
   103 lemma preal_nonempty: "A \<in> preal ==> \<exists>x\<in>A. 0 < x"
   104 by (unfold preal_def cut_def, blast)
   105 
   106 lemma preal_Ex_mem: "A \<in> preal \<Longrightarrow> \<exists>x. x \<in> A"
   107 by (drule preal_nonempty, fast)
   108 
   109 lemma preal_imp_psubset_positives: "A \<in> preal ==> A < {r. 0 < r}"
   110 by (force simp add: preal_def cut_def)
   111 
   112 lemma preal_exists_bound: "A \<in> preal ==> \<exists>x. 0 < x & x \<notin> A"
   113 by (drule preal_imp_psubset_positives, auto)
   114 
   115 lemma preal_exists_greater: "[| A \<in> preal; y \<in> A |] ==> \<exists>u \<in> A. y < u"
   116 by (unfold preal_def cut_def, blast)
   117 
   118 lemma preal_downwards_closed: "[| A \<in> preal; y \<in> A; 0 < z; z < y |] ==> z \<in> A"
   119 by (unfold preal_def cut_def, blast)
   120 
   121 text{*Relaxing the final premise*}
   122 lemma preal_downwards_closed':
   123      "[| A \<in> preal; y \<in> A; 0 < z; z \<le> y |] ==> z \<in> A"
   124 apply (simp add: order_le_less)
   125 apply (blast intro: preal_downwards_closed)
   126 done
   127 
   128 text{*A positive fraction not in a positive real is an upper bound.
   129  Gleason p. 122 - Remark (1)*}
   130 
   131 lemma not_in_preal_ub:
   132   assumes A: "A \<in> preal"
   133     and notx: "x \<notin> A"
   134     and y: "y \<in> A"
   135     and pos: "0 < x"
   136   shows "y < x"
   137 proof (cases rule: linorder_cases)
   138   assume "x<y"
   139   with notx show ?thesis
   140     by (simp add:  preal_downwards_closed [OF A y] pos)
   141 next
   142   assume "x=y"
   143   with notx and y show ?thesis by simp
   144 next
   145   assume "y<x"
   146   thus ?thesis .
   147 qed
   148 
   149 text {* preal lemmas instantiated to @{term "Rep_preal X"} *}
   150 
   151 lemma mem_Rep_preal_Ex: "\<exists>x. x \<in> Rep_preal X"
   152 by (rule preal_Ex_mem [OF Rep_preal])
   153 
   154 lemma Rep_preal_exists_bound: "\<exists>x>0. x \<notin> Rep_preal X"
   155 by (rule preal_exists_bound [OF Rep_preal])
   156 
   157 lemmas not_in_Rep_preal_ub = not_in_preal_ub [OF Rep_preal]
   158 
   159 
   160 
   161 subsection{*@{term preal_of_prat}: the Injection from prat to preal*}
   162 
   163 lemma rat_less_set_mem_preal: "0 < y ==> {u::rat. 0 < u & u < y} \<in> preal"
   164 by (simp add: preal_def cut_of_rat)
   165 
   166 lemma rat_subset_imp_le:
   167      "[|{u::rat. 0 < u & u < x} \<subseteq> {u. 0 < u & u < y}; 0<x|] ==> x \<le> y"
   168 apply (simp add: linorder_not_less [symmetric])
   169 apply (blast dest: dense intro: order_less_trans)
   170 done
   171 
   172 lemma rat_set_eq_imp_eq:
   173      "[|{u::rat. 0 < u & u < x} = {u. 0 < u & u < y};
   174         0 < x; 0 < y|] ==> x = y"
   175 by (blast intro: rat_subset_imp_le order_antisym)
   176 
   177 
   178 
   179 subsection{*Properties of Ordering*}
   180 
   181 lemma preal_le_refl: "w \<le> (w::preal)"
   182 by (simp add: preal_le_def)
   183 
   184 lemma preal_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::preal)"
   185 by (force simp add: preal_le_def)
   186 
   187 lemma preal_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::preal)"
   188 apply (simp add: preal_le_def)
   189 apply (rule Rep_preal_inject [THEN iffD1], blast)
   190 done
   191 
   192 (* Axiom 'order_less_le' of class 'order': *)
   193 lemma preal_less_le: "((w::preal) < z) = (w \<le> z & w \<noteq> z)"
   194 by (simp add: preal_le_def preal_less_def Rep_preal_inject psubset_def)
   195 
   196 instance preal :: order
   197   by intro_classes
   198     (assumption |
   199       rule preal_le_refl preal_le_trans preal_le_anti_sym preal_less_le)+
   200 
   201 lemma preal_imp_pos: "[|A \<in> preal; r \<in> A|] ==> 0 < r"
   202 by (insert preal_imp_psubset_positives, blast)
   203 
   204 lemma preal_le_linear: "x <= y | y <= (x::preal)"
   205 apply (auto simp add: preal_le_def)
   206 apply (rule ccontr)
   207 apply (blast dest: not_in_Rep_preal_ub intro: preal_imp_pos [OF Rep_preal]
   208              elim: order_less_asym)
   209 done
   210 
   211 instance preal :: linorder
   212   by intro_classes (rule preal_le_linear)
   213 
   214 instantiation preal :: distrib_lattice
   215 begin
   216 
   217 definition
   218   "(inf \<Colon> preal \<Rightarrow> preal \<Rightarrow> preal) = min"
   219 
   220 definition
   221   "(sup \<Colon> preal \<Rightarrow> preal \<Rightarrow> preal) = max"
   222 
   223 instance
   224   by intro_classes
   225     (auto simp add: inf_preal_def sup_preal_def min_max.sup_inf_distrib1)
   226 
   227 end
   228 
   229 subsection{*Properties of Addition*}
   230 
   231 lemma preal_add_commute: "(x::preal) + y = y + x"
   232 apply (unfold preal_add_def add_set_def)
   233 apply (rule_tac f = Abs_preal in arg_cong)
   234 apply (force simp add: add_commute)
   235 done
   236 
   237 text{*Lemmas for proving that addition of two positive reals gives
   238  a positive real*}
   239 
   240 lemma empty_psubset_nonempty: "a \<in> A ==> {} \<subset> A"
   241 by blast
   242 
   243 text{*Part 1 of Dedekind sections definition*}
   244 lemma add_set_not_empty:
   245      "[|A \<in> preal; B \<in> preal|] ==> {} \<subset> add_set A B"
   246 apply (drule preal_nonempty)+
   247 apply (auto simp add: add_set_def)
   248 done
   249 
   250 text{*Part 2 of Dedekind sections definition.  A structured version of
   251 this proof is @{text preal_not_mem_mult_set_Ex} below.*}
   252 lemma preal_not_mem_add_set_Ex:
   253      "[|A \<in> preal; B \<in> preal|] ==> \<exists>q>0. q \<notin> add_set A B"
   254 apply (insert preal_exists_bound [of A] preal_exists_bound [of B], auto) 
   255 apply (rule_tac x = "x+xa" in exI)
   256 apply (simp add: add_set_def, clarify)
   257 apply (drule (3) not_in_preal_ub)+
   258 apply (force dest: add_strict_mono)
   259 done
   260 
   261 lemma add_set_not_rat_set:
   262    assumes A: "A \<in> preal" 
   263        and B: "B \<in> preal"
   264      shows "add_set A B < {r. 0 < r}"
   265 proof
   266   from preal_imp_pos [OF A] preal_imp_pos [OF B]
   267   show "add_set A B \<subseteq> {r. 0 < r}" by (force simp add: add_set_def) 
   268 next
   269   show "add_set A B \<noteq> {r. 0 < r}"
   270     by (insert preal_not_mem_add_set_Ex [OF A B], blast) 
   271 qed
   272 
   273 text{*Part 3 of Dedekind sections definition*}
   274 lemma add_set_lemma3:
   275      "[|A \<in> preal; B \<in> preal; u \<in> add_set A B; 0 < z; z < u|] 
   276       ==> z \<in> add_set A B"
   277 proof (unfold add_set_def, clarify)
   278   fix x::rat and y::rat
   279   assume A: "A \<in> preal" 
   280     and B: "B \<in> preal"
   281     and [simp]: "0 < z"
   282     and zless: "z < x + y"
   283     and x:  "x \<in> A"
   284     and y:  "y \<in> B"
   285   have xpos [simp]: "0<x" by (rule preal_imp_pos [OF A x])
   286   have ypos [simp]: "0<y" by (rule preal_imp_pos [OF B y])
   287   have xypos [simp]: "0 < x+y" by (simp add: pos_add_strict)
   288   let ?f = "z/(x+y)"
   289   have fless: "?f < 1" by (simp add: zless pos_divide_less_eq)
   290   show "\<exists>x' \<in> A. \<exists>y'\<in>B. z = x' + y'"
   291   proof (intro bexI)
   292     show "z = x*?f + y*?f"
   293       by (simp add: left_distrib [symmetric] divide_inverse mult_ac
   294           order_less_imp_not_eq2)
   295   next
   296     show "y * ?f \<in> B"
   297     proof (rule preal_downwards_closed [OF B y])
   298       show "0 < y * ?f"
   299         by (simp add: divide_inverse zero_less_mult_iff)
   300     next
   301       show "y * ?f < y"
   302         by (insert mult_strict_left_mono [OF fless ypos], simp)
   303     qed
   304   next
   305     show "x * ?f \<in> A"
   306     proof (rule preal_downwards_closed [OF A x])
   307       show "0 < x * ?f"
   308 	by (simp add: divide_inverse zero_less_mult_iff)
   309     next
   310       show "x * ?f < x"
   311 	by (insert mult_strict_left_mono [OF fless xpos], simp)
   312     qed
   313   qed
   314 qed
   315 
   316 text{*Part 4 of Dedekind sections definition*}
   317 lemma add_set_lemma4:
   318      "[|A \<in> preal; B \<in> preal; y \<in> add_set A B|] ==> \<exists>u \<in> add_set A B. y < u"
   319 apply (auto simp add: add_set_def)
   320 apply (frule preal_exists_greater [of A], auto) 
   321 apply (rule_tac x="u + y" in exI)
   322 apply (auto intro: add_strict_left_mono)
   323 done
   324 
   325 lemma mem_add_set:
   326      "[|A \<in> preal; B \<in> preal|] ==> add_set A B \<in> preal"
   327 apply (simp (no_asm_simp) add: preal_def cut_def)
   328 apply (blast intro!: add_set_not_empty add_set_not_rat_set
   329                      add_set_lemma3 add_set_lemma4)
   330 done
   331 
   332 lemma preal_add_assoc: "((x::preal) + y) + z = x + (y + z)"
   333 apply (simp add: preal_add_def mem_add_set Rep_preal)
   334 apply (force simp add: add_set_def add_ac)
   335 done
   336 
   337 instance preal :: ab_semigroup_add
   338 proof
   339   fix a b c :: preal
   340   show "(a + b) + c = a + (b + c)" by (rule preal_add_assoc)
   341   show "a + b = b + a" by (rule preal_add_commute)
   342 qed
   343 
   344 lemma preal_add_left_commute: "x + (y + z) = y + ((x + z)::preal)"
   345 by (rule add_left_commute)
   346 
   347 text{* Positive Real addition is an AC operator *}
   348 lemmas preal_add_ac = preal_add_assoc preal_add_commute preal_add_left_commute
   349 
   350 
   351 subsection{*Properties of Multiplication*}
   352 
   353 text{*Proofs essentially same as for addition*}
   354 
   355 lemma preal_mult_commute: "(x::preal) * y = y * x"
   356 apply (unfold preal_mult_def mult_set_def)
   357 apply (rule_tac f = Abs_preal in arg_cong)
   358 apply (force simp add: mult_commute)
   359 done
   360 
   361 text{*Multiplication of two positive reals gives a positive real.*}
   362 
   363 text{*Lemmas for proving positive reals multiplication set in @{typ preal}*}
   364 
   365 text{*Part 1 of Dedekind sections definition*}
   366 lemma mult_set_not_empty:
   367      "[|A \<in> preal; B \<in> preal|] ==> {} \<subset> mult_set A B"
   368 apply (insert preal_nonempty [of A] preal_nonempty [of B]) 
   369 apply (auto simp add: mult_set_def)
   370 done
   371 
   372 text{*Part 2 of Dedekind sections definition*}
   373 lemma preal_not_mem_mult_set_Ex:
   374    assumes A: "A \<in> preal" 
   375        and B: "B \<in> preal"
   376      shows "\<exists>q. 0 < q & q \<notin> mult_set A B"
   377 proof -
   378   from preal_exists_bound [OF A]
   379   obtain x where [simp]: "0 < x" "x \<notin> A" by blast
   380   from preal_exists_bound [OF B]
   381   obtain y where [simp]: "0 < y" "y \<notin> B" by blast
   382   show ?thesis
   383   proof (intro exI conjI)
   384     show "0 < x*y" by (simp add: mult_pos_pos)
   385     show "x * y \<notin> mult_set A B"
   386     proof -
   387       { fix u::rat and v::rat
   388 	      assume "u \<in> A" and "v \<in> B" and "x*y = u*v"
   389 	      moreover
   390 	      with prems have "u<x" and "v<y" by (blast dest: not_in_preal_ub)+
   391 	      moreover
   392 	      with prems have "0\<le>v"
   393 	        by (blast intro: preal_imp_pos [OF B]  order_less_imp_le prems)
   394 	      moreover
   395         from calculation
   396 	      have "u*v < x*y" by (blast intro: mult_strict_mono prems)
   397 	      ultimately have False by force }
   398       thus ?thesis by (auto simp add: mult_set_def)
   399     qed
   400   qed
   401 qed
   402 
   403 lemma mult_set_not_rat_set:
   404   assumes A: "A \<in> preal" 
   405     and B: "B \<in> preal"
   406   shows "mult_set A B < {r. 0 < r}"
   407 proof
   408   show "mult_set A B \<subseteq> {r. 0 < r}"
   409     by (force simp add: mult_set_def
   410       intro: preal_imp_pos [OF A] preal_imp_pos [OF B] mult_pos_pos)
   411   show "mult_set A B \<noteq> {r. 0 < r}"
   412     using preal_not_mem_mult_set_Ex [OF A B] by blast
   413 qed
   414 
   415 
   416 
   417 text{*Part 3 of Dedekind sections definition*}
   418 lemma mult_set_lemma3:
   419      "[|A \<in> preal; B \<in> preal; u \<in> mult_set A B; 0 < z; z < u|] 
   420       ==> z \<in> mult_set A B"
   421 proof (unfold mult_set_def, clarify)
   422   fix x::rat and y::rat
   423   assume A: "A \<in> preal" 
   424     and B: "B \<in> preal"
   425     and [simp]: "0 < z"
   426     and zless: "z < x * y"
   427     and x:  "x \<in> A"
   428     and y:  "y \<in> B"
   429   have [simp]: "0<y" by (rule preal_imp_pos [OF B y])
   430   show "\<exists>x' \<in> A. \<exists>y' \<in> B. z = x' * y'"
   431   proof
   432     show "\<exists>y'\<in>B. z = (z/y) * y'"
   433     proof
   434       show "z = (z/y)*y"
   435 	by (simp add: divide_inverse mult_commute [of y] mult_assoc
   436 		      order_less_imp_not_eq2)
   437       show "y \<in> B" by fact
   438     qed
   439   next
   440     show "z/y \<in> A"
   441     proof (rule preal_downwards_closed [OF A x])
   442       show "0 < z/y"
   443 	by (simp add: zero_less_divide_iff)
   444       show "z/y < x" by (simp add: pos_divide_less_eq zless)
   445     qed
   446   qed
   447 qed
   448 
   449 text{*Part 4 of Dedekind sections definition*}
   450 lemma mult_set_lemma4:
   451      "[|A \<in> preal; B \<in> preal; y \<in> mult_set A B|] ==> \<exists>u \<in> mult_set A B. y < u"
   452 apply (auto simp add: mult_set_def)
   453 apply (frule preal_exists_greater [of A], auto) 
   454 apply (rule_tac x="u * y" in exI)
   455 apply (auto intro: preal_imp_pos [of A] preal_imp_pos [of B] 
   456                    mult_strict_right_mono)
   457 done
   458 
   459 
   460 lemma mem_mult_set:
   461      "[|A \<in> preal; B \<in> preal|] ==> mult_set A B \<in> preal"
   462 apply (simp (no_asm_simp) add: preal_def cut_def)
   463 apply (blast intro!: mult_set_not_empty mult_set_not_rat_set
   464                      mult_set_lemma3 mult_set_lemma4)
   465 done
   466 
   467 lemma preal_mult_assoc: "((x::preal) * y) * z = x * (y * z)"
   468 apply (simp add: preal_mult_def mem_mult_set Rep_preal)
   469 apply (force simp add: mult_set_def mult_ac)
   470 done
   471 
   472 instance preal :: ab_semigroup_mult
   473 proof
   474   fix a b c :: preal
   475   show "(a * b) * c = a * (b * c)" by (rule preal_mult_assoc)
   476   show "a * b = b * a" by (rule preal_mult_commute)
   477 qed
   478 
   479 lemma preal_mult_left_commute: "x * (y * z) = y * ((x * z)::preal)"
   480 by (rule mult_left_commute)
   481 
   482 
   483 text{* Positive Real multiplication is an AC operator *}
   484 lemmas preal_mult_ac =
   485        preal_mult_assoc preal_mult_commute preal_mult_left_commute
   486 
   487 
   488 text{* Positive real 1 is the multiplicative identity element *}
   489 
   490 lemma preal_mult_1: "(1::preal) * z = z"
   491 unfolding preal_one_def
   492 proof (induct z)
   493   fix A :: "rat set"
   494   assume A: "A \<in> preal"
   495   have "{w. \<exists>u. 0 < u \<and> u < 1 & (\<exists>v \<in> A. w = u * v)} = A" (is "?lhs = A")
   496   proof
   497     show "?lhs \<subseteq> A"
   498     proof clarify
   499       fix x::rat and u::rat and v::rat
   500       assume upos: "0<u" and "u<1" and v: "v \<in> A"
   501       have vpos: "0<v" by (rule preal_imp_pos [OF A v])
   502       hence "u*v < 1*v" by (simp only: mult_strict_right_mono prems)
   503       thus "u * v \<in> A"
   504         by (force intro: preal_downwards_closed [OF A v] mult_pos_pos 
   505           upos vpos)
   506     qed
   507   next
   508     show "A \<subseteq> ?lhs"
   509     proof clarify
   510       fix x::rat
   511       assume x: "x \<in> A"
   512       have xpos: "0<x" by (rule preal_imp_pos [OF A x])
   513       from preal_exists_greater [OF A x]
   514       obtain v where v: "v \<in> A" and xlessv: "x < v" ..
   515       have vpos: "0<v" by (rule preal_imp_pos [OF A v])
   516       show "\<exists>u. 0 < u \<and> u < 1 \<and> (\<exists>v\<in>A. x = u * v)"
   517       proof (intro exI conjI)
   518         show "0 < x/v"
   519           by (simp add: zero_less_divide_iff xpos vpos)
   520 	show "x / v < 1"
   521           by (simp add: pos_divide_less_eq vpos xlessv)
   522         show "\<exists>v'\<in>A. x = (x / v) * v'"
   523         proof
   524           show "x = (x/v)*v"
   525 	    by (simp add: divide_inverse mult_assoc vpos
   526                           order_less_imp_not_eq2)
   527           show "v \<in> A" by fact
   528         qed
   529       qed
   530     qed
   531   qed
   532   thus "preal_of_rat 1 * Abs_preal A = Abs_preal A"
   533     by (simp add: preal_of_rat_def preal_mult_def mult_set_def 
   534                   rat_mem_preal A)
   535 qed
   536 
   537 instance preal :: comm_monoid_mult
   538 by intro_classes (rule preal_mult_1)
   539 
   540 lemma preal_mult_1_right: "z * (1::preal) = z"
   541 by (rule mult_1_right)
   542 
   543 
   544 subsection{*Distribution of Multiplication across Addition*}
   545 
   546 lemma mem_Rep_preal_add_iff:
   547       "(z \<in> Rep_preal(R+S)) = (\<exists>x \<in> Rep_preal R. \<exists>y \<in> Rep_preal S. z = x + y)"
   548 apply (simp add: preal_add_def mem_add_set Rep_preal)
   549 apply (simp add: add_set_def) 
   550 done
   551 
   552 lemma mem_Rep_preal_mult_iff:
   553       "(z \<in> Rep_preal(R*S)) = (\<exists>x \<in> Rep_preal R. \<exists>y \<in> Rep_preal S. z = x * y)"
   554 apply (simp add: preal_mult_def mem_mult_set Rep_preal)
   555 apply (simp add: mult_set_def) 
   556 done
   557 
   558 lemma distrib_subset1:
   559      "Rep_preal (w * (x + y)) \<subseteq> Rep_preal (w * x + w * y)"
   560 apply (auto simp add: Bex_def mem_Rep_preal_add_iff mem_Rep_preal_mult_iff)
   561 apply (force simp add: right_distrib)
   562 done
   563 
   564 lemma preal_add_mult_distrib_mean:
   565   assumes a: "a \<in> Rep_preal w"
   566     and b: "b \<in> Rep_preal w"
   567     and d: "d \<in> Rep_preal x"
   568     and e: "e \<in> Rep_preal y"
   569   shows "\<exists>c \<in> Rep_preal w. a * d + b * e = c * (d + e)"
   570 proof
   571   let ?c = "(a*d + b*e)/(d+e)"
   572   have [simp]: "0<a" "0<b" "0<d" "0<e" "0<d+e"
   573     by (blast intro: preal_imp_pos [OF Rep_preal] a b d e pos_add_strict)+
   574   have cpos: "0 < ?c"
   575     by (simp add: zero_less_divide_iff zero_less_mult_iff pos_add_strict)
   576   show "a * d + b * e = ?c * (d + e)"
   577     by (simp add: divide_inverse mult_assoc order_less_imp_not_eq2)
   578   show "?c \<in> Rep_preal w"
   579   proof (cases rule: linorder_le_cases)
   580     assume "a \<le> b"
   581     hence "?c \<le> b"
   582       by (simp add: pos_divide_le_eq right_distrib mult_right_mono
   583                     order_less_imp_le)
   584     thus ?thesis by (rule preal_downwards_closed' [OF Rep_preal b cpos])
   585   next
   586     assume "b \<le> a"
   587     hence "?c \<le> a"
   588       by (simp add: pos_divide_le_eq right_distrib mult_right_mono
   589                     order_less_imp_le)
   590     thus ?thesis by (rule preal_downwards_closed' [OF Rep_preal a cpos])
   591   qed
   592 qed
   593 
   594 lemma distrib_subset2:
   595      "Rep_preal (w * x + w * y) \<subseteq> Rep_preal (w * (x + y))"
   596 apply (auto simp add: Bex_def mem_Rep_preal_add_iff mem_Rep_preal_mult_iff)
   597 apply (drule_tac w=w and x=x and y=y in preal_add_mult_distrib_mean, auto)
   598 done
   599 
   600 lemma preal_add_mult_distrib2: "(w * ((x::preal) + y)) = (w * x) + (w * y)"
   601 apply (rule Rep_preal_inject [THEN iffD1])
   602 apply (rule equalityI [OF distrib_subset1 distrib_subset2])
   603 done
   604 
   605 lemma preal_add_mult_distrib: "(((x::preal) + y) * w) = (x * w) + (y * w)"
   606 by (simp add: preal_mult_commute preal_add_mult_distrib2)
   607 
   608 instance preal :: comm_semiring
   609 by intro_classes (rule preal_add_mult_distrib)
   610 
   611 
   612 subsection{*Existence of Inverse, a Positive Real*}
   613 
   614 lemma mem_inv_set_ex:
   615   assumes A: "A \<in> preal" shows "\<exists>x y. 0 < x & x < y & inverse y \<notin> A"
   616 proof -
   617   from preal_exists_bound [OF A]
   618   obtain x where [simp]: "0<x" "x \<notin> A" by blast
   619   show ?thesis
   620   proof (intro exI conjI)
   621     show "0 < inverse (x+1)"
   622       by (simp add: order_less_trans [OF _ less_add_one]) 
   623     show "inverse(x+1) < inverse x"
   624       by (simp add: less_imp_inverse_less less_add_one)
   625     show "inverse (inverse x) \<notin> A"
   626       by (simp add: order_less_imp_not_eq2)
   627   qed
   628 qed
   629 
   630 text{*Part 1 of Dedekind sections definition*}
   631 lemma inverse_set_not_empty:
   632      "A \<in> preal ==> {} \<subset> inverse_set A"
   633 apply (insert mem_inv_set_ex [of A])
   634 apply (auto simp add: inverse_set_def)
   635 done
   636 
   637 text{*Part 2 of Dedekind sections definition*}
   638 
   639 lemma preal_not_mem_inverse_set_Ex:
   640    assumes A: "A \<in> preal"  shows "\<exists>q. 0 < q & q \<notin> inverse_set A"
   641 proof -
   642   from preal_nonempty [OF A]
   643   obtain x where x: "x \<in> A" and  xpos [simp]: "0<x" ..
   644   show ?thesis
   645   proof (intro exI conjI)
   646     show "0 < inverse x" by simp
   647     show "inverse x \<notin> inverse_set A"
   648     proof -
   649       { fix y::rat 
   650 	assume ygt: "inverse x < y"
   651 	have [simp]: "0 < y" by (simp add: order_less_trans [OF _ ygt])
   652 	have iyless: "inverse y < x" 
   653 	  by (simp add: inverse_less_imp_less [of x] ygt)
   654 	have "inverse y \<in> A"
   655 	  by (simp add: preal_downwards_closed [OF A x] iyless)}
   656      thus ?thesis by (auto simp add: inverse_set_def)
   657     qed
   658   qed
   659 qed
   660 
   661 lemma inverse_set_not_rat_set:
   662    assumes A: "A \<in> preal"  shows "inverse_set A < {r. 0 < r}"
   663 proof
   664   show "inverse_set A \<subseteq> {r. 0 < r}"  by (force simp add: inverse_set_def)
   665 next
   666   show "inverse_set A \<noteq> {r. 0 < r}"
   667     by (insert preal_not_mem_inverse_set_Ex [OF A], blast)
   668 qed
   669 
   670 text{*Part 3 of Dedekind sections definition*}
   671 lemma inverse_set_lemma3:
   672      "[|A \<in> preal; u \<in> inverse_set A; 0 < z; z < u|] 
   673       ==> z \<in> inverse_set A"
   674 apply (auto simp add: inverse_set_def)
   675 apply (auto intro: order_less_trans)
   676 done
   677 
   678 text{*Part 4 of Dedekind sections definition*}
   679 lemma inverse_set_lemma4:
   680      "[|A \<in> preal; y \<in> inverse_set A|] ==> \<exists>u \<in> inverse_set A. y < u"
   681 apply (auto simp add: inverse_set_def)
   682 apply (drule dense [of y]) 
   683 apply (blast intro: order_less_trans)
   684 done
   685 
   686 
   687 lemma mem_inverse_set:
   688      "A \<in> preal ==> inverse_set A \<in> preal"
   689 apply (simp (no_asm_simp) add: preal_def cut_def)
   690 apply (blast intro!: inverse_set_not_empty inverse_set_not_rat_set
   691                      inverse_set_lemma3 inverse_set_lemma4)
   692 done
   693 
   694 
   695 subsection{*Gleason's Lemma 9-3.4, page 122*}
   696 
   697 lemma Gleason9_34_exists:
   698   assumes A: "A \<in> preal"
   699     and "\<forall>x\<in>A. x + u \<in> A"
   700     and "0 \<le> z"
   701   shows "\<exists>b\<in>A. b + (of_int z) * u \<in> A"
   702 proof (cases z rule: int_cases)
   703   case (nonneg n)
   704   show ?thesis
   705   proof (simp add: prems, induct n)
   706     case 0
   707       from preal_nonempty [OF A]
   708       show ?case  by force 
   709     case (Suc k)
   710       from this obtain b where "b \<in> A" "b + of_nat k * u \<in> A" ..
   711       hence "b + of_int (int k)*u + u \<in> A" by (simp add: prems)
   712       thus ?case by (force simp add: left_distrib add_ac prems) 
   713   qed
   714 next
   715   case (neg n)
   716   with prems show ?thesis by simp
   717 qed
   718 
   719 lemma Gleason9_34_contra:
   720   assumes A: "A \<in> preal"
   721     shows "[|\<forall>x\<in>A. x + u \<in> A; 0 < u; 0 < y; y \<notin> A|] ==> False"
   722 proof (induct u, induct y)
   723   fix a::int and b::int
   724   fix c::int and d::int
   725   assume bpos [simp]: "0 < b"
   726     and dpos [simp]: "0 < d"
   727     and closed: "\<forall>x\<in>A. x + (Fract c d) \<in> A"
   728     and upos: "0 < Fract c d"
   729     and ypos: "0 < Fract a b"
   730     and notin: "Fract a b \<notin> A"
   731   have cpos [simp]: "0 < c" 
   732     by (simp add: zero_less_Fract_iff [OF dpos, symmetric] upos) 
   733   have apos [simp]: "0 < a" 
   734     by (simp add: zero_less_Fract_iff [OF bpos, symmetric] ypos) 
   735   let ?k = "a*d"
   736   have frle: "Fract a b \<le> Fract ?k 1 * (Fract c d)" 
   737   proof -
   738     have "?thesis = ((a * d * b * d) \<le> c * b * (a * d * b * d))"
   739       by (simp add: mult_rat le_rat order_less_imp_not_eq2 mult_ac) 
   740     moreover
   741     have "(1 * (a * d * b * d)) \<le> c * b * (a * d * b * d)"
   742       by (rule mult_mono, 
   743           simp_all add: int_one_le_iff_zero_less zero_less_mult_iff 
   744                         order_less_imp_le)
   745     ultimately
   746     show ?thesis by simp
   747   qed
   748   have k: "0 \<le> ?k" by (simp add: order_less_imp_le zero_less_mult_iff)  
   749   from Gleason9_34_exists [OF A closed k]
   750   obtain z where z: "z \<in> A" 
   751              and mem: "z + of_int ?k * Fract c d \<in> A" ..
   752   have less: "z + of_int ?k * Fract c d < Fract a b"
   753     by (rule not_in_preal_ub [OF A notin mem ypos])
   754   have "0<z" by (rule preal_imp_pos [OF A z])
   755   with frle and less show False by (simp add: Fract_of_int_eq) 
   756 qed
   757 
   758 
   759 lemma Gleason9_34:
   760   assumes A: "A \<in> preal"
   761     and upos: "0 < u"
   762   shows "\<exists>r \<in> A. r + u \<notin> A"
   763 proof (rule ccontr, simp)
   764   assume closed: "\<forall>r\<in>A. r + u \<in> A"
   765   from preal_exists_bound [OF A]
   766   obtain y where y: "y \<notin> A" and ypos: "0 < y" by blast
   767   show False
   768     by (rule Gleason9_34_contra [OF A closed upos ypos y])
   769 qed
   770 
   771 
   772 
   773 subsection{*Gleason's Lemma 9-3.6*}
   774 
   775 lemma lemma_gleason9_36:
   776   assumes A: "A \<in> preal"
   777     and x: "1 < x"
   778   shows "\<exists>r \<in> A. r*x \<notin> A"
   779 proof -
   780   from preal_nonempty [OF A]
   781   obtain y where y: "y \<in> A" and  ypos: "0<y" ..
   782   show ?thesis 
   783   proof (rule classical)
   784     assume "~(\<exists>r\<in>A. r * x \<notin> A)"
   785     with y have ymem: "y * x \<in> A" by blast 
   786     from ypos mult_strict_left_mono [OF x]
   787     have yless: "y < y*x" by simp 
   788     let ?d = "y*x - y"
   789     from yless have dpos: "0 < ?d" and eq: "y + ?d = y*x" by auto
   790     from Gleason9_34 [OF A dpos]
   791     obtain r where r: "r\<in>A" and notin: "r + ?d \<notin> A" ..
   792     have rpos: "0<r" by (rule preal_imp_pos [OF A r])
   793     with dpos have rdpos: "0 < r + ?d" by arith
   794     have "~ (r + ?d \<le> y + ?d)"
   795     proof
   796       assume le: "r + ?d \<le> y + ?d" 
   797       from ymem have yd: "y + ?d \<in> A" by (simp add: eq)
   798       have "r + ?d \<in> A" by (rule preal_downwards_closed' [OF A yd rdpos le])
   799       with notin show False by simp
   800     qed
   801     hence "y < r" by simp
   802     with ypos have  dless: "?d < (r * ?d)/y"
   803       by (simp add: pos_less_divide_eq mult_commute [of ?d]
   804                     mult_strict_right_mono dpos)
   805     have "r + ?d < r*x"
   806     proof -
   807       have "r + ?d < r + (r * ?d)/y" by (simp add: dless)
   808       also with ypos have "... = (r/y) * (y + ?d)"
   809 	by (simp only: right_distrib divide_inverse mult_ac, simp)
   810       also have "... = r*x" using ypos
   811 	by (simp add: times_divide_eq_left) 
   812       finally show "r + ?d < r*x" .
   813     qed
   814     with r notin rdpos
   815     show "\<exists>r\<in>A. r * x \<notin> A" by (blast dest:  preal_downwards_closed [OF A])
   816   qed  
   817 qed
   818 
   819 subsection{*Existence of Inverse: Part 2*}
   820 
   821 lemma mem_Rep_preal_inverse_iff:
   822       "(z \<in> Rep_preal(inverse R)) = 
   823        (0 < z \<and> (\<exists>y. z < y \<and> inverse y \<notin> Rep_preal R))"
   824 apply (simp add: preal_inverse_def mem_inverse_set Rep_preal)
   825 apply (simp add: inverse_set_def) 
   826 done
   827 
   828 lemma Rep_preal_of_rat:
   829      "0 < q ==> Rep_preal (preal_of_rat q) = {x. 0 < x \<and> x < q}"
   830 by (simp add: preal_of_rat_def rat_mem_preal) 
   831 
   832 lemma subset_inverse_mult_lemma:
   833   assumes xpos: "0 < x" and xless: "x < 1"
   834   shows "\<exists>r u y. 0 < r & r < y & inverse y \<notin> Rep_preal R & 
   835     u \<in> Rep_preal R & x = r * u"
   836 proof -
   837   from xpos and xless have "1 < inverse x" by (simp add: one_less_inverse_iff)
   838   from lemma_gleason9_36 [OF Rep_preal this]
   839   obtain r where r: "r \<in> Rep_preal R" 
   840              and notin: "r * (inverse x) \<notin> Rep_preal R" ..
   841   have rpos: "0<r" by (rule preal_imp_pos [OF Rep_preal r])
   842   from preal_exists_greater [OF Rep_preal r]
   843   obtain u where u: "u \<in> Rep_preal R" and rless: "r < u" ..
   844   have upos: "0<u" by (rule preal_imp_pos [OF Rep_preal u])
   845   show ?thesis
   846   proof (intro exI conjI)
   847     show "0 < x/u" using xpos upos
   848       by (simp add: zero_less_divide_iff)  
   849     show "x/u < x/r" using xpos upos rpos
   850       by (simp add: divide_inverse mult_less_cancel_left rless) 
   851     show "inverse (x / r) \<notin> Rep_preal R" using notin
   852       by (simp add: divide_inverse mult_commute) 
   853     show "u \<in> Rep_preal R" by (rule u) 
   854     show "x = x / u * u" using upos 
   855       by (simp add: divide_inverse mult_commute) 
   856   qed
   857 qed
   858 
   859 lemma subset_inverse_mult: 
   860      "Rep_preal(preal_of_rat 1) \<subseteq> Rep_preal(inverse R * R)"
   861 apply (auto simp add: Bex_def Rep_preal_of_rat mem_Rep_preal_inverse_iff 
   862                       mem_Rep_preal_mult_iff)
   863 apply (blast dest: subset_inverse_mult_lemma) 
   864 done
   865 
   866 lemma inverse_mult_subset_lemma:
   867   assumes rpos: "0 < r" 
   868     and rless: "r < y"
   869     and notin: "inverse y \<notin> Rep_preal R"
   870     and q: "q \<in> Rep_preal R"
   871   shows "r*q < 1"
   872 proof -
   873   have "q < inverse y" using rpos rless
   874     by (simp add: not_in_preal_ub [OF Rep_preal notin] q)
   875   hence "r * q < r/y" using rpos
   876     by (simp add: divide_inverse mult_less_cancel_left)
   877   also have "... \<le> 1" using rpos rless
   878     by (simp add: pos_divide_le_eq)
   879   finally show ?thesis .
   880 qed
   881 
   882 lemma inverse_mult_subset:
   883      "Rep_preal(inverse R * R) \<subseteq> Rep_preal(preal_of_rat 1)"
   884 apply (auto simp add: Bex_def Rep_preal_of_rat mem_Rep_preal_inverse_iff 
   885                       mem_Rep_preal_mult_iff)
   886 apply (simp add: zero_less_mult_iff preal_imp_pos [OF Rep_preal]) 
   887 apply (blast intro: inverse_mult_subset_lemma) 
   888 done
   889 
   890 lemma preal_mult_inverse: "inverse R * R = (1::preal)"
   891 unfolding preal_one_def
   892 apply (rule Rep_preal_inject [THEN iffD1])
   893 apply (rule equalityI [OF inverse_mult_subset subset_inverse_mult]) 
   894 done
   895 
   896 lemma preal_mult_inverse_right: "R * inverse R = (1::preal)"
   897 apply (rule preal_mult_commute [THEN subst])
   898 apply (rule preal_mult_inverse)
   899 done
   900 
   901 
   902 text{*Theorems needing @{text Gleason9_34}*}
   903 
   904 lemma Rep_preal_self_subset: "Rep_preal (R) \<subseteq> Rep_preal(R + S)"
   905 proof 
   906   fix r
   907   assume r: "r \<in> Rep_preal R"
   908   have rpos: "0<r" by (rule preal_imp_pos [OF Rep_preal r])
   909   from mem_Rep_preal_Ex 
   910   obtain y where y: "y \<in> Rep_preal S" ..
   911   have ypos: "0<y" by (rule preal_imp_pos [OF Rep_preal y])
   912   have ry: "r+y \<in> Rep_preal(R + S)" using r y
   913     by (auto simp add: mem_Rep_preal_add_iff)
   914   show "r \<in> Rep_preal(R + S)" using r ypos rpos 
   915     by (simp add:  preal_downwards_closed [OF Rep_preal ry]) 
   916 qed
   917 
   918 lemma Rep_preal_sum_not_subset: "~ Rep_preal (R + S) \<subseteq> Rep_preal(R)"
   919 proof -
   920   from mem_Rep_preal_Ex 
   921   obtain y where y: "y \<in> Rep_preal S" ..
   922   have ypos: "0<y" by (rule preal_imp_pos [OF Rep_preal y])
   923   from  Gleason9_34 [OF Rep_preal ypos]
   924   obtain r where r: "r \<in> Rep_preal R" and notin: "r + y \<notin> Rep_preal R" ..
   925   have "r + y \<in> Rep_preal (R + S)" using r y
   926     by (auto simp add: mem_Rep_preal_add_iff)
   927   thus ?thesis using notin by blast
   928 qed
   929 
   930 lemma Rep_preal_sum_not_eq: "Rep_preal (R + S) \<noteq> Rep_preal(R)"
   931 by (insert Rep_preal_sum_not_subset, blast)
   932 
   933 text{*at last, Gleason prop. 9-3.5(iii) page 123*}
   934 lemma preal_self_less_add_left: "(R::preal) < R + S"
   935 apply (unfold preal_less_def psubset_def)
   936 apply (simp add: Rep_preal_self_subset Rep_preal_sum_not_eq [THEN not_sym])
   937 done
   938 
   939 lemma preal_self_less_add_right: "(R::preal) < S + R"
   940 by (simp add: preal_add_commute preal_self_less_add_left)
   941 
   942 lemma preal_not_eq_self: "x \<noteq> x + (y::preal)"
   943 by (insert preal_self_less_add_left [of x y], auto)
   944 
   945 
   946 subsection{*Subtraction for Positive Reals*}
   947 
   948 text{*Gleason prop. 9-3.5(iv), page 123: proving @{prop "A < B ==> \<exists>D. A + D =
   949 B"}. We define the claimed @{term D} and show that it is a positive real*}
   950 
   951 text{*Part 1 of Dedekind sections definition*}
   952 lemma diff_set_not_empty:
   953      "R < S ==> {} \<subset> diff_set (Rep_preal S) (Rep_preal R)"
   954 apply (auto simp add: preal_less_def diff_set_def elim!: equalityE) 
   955 apply (frule_tac x1 = S in Rep_preal [THEN preal_exists_greater])
   956 apply (drule preal_imp_pos [OF Rep_preal], clarify)
   957 apply (cut_tac a=x and b=u in add_eq_exists, force) 
   958 done
   959 
   960 text{*Part 2 of Dedekind sections definition*}
   961 lemma diff_set_nonempty:
   962      "\<exists>q. 0 < q & q \<notin> diff_set (Rep_preal S) (Rep_preal R)"
   963 apply (cut_tac X = S in Rep_preal_exists_bound)
   964 apply (erule exE)
   965 apply (rule_tac x = x in exI, auto)
   966 apply (simp add: diff_set_def) 
   967 apply (auto dest: Rep_preal [THEN preal_downwards_closed])
   968 done
   969 
   970 lemma diff_set_not_rat_set:
   971   "diff_set (Rep_preal S) (Rep_preal R) < {r. 0 < r}" (is "?lhs < ?rhs")
   972 proof
   973   show "?lhs \<subseteq> ?rhs" by (auto simp add: diff_set_def) 
   974   show "?lhs \<noteq> ?rhs" using diff_set_nonempty by blast
   975 qed
   976 
   977 text{*Part 3 of Dedekind sections definition*}
   978 lemma diff_set_lemma3:
   979      "[|R < S; u \<in> diff_set (Rep_preal S) (Rep_preal R); 0 < z; z < u|] 
   980       ==> z \<in> diff_set (Rep_preal S) (Rep_preal R)"
   981 apply (auto simp add: diff_set_def) 
   982 apply (rule_tac x=x in exI) 
   983 apply (drule Rep_preal [THEN preal_downwards_closed], auto)
   984 done
   985 
   986 text{*Part 4 of Dedekind sections definition*}
   987 lemma diff_set_lemma4:
   988      "[|R < S; y \<in> diff_set (Rep_preal S) (Rep_preal R)|] 
   989       ==> \<exists>u \<in> diff_set (Rep_preal S) (Rep_preal R). y < u"
   990 apply (auto simp add: diff_set_def) 
   991 apply (drule Rep_preal [THEN preal_exists_greater], clarify) 
   992 apply (cut_tac a="x+y" and b=u in add_eq_exists, clarify)  
   993 apply (rule_tac x="y+xa" in exI) 
   994 apply (auto simp add: add_ac)
   995 done
   996 
   997 lemma mem_diff_set:
   998      "R < S ==> diff_set (Rep_preal S) (Rep_preal R) \<in> preal"
   999 apply (unfold preal_def cut_def)
  1000 apply (blast intro!: diff_set_not_empty diff_set_not_rat_set
  1001                      diff_set_lemma3 diff_set_lemma4)
  1002 done
  1003 
  1004 lemma mem_Rep_preal_diff_iff:
  1005       "R < S ==>
  1006        (z \<in> Rep_preal(S-R)) = 
  1007        (\<exists>x. 0 < x & 0 < z & x \<notin> Rep_preal R & x + z \<in> Rep_preal S)"
  1008 apply (simp add: preal_diff_def mem_diff_set Rep_preal)
  1009 apply (force simp add: diff_set_def) 
  1010 done
  1011 
  1012 
  1013 text{*proving that @{term "R + D \<le> S"}*}
  1014 
  1015 lemma less_add_left_lemma:
  1016   assumes Rless: "R < S"
  1017     and a: "a \<in> Rep_preal R"
  1018     and cb: "c + b \<in> Rep_preal S"
  1019     and "c \<notin> Rep_preal R"
  1020     and "0 < b"
  1021     and "0 < c"
  1022   shows "a + b \<in> Rep_preal S"
  1023 proof -
  1024   have "0<a" by (rule preal_imp_pos [OF Rep_preal a])
  1025   moreover
  1026   have "a < c" using prems
  1027     by (blast intro: not_in_Rep_preal_ub ) 
  1028   ultimately show ?thesis using prems
  1029     by (simp add: preal_downwards_closed [OF Rep_preal cb]) 
  1030 qed
  1031 
  1032 lemma less_add_left_le1:
  1033        "R < (S::preal) ==> R + (S-R) \<le> S"
  1034 apply (auto simp add: Bex_def preal_le_def mem_Rep_preal_add_iff 
  1035                       mem_Rep_preal_diff_iff)
  1036 apply (blast intro: less_add_left_lemma) 
  1037 done
  1038 
  1039 subsection{*proving that @{term "S \<le> R + D"} --- trickier*}
  1040 
  1041 lemma lemma_sum_mem_Rep_preal_ex:
  1042      "x \<in> Rep_preal S ==> \<exists>e. 0 < e & x + e \<in> Rep_preal S"
  1043 apply (drule Rep_preal [THEN preal_exists_greater], clarify) 
  1044 apply (cut_tac a=x and b=u in add_eq_exists, auto) 
  1045 done
  1046 
  1047 lemma less_add_left_lemma2:
  1048   assumes Rless: "R < S"
  1049     and x:     "x \<in> Rep_preal S"
  1050     and xnot: "x \<notin>  Rep_preal R"
  1051   shows "\<exists>u v z. 0 < v & 0 < z & u \<in> Rep_preal R & z \<notin> Rep_preal R & 
  1052                      z + v \<in> Rep_preal S & x = u + v"
  1053 proof -
  1054   have xpos: "0<x" by (rule preal_imp_pos [OF Rep_preal x])
  1055   from lemma_sum_mem_Rep_preal_ex [OF x]
  1056   obtain e where epos: "0 < e" and xe: "x + e \<in> Rep_preal S" by blast
  1057   from  Gleason9_34 [OF Rep_preal epos]
  1058   obtain r where r: "r \<in> Rep_preal R" and notin: "r + e \<notin> Rep_preal R" ..
  1059   with x xnot xpos have rless: "r < x" by (blast intro: not_in_Rep_preal_ub)
  1060   from add_eq_exists [of r x]
  1061   obtain y where eq: "x = r+y" by auto
  1062   show ?thesis 
  1063   proof (intro exI conjI)
  1064     show "r \<in> Rep_preal R" by (rule r)
  1065     show "r + e \<notin> Rep_preal R" by (rule notin)
  1066     show "r + e + y \<in> Rep_preal S" using xe eq by (simp add: add_ac)
  1067     show "x = r + y" by (simp add: eq)
  1068     show "0 < r + e" using epos preal_imp_pos [OF Rep_preal r]
  1069       by simp
  1070     show "0 < y" using rless eq by arith
  1071   qed
  1072 qed
  1073 
  1074 lemma less_add_left_le2: "R < (S::preal) ==> S \<le> R + (S-R)"
  1075 apply (auto simp add: preal_le_def)
  1076 apply (case_tac "x \<in> Rep_preal R")
  1077 apply (cut_tac Rep_preal_self_subset [of R], force)
  1078 apply (auto simp add: Bex_def mem_Rep_preal_add_iff mem_Rep_preal_diff_iff)
  1079 apply (blast dest: less_add_left_lemma2)
  1080 done
  1081 
  1082 lemma less_add_left: "R < (S::preal) ==> R + (S-R) = S"
  1083 by (blast intro: preal_le_anti_sym [OF less_add_left_le1 less_add_left_le2])
  1084 
  1085 lemma less_add_left_Ex: "R < (S::preal) ==> \<exists>D. R + D = S"
  1086 by (fast dest: less_add_left)
  1087 
  1088 lemma preal_add_less2_mono1: "R < (S::preal) ==> R + T < S + T"
  1089 apply (auto dest!: less_add_left_Ex simp add: preal_add_assoc)
  1090 apply (rule_tac y1 = D in preal_add_commute [THEN subst])
  1091 apply (auto intro: preal_self_less_add_left simp add: preal_add_assoc [symmetric])
  1092 done
  1093 
  1094 lemma preal_add_less2_mono2: "R < (S::preal) ==> T + R < T + S"
  1095 by (auto intro: preal_add_less2_mono1 simp add: preal_add_commute [of T])
  1096 
  1097 lemma preal_add_right_less_cancel: "R + T < S + T ==> R < (S::preal)"
  1098 apply (insert linorder_less_linear [of R S], auto)
  1099 apply (drule_tac R = S and T = T in preal_add_less2_mono1)
  1100 apply (blast dest: order_less_trans) 
  1101 done
  1102 
  1103 lemma preal_add_left_less_cancel: "T + R < T + S ==> R <  (S::preal)"
  1104 by (auto elim: preal_add_right_less_cancel simp add: preal_add_commute [of T])
  1105 
  1106 lemma preal_add_less_cancel_right: "((R::preal) + T < S + T) = (R < S)"
  1107 by (blast intro: preal_add_less2_mono1 preal_add_right_less_cancel)
  1108 
  1109 lemma preal_add_less_cancel_left: "(T + (R::preal) < T + S) = (R < S)"
  1110 by (blast intro: preal_add_less2_mono2 preal_add_left_less_cancel)
  1111 
  1112 lemma preal_add_le_cancel_right: "((R::preal) + T \<le> S + T) = (R \<le> S)"
  1113 by (simp add: linorder_not_less [symmetric] preal_add_less_cancel_right) 
  1114 
  1115 lemma preal_add_le_cancel_left: "(T + (R::preal) \<le> T + S) = (R \<le> S)"
  1116 by (simp add: linorder_not_less [symmetric] preal_add_less_cancel_left) 
  1117 
  1118 lemma preal_add_less_mono:
  1119      "[| x1 < y1; x2 < y2 |] ==> x1 + x2 < y1 + (y2::preal)"
  1120 apply (auto dest!: less_add_left_Ex simp add: preal_add_ac)
  1121 apply (rule preal_add_assoc [THEN subst])
  1122 apply (rule preal_self_less_add_right)
  1123 done
  1124 
  1125 lemma preal_add_right_cancel: "(R::preal) + T = S + T ==> R = S"
  1126 apply (insert linorder_less_linear [of R S], safe)
  1127 apply (drule_tac [!] T = T in preal_add_less2_mono1, auto)
  1128 done
  1129 
  1130 lemma preal_add_left_cancel: "C + A = C + B ==> A = (B::preal)"
  1131 by (auto intro: preal_add_right_cancel simp add: preal_add_commute)
  1132 
  1133 lemma preal_add_left_cancel_iff: "(C + A = C + B) = ((A::preal) = B)"
  1134 by (fast intro: preal_add_left_cancel)
  1135 
  1136 lemma preal_add_right_cancel_iff: "(A + C = B + C) = ((A::preal) = B)"
  1137 by (fast intro: preal_add_right_cancel)
  1138 
  1139 lemmas preal_cancels =
  1140     preal_add_less_cancel_right preal_add_less_cancel_left
  1141     preal_add_le_cancel_right preal_add_le_cancel_left
  1142     preal_add_left_cancel_iff preal_add_right_cancel_iff
  1143 
  1144 instance preal :: ordered_cancel_ab_semigroup_add
  1145 proof
  1146   fix a b c :: preal
  1147   show "a + b = a + c \<Longrightarrow> b = c" by (rule preal_add_left_cancel)
  1148   show "a \<le> b \<Longrightarrow> c + a \<le> c + b" by (simp only: preal_add_le_cancel_left)
  1149 qed
  1150 
  1151 
  1152 subsection{*Completeness of type @{typ preal}*}
  1153 
  1154 text{*Prove that supremum is a cut*}
  1155 
  1156 text{*Part 1 of Dedekind sections definition*}
  1157 
  1158 lemma preal_sup_set_not_empty:
  1159      "P \<noteq> {} ==> {} \<subset> (\<Union>X \<in> P. Rep_preal(X))"
  1160 apply auto
  1161 apply (cut_tac X = x in mem_Rep_preal_Ex, auto)
  1162 done
  1163 
  1164 
  1165 text{*Part 2 of Dedekind sections definition*}
  1166 
  1167 lemma preal_sup_not_exists:
  1168      "\<forall>X \<in> P. X \<le> Y ==> \<exists>q. 0 < q & q \<notin> (\<Union>X \<in> P. Rep_preal(X))"
  1169 apply (cut_tac X = Y in Rep_preal_exists_bound)
  1170 apply (auto simp add: preal_le_def)
  1171 done
  1172 
  1173 lemma preal_sup_set_not_rat_set:
  1174      "\<forall>X \<in> P. X \<le> Y ==> (\<Union>X \<in> P. Rep_preal(X)) < {r. 0 < r}"
  1175 apply (drule preal_sup_not_exists)
  1176 apply (blast intro: preal_imp_pos [OF Rep_preal])  
  1177 done
  1178 
  1179 text{*Part 3 of Dedekind sections definition*}
  1180 lemma preal_sup_set_lemma3:
  1181      "[|P \<noteq> {}; \<forall>X \<in> P. X \<le> Y; u \<in> (\<Union>X \<in> P. Rep_preal(X)); 0 < z; z < u|]
  1182       ==> z \<in> (\<Union>X \<in> P. Rep_preal(X))"
  1183 by (auto elim: Rep_preal [THEN preal_downwards_closed])
  1184 
  1185 text{*Part 4 of Dedekind sections definition*}
  1186 lemma preal_sup_set_lemma4:
  1187      "[|P \<noteq> {}; \<forall>X \<in> P. X \<le> Y; y \<in> (\<Union>X \<in> P. Rep_preal(X)) |]
  1188           ==> \<exists>u \<in> (\<Union>X \<in> P. Rep_preal(X)). y < u"
  1189 by (blast dest: Rep_preal [THEN preal_exists_greater])
  1190 
  1191 lemma preal_sup:
  1192      "[|P \<noteq> {}; \<forall>X \<in> P. X \<le> Y|] ==> (\<Union>X \<in> P. Rep_preal(X)) \<in> preal"
  1193 apply (unfold preal_def cut_def)
  1194 apply (blast intro!: preal_sup_set_not_empty preal_sup_set_not_rat_set
  1195                      preal_sup_set_lemma3 preal_sup_set_lemma4)
  1196 done
  1197 
  1198 lemma preal_psup_le:
  1199      "[| \<forall>X \<in> P. X \<le> Y;  x \<in> P |] ==> x \<le> psup P"
  1200 apply (simp (no_asm_simp) add: preal_le_def) 
  1201 apply (subgoal_tac "P \<noteq> {}") 
  1202 apply (auto simp add: psup_def preal_sup) 
  1203 done
  1204 
  1205 lemma psup_le_ub: "[| P \<noteq> {}; \<forall>X \<in> P. X \<le> Y |] ==> psup P \<le> Y"
  1206 apply (simp (no_asm_simp) add: preal_le_def)
  1207 apply (simp add: psup_def preal_sup) 
  1208 apply (auto simp add: preal_le_def)
  1209 done
  1210 
  1211 text{*Supremum property*}
  1212 lemma preal_complete:
  1213      "[| P \<noteq> {}; \<forall>X \<in> P. X \<le> Y |] ==> (\<exists>X \<in> P. Z < X) = (Z < psup P)"
  1214 apply (simp add: preal_less_def psup_def preal_sup)
  1215 apply (auto simp add: preal_le_def)
  1216 apply (rename_tac U) 
  1217 apply (cut_tac x = U and y = Z in linorder_less_linear)
  1218 apply (auto simp add: preal_less_def)
  1219 done
  1220 
  1221 
  1222 subsection{*The Embedding from @{typ rat} into @{typ preal}*}
  1223 
  1224 lemma preal_of_rat_add_lemma1:
  1225      "[|x < y + z; 0 < x; 0 < y|] ==> x * y * inverse (y + z) < (y::rat)"
  1226 apply (frule_tac c = "y * inverse (y + z) " in mult_strict_right_mono)
  1227 apply (simp add: zero_less_mult_iff) 
  1228 apply (simp add: mult_ac)
  1229 done
  1230 
  1231 lemma preal_of_rat_add_lemma2:
  1232   assumes "u < x + y"
  1233     and "0 < x"
  1234     and "0 < y"
  1235     and "0 < u"
  1236   shows "\<exists>v w::rat. w < y & 0 < v & v < x & 0 < w & u = v + w"
  1237 proof (intro exI conjI)
  1238   show "u * x * inverse(x+y) < x" using prems 
  1239     by (simp add: preal_of_rat_add_lemma1) 
  1240   show "u * y * inverse(x+y) < y" using prems 
  1241     by (simp add: preal_of_rat_add_lemma1 add_commute [of x]) 
  1242   show "0 < u * x * inverse (x + y)" using prems
  1243     by (simp add: zero_less_mult_iff) 
  1244   show "0 < u * y * inverse (x + y)" using prems
  1245     by (simp add: zero_less_mult_iff) 
  1246   show "u = u * x * inverse (x + y) + u * y * inverse (x + y)" using prems
  1247     by (simp add: left_distrib [symmetric] right_distrib [symmetric] mult_ac)
  1248 qed
  1249 
  1250 lemma preal_of_rat_add:
  1251      "[| 0 < x; 0 < y|] 
  1252       ==> preal_of_rat ((x::rat) + y) = preal_of_rat x + preal_of_rat y"
  1253 apply (unfold preal_of_rat_def preal_add_def)
  1254 apply (simp add: rat_mem_preal) 
  1255 apply (rule_tac f = Abs_preal in arg_cong)
  1256 apply (auto simp add: add_set_def) 
  1257 apply (blast dest: preal_of_rat_add_lemma2) 
  1258 done
  1259 
  1260 lemma preal_of_rat_mult_lemma1:
  1261      "[|x < y; 0 < x; 0 < z|] ==> x * z * inverse y < (z::rat)"
  1262 apply (frule_tac c = "z * inverse y" in mult_strict_right_mono)
  1263 apply (simp add: zero_less_mult_iff)
  1264 apply (subgoal_tac "y * (z * inverse y) = z * (y * inverse y)")
  1265 apply (simp_all add: mult_ac)
  1266 done
  1267 
  1268 lemma preal_of_rat_mult_lemma2: 
  1269   assumes xless: "x < y * z"
  1270     and xpos: "0 < x"
  1271     and ypos: "0 < y"
  1272   shows "x * z * inverse y * inverse z < (z::rat)"
  1273 proof -
  1274   have "0 < y * z" using prems by simp
  1275   hence zpos:  "0 < z" using prems by (simp add: zero_less_mult_iff)
  1276   have "x * z * inverse y * inverse z = x * inverse y * (z * inverse z)"
  1277     by (simp add: mult_ac)
  1278   also have "... = x/y" using zpos
  1279     by (simp add: divide_inverse)
  1280   also from xless have "... < z"
  1281     by (simp add: pos_divide_less_eq [OF ypos] mult_commute)
  1282   finally show ?thesis .
  1283 qed
  1284 
  1285 lemma preal_of_rat_mult_lemma3:
  1286   assumes uless: "u < x * y"
  1287     and "0 < x"
  1288     and "0 < y"
  1289     and "0 < u"
  1290   shows "\<exists>v w::rat. v < x & w < y & 0 < v & 0 < w & u = v * w"
  1291 proof -
  1292   from dense [OF uless] 
  1293   obtain r where "u < r" "r < x * y" by blast
  1294   thus ?thesis
  1295   proof (intro exI conjI)
  1296   show "u * x * inverse r < x" using prems 
  1297     by (simp add: preal_of_rat_mult_lemma1) 
  1298   show "r * y * inverse x * inverse y < y" using prems
  1299     by (simp add: preal_of_rat_mult_lemma2)
  1300   show "0 < u * x * inverse r" using prems
  1301     by (simp add: zero_less_mult_iff) 
  1302   show "0 < r * y * inverse x * inverse y" using prems
  1303     by (simp add: zero_less_mult_iff) 
  1304   have "u * x * inverse r * (r * y * inverse x * inverse y) =
  1305         u * (r * inverse r) * (x * inverse x) * (y * inverse y)"
  1306     by (simp only: mult_ac)
  1307   thus "u = u * x * inverse r * (r * y * inverse x * inverse y)" using prems
  1308     by simp
  1309   qed
  1310 qed
  1311 
  1312 lemma preal_of_rat_mult:
  1313      "[| 0 < x; 0 < y|] 
  1314       ==> preal_of_rat ((x::rat) * y) = preal_of_rat x * preal_of_rat y"
  1315 apply (unfold preal_of_rat_def preal_mult_def)
  1316 apply (simp add: rat_mem_preal) 
  1317 apply (rule_tac f = Abs_preal in arg_cong)
  1318 apply (auto simp add: zero_less_mult_iff mult_strict_mono mult_set_def) 
  1319 apply (blast dest: preal_of_rat_mult_lemma3) 
  1320 done
  1321 
  1322 lemma preal_of_rat_less_iff:
  1323       "[| 0 < x; 0 < y|] ==> (preal_of_rat x < preal_of_rat y) = (x < y)"
  1324 by (force simp add: preal_of_rat_def preal_less_def rat_mem_preal) 
  1325 
  1326 lemma preal_of_rat_le_iff:
  1327       "[| 0 < x; 0 < y|] ==> (preal_of_rat x \<le> preal_of_rat y) = (x \<le> y)"
  1328 by (simp add: preal_of_rat_less_iff linorder_not_less [symmetric]) 
  1329 
  1330 lemma preal_of_rat_eq_iff:
  1331       "[| 0 < x; 0 < y|] ==> (preal_of_rat x = preal_of_rat y) = (x = y)"
  1332 by (simp add: preal_of_rat_le_iff order_eq_iff) 
  1333 
  1334 end