src/HOL/hologic.ML
author paulson
Sun Feb 15 10:46:37 2004 +0100 (2004-02-15)
changeset 14387 e96d5c42c4b0
parent 14103 afd168fdcd3a
child 15013 34264f5e4691
permissions -rw-r--r--
Polymorphic treatment of binary arithmetic using axclasses
     1 (*  Title:      HOL/hologic.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Abstract syntax operations for HOL.
     6 *)
     7 
     8 signature HOLOGIC =
     9 sig
    10   val typeS: sort
    11   val typeT: typ
    12   val read_cterm: Sign.sg -> string -> cterm
    13   val boolN: string
    14   val boolT: typ
    15   val false_const: term
    16   val true_const: term
    17   val not_const: term
    18   val mk_setT: typ -> typ
    19   val dest_setT: typ -> typ
    20   val mk_Trueprop: term -> term
    21   val dest_Trueprop: term -> term
    22   val conj: term
    23   val disj: term
    24   val imp: term
    25   val Not: term
    26   val mk_conj: term * term -> term
    27   val mk_disj: term * term -> term
    28   val mk_imp: term * term -> term
    29   val dest_imp: term -> term * term
    30   val dest_conj: term -> term list
    31   val dest_concls: term -> term list
    32   val eq_const: typ -> term
    33   val all_const: typ -> term
    34   val exists_const: typ -> term
    35   val Collect_const: typ -> term
    36   val mk_eq: term * term -> term
    37   val dest_eq: term -> term * term
    38   val mk_all: string * typ * term -> term
    39   val list_all: (string * typ) list * term -> term
    40   val mk_exists: string * typ * term -> term
    41   val mk_Collect: string * typ * term -> term
    42   val mk_mem: term * term -> term
    43   val dest_mem: term -> term * term
    44   val mk_UNIV: typ -> term
    45   val mk_binop: string -> term * term -> term
    46   val mk_binrel: string -> term * term -> term
    47   val dest_bin: string -> typ -> term -> term * term
    48   val unitT: typ
    49   val is_unitT: typ -> bool
    50   val unit: term
    51   val is_unit: term -> bool
    52   val mk_prodT: typ * typ -> typ
    53   val dest_prodT: typ -> typ * typ
    54   val pair_const: typ -> typ -> term
    55   val mk_prod: term * term -> term
    56   val dest_prod: term -> term * term
    57   val mk_fst: term -> term
    58   val mk_snd: term -> term
    59   val prodT_factors: typ -> typ list
    60   val split_const: typ * typ * typ -> term
    61   val mk_tuple: typ -> term list -> term
    62   val natT: typ
    63   val zero: term
    64   val is_zero: term -> bool
    65   val mk_Suc: term -> term
    66   val dest_Suc: term -> term
    67   val mk_nat: int -> term
    68   val dest_nat: term -> int
    69   val intT: typ
    70   val mk_int: int -> term
    71   val realT: typ
    72   val binT: typ
    73   val pls_const: term
    74   val min_const: term
    75   val bit_const: term
    76   val number_of_const: typ -> term
    77   val int_of: int list -> int
    78   val dest_binum: term -> int
    79   val mk_bin: int -> term
    80   val mk_list: ('a -> term) -> typ -> 'a list -> term
    81 end;
    82 
    83 
    84 structure HOLogic: HOLOGIC =
    85 struct
    86 
    87 (* HOL syntax *)
    88 
    89 val typeS: sort = ["HOL.type"];
    90 val typeT = TypeInfer.anyT typeS;
    91 
    92 fun read_cterm sg s = Thm.read_cterm sg (s, typeT);
    93 
    94 
    95 (* bool and set *)
    96 
    97 val boolN = "bool";
    98 val boolT = Type (boolN, []);
    99 
   100 val true_const =  Const ("True", boolT);
   101 val false_const = Const ("False", boolT);
   102 val not_const = Const ("Not", boolT --> boolT);
   103 
   104 fun mk_setT T = Type ("set", [T]);
   105 
   106 fun dest_setT (Type ("set", [T])) = T
   107   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   108 
   109 
   110 (* logic *)
   111 
   112 val Trueprop = Const ("Trueprop", boolT --> propT);
   113 
   114 fun mk_Trueprop P = Trueprop $ P;
   115 
   116 fun dest_Trueprop (Const ("Trueprop", _) $ P) = P
   117   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   118 
   119 
   120 val conj = Const ("op &", [boolT, boolT] ---> boolT)
   121 and disj = Const ("op |", [boolT, boolT] ---> boolT)
   122 and imp = Const ("op -->", [boolT, boolT] ---> boolT)
   123 and Not = Const ("Not", boolT --> boolT);
   124 
   125 fun mk_conj (t1, t2) = conj $ t1 $ t2
   126 and mk_disj (t1, t2) = disj $ t1 $ t2
   127 and mk_imp (t1, t2) = imp $ t1 $ t2;
   128 
   129 fun dest_imp (Const("op -->",_) $ A $ B) = (A, B)
   130   | dest_imp  t = raise TERM ("dest_imp", [t]);
   131 
   132 fun dest_conj (Const ("op &", _) $ t $ t') = t :: dest_conj t'
   133   | dest_conj t = [t];
   134 
   135 fun imp_concl_of t = imp_concl_of (#2 (dest_imp t)) handle TERM _ => t;
   136 val dest_concls = map imp_concl_of o dest_conj o dest_Trueprop;
   137 
   138 fun eq_const T = Const ("op =", [T, T] ---> boolT);
   139 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   140 
   141 fun dest_eq (Const ("op =", _) $ lhs $ rhs) = (lhs, rhs)
   142   | dest_eq t = raise TERM ("dest_eq", [t])
   143 
   144 fun all_const T = Const ("All", [T --> boolT] ---> boolT);
   145 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   146 val list_all = foldr (fn ((x, T), P) => all_const T $ Abs (x, T, P));
   147 
   148 fun exists_const T = Const ("Ex", [T --> boolT] ---> boolT);
   149 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   150 
   151 fun Collect_const T = Const ("Collect", [T --> boolT] ---> mk_setT T);
   152 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   153 
   154 fun mk_mem (x, A) =
   155   let val setT = fastype_of A in
   156     Const ("op :", [dest_setT setT, setT] ---> boolT) $ x $ A
   157   end;
   158 
   159 fun dest_mem (Const ("op :", _) $ x $ A) = (x, A)
   160   | dest_mem t = raise TERM ("dest_mem", [t]);
   161 
   162 fun mk_UNIV T = Const ("UNIV", mk_setT T);
   163 
   164 
   165 (* binary operations and relations *)
   166 
   167 fun mk_binop c (t, u) =
   168   let val T = fastype_of t in
   169     Const (c, [T, T] ---> T) $ t $ u
   170   end;
   171 
   172 fun mk_binrel c (t, u) =
   173   let val T = fastype_of t in
   174     Const (c, [T, T] ---> boolT) $ t $ u
   175   end;
   176 
   177 (*destruct the application of a binary operator. The dummyT case is a crude
   178   way of handling polymorphic operators.*)
   179 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   180       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   181       else raise TERM ("dest_bin " ^ c, [tm])
   182   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   183 
   184 
   185 (* unit *)
   186 
   187 val unitT = Type ("Product_Type.unit", []);
   188 
   189 fun is_unitT (Type ("Product_Type.unit", [])) = true
   190   | is_unitT _ = false;
   191 
   192 val unit = Const ("Product_Type.Unity", unitT);
   193 
   194 fun is_unit (Const ("Product_Type.Unity", _)) = true
   195   | is_unit _ = false;
   196 
   197 
   198 (* prod *)
   199 
   200 fun mk_prodT (T1, T2) = Type ("*", [T1, T2]);
   201 
   202 fun dest_prodT (Type ("*", [T1, T2])) = (T1, T2)
   203   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   204 
   205 fun pair_const T1 T2 = Const ("Pair", [T1, T2] ---> mk_prodT (T1, T2));
   206 
   207 fun mk_prod (t1, t2) =
   208   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   209     pair_const T1 T2 $ t1 $ t2
   210   end;
   211 
   212 fun dest_prod (Const ("Pair", _) $ t1 $ t2) = (t1, t2)
   213   | dest_prod t = raise TERM ("dest_prod", [t]);
   214 
   215 fun mk_fst p =
   216   let val pT = fastype_of p in
   217     Const ("fst", pT --> fst (dest_prodT pT)) $ p
   218   end;
   219 
   220 fun mk_snd p =
   221   let val pT = fastype_of p in
   222     Const ("snd", pT --> snd (dest_prodT pT)) $ p
   223   end;
   224 
   225 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   226 fun prodT_factors (Type ("*", [T1, T2])) = prodT_factors T1 @ prodT_factors T2
   227   | prodT_factors T = [T];
   228 
   229 fun split_const (Ta, Tb, Tc) = 
   230     Const ("split", [[Ta, Tb] ---> Tc, mk_prodT (Ta, Tb)] ---> Tc);
   231 
   232 (*Makes a nested tuple from a list, following the product type structure*)
   233 fun mk_tuple (Type ("*", [T1, T2])) tms = 
   234         mk_prod (mk_tuple T1 tms, 
   235                  mk_tuple T2 (drop (length (prodT_factors T1), tms)))
   236   | mk_tuple T (t::_) = t;
   237 
   238 
   239 
   240 (* proper tuples *)
   241 
   242 local  (*currently unused*)
   243 
   244 fun mk_tupleT Ts = foldr mk_prodT (Ts, unitT);
   245 
   246 fun dest_tupleT (Type ("Product_Type.unit", [])) = []
   247   | dest_tupleT (Type ("*", [T, U])) = T :: dest_tupleT U
   248   | dest_tupleT T = raise TYPE ("dest_tupleT", [T], []);
   249 
   250 fun mk_tuple ts = foldr mk_prod (ts, unit);
   251 
   252 fun dest_tuple (Const ("Product_Type.Unity", _)) = []
   253   | dest_tuple (Const ("Pair", _) $ t $ u) = t :: dest_tuple u
   254   | dest_tuple t = raise TERM ("dest_tuple", [t]);
   255 
   256 in val _ = unit end;
   257 
   258 
   259 (* nat *)
   260 
   261 val natT = Type ("nat", []);
   262 
   263 val zero = Const ("0", natT);
   264 
   265 fun is_zero (Const ("0", _)) = true
   266   | is_zero _ = false;
   267 
   268 fun mk_Suc t = Const ("Suc", natT --> natT) $ t;
   269 
   270 fun dest_Suc (Const ("Suc", _) $ t) = t
   271   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   272 
   273 fun mk_nat 0 = zero
   274   | mk_nat n = mk_Suc (mk_nat (n - 1));
   275 
   276 fun dest_nat (Const ("0", _)) = 0
   277   | dest_nat (Const ("Suc", _) $ t) = dest_nat t + 1
   278   | dest_nat t = raise TERM ("dest_nat", [t]);
   279 
   280 
   281 (* binary numerals *)
   282 
   283 val binT = Type ("Numeral.bin", []);
   284 
   285 val pls_const = Const ("Numeral.bin.Pls", binT)
   286 and min_const = Const ("Numeral.bin.Min", binT)
   287 and bit_const = Const ("Numeral.bin.Bit", [binT, boolT] ---> binT);
   288 
   289 fun number_of_const T = Const ("Numeral.number_of", binT --> T);
   290 
   291 
   292 fun int_of [] = 0
   293   | int_of (b :: bs) = b + 2 * int_of bs;
   294 
   295 fun dest_bit (Const ("False", _)) = 0
   296   | dest_bit (Const ("True", _)) = 1
   297   | dest_bit t = raise TERM("dest_bit", [t]);
   298 
   299 fun bin_of (Const ("Numeral.bin.Pls", _)) = []
   300   | bin_of (Const ("Numeral.bin.Min", _)) = [~1]
   301   | bin_of (Const ("Numeral.bin.Bit", _) $ bs $ b) = dest_bit b :: bin_of bs
   302   | bin_of t = raise TERM("bin_of", [t]);
   303 
   304 val dest_binum = int_of o bin_of;
   305 
   306 fun mk_bit 0 = false_const
   307   | mk_bit 1 = true_const
   308   | mk_bit _ = sys_error "mk_bit";
   309 
   310 fun mk_bin n =
   311   let
   312     fun bin_of 0  = []
   313       | bin_of ~1 = [~1]
   314       | bin_of n  = (n mod 2) :: bin_of (n div 2);
   315 
   316     fun term_of []   = pls_const
   317       | term_of [~1] = min_const
   318       | term_of (b :: bs) = bit_const $ term_of bs $ mk_bit b;
   319     in term_of (bin_of n) end;
   320 
   321 
   322 (* int *)
   323 
   324 val intT = Type ("IntDef.int", []);
   325 
   326 fun mk_int 0 = Const ("0", intT)
   327   | mk_int 1 = Const ("1", intT)
   328   | mk_int i = number_of_const intT $ mk_bin i;
   329 
   330 
   331 (* real *)
   332 
   333 val realT = Type("RealDef.real", []);
   334 
   335 
   336 (* list *)
   337 
   338 fun mk_list f T [] = Const ("List.list.Nil", Type ("List.list", [T]))
   339   | mk_list f T (x :: xs) = Const ("List.list.Cons",
   340       T --> Type ("List.list", [T]) --> Type ("List.list", [T])) $ f x $
   341         mk_list f T xs;
   342 
   343 end;