src/Pure/library.ML
author berghofe
Fri Mar 15 12:01:19 1996 +0100 (1996-03-15)
changeset 1580 e3fd931e6095
parent 1576 af8f43f742a0
child 1592 d89d5ff2397f
permissions -rw-r--r--
Added some functions which allow redirection of Isabelle's output
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic tables, balanced trees,
     8 input / output, timing, filenames, misc functions.
     9 *)
    10 
    11 infix |> ~~ \ \\ orelf ins ins_string ins_int orf andf prefix upto downto
    12       mem mem_int mem_string union union_string union_int inter inter_int
    13       inter_string subset subset_int subset_string subdir_of;
    14 
    15 
    16 structure Library =
    17 struct
    18 
    19 (** functions **)
    20 
    21 (*handy combinators*)
    22 fun curry f x y = f (x, y);
    23 fun uncurry f (x, y) = f x y;
    24 fun I x = x;
    25 fun K x y = x;
    26 
    27 (*reverse apply*)
    28 fun (x |> f) = f x;
    29 
    30 (*combine two functions forming the union of their domains*)
    31 fun f orelf g = fn x => f x handle Match => g x;
    32 
    33 (*application of (infix) operator to its left or right argument*)
    34 fun apl (x, f) y = f (x, y);
    35 fun apr (f, y) x = f (x, y);
    36 
    37 (*functional for pairs*)
    38 fun pairself f (x, y) = (f x, f y);
    39 
    40 (*function exponentiation: f(...(f x)...) with n applications of f*)
    41 fun funpow n f x =
    42   let fun rep (0, x) = x
    43         | rep (n, x) = rep (n - 1, f x)
    44   in rep (n, x) end;
    45 
    46 
    47 
    48 (** options **)
    49 
    50 datatype 'a option = None | Some of 'a;
    51 
    52 exception OPTION of string;
    53 
    54 fun the (Some x) = x
    55   | the None = raise OPTION "the";
    56 
    57 fun if_none None y = y
    58   | if_none (Some x) _ = x;
    59 
    60 fun is_some (Some _) = true
    61   | is_some None = false;
    62 
    63 fun is_none (Some _) = false
    64   | is_none None = true;
    65 
    66 fun apsome f (Some x) = Some (f x)
    67   | apsome _ None = None;
    68 
    69 
    70 
    71 (** pairs **)
    72 
    73 fun pair x y = (x, y);
    74 fun rpair x y = (y, x);
    75 
    76 fun fst (x, y) = x;
    77 fun snd (x, y) = y;
    78 
    79 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
    80 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
    81 
    82 fun swap (x, y) = (y, x);
    83 
    84 (*apply the function to a component of a pair*)
    85 fun apfst f (x, y) = (f x, y);
    86 fun apsnd f (x, y) = (x, f y);
    87 
    88 
    89 
    90 (** booleans **)
    91 
    92 (* equality *)
    93 
    94 fun equal x y = x = y;
    95 fun not_equal x y = x <> y;
    96 
    97 
    98 (* operators for combining predicates *)
    99 
   100 fun p orf q = fn x => p x orelse q x;
   101 
   102 fun p andf q = fn x => p x andalso q x;
   103 
   104 fun notf p x = not (p x);
   105 
   106 
   107 (* predicates on lists *)
   108 
   109 fun orl [] = false
   110   | orl (x :: xs) = x orelse orl xs;
   111 
   112 fun andl [] = true
   113   | andl (x :: xs) = x andalso andl xs;
   114 
   115 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   116 fun exists (pred: 'a -> bool) : 'a list -> bool =
   117   let fun boolf [] = false
   118         | boolf (x :: xs) = pred x orelse boolf xs
   119   in boolf end;
   120 
   121 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   122 fun forall (pred: 'a -> bool) : 'a list -> bool =
   123   let fun boolf [] = true
   124         | boolf (x :: xs) = pred x andalso boolf xs
   125   in boolf end;
   126 
   127 
   128 (* flags *)
   129 
   130 fun set flag = (flag := true; true);
   131 fun reset flag = (flag := false; false);
   132 fun toggle flag = (flag := not (! flag); ! flag);
   133 
   134 
   135 
   136 (** lists **)
   137 
   138 exception LIST of string;
   139 
   140 fun null [] = true
   141   | null (_ :: _) = false;
   142 
   143 fun hd [] = raise LIST "hd"
   144   | hd (x :: _) = x;
   145 
   146 fun tl [] = raise LIST "tl"
   147   | tl (_ :: xs) = xs;
   148 
   149 fun cons x xs = x :: xs;
   150 
   151 
   152 (* fold *)
   153 
   154 (*the following versions of fold are designed to fit nicely with infixes*)
   155 
   156 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   157     for operators that associate to the left (TAIL RECURSIVE)*)
   158 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   159   let fun itl (e, [])  = e
   160         | itl (e, a::l) = itl (f(e, a), l)
   161   in  itl end;
   162 
   163 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   164     for operators that associate to the right (not tail recursive)*)
   165 fun foldr f (l, e) =
   166   let fun itr [] = e
   167         | itr (a::l) = f(a, itr l)
   168   in  itr l  end;
   169 
   170 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   171     for n > 0, operators that associate to the right (not tail recursive)*)
   172 fun foldr1 f l =
   173   let fun itr [x] = x                       (* FIXME [] case: elim warn (?) *)
   174         | itr (x::l) = f(x, itr l)
   175   in  itr l  end;
   176 
   177 
   178 (* basic list functions *)
   179 
   180 (*length of a list, should unquestionably be a standard function*)
   181 local fun length1 (n, [])  = n   (*TAIL RECURSIVE*)
   182         | length1 (n, x :: xs) = length1 (n + 1, xs)
   183 in  fun length l = length1 (0, l) end;
   184 
   185 (*take the first n elements from a list*)
   186 fun take (n, []) = []
   187   | take (n, x :: xs) =
   188       if n > 0 then x :: take (n - 1, xs) else [];
   189 
   190 (*drop the first n elements from a list*)
   191 fun drop (n, []) = []
   192   | drop (n, x :: xs) =
   193       if n > 0 then drop (n - 1, xs) else x :: xs;
   194 
   195 (*return nth element of a list, where 0 designates the first element;
   196   raise EXCEPTION if list too short*)
   197 fun nth_elem NL =
   198   (case drop NL of
   199     [] => raise LIST "nth_elem"
   200   | x :: _ => x);
   201 
   202 (*last element of a list*)
   203 fun last_elem [] = raise LIST "last_elem"
   204   | last_elem [x] = x
   205   | last_elem (_ :: xs) = last_elem xs;
   206 
   207 (*find the position of an element in a list*)
   208 fun find (x, ys) =
   209   let fun f (y :: ys, i) = if x = y then i else f (ys, i + 1)
   210         | f (_, _) = raise LIST "find"
   211   in f (ys, 0) end;
   212 
   213 (*flatten a list of lists to a list*)
   214 fun flat (ls: 'c list list) : 'c list = foldr (op @) (ls, []);
   215 
   216 
   217 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   218   (proc x1; ...; proc xn) for side effects*)
   219 fun seq (proc: 'a -> unit) : 'a list -> unit =
   220   let fun seqf [] = ()
   221         | seqf (x :: xs) = (proc x; seqf xs)
   222   in seqf end;
   223 
   224 
   225 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   226 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   227   | separate _ xs = xs;
   228 
   229 (*make the list [x, x, ..., x] of length n*)
   230 fun replicate n (x: 'a) : 'a list =
   231   let fun rep (0, xs) = xs
   232         | rep (n, xs) = rep (n - 1, x :: xs)
   233   in
   234     if n < 0 then raise LIST "replicate"
   235     else rep (n, [])
   236   end;
   237 
   238 
   239 (* filter *)
   240 
   241 (*copy the list preserving elements that satisfy the predicate*)
   242 fun filter (pred: 'a->bool) : 'a list -> 'a list =
   243   let fun filt [] = []
   244         | filt (x :: xs) = if pred x then x :: filt xs else filt xs
   245   in filt end;
   246 
   247 fun filter_out f = filter (not o f);
   248 
   249 
   250 fun mapfilter (f: 'a -> 'b option) ([]: 'a list) = [] : 'b list
   251   | mapfilter f (x :: xs) =
   252       (case f x of
   253         None => mapfilter f xs
   254       | Some y => y :: mapfilter f xs);
   255 
   256 
   257 fun find_first _ [] = None
   258   | find_first pred (x :: xs) =
   259       if pred x then Some x else find_first pred xs;
   260 
   261 
   262 (* lists of pairs *)
   263 
   264 fun map2 _ ([], []) = []
   265   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   266   | map2 _ _ = raise LIST "map2";
   267 
   268 fun exists2 _ ([], []) = false
   269   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   270   | exists2 _ _ = raise LIST "exists2";
   271 
   272 fun forall2 _ ([], []) = true
   273   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   274   | forall2 _ _ = raise LIST "forall2";
   275 
   276 (*combine two lists forming a list of pairs:
   277   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   278 fun [] ~~ [] = []
   279   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   280   | _ ~~ _ = raise LIST "~~";
   281 
   282 
   283 (*inverse of ~~; the old 'split':
   284   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   285 fun split_list (l: ('a * 'b) list) = (map #1 l, map #2 l);
   286 
   287 
   288 (* prefixes, suffixes *)
   289 
   290 fun [] prefix _ = true
   291   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   292   | _ prefix _ = false;
   293 
   294 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   295    where xi is the first element that does not satisfy the predicate*)
   296 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   297   let fun take (rxs, []) = (rev rxs, [])
   298         | take (rxs, x :: xs) =
   299             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   300   in  take([], xs)  end;
   301 
   302 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   303    where xi is the last element that does not satisfy the predicate*)
   304 fun take_suffix _ [] = ([], [])
   305   | take_suffix pred (x :: xs) =
   306       (case take_suffix pred xs of
   307         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   308       | (prfx, sffx) => (x :: prfx, sffx));
   309 
   310 
   311 
   312 (** integers **)
   313 
   314 fun inc i = i := ! i + 1;
   315 fun dec i = i := ! i - 1;
   316 
   317 
   318 (* lists of integers *)
   319 
   320 (*make the list [from, from + 1, ..., to]*)
   321 fun from upto to =
   322   if from > to then [] else from :: ((from + 1) upto to);
   323 
   324 (*make the list [from, from - 1, ..., to]*)
   325 fun from downto to =
   326   if from < to then [] else from :: ((from - 1) downto to);
   327 
   328 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   329 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   330   | downto0 ([], n) = n = ~1;
   331 
   332 
   333 (* operations on integer lists *)
   334 
   335 fun sum [] = 0
   336   | sum (n :: ns) = n + sum ns;
   337 
   338 fun max [m:int] = m
   339   | max (m :: n :: ns) = if m > n then max (m :: ns) else max (n :: ns)
   340   | max [] = raise LIST "max";
   341 
   342 fun min [m:int] = m
   343   | min (m :: n :: ns) = if m < n then min (m :: ns) else min (n :: ns)
   344   | min [] = raise LIST "min";
   345 
   346 
   347 (* convert integers to strings *)
   348 
   349 (*expand the number in the given base;
   350   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   351 fun radixpand (base, num) : int list =
   352   let
   353     fun radix (n, tail) =
   354       if n < base then n :: tail
   355       else radix (n div base, (n mod base) :: tail)
   356   in radix (num, []) end;
   357 
   358 (*expands a number into a string of characters starting from "zerochar";
   359   example: radixstring (2, "0", 8) gives "1000"*)
   360 fun radixstring (base, zerochar, num) =
   361   let val offset = ord zerochar;
   362       fun chrof n = chr (offset + n)
   363   in implode (map chrof (radixpand (base, num))) end;
   364 
   365 
   366 fun string_of_int n =
   367   if n < 0 then "~" ^ radixstring (10, "0", ~n) else radixstring (10, "0", n);
   368 
   369 
   370 
   371 (** strings **)
   372 
   373 fun is_letter ch =
   374   ord "A" <= ord ch andalso ord ch <= ord "Z" orelse
   375   ord "a" <= ord ch andalso ord ch <= ord "z";
   376 
   377 fun is_digit ch =
   378   ord "0" <= ord ch andalso ord ch <= ord "9";
   379 
   380 (*letter or _ or prime (')*)
   381 fun is_quasi_letter "_" = true
   382   | is_quasi_letter "'" = true
   383   | is_quasi_letter ch = is_letter ch;
   384 
   385 (*white space: blanks, tabs, newlines, formfeeds*)
   386 val is_blank : string -> bool =
   387   fn " " => true | "\t" => true | "\n" => true | "\^L" => true | _ => false;
   388 
   389 val is_letdig = is_quasi_letter orf is_digit;
   390 
   391 
   392 (*lower all chars of string*)
   393 val to_lower =
   394   let
   395     fun lower ch =
   396       if ch >= "A" andalso ch <= "Z" then
   397         chr (ord ch - ord "A" + ord "a")
   398       else ch;
   399   in implode o (map lower) o explode end;
   400 
   401 
   402 (*enclose in brackets*)
   403 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   404 
   405 (*simple quoting (does not escape special chars)*)
   406 val quote = enclose "\"" "\"";
   407 
   408 (*space_implode "..." (explode "hello"); gives "h...e...l...l...o"*)
   409 fun space_implode a bs = implode (separate a bs);
   410 
   411 val commas = space_implode ", ";
   412 val commas_quote = commas o map quote;
   413 
   414 (*concatenate messages, one per line, into a string*)
   415 val cat_lines = space_implode "\n";
   416 
   417 (*space_explode "." "h.e..l.lo"; gives ["h", "e", "l", "lo"]*)
   418 fun space_explode sep s =
   419   let fun divide [] "" = []
   420         | divide [] part = [part]
   421         | divide (c::s) part =
   422             if c = sep then
   423               (if part = "" then divide s "" else part :: divide s "")
   424             else divide s (part ^ c)
   425   in divide (explode s) "" end;
   426 
   427 
   428 (** lists as sets **)
   429 
   430 (*membership in a list*)
   431 fun x mem [] = false
   432   | x mem (y :: ys) = x = y orelse x mem ys;
   433 
   434 (*membership in a list, optimized version for int lists*)
   435 fun (x:int) mem_int [] = false
   436   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   437 
   438 (*membership in a list, optimized version for string lists*)
   439 fun (x:string) mem_string [] = false
   440   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   441 
   442 (*generalized membership test*)
   443 fun gen_mem eq (x, []) = false
   444   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   445 
   446 
   447 (*insertion into list if not already there*)
   448 fun x ins xs = if x mem xs then xs else x :: xs;
   449 
   450 (*insertion into list if not already there, optimized version for int lists*)
   451 fun (x:int) ins_int xs = if x mem_int xs then xs else x :: xs;
   452 
   453 (*insertion into list if not already there, optimized version for string lists*)
   454 fun (x:string) ins_string xs = if x mem_string xs then xs else x :: xs;
   455 
   456 (*generalized insertion*)
   457 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   458 
   459 
   460 (*union of sets represented as lists: no repetitions*)
   461 fun xs union [] = xs
   462   | [] union ys = ys
   463   | (x :: xs) union ys = xs union (x ins ys);
   464 
   465 (*union of sets represented as lists: no repetitions, optimized version for int lists*)
   466 fun (xs:int list) union_int [] = xs
   467   | [] union_int ys = ys
   468   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   469 
   470 (*union of sets represented as lists: no repetitions, optimized version for string lists*)
   471 fun (xs:string list) union_string [] = xs
   472   | [] union_string ys = ys
   473   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   474 
   475 (*generalized union*)
   476 fun gen_union eq (xs, []) = xs
   477   | gen_union eq ([], ys) = ys
   478   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   479 
   480 
   481 (*intersection*)
   482 fun [] inter ys = []
   483   | (x :: xs) inter ys =
   484       if x mem ys then x :: (xs inter ys) else xs inter ys;
   485 
   486 (*intersection, optimized version for int lists*)
   487 fun ([]:int list) inter_int ys = []
   488   | (x :: xs) inter_int ys =
   489       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   490 
   491 (*intersection, optimized version for string lists *)
   492 fun ([]:string list) inter_string ys = []
   493   | (x :: xs) inter_string ys =
   494       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   495 
   496 
   497 (*subset*)
   498 fun [] subset ys = true
   499   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   500 
   501 (*subset, optimized version for int lists*)
   502 fun ([]:int list) subset_int ys = true
   503   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   504 
   505 (*subset, optimized version for string lists*)
   506 fun ([]:string list) subset_string ys = true
   507   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   508 
   509 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   510 
   511 
   512 (*eq_set*)
   513 
   514 fun eq_set (xs, ys) =
   515   xs = ys orelse (xs subset ys andalso ys subset xs);
   516 
   517 (*eq_set, optimized version for int lists*)
   518 
   519 fun eq_set_int ((xs:int list), ys) =
   520   xs = ys orelse (xs subset_int ys andalso ys subset_int xs);
   521 
   522 (*eq_set, optimized version for string lists*)
   523 
   524 fun eq_set_string ((xs:string list), ys) =
   525   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   526 
   527 
   528 (*removing an element from a list WITHOUT duplicates*)
   529 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   530   | [] \ x = [];
   531 
   532 val op \\ = foldl (op \);
   533 
   534 (*removing an element from a list -- possibly WITH duplicates*)
   535 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   536 
   537 val gen_rems = foldl o gen_rem;
   538 
   539 
   540 (*makes a list of the distinct members of the input; preserves order, takes
   541   first of equal elements*)
   542 fun gen_distinct eq lst =
   543   let
   544     val memb = gen_mem eq;
   545 
   546     fun dist (rev_seen, []) = rev rev_seen
   547       | dist (rev_seen, x :: xs) =
   548           if memb (x, rev_seen) then dist (rev_seen, xs)
   549           else dist (x :: rev_seen, xs);
   550   in
   551     dist ([], lst)
   552   end;
   553 
   554 val distinct = gen_distinct (op =);
   555 
   556 
   557 (*returns the tail beginning with the first repeated element, or []*)
   558 fun findrep [] = []
   559   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   560 
   561 
   562 (*returns a list containing all repeated elements exactly once; preserves
   563   order, takes first of equal elements*)
   564 fun gen_duplicates eq lst =
   565   let
   566     val memb = gen_mem eq;
   567 
   568     fun dups (rev_dups, []) = rev rev_dups
   569       | dups (rev_dups, x :: xs) =
   570           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   571             dups (rev_dups, xs)
   572           else dups (x :: rev_dups, xs);
   573   in
   574     dups ([], lst)
   575   end;
   576 
   577 val duplicates = gen_duplicates (op =);
   578 
   579 
   580 
   581 (** association lists **)
   582 
   583 (*association list lookup*)
   584 fun assoc ([], key) = None
   585   | assoc ((keyi, xi) :: pairs, key) =
   586       if key = keyi then Some xi else assoc (pairs, key);
   587 
   588 (*association list lookup, optimized version for int lists*)
   589 fun assoc_int ([], (key:int)) = None
   590   | assoc_int ((keyi, xi) :: pairs, key) =
   591       if key = keyi then Some xi else assoc_int (pairs, key);
   592 
   593 (*association list lookup, optimized version for string lists*)
   594 fun assoc_string ([], (key:string)) = None
   595   | assoc_string ((keyi, xi) :: pairs, key) =
   596       if key = keyi then Some xi else assoc_string (pairs, key);
   597 
   598 (*association list lookup, optimized version for string*int lists*)
   599 fun assoc_string_int ([], (key:string*int)) = None
   600   | assoc_string_int ((keyi, xi) :: pairs, key) =
   601       if key = keyi then Some xi else assoc_string_int (pairs, key);
   602 
   603 fun assocs ps x =
   604   (case assoc (ps, x) of
   605     None => []
   606   | Some ys => ys);
   607 
   608 (*two-fold association list lookup*)
   609 fun assoc2 (aal, (key1, key2)) =
   610   (case assoc (aal, key1) of
   611     Some al => assoc (al, key2)
   612   | None => None);
   613 
   614 (*generalized association list lookup*)
   615 fun gen_assoc eq ([], key) = None
   616   | gen_assoc eq ((keyi, xi) :: pairs, key) =
   617       if eq (key, keyi) then Some xi else gen_assoc eq (pairs, key);
   618 
   619 (*association list update*)
   620 fun overwrite (al, p as (key, _)) =
   621   let fun over ((q as (keyi, _)) :: pairs) =
   622             if keyi = key then p :: pairs else q :: (over pairs)
   623         | over [] = [p]
   624   in over al end;
   625 
   626 
   627 
   628 (** generic tables **)
   629 
   630 (*Tables are supposed to be 'efficient' encodings of lists of elements distinct
   631   wrt. an equality "eq". The extend and merge operations below are optimized
   632   for long-term space efficiency.*)
   633 
   634 (*append (new) elements to a table*)
   635 fun generic_extend _ _ _ tab [] = tab
   636   | generic_extend eq dest_tab mk_tab tab1 lst2 =
   637       let
   638         val lst1 = dest_tab tab1;
   639         val new_lst2 = gen_rems eq (lst2, lst1);
   640       in
   641         if null new_lst2 then tab1
   642         else mk_tab (lst1 @ new_lst2)
   643       end;
   644 
   645 (*append (new) elements of 2nd table to 1st table*)
   646 fun generic_merge eq dest_tab mk_tab tab1 tab2 =
   647   let
   648     val lst1 = dest_tab tab1;
   649     val lst2 = dest_tab tab2;
   650     val new_lst2 = gen_rems eq (lst2, lst1);
   651   in
   652     if null new_lst2 then tab1
   653     else if gen_subset eq (lst1, lst2) then tab2
   654     else mk_tab (lst1 @ new_lst2)
   655   end;
   656 
   657 
   658 (*lists as tables*)
   659 val extend_list = generic_extend (op =) I I;
   660 val merge_lists = generic_merge (op =) I I;
   661 
   662 fun merge_rev_lists xs [] = xs
   663   | merge_rev_lists [] ys = ys
   664   | merge_rev_lists xs (y :: ys) =
   665       (if y mem xs then I else cons y) (merge_rev_lists xs ys);
   666 
   667 
   668 
   669 (** balanced trees **)
   670 
   671 exception Balance;      (*indicates non-positive argument to balancing fun*)
   672 
   673 (*balanced folding; avoids deep nesting*)
   674 fun fold_bal f [x] = x
   675   | fold_bal f [] = raise Balance
   676   | fold_bal f xs =
   677       let val k = length xs div 2
   678       in  f (fold_bal f (take(k, xs)),
   679              fold_bal f (drop(k, xs)))
   680       end;
   681 
   682 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   683 fun access_bal (f, g, x) n i =
   684   let fun acc n i =     (*1<=i<=n*)
   685           if n=1 then x else
   686           let val n2 = n div 2
   687           in  if i<=n2 then f (acc n2 i)
   688                        else g (acc (n-n2) (i-n2))
   689           end
   690   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   691 
   692 (*construct ALL such accesses; could try harder to share recursive calls!*)
   693 fun accesses_bal (f, g, x) n =
   694   let fun acc n =
   695           if n=1 then [x] else
   696           let val n2 = n div 2
   697               val acc2 = acc n2
   698           in  if n-n2=n2 then map f acc2 @ map g acc2
   699                          else map f acc2 @ map g (acc (n-n2)) end
   700   in  if 1<=n then acc n else raise Balance  end;
   701 
   702 
   703 
   704 (** input / output **)
   705 
   706 val prs_fn = ref(fn s => output (std_out, s));
   707 
   708 fun prs s = !prs_fn s;
   709 fun writeln s = prs (s ^ "\n");
   710 
   711 (*print warning*)
   712 val warning_fn = ref(fn s => output (std_out, s ^ "\n"));
   713 fun warning s = !warning_fn ("Warning: " ^ s);
   714 
   715 (*print error message and abort to top level*)
   716 
   717 val error_fn = ref(fn s => output (std_out, s ^ "\n"));
   718 
   719 exception ERROR;
   720 fun error msg = (!error_fn msg; raise ERROR);
   721 fun sys_error msg = (!error_fn "*** SYSTEM ERROR ***"; error msg);
   722 
   723 fun assert p msg = if p then () else error msg;
   724 fun deny p msg = if p then error msg else ();
   725 
   726 (*Assert pred for every member of l, generating a message if pred fails*)
   727 fun assert_all pred l msg_fn = 
   728   let fun asl [] = ()
   729 	| asl (x::xs) = if pred x then asl xs
   730 	                else error (msg_fn x)
   731   in  asl l  end;
   732 
   733 (* FIXME close file (?) *)
   734 (*for the "test" target in Makefiles -- signifies successful termination*)
   735 fun maketest msg =
   736   (writeln msg; output (open_out "test", "Test examples ran successfully\n"));
   737 
   738 
   739 (*print a list surrounded by the brackets lpar and rpar, with comma separator
   740   print nothing for empty list*)
   741 fun print_list (lpar, rpar, pre: 'a -> unit) (l : 'a list) =
   742   let fun prec x = (prs ","; pre x)
   743   in
   744     (case l of
   745       [] => ()
   746     | x::l => (prs lpar; pre x; seq prec l; prs rpar))
   747   end;
   748 
   749 (*print a list of items separated by newlines*)
   750 fun print_list_ln (pre: 'a -> unit) : 'a list -> unit =
   751   seq (fn x => (pre x; writeln ""));
   752 
   753 
   754 val print_int = prs o string_of_int;
   755 
   756 
   757 
   758 (** timing **)
   759 
   760 (*unconditional timing function*)
   761 val timeit = cond_timeit true;
   762 
   763 (*timed application function*)
   764 fun timeap f x = timeit (fn () => f x);
   765 
   766 (*timed "use" function, printing filenames*)
   767 fun time_use fname = timeit (fn () =>
   768   (writeln ("\n**** Starting " ^ fname ^ " ****"); use fname;
   769    writeln ("\n**** Finished " ^ fname ^ " ****")));
   770 
   771 (*For Makefiles: use the file, but exit with error code if errors found.*)
   772 fun exit_use fname = use fname handle _ => exit 1;
   773 
   774 
   775 (** filenames and paths **)
   776 
   777 (*Convert UNIX filename of the form "path/file" to "path/" and "file";
   778   if filename contains no slash, then it returns "" and "file"*)
   779 val split_filename =
   780   (pairself implode) o take_suffix (not_equal "/") o explode;
   781 
   782 val base_name = #2 o split_filename;
   783 
   784 (*Merge splitted filename (path and file);
   785   if path does not end with one a slash is appended*)
   786 fun tack_on "" name = name
   787   | tack_on path name =
   788       if last_elem (explode path) = "/" then path ^ name
   789       else path ^ "/" ^ name;
   790 
   791 (*Remove the extension of a filename, i.e. the part after the last '.'*)
   792 val remove_ext = implode o #1 o take_suffix (not_equal ".") o explode;
   793 
   794 (*Make relative path to reach an absolute location from a different one*)
   795 fun relative_path cur_path dest_path =
   796   let (*Remove common beginning of both paths and make relative path*)
   797       fun mk_relative [] [] = []
   798         | mk_relative [] ds = ds
   799         | mk_relative cs [] = map (fn _ => "..") cs
   800         | mk_relative (c::cs) (d::ds) =
   801             if c = d then mk_relative cs ds
   802             else ".." :: map (fn _ => "..") cs @ (d::ds);
   803   in if cur_path = "" orelse hd (explode cur_path) <> "/" orelse
   804         dest_path = "" orelse hd (explode dest_path) <> "/" then
   805        error "Relative or empty path passed to relative_path"
   806      else ();
   807      space_implode "/" (mk_relative (space_explode "/" cur_path)
   808                                     (space_explode "/" dest_path))
   809   end;
   810 
   811 (*Determine if absolute path1 is a subdirectory of absolute path2*)
   812 fun path1 subdir_of path2 =
   813   if hd (explode path1) <> "/" orelse hd (explode path2) <> "/" then
   814     error "Relative or empty path passed to subdir_of"
   815   else (space_explode "/" path2) prefix (space_explode "/" path1);
   816 
   817 fun absolute_path cwd file =
   818   let fun rm_points [] result = rev result
   819         | rm_points (".."::ds) result = rm_points ds (tl result)
   820         | rm_points ("."::ds) result = rm_points ds result
   821         | rm_points (d::ds) result = rm_points ds (d::result);
   822   in if file = "" then ""
   823      else if hd (explode file) = "/" then file
   824      else "/" ^ space_implode "/"
   825                   (rm_points (space_explode "/" (tack_on cwd file)) [])
   826   end;
   827 
   828 
   829 (** misc functions **)
   830 
   831 (*use the keyfun to make a list of (x, key) pairs*)
   832 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
   833   let fun keypair x = (x, keyfun x)
   834   in map keypair end;
   835 
   836 (*given a list of (x, key) pairs and a searchkey
   837   return the list of xs from each pair whose key equals searchkey*)
   838 fun keyfilter [] searchkey = []
   839   | keyfilter ((x, key) :: pairs) searchkey =
   840       if key = searchkey then x :: keyfilter pairs searchkey
   841       else keyfilter pairs searchkey;
   842 
   843 
   844 (*Partition list into elements that satisfy predicate and those that don't.
   845   Preserves order of elements in both lists.*)
   846 fun partition (pred: 'a->bool) (ys: 'a list) : ('a list * 'a list) =
   847     let fun part ([], answer) = answer
   848           | part (x::xs, (ys, ns)) = if pred(x)
   849             then  part (xs, (x::ys, ns))
   850             else  part (xs, (ys, x::ns))
   851     in  part (rev ys, ([], []))  end;
   852 
   853 
   854 fun partition_eq (eq:'a * 'a -> bool) =
   855     let fun part [] = []
   856           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
   857                            in (x::xs)::(part xs') end
   858     in part end;
   859 
   860 
   861 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   862    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   863 fun partition_list p i j =
   864   let fun part k xs =
   865             if k>j then
   866               (case xs of [] => []
   867                          | _ => raise LIST "partition_list")
   868             else
   869             let val (ns, rest) = partition (p k) xs;
   870             in  ns :: part(k+1)rest  end
   871   in  part i end;
   872 
   873 
   874 (* sorting *)
   875 
   876 (*insertion sort; stable (does not reorder equal elements)
   877   'less' is less-than test on type 'a*)
   878 fun sort (less: 'a*'a -> bool) =
   879   let fun insert (x, []) = [x]
   880         | insert (x, y::ys) =
   881               if less(y, x) then y :: insert (x, ys) else x::y::ys;
   882       fun sort1 [] = []
   883         | sort1 (x::xs) = insert (x, sort1 xs)
   884   in  sort1  end;
   885 
   886 (*sort strings*)
   887 val sort_strings = sort (op <= : string * string -> bool);
   888 
   889 
   890 (* transitive closure (not Warshall's algorithm) *)
   891 
   892 fun transitive_closure [] = []
   893   | transitive_closure ((x, ys)::ps) =
   894       let val qs = transitive_closure ps
   895           val zs = foldl (fn (zs, y) => assocs qs y union zs) (ys, ys)
   896           fun step(u, us) = (u, if x mem us then zs union us else us)
   897       in (x, zs) :: map step qs end;
   898 
   899 
   900 (* generating identifiers *)
   901 
   902 local
   903   val a = ord "a" and z = ord "z" and A = ord "A" and Z = ord "Z"
   904   and k0 = ord "0" and k9 = ord "9"
   905 in
   906 
   907 (*Increment a list of letters like a reversed base 26 number.
   908   If head is "z", bumps chars in tail.
   909   Digits are incremented as if they were integers.
   910   "_" and "'" are not changed.
   911   For making variants of identifiers.*)
   912 
   913 fun bump_int_list(c::cs) = if c="9" then "0" :: bump_int_list cs else
   914         if k0 <= ord(c) andalso ord(c) < k9 then chr(ord(c)+1) :: cs
   915         else "1" :: c :: cs
   916   | bump_int_list([]) = error("bump_int_list: not an identifier");
   917 
   918 fun bump_list([], d) = [d]
   919   | bump_list(["'"], d) = [d, "'"]
   920   | bump_list("z"::cs, _) = "a" :: bump_list(cs, "a")
   921   | bump_list("Z"::cs, _) = "A" :: bump_list(cs, "A")
   922   | bump_list("9"::cs, _) = "0" :: bump_int_list cs
   923   | bump_list(c::cs, _) = let val k = ord(c)
   924         in if (a <= k andalso k < z) orelse (A <= k andalso k < Z) orelse
   925               (k0 <= k andalso k < k9) then chr(k+1) :: cs else
   926            if c="'" orelse c="_" then c :: bump_list(cs, "") else
   927                 error("bump_list: not legal in identifier: " ^
   928                         implode(rev(c::cs)))
   929         end;
   930 
   931 end;
   932 
   933 fun bump_string s : string = implode (rev (bump_list(rev(explode s), "")));
   934 
   935 
   936 (* lexical scanning *)
   937 
   938 (*scan a list of characters into "words" composed of "letters" (recognized by
   939   is_let) and separated by any number of non-"letters"*)
   940 fun scanwords is_let cs =
   941   let fun scan1 [] = []
   942         | scan1 cs =
   943             let val (lets, rest) = take_prefix is_let cs
   944             in implode lets :: scanwords is_let rest end;
   945   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
   946 
   947 end;
   948 
   949 open Library;