src/Pure/Isar/theory_target.ML
author haftmann
Fri Nov 23 21:09:35 2007 +0100 (2007-11-23)
changeset 25462 dad0291cb76a
parent 25395 e83bef45e6a7
child 25485 33840a854e63
permissions -rw-r--r--
rudimentary instantiation target
     1 (*  Title:      Pure/Isar/theory_target.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Common theory/locale/class/instantiation targets.
     6 *)
     7 
     8 signature THEORY_TARGET =
     9 sig
    10   val peek: local_theory -> {target: string, is_locale: bool,
    11     is_class: bool, instantiation: arity list}
    12   val init: string option -> theory -> local_theory
    13   val begin: string -> Proof.context -> local_theory
    14   val context: xstring -> theory -> local_theory
    15   val instantiation: arity list -> theory -> local_theory
    16 end;
    17 
    18 structure TheoryTarget: THEORY_TARGET =
    19 struct
    20 
    21 (* context data *)
    22 
    23 datatype target = Target of {target: string, is_locale: bool,
    24   is_class: bool, instantiation: arity list};
    25 
    26 fun make_target target is_locale is_class instantiation =
    27   Target {target = target, is_locale = is_locale,
    28     is_class = is_class, instantiation = instantiation};
    29 
    30 val global_target = make_target "" false false [];
    31 
    32 structure Data = ProofDataFun
    33 (
    34   type T = target;
    35   fun init _ = global_target;
    36 );
    37 
    38 val peek = (fn Target args => args) o Data.get;
    39 
    40 
    41 (* pretty *)
    42 
    43 fun pretty (Target {target, is_locale, is_class, instantiation}) ctxt =
    44   let
    45     val thy = ProofContext.theory_of ctxt;
    46     val target_name = (if is_class then "class " else "locale ") ^ Locale.extern thy target;
    47     val fixes = map (fn (x, T) => (x, SOME T, NoSyn)) (#1 (ProofContext.inferred_fixes ctxt));
    48     val assumes = map (fn A => (("", []), [(A, [])])) (map Thm.term_of (Assumption.assms_of ctxt));
    49     val elems =
    50       (if null fixes then [] else [Element.Fixes fixes]) @
    51       (if null assumes then [] else [Element.Assumes assumes]);
    52   in
    53     Pretty.block [Pretty.str "theory", Pretty.brk 1, Pretty.str (Context.theory_name thy)] ::
    54      (if target = "" then []
    55       else if null elems then [Pretty.str target_name]
    56       else [Pretty.big_list (target_name ^ " =")
    57         (map (Pretty.chunks o Element.pretty_ctxt ctxt) elems)])
    58   end;
    59 
    60 
    61 (* target declarations *)
    62 
    63 fun target_decl add (Target {target, ...}) d lthy =
    64   let
    65     val d' = Morphism.transform (LocalTheory.target_morphism lthy) d;
    66     val d0 = Morphism.form d';
    67   in
    68     if target = "" then
    69       lthy
    70       |> LocalTheory.theory (Context.theory_map d0)
    71       |> LocalTheory.target (Context.proof_map d0)
    72     else
    73       lthy
    74       |> LocalTheory.target (add target d')
    75   end;
    76 
    77 val type_syntax = target_decl Locale.add_type_syntax;
    78 val term_syntax = target_decl Locale.add_term_syntax;
    79 val declaration = target_decl Locale.add_declaration;
    80 
    81 fun class_target (Target {target, ...}) f =
    82   LocalTheory.raw_theory f #>
    83   LocalTheory.target (Class.refresh_syntax target);
    84 
    85 
    86 (* notes *)
    87 
    88 fun import_export_proof ctxt (name, raw_th) =
    89   let
    90     val thy = ProofContext.theory_of ctxt;
    91     val thy_ctxt = ProofContext.init thy;
    92     val certT = Thm.ctyp_of thy;
    93     val cert = Thm.cterm_of thy;
    94 
    95     (*export assumes/defines*)
    96     val th = Goal.norm_result raw_th;
    97     val (defs, th') = LocalDefs.export ctxt thy_ctxt th;
    98     val concl_conv = MetaSimplifier.rewrite true defs (Thm.cprop_of th);
    99     val assms = map (MetaSimplifier.rewrite_rule defs o Thm.assume) (Assumption.assms_of ctxt);
   100     val nprems = Thm.nprems_of th' - Thm.nprems_of th;
   101 
   102     (*export fixes*)
   103     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   104     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   105     val (th'' :: vs) = (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   106       |> Variable.export ctxt thy_ctxt
   107       |> Drule.zero_var_indexes_list;
   108 
   109     (*thm definition*)
   110     val result = th''
   111       |> PureThy.name_thm true true ""
   112       |> Goal.close_result
   113       |> fold PureThy.tag_rule (ContextPosition.properties_of ctxt)
   114       |> PureThy.name_thm true true name;
   115 
   116     (*import fixes*)
   117     val (tvars, vars) =
   118       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   119       |>> map Logic.dest_type;
   120 
   121     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   122     val inst = filter (is_Var o fst) (vars ~~ frees);
   123     val cinstT = map (pairself certT o apfst TVar) instT;
   124     val cinst = map (pairself (cert o Term.map_types (TermSubst.instantiateT instT))) inst;
   125     val result' = Thm.instantiate (cinstT, cinst) result;
   126 
   127     (*import assumes/defines*)
   128     val assm_tac = FIRST' (map (fn assm => Tactic.compose_tac (false, assm, 0)) assms);
   129     val result'' =
   130       (case SINGLE (Seq.INTERVAL assm_tac 1 nprems) result' of
   131         NONE => raise THM ("Failed to re-import result", 0, [result'])
   132       | SOME res => LocalDefs.trans_props ctxt [res, Thm.symmetric concl_conv])
   133       |> Goal.norm_result
   134       |> PureThy.name_thm false false name;
   135 
   136   in (result'', result) end;
   137 
   138 fun notes (Target {target, is_locale, ...}) kind facts lthy =
   139   let
   140     val thy = ProofContext.theory_of lthy;
   141     val full = LocalTheory.full_name lthy;
   142 
   143     val facts' = facts
   144       |> map (fn (a, bs) => (a, PureThy.burrow_fact (PureThy.name_multi (full (fst a))) bs))
   145       |> PureThy.map_facts (import_export_proof lthy);
   146     val local_facts = PureThy.map_facts #1 facts'
   147       |> Attrib.map_facts (Attrib.attribute_i thy);
   148     val target_facts = PureThy.map_facts #1 facts'
   149       |> is_locale ? Element.facts_map (Element.morph_ctxt (LocalTheory.target_morphism lthy));
   150     val global_facts = PureThy.map_facts #2 facts'
   151       |> Attrib.map_facts (if is_locale then K I else Attrib.attribute_i thy);
   152   in
   153     lthy |> LocalTheory.theory
   154       (Sign.qualified_names
   155         #> PureThy.note_thmss_i kind global_facts #> snd
   156         #> Sign.restore_naming thy)
   157 
   158     |> is_locale ? LocalTheory.target (Locale.add_thmss target kind target_facts)
   159 
   160     |> ProofContext.qualified_names
   161     |> ProofContext.note_thmss_i kind local_facts
   162     ||> ProofContext.restore_naming lthy
   163   end;
   164 
   165 
   166 (* declare_const *)
   167 
   168 fun fork_mixfix (Target {is_locale, is_class, ...}) mx =
   169   if not is_locale then (NoSyn, NoSyn, mx)
   170   else if not is_class then (NoSyn, mx, NoSyn)
   171   else (mx, NoSyn, NoSyn);
   172 
   173 fun locale_const (Target {target, is_class, ...}) (prmode as (mode, _)) pos ((c, mx), rhs) phi =
   174   let
   175     val c' = Morphism.name phi c;
   176     val rhs' = Morphism.term phi rhs;
   177     val legacy_arg = (c', Term.close_schematic_term (Logic.legacy_varify rhs'));
   178     val arg = (c', Term.close_schematic_term rhs');
   179     val similar_body = Type.similar_types (rhs, rhs');
   180     (* FIXME workaround based on educated guess *)
   181     val class_global = c' = NameSpace.qualified (Class.class_prefix target) c;
   182   in
   183     not (is_class andalso (similar_body orelse class_global)) ?
   184       (Context.mapping_result
   185         (Sign.add_abbrev PrintMode.internal pos legacy_arg)
   186         (ProofContext.add_abbrev PrintMode.internal pos arg)
   187       #-> (fn (lhs' as Const (d, _), _) =>
   188           similar_body ?
   189             (Context.mapping (Sign.revert_abbrev mode d) (ProofContext.revert_abbrev mode d) #>
   190              Morphism.form (ProofContext.target_notation true prmode [(lhs', mx)]))))
   191   end;
   192 
   193 fun declare_const (ta as Target {target, is_locale, is_class, instantiation}) depends ((c, T), mx) lthy =
   194   let
   195     val pos = ContextPosition.properties_of lthy;
   196     val xs = filter depends (#1 (ProofContext.inferred_fixes (LocalTheory.target_of lthy)));
   197     val U = map #2 xs ---> T;
   198     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   199     val declare_const = if null instantiation
   200       then Sign.declare_const pos (c, U, mx3)
   201       else case Class.instantiation_const lthy c
   202        of SOME c' => Class.declare_overloaded (c', U, mx3)
   203         | NONE => Sign.declare_const pos (c, U, mx3);
   204     val (const, lthy') = lthy |> LocalTheory.theory_result declare_const;
   205     val t = Term.list_comb (const, map Free xs);
   206   in
   207     lthy'
   208     |> is_locale ? term_syntax ta (locale_const ta Syntax.mode_default pos ((c, mx2), t))
   209     |> is_class ? class_target ta (Class.add_logical_const target pos ((c, mx1), t))
   210     |> LocalDefs.add_def ((c, NoSyn), t)
   211   end;
   212 
   213 
   214 (* abbrev *)
   215 
   216 fun abbrev (ta as Target {target, is_locale, is_class, instantiation}) prmode ((c, mx), t) lthy =
   217   let
   218     val pos = ContextPosition.properties_of lthy;
   219     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   220     val target_ctxt = LocalTheory.target_of lthy;
   221 
   222     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   223     val t' = Assumption.export_term lthy target_ctxt t;
   224     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   225     val u = fold_rev lambda xs t';
   226     val global_rhs =
   227       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   228   in
   229     lthy |>
   230      (if is_locale then
   231         LocalTheory.theory_result (Sign.add_abbrev PrintMode.internal pos (c, global_rhs))
   232         #-> (fn (lhs, _) =>
   233           let val lhs' = Term.list_comb (Logic.unvarify lhs, xs) in
   234             term_syntax ta (locale_const ta prmode pos ((c, mx2), lhs')) #>
   235             is_class ? class_target ta (Class.add_syntactic_const target prmode pos ((c, mx1), t'))
   236           end)
   237       else
   238         LocalTheory.theory
   239           (Sign.add_abbrev (#1 prmode) pos (c, global_rhs) #-> (fn (lhs, _) =>
   240            Sign.notation true prmode [(lhs, mx3)])))
   241     |> ProofContext.add_abbrev PrintMode.internal pos (c, t) |> snd
   242     |> LocalDefs.fixed_abbrev ((c, NoSyn), t)
   243   end;
   244 
   245 
   246 (* define *)
   247 
   248 fun define (ta as Target {target, is_locale, is_class, instantiation})
   249     kind ((c, mx), ((name, atts), rhs)) lthy =
   250   let
   251     val thy = ProofContext.theory_of lthy;
   252     val thy_ctxt = ProofContext.init thy;
   253 
   254     val name' = Thm.def_name_optional c name;
   255     val (rhs', rhs_conv) =
   256       LocalDefs.export_cterm lthy thy_ctxt (Thm.cterm_of thy rhs) |>> Thm.term_of;
   257     val xs = Variable.add_fixed (LocalTheory.target_of lthy) rhs' [];
   258     val T = Term.fastype_of rhs;
   259 
   260     (*const*)
   261     val ((lhs, local_def), lthy2) = lthy |> declare_const ta (member (op =) xs) ((c, T), mx);
   262     val (_, lhs') = Logic.dest_equals (Thm.prop_of local_def);
   263 
   264     (*def*)
   265     val is_instantiation = not (null instantiation)
   266       andalso is_some (Class.instantiation_const lthy c);
   267     val define_const = if not is_instantiation
   268       then (fn name => fn eq => Thm.add_def false (name, Logic.mk_equals eq))
   269       else (fn name => fn (Const (c, _), rhs) => Class.define_overloaded name (c, rhs));
   270     val (global_def, lthy3) = lthy2
   271       |> LocalTheory.theory_result (define_const name' (lhs', rhs'));
   272     val def = if not is_instantiation then LocalDefs.trans_terms lthy3
   273       [(*c == global.c xs*)     local_def,
   274        (*global.c xs == rhs'*)  global_def,
   275        (*rhs' == rhs*)          Thm.symmetric rhs_conv]
   276       else Thm.transitive local_def global_def;
   277 
   278     (*note*)
   279     val ([(res_name, [res])], lthy4) = lthy3
   280       |> notes ta kind [((name', atts), [([def], [])])];
   281   in ((lhs, (res_name, res)), lthy4) end;
   282 
   283 
   284 (* axioms *)
   285 
   286 fun axioms ta kind (vars, specs) lthy =
   287   let
   288     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   289     val expanded_props = map (Assumption.export_term lthy thy_ctxt) (maps snd specs);
   290     val xs = fold Term.add_frees expanded_props [];
   291 
   292     (*consts*)
   293     val (consts, lthy') = fold_map (declare_const ta (member (op =) xs)) vars lthy;
   294     val global_consts = map (Term.dest_Const o Term.head_of o Thm.term_of o Thm.rhs_of o #2) consts;
   295 
   296     (*axioms*)
   297     val hyps = map Thm.term_of (Assumption.assms_of lthy');
   298     fun axiom ((name, atts), props) thy = thy
   299       |> fold_map (Thm.add_axiom hyps) (PureThy.name_multi name props)
   300       |-> (fn ths => pair ((name, atts), [(ths, [])]));
   301   in
   302     lthy'
   303     |> fold Variable.declare_term expanded_props
   304     |> LocalTheory.theory (fold (fn c => Theory.add_deps "" c []) global_consts)
   305     |> LocalTheory.theory_result (fold_map axiom specs)
   306     |-> notes ta kind
   307     |>> pair (map #1 consts)
   308   end;
   309 
   310 
   311 (* init *)
   312 
   313 local
   314 
   315 fun init_target _ NONE = global_target
   316   | init_target thy (SOME target) = make_target target true (Class.is_class thy target) [];
   317 
   318 fun init_instantiaton arities = make_target "" false false arities
   319 
   320 fun init_ctxt (Target {target, is_locale, is_class, instantiation}) =
   321   if null instantiation then
   322     if not is_locale then ProofContext.init
   323     else if not is_class then Locale.init target
   324     else Class.init target
   325   else Class.instantiation instantiation;
   326 
   327 fun init_lthy (ta as Target {target, instantiation, ...}) =
   328   Data.put ta #>
   329   LocalTheory.init (NameSpace.base target)
   330    {pretty = pretty ta,
   331     axioms = axioms ta,
   332     abbrev = abbrev ta,
   333     define = define ta,
   334     notes = notes ta,
   335     type_syntax = type_syntax ta,
   336     term_syntax = term_syntax ta,
   337     declaration = declaration ta,
   338     reinit = fn lthy => init_lthy_ctxt ta (ProofContext.theory_of lthy),
   339     exit = if null instantiation then LocalTheory.target_of else Class.end_instantiation}
   340 and init_lthy_ctxt ta = init_lthy ta o init_ctxt ta;
   341 
   342 in
   343 
   344 fun init target thy = init_lthy_ctxt (init_target thy target) thy;
   345 fun begin target ctxt = init_lthy (init_target (ProofContext.theory_of ctxt) (SOME target)) ctxt;
   346 
   347 fun context "-" thy = init NONE thy
   348   | context target thy = init (SOME (Locale.intern thy target)) thy;
   349 
   350 fun instantiation raw_arities thy =
   351   init_lthy_ctxt (init_instantiaton (map (Sign.cert_arity thy) raw_arities)) thy;
   352 
   353 end;
   354 
   355 end;
   356