src/HOL/Filter.thy
author wenzelm
Mon Dec 28 21:47:32 2015 +0100 (2015-12-28)
changeset 61955 e96292f32c3c
parent 61953 7247cb62406c
child 62101 26c0a70f78a3
permissions -rw-r--r--
former "xsymbols" syntax is used by default, and ASCII replacement syntax with print mode "ASCII";
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Filters on predicates\<close>
     7 
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    11 
    12 subsection \<open>Filters\<close>
    13 
    14 text \<open>
    15   This definition also allows non-proper filters.
    16 \<close>
    17 
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    23 
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    28 
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    31 
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    35 
    36 
    37 subsubsection \<open>Eventually\<close>
    38 
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    41 
    42 syntax
    43   "_eventually" :: "pttrn => 'a filter => bool => bool"  ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 translations
    45   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    46 
    47 lemma eventually_Abs_filter:
    48   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    49   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    50 
    51 lemma filter_eq_iff:
    52   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    53   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    54 
    55 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    56   unfolding eventually_def
    57   by (rule is_filter.True [OF is_filter_Rep_filter])
    58 
    59 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    60 proof -
    61   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    62   thus "eventually P F" by simp
    63 qed
    64 
    65 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    66   by (auto intro: always_eventually)
    67 
    68 lemma eventually_mono:
    69   "\<lbrakk>eventually P F; \<And>x. P x \<Longrightarrow> Q x\<rbrakk> \<Longrightarrow> eventually Q F"
    70   unfolding eventually_def
    71   by (blast intro: is_filter.mono [OF is_filter_Rep_filter])
    72 
    73 lemma eventually_conj:
    74   assumes P: "eventually (\<lambda>x. P x) F"
    75   assumes Q: "eventually (\<lambda>x. Q x) F"
    76   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    77   using assms unfolding eventually_def
    78   by (rule is_filter.conj [OF is_filter_Rep_filter])
    79 
    80 lemma eventually_mp:
    81   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    82   assumes "eventually (\<lambda>x. P x) F"
    83   shows "eventually (\<lambda>x. Q x) F"
    84 proof -
    85   have "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    86     using assms by (rule eventually_conj)
    87   then show ?thesis
    88     by (blast intro: eventually_mono)
    89 qed
    90 
    91 lemma eventually_rev_mp:
    92   assumes "eventually (\<lambda>x. P x) F"
    93   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    94   shows "eventually (\<lambda>x. Q x) F"
    95 using assms(2) assms(1) by (rule eventually_mp)
    96 
    97 lemma eventually_conj_iff:
    98   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    99   by (auto intro: eventually_conj elim: eventually_rev_mp)
   100 
   101 lemma eventually_elim2:
   102   assumes "eventually (\<lambda>i. P i) F"
   103   assumes "eventually (\<lambda>i. Q i) F"
   104   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   105   shows "eventually (\<lambda>i. R i) F"
   106   using assms by (auto elim!: eventually_rev_mp)
   107 
   108 lemma eventually_ball_finite_distrib:
   109   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   110   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   111 
   112 lemma eventually_ball_finite:
   113   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   114   by (auto simp: eventually_ball_finite_distrib)
   115 
   116 lemma eventually_all_finite:
   117   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   118   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   119   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   120 using eventually_ball_finite [of UNIV P] assms by simp
   121 
   122 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   123 proof
   124   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   125   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   126     by (auto intro: someI_ex eventually_mono)
   127   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   128     by auto
   129 qed (auto intro: eventually_mono)
   130 
   131 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   132   by (auto intro: eventually_mp)
   133 
   134 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   135   by (metis always_eventually)
   136 
   137 lemma eventually_subst:
   138   assumes "eventually (\<lambda>n. P n = Q n) F"
   139   shows "eventually P F = eventually Q F" (is "?L = ?R")
   140 proof -
   141   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   142       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   143     by (auto elim: eventually_mono)
   144   then show ?thesis by (auto elim: eventually_elim2)
   145 qed
   146 
   147 subsection \<open> Frequently as dual to eventually \<close>
   148 
   149 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   150   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   151 
   152 syntax
   153   "_frequently" :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   154 translations
   155   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   156 
   157 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   158   by (simp add: frequently_def)
   159 
   160 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   161   by (auto simp: frequently_def dest: not_eventuallyD)
   162 
   163 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   164   using frequently_ex[OF assms] by auto
   165 
   166 lemma frequently_mp:
   167   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   168 proof -
   169   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   170     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   171   from eventually_mp[OF this] P show ?thesis
   172     by (auto simp: frequently_def)
   173 qed
   174 
   175 lemma frequently_rev_mp:
   176   assumes "\<exists>\<^sub>Fx in F. P x"
   177   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   178   shows "\<exists>\<^sub>Fx in F. Q x"
   179 using assms(2) assms(1) by (rule frequently_mp)
   180 
   181 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   182   using frequently_mp[of P Q] by (simp add: always_eventually)
   183 
   184 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   185   by (metis frequently_mono)
   186 
   187 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   188   by (simp add: frequently_def eventually_conj_iff)
   189 
   190 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   191   by (simp add: frequently_disj_iff)
   192 
   193 lemma frequently_bex_finite_distrib:
   194   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   195   using assms by induction (auto simp: frequently_disj_iff)
   196 
   197 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   198   by (simp add: frequently_bex_finite_distrib)
   199 
   200 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   201   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   202 
   203 lemma
   204   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   205     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   206   by (auto simp: frequently_def)
   207 
   208 lemma frequently_imp_iff:
   209   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   210   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   211 
   212 lemma eventually_frequently_const_simps:
   213   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   214   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   215   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   216   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   217   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   218   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   219   by (cases C; simp add: not_frequently)+
   220 
   221 lemmas eventually_frequently_simps =
   222   eventually_frequently_const_simps
   223   not_eventually
   224   eventually_conj_iff
   225   eventually_ball_finite_distrib
   226   eventually_ex
   227   not_frequently
   228   frequently_disj_iff
   229   frequently_bex_finite_distrib
   230   frequently_all
   231   frequently_imp_iff
   232 
   233 ML \<open>
   234   fun eventually_elim_tac facts =
   235     CONTEXT_SUBGOAL (fn (goal, i) => fn (ctxt, st) =>
   236       let
   237         val mp_thms = facts RL @{thms eventually_rev_mp}
   238         val raw_elim_thm =
   239           (@{thm allI} RS @{thm always_eventually})
   240           |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   241           |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   242         val cases_prop =
   243           Thm.prop_of
   244             (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
   245         val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   246       in CONTEXT_CASES cases (resolve_tac ctxt [raw_elim_thm] i) (ctxt, st) end)
   247 \<close>
   248 
   249 method_setup eventually_elim = \<open>
   250   Scan.succeed (fn _ => CONTEXT_METHOD (fn facts => eventually_elim_tac facts 1))
   251 \<close> "elimination of eventually quantifiers"
   252 
   253 subsubsection \<open>Finer-than relation\<close>
   254 
   255 text \<open>@{term "F \<le> F'"} means that filter @{term F} is finer than
   256 filter @{term F'}.\<close>
   257 
   258 instantiation filter :: (type) complete_lattice
   259 begin
   260 
   261 definition le_filter_def:
   262   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   263 
   264 definition
   265   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   266 
   267 definition
   268   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   269 
   270 definition
   271   "bot = Abs_filter (\<lambda>P. True)"
   272 
   273 definition
   274   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   275 
   276 definition
   277   "inf F F' = Abs_filter
   278       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   279 
   280 definition
   281   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   282 
   283 definition
   284   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   285 
   286 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   287   unfolding top_filter_def
   288   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   289 
   290 lemma eventually_bot [simp]: "eventually P bot"
   291   unfolding bot_filter_def
   292   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   293 
   294 lemma eventually_sup:
   295   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   296   unfolding sup_filter_def
   297   by (rule eventually_Abs_filter, rule is_filter.intro)
   298      (auto elim!: eventually_rev_mp)
   299 
   300 lemma eventually_inf:
   301   "eventually P (inf F F') \<longleftrightarrow>
   302    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   303   unfolding inf_filter_def
   304   apply (rule eventually_Abs_filter, rule is_filter.intro)
   305   apply (fast intro: eventually_True)
   306   apply clarify
   307   apply (intro exI conjI)
   308   apply (erule (1) eventually_conj)
   309   apply (erule (1) eventually_conj)
   310   apply simp
   311   apply auto
   312   done
   313 
   314 lemma eventually_Sup:
   315   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   316   unfolding Sup_filter_def
   317   apply (rule eventually_Abs_filter, rule is_filter.intro)
   318   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   319   done
   320 
   321 instance proof
   322   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   323   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   324     by (rule less_filter_def) }
   325   { show "F \<le> F"
   326     unfolding le_filter_def by simp }
   327   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   328     unfolding le_filter_def by simp }
   329   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   330     unfolding le_filter_def filter_eq_iff by fast }
   331   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   332     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   333   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   334     unfolding le_filter_def eventually_inf
   335     by (auto intro: eventually_mono [OF eventually_conj]) }
   336   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   337     unfolding le_filter_def eventually_sup by simp_all }
   338   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   339     unfolding le_filter_def eventually_sup by simp }
   340   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   341     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   342   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   343     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   344   { assume "F \<in> S" thus "F \<le> Sup S"
   345     unfolding le_filter_def eventually_Sup by simp }
   346   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   347     unfolding le_filter_def eventually_Sup by simp }
   348   { show "Inf {} = (top::'a filter)"
   349     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   350       (metis (full_types) top_filter_def always_eventually eventually_top) }
   351   { show "Sup {} = (bot::'a filter)"
   352     by (auto simp: bot_filter_def Sup_filter_def) }
   353 qed
   354 
   355 end
   356 
   357 lemma filter_leD:
   358   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   359   unfolding le_filter_def by simp
   360 
   361 lemma filter_leI:
   362   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   363   unfolding le_filter_def by simp
   364 
   365 lemma eventually_False:
   366   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   367   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   368 
   369 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   370   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   371   by (auto simp add: frequently_def eventually_False)
   372 
   373 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   374   by (cases P) (auto simp: eventually_False)
   375 
   376 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   377   by (simp add: eventually_const_iff)
   378 
   379 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   380   by (simp add: frequently_def eventually_const_iff)
   381 
   382 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   383   by (simp add: frequently_const_iff)
   384 
   385 lemma eventually_happens: "eventually P net \<Longrightarrow> net = bot \<or> (\<exists>x. P x)"
   386   by (metis frequentlyE eventually_frequently)
   387 
   388 lemma eventually_happens':
   389   assumes "F \<noteq> bot" "eventually P F"
   390   shows   "\<exists>x. P x"
   391   using assms eventually_frequently frequentlyE by blast
   392 
   393 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   394   where "trivial_limit F \<equiv> F = bot"
   395 
   396 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   397   by (rule eventually_False [symmetric])
   398 
   399 lemma False_imp_not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
   400   by (simp add: eventually_False)
   401 
   402 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   403 proof -
   404   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   405 
   406   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   407     proof (rule eventually_Abs_filter is_filter.intro)+
   408       show "?F (\<lambda>x. True)"
   409         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   410     next
   411       fix P Q
   412       assume "?F P" then guess X ..
   413       moreover
   414       assume "?F Q" then guess Y ..
   415       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   416         by (intro exI[of _ "X \<union> Y"])
   417            (auto simp: Inf_union_distrib eventually_inf)
   418     next
   419       fix P Q
   420       assume "?F P" then guess X ..
   421       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   422       ultimately show "?F Q"
   423         by (intro exI[of _ X]) (auto elim: eventually_mono)
   424     qed }
   425   note eventually_F = this
   426 
   427   have "Inf B = Abs_filter ?F"
   428   proof (intro antisym Inf_greatest)
   429     show "Inf B \<le> Abs_filter ?F"
   430       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   431   next
   432     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   433       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   434   qed
   435   then show ?thesis
   436     by (simp add: eventually_F)
   437 qed
   438 
   439 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   440   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   441   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   442 
   443 lemma Inf_filter_not_bot:
   444   fixes B :: "'a filter set"
   445   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   446   unfolding trivial_limit_def eventually_Inf[of _ B]
   447     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   448 
   449 lemma INF_filter_not_bot:
   450   fixes F :: "'i \<Rightarrow> 'a filter"
   451   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   452   unfolding trivial_limit_def eventually_INF[of _ B]
   453     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   454 
   455 lemma eventually_Inf_base:
   456   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   457   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   458 proof (subst eventually_Inf, safe)
   459   fix X assume "finite X" "X \<subseteq> B"
   460   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   461   proof induct
   462     case empty then show ?case
   463       using \<open>B \<noteq> {}\<close> by auto
   464   next
   465     case (insert x X)
   466     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   467       by auto
   468     with \<open>insert x X \<subseteq> B\<close> base[of b x] show ?case
   469       by (auto intro: order_trans)
   470   qed
   471   then obtain b where "b \<in> B" "b \<le> Inf X"
   472     by (auto simp: le_Inf_iff)
   473   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   474     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   475 qed (auto intro!: exI[of _ "{x}" for x])
   476 
   477 lemma eventually_INF_base:
   478   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   479     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   480   unfolding INF_def by (subst eventually_Inf_base) auto
   481 
   482 
   483 subsubsection \<open>Map function for filters\<close>
   484 
   485 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   486   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   487 
   488 lemma eventually_filtermap:
   489   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   490   unfolding filtermap_def
   491   apply (rule eventually_Abs_filter)
   492   apply (rule is_filter.intro)
   493   apply (auto elim!: eventually_rev_mp)
   494   done
   495 
   496 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   497   by (simp add: filter_eq_iff eventually_filtermap)
   498 
   499 lemma filtermap_filtermap:
   500   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   501   by (simp add: filter_eq_iff eventually_filtermap)
   502 
   503 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   504   unfolding le_filter_def eventually_filtermap by simp
   505 
   506 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   507   by (simp add: filter_eq_iff eventually_filtermap)
   508 
   509 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   510   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   511 
   512 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   513   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   514 
   515 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   516 proof -
   517   { fix X :: "'c set" assume "finite X"
   518     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   519     proof induct
   520       case (insert x X)
   521       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   522         by (rule order_trans[OF _ filtermap_inf]) simp
   523       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   524         by (intro inf_mono insert order_refl)
   525       finally show ?case
   526         by simp
   527     qed simp }
   528   then show ?thesis
   529     unfolding le_filter_def eventually_filtermap
   530     by (subst (1 2) eventually_INF) auto
   531 qed
   532 subsubsection \<open>Standard filters\<close>
   533 
   534 definition principal :: "'a set \<Rightarrow> 'a filter" where
   535   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   536 
   537 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   538   unfolding principal_def
   539   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   540 
   541 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   542   unfolding eventually_inf eventually_principal by (auto elim: eventually_mono)
   543 
   544 lemma principal_UNIV[simp]: "principal UNIV = top"
   545   by (auto simp: filter_eq_iff eventually_principal)
   546 
   547 lemma principal_empty[simp]: "principal {} = bot"
   548   by (auto simp: filter_eq_iff eventually_principal)
   549 
   550 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   551   by (auto simp add: filter_eq_iff eventually_principal)
   552 
   553 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   554   by (auto simp: le_filter_def eventually_principal)
   555 
   556 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   557   unfolding le_filter_def eventually_principal
   558   apply safe
   559   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   560   apply (auto elim: eventually_mono)
   561   done
   562 
   563 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   564   unfolding eq_iff by simp
   565 
   566 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   567   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   568 
   569 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   570   unfolding filter_eq_iff eventually_inf eventually_principal
   571   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   572 
   573 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   574   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   575 
   576 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   577   by (induct X rule: finite_induct) auto
   578 
   579 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   580   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   581 
   582 subsubsection \<open>Order filters\<close>
   583 
   584 definition at_top :: "('a::order) filter"
   585   where "at_top = (INF k. principal {k ..})"
   586 
   587 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   588   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   589 
   590 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   591   unfolding at_top_def
   592   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   593 
   594 lemma eventually_ge_at_top:
   595   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   596   unfolding eventually_at_top_linorder by auto
   597 
   598 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   599 proof -
   600   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   601     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   602   also have "(INF k. principal {k::'a <..}) = at_top"
   603     unfolding at_top_def
   604     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   605   finally show ?thesis .
   606 qed
   607 
   608 lemma eventually_at_top_not_equal: "eventually (\<lambda>x::'a::{no_top, linorder}. x \<noteq> c) at_top"
   609   unfolding eventually_at_top_dense by auto
   610 
   611 lemma eventually_gt_at_top: "eventually (\<lambda>x. (c::_::{no_top, linorder}) < x) at_top"
   612   unfolding eventually_at_top_dense by auto
   613 
   614 lemma eventually_all_ge_at_top:
   615   assumes "eventually P (at_top :: ('a :: linorder) filter)"
   616   shows   "eventually (\<lambda>x. \<forall>y\<ge>x. P y) at_top"
   617 proof -
   618   from assms obtain x where "\<And>y. y \<ge> x \<Longrightarrow> P y" by (auto simp: eventually_at_top_linorder)
   619   hence "\<forall>z\<ge>y. P z" if "y \<ge> x" for y using that by simp
   620   thus ?thesis by (auto simp: eventually_at_top_linorder)
   621 qed
   622 
   623 definition at_bot :: "('a::order) filter"
   624   where "at_bot = (INF k. principal {.. k})"
   625 
   626 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   627   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   628 
   629 lemma eventually_at_bot_linorder:
   630   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   631   unfolding at_bot_def
   632   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   633 
   634 lemma eventually_le_at_bot:
   635   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   636   unfolding eventually_at_bot_linorder by auto
   637 
   638 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   639 proof -
   640   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   641     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   642   also have "(INF k. principal {..< k::'a}) = at_bot"
   643     unfolding at_bot_def
   644     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   645   finally show ?thesis .
   646 qed
   647 
   648 lemma eventually_at_bot_not_equal: "eventually (\<lambda>x::'a::{no_bot, linorder}. x \<noteq> c) at_bot"
   649   unfolding eventually_at_bot_dense by auto
   650 
   651 lemma eventually_gt_at_bot:
   652   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   653   unfolding eventually_at_bot_dense by auto
   654 
   655 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   656   unfolding trivial_limit_def
   657   by (metis eventually_at_bot_linorder order_refl)
   658 
   659 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   660   unfolding trivial_limit_def
   661   by (metis eventually_at_top_linorder order_refl)
   662 
   663 subsection \<open>Sequentially\<close>
   664 
   665 abbreviation sequentially :: "nat filter"
   666   where "sequentially \<equiv> at_top"
   667 
   668 lemma eventually_sequentially:
   669   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   670   by (rule eventually_at_top_linorder)
   671 
   672 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   673   unfolding filter_eq_iff eventually_sequentially by auto
   674 
   675 lemmas trivial_limit_sequentially = sequentially_bot
   676 
   677 lemma eventually_False_sequentially [simp]:
   678   "\<not> eventually (\<lambda>n. False) sequentially"
   679   by (simp add: eventually_False)
   680 
   681 lemma le_sequentially:
   682   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   683   by (simp add: at_top_def le_INF_iff le_principal)
   684 
   685 lemma eventually_sequentiallyI [intro?]:
   686   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   687   shows "eventually P sequentially"
   688 using assms by (auto simp: eventually_sequentially)
   689 
   690 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   691   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   692 
   693 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   694   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   695 
   696 
   697 subsection \<open>The cofinite filter\<close>
   698 
   699 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   700 
   701 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>\<^sub>\<infinity>" 10)
   702   where "Inf_many P \<equiv> frequently P cofinite"
   703 
   704 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<forall>\<^sub>\<infinity>" 10)
   705   where "Alm_all P \<equiv> eventually P cofinite"
   706 
   707 notation (ASCII)
   708   Inf_many  (binder "INFM " 10) and
   709   Alm_all  (binder "MOST " 10)
   710 
   711 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   712   unfolding cofinite_def
   713 proof (rule eventually_Abs_filter, rule is_filter.intro)
   714   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   715   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   716     by (rule rev_finite_subset) auto
   717 next
   718   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   719   from * show "finite {x. \<not> Q x}"
   720     by (intro finite_subset[OF _ P]) auto
   721 qed simp
   722 
   723 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   724   by (simp add: frequently_def eventually_cofinite)
   725 
   726 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   727   unfolding trivial_limit_def eventually_cofinite by simp
   728 
   729 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   730   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   731 proof safe
   732   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   733   show "\<exists>N. \<forall>n\<ge>N. P n"
   734   proof cases
   735     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   736       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   737   qed auto
   738 next
   739   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   740   then have "{x. \<not> P x} \<subseteq> {..< N}"
   741     by (auto simp: not_le)
   742   then show "finite {x. \<not> P x}"
   743     by (blast intro: finite_subset)
   744 qed
   745 
   746 subsection \<open>Limits\<close>
   747 
   748 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   749   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   750 
   751 syntax
   752   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   753 
   754 translations
   755   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   756 
   757 lemma filterlim_iff:
   758   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   759   unfolding filterlim_def le_filter_def eventually_filtermap ..
   760 
   761 lemma filterlim_compose:
   762   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   763   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   764 
   765 lemma filterlim_mono:
   766   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   767   unfolding filterlim_def by (metis filtermap_mono order_trans)
   768 
   769 lemma filterlim_ident: "LIM x F. x :> F"
   770   by (simp add: filterlim_def filtermap_ident)
   771 
   772 lemma filterlim_cong:
   773   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   774   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   775 
   776 lemma filterlim_mono_eventually:
   777   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
   778   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
   779   shows "filterlim f' F' G'"
   780   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
   781   apply (rule filterlim_mono[OF _ ord])
   782   apply fact
   783   done
   784 
   785 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
   786   apply (auto intro!: filtermap_mono) []
   787   apply (auto simp: le_filter_def eventually_filtermap)
   788   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
   789   apply auto
   790   done
   791 
   792 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
   793   by (simp add: filtermap_mono_strong eq_iff)
   794 
   795 lemma filtermap_fun_inverse:
   796   assumes g: "filterlim g F G"
   797   assumes f: "filterlim f G F"
   798   assumes ev: "eventually (\<lambda>x. f (g x) = x) G"
   799   shows "filtermap f F = G"
   800 proof (rule antisym)
   801   show "filtermap f F \<le> G"
   802     using f unfolding filterlim_def .
   803   have "G = filtermap f (filtermap g G)"
   804     using ev by (auto elim: eventually_elim2 simp: filter_eq_iff eventually_filtermap)
   805   also have "\<dots> \<le> filtermap f F"
   806     using g by (intro filtermap_mono) (simp add: filterlim_def)
   807   finally show "G \<le> filtermap f F" .
   808 qed
   809 
   810 lemma filterlim_principal:
   811   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   812   unfolding filterlim_def eventually_filtermap le_principal ..
   813 
   814 lemma filterlim_inf:
   815   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   816   unfolding filterlim_def by simp
   817 
   818 lemma filterlim_INF:
   819   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
   820   unfolding filterlim_def le_INF_iff ..
   821 
   822 lemma filterlim_INF_INF:
   823   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
   824   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
   825 
   826 lemma filterlim_base:
   827   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow>
   828     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
   829   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
   830 
   831 lemma filterlim_base_iff:
   832   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
   833   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
   834     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
   835   unfolding filterlim_INF filterlim_principal
   836 proof (subst eventually_INF_base)
   837   fix i j assume "i \<in> I" "j \<in> I"
   838   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
   839     by auto
   840 qed (auto simp: eventually_principal \<open>I \<noteq> {}\<close>)
   841 
   842 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   843   unfolding filterlim_def filtermap_filtermap ..
   844 
   845 lemma filterlim_sup:
   846   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   847   unfolding filterlim_def filtermap_sup by auto
   848 
   849 lemma filterlim_sequentially_Suc:
   850   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
   851   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
   852 
   853 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   854   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   855 
   856 lemma filterlim_If:
   857   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
   858     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
   859     LIM x F. if P x then f x else g x :> G"
   860   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
   861 
   862 subsection \<open>Limits to @{const at_top} and @{const at_bot}\<close>
   863 
   864 lemma filterlim_at_top:
   865   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   866   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
   867   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_mono)
   868 
   869 lemma filterlim_at_top_mono:
   870   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
   871     LIM x F. g x :> at_top"
   872   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
   873 
   874 lemma filterlim_at_top_dense:
   875   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
   876   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
   877   by (metis eventually_mono[of _ F] eventually_gt_at_top order_less_imp_le
   878             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
   879 
   880 lemma filterlim_at_top_ge:
   881   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   882   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
   883   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
   884 
   885 lemma filterlim_at_top_at_top:
   886   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
   887   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   888   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   889   assumes Q: "eventually Q at_top"
   890   assumes P: "eventually P at_top"
   891   shows "filterlim f at_top at_top"
   892 proof -
   893   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   894     unfolding eventually_at_top_linorder by auto
   895   show ?thesis
   896   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   897     fix z assume "x \<le> z"
   898     with x have "P z" by auto
   899     have "eventually (\<lambda>x. g z \<le> x) at_top"
   900       by (rule eventually_ge_at_top)
   901     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
   902       by eventually_elim (metis mono bij \<open>P z\<close>)
   903   qed
   904 qed
   905 
   906 lemma filterlim_at_top_gt:
   907   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   908   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
   909   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
   910 
   911 lemma filterlim_at_bot:
   912   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   913   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
   914   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_mono)
   915 
   916 lemma filterlim_at_bot_dense:
   917   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
   918   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
   919 proof (auto simp add: filterlim_at_bot[of f F])
   920   fix Z :: 'b
   921   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
   922   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
   923   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
   924   thus "eventually (\<lambda>x. f x < Z) F"
   925     apply (rule eventually_mono)
   926     using 1 by auto
   927   next
   928     fix Z :: 'b
   929     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
   930       by (drule spec [of _ Z], erule eventually_mono, auto simp add: less_imp_le)
   931 qed
   932 
   933 lemma filterlim_at_bot_le:
   934   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   935   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
   936   unfolding filterlim_at_bot
   937 proof safe
   938   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
   939   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
   940     by (auto elim!: eventually_mono)
   941 qed simp
   942 
   943 lemma filterlim_at_bot_lt:
   944   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   945   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
   946   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
   947 
   948 
   949 subsection \<open>Setup @{typ "'a filter"} for lifting and transfer\<close>
   950 
   951 context begin interpretation lifting_syntax .
   952 
   953 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
   954 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
   955 
   956 lemma rel_filter_eventually:
   957   "rel_filter R F G \<longleftrightarrow>
   958   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
   959 by(simp add: rel_filter_def eventually_def)
   960 
   961 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
   962 by(simp add: fun_eq_iff id_def filtermap_ident)
   963 
   964 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
   965 using filtermap_id unfolding id_def .
   966 
   967 lemma Quotient_filter [quot_map]:
   968   assumes Q: "Quotient R Abs Rep T"
   969   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
   970 unfolding Quotient_alt_def
   971 proof(intro conjI strip)
   972   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
   973     unfolding Quotient_alt_def by blast
   974 
   975   fix F G
   976   assume "rel_filter T F G"
   977   thus "filtermap Abs F = G" unfolding filter_eq_iff
   978     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
   979 next
   980   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
   981 
   982   fix F
   983   show "rel_filter T (filtermap Rep F) F"
   984     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
   985             del: iffI simp add: eventually_filtermap rel_filter_eventually)
   986 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
   987          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
   988 
   989 lemma eventually_parametric [transfer_rule]:
   990   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
   991 by(simp add: rel_fun_def rel_filter_eventually)
   992 
   993 lemma frequently_parametric [transfer_rule]:
   994   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
   995   unfolding frequently_def[abs_def] by transfer_prover
   996 
   997 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
   998 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
   999 
  1000 lemma rel_filter_mono [relator_mono]:
  1001   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  1002 unfolding rel_filter_eventually[abs_def]
  1003 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  1004 
  1005 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  1006 apply (simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  1007 apply (safe; metis)
  1008 done
  1009 
  1010 lemma is_filter_parametric_aux:
  1011   assumes "is_filter F"
  1012   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1013   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  1014   shows "is_filter G"
  1015 proof -
  1016   interpret is_filter F by fact
  1017   show ?thesis
  1018   proof
  1019     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  1020     thus "G (\<lambda>x. True)" by(simp add: True)
  1021   next
  1022     fix P' Q'
  1023     assume "G P'" "G Q'"
  1024     moreover
  1025     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1026     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1027     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  1028     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  1029     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  1030     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  1031   next
  1032     fix P' Q'
  1033     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  1034     moreover
  1035     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1036     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1037     have "F P = G P'" by transfer_prover
  1038     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1039     ultimately have "F Q" by(simp add: mono)
  1040     moreover have "F Q = G Q'" by transfer_prover
  1041     ultimately show "G Q'" by simp
  1042   qed
  1043 qed
  1044 
  1045 lemma is_filter_parametric [transfer_rule]:
  1046   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1047   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1048 apply(rule rel_funI)
  1049 apply(rule iffI)
  1050  apply(erule (3) is_filter_parametric_aux)
  1051 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1052 apply (simp_all add: rel_fun_def)
  1053 apply metis
  1054 done
  1055 
  1056 lemma left_total_rel_filter [transfer_rule]:
  1057   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1058   shows "left_total (rel_filter A)"
  1059 proof(rule left_totalI)
  1060   fix F :: "'a filter"
  1061   from bi_total_fun[OF bi_unique_fun[OF \<open>bi_total A\<close> bi_unique_eq] bi_total_eq]
  1062   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G"
  1063     unfolding  bi_total_def by blast
  1064   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1065   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1066   ultimately have "rel_filter A F (Abs_filter G)"
  1067     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1068   thus "\<exists>G. rel_filter A F G" ..
  1069 qed
  1070 
  1071 lemma right_total_rel_filter [transfer_rule]:
  1072   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1073 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1074 
  1075 lemma bi_total_rel_filter [transfer_rule]:
  1076   assumes "bi_total A" "bi_unique A"
  1077   shows "bi_total (rel_filter A)"
  1078 unfolding bi_total_alt_def using assms
  1079 by(simp add: left_total_rel_filter right_total_rel_filter)
  1080 
  1081 lemma left_unique_rel_filter [transfer_rule]:
  1082   assumes "left_unique A"
  1083   shows "left_unique (rel_filter A)"
  1084 proof(rule left_uniqueI)
  1085   fix F F' G
  1086   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1087   show "F = F'"
  1088     unfolding filter_eq_iff
  1089   proof
  1090     fix P :: "'a \<Rightarrow> bool"
  1091     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1092       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1093     have "eventually P F = eventually P' G"
  1094       and "eventually P F' = eventually P' G" by transfer_prover+
  1095     thus "eventually P F = eventually P F'" by simp
  1096   qed
  1097 qed
  1098 
  1099 lemma right_unique_rel_filter [transfer_rule]:
  1100   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1101 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1102 
  1103 lemma bi_unique_rel_filter [transfer_rule]:
  1104   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1105 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1106 
  1107 lemma top_filter_parametric [transfer_rule]:
  1108   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1109 by(simp add: rel_filter_eventually All_transfer)
  1110 
  1111 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1112 by(simp add: rel_filter_eventually rel_fun_def)
  1113 
  1114 lemma sup_filter_parametric [transfer_rule]:
  1115   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1116 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1117 
  1118 lemma Sup_filter_parametric [transfer_rule]:
  1119   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1120 proof(rule rel_funI)
  1121   fix S T
  1122   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1123   show "rel_filter A (Sup S) (Sup T)"
  1124     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1125 qed
  1126 
  1127 lemma principal_parametric [transfer_rule]:
  1128   "(rel_set A ===> rel_filter A) principal principal"
  1129 proof(rule rel_funI)
  1130   fix S S'
  1131   assume [transfer_rule]: "rel_set A S S'"
  1132   show "rel_filter A (principal S) (principal S')"
  1133     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1134 qed
  1135 
  1136 context
  1137   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1138   assumes [transfer_rule]: "bi_unique A"
  1139 begin
  1140 
  1141 lemma le_filter_parametric [transfer_rule]:
  1142   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1143 unfolding le_filter_def[abs_def] by transfer_prover
  1144 
  1145 lemma less_filter_parametric [transfer_rule]:
  1146   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1147 unfolding less_filter_def[abs_def] by transfer_prover
  1148 
  1149 context
  1150   assumes [transfer_rule]: "bi_total A"
  1151 begin
  1152 
  1153 lemma Inf_filter_parametric [transfer_rule]:
  1154   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1155 unfolding Inf_filter_def[abs_def] by transfer_prover
  1156 
  1157 lemma inf_filter_parametric [transfer_rule]:
  1158   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1159 proof(intro rel_funI)+
  1160   fix F F' G G'
  1161   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1162   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1163   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1164 qed
  1165 
  1166 end
  1167 
  1168 end
  1169 
  1170 end
  1171 
  1172 end