src/Pure/library.ML
author wenzelm
Wed Apr 04 00:11:13 2007 +0200 (2007-04-04)
changeset 22582 f315da9400fb
parent 22567 1565d476a9e2
child 22593 de39593f2948
permissions -rw-r--r--
removed obsolete scanwords (see obsolete tactic.ML:rename_tac for its only use);
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    27   val ? : bool * ('a -> 'a) -> 'a -> 'a
    28   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    29   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    30   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    31   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    32 
    33   (*exceptions*)
    34   exception EXCEPTION of exn * string
    35   val do_transform_failure: bool ref
    36   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    37   datatype 'a result = Result of 'a | Exn of exn
    38   val capture: ('a -> 'b) -> 'a -> 'b result
    39   val release: 'a result -> 'a
    40   val get_result: 'a result -> 'a option
    41   val get_exn: 'a result -> exn option
    42 
    43   (*errors*)
    44   exception SYS_ERROR of string
    45   val sys_error: string -> 'a
    46   exception ERROR of string
    47   val error: string -> 'a
    48   val cat_error: string -> string -> 'a
    49   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    50 
    51   (*pairs*)
    52   val pair: 'a -> 'b -> 'a * 'b
    53   val rpair: 'a -> 'b -> 'b * 'a
    54   val fst: 'a * 'b -> 'a
    55   val snd: 'a * 'b -> 'b
    56   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    57   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    58   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    59   val swap: 'a * 'b -> 'b * 'a
    60   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    61   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    62   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    63 
    64   (*booleans*)
    65   val equal: ''a -> ''a -> bool
    66   val not_equal: ''a -> ''a -> bool
    67   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    68   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    69   val exists: ('a -> bool) -> 'a list -> bool
    70   val forall: ('a -> bool) -> 'a list -> bool
    71   val set: bool ref -> bool
    72   val reset: bool ref -> bool
    73   val toggle: bool ref -> bool
    74   val change: 'a ref -> ('a -> 'a) -> unit
    75   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    76 
    77   (*lists*)
    78   exception UnequalLengths
    79   val single: 'a -> 'a list
    80   val the_single: 'a list -> 'a
    81   val singleton: ('a list -> 'b list) -> 'a -> 'b
    82   val apply: ('a -> 'a) list -> 'a -> 'a
    83   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    84   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    85   val flat: 'a list list -> 'a list
    86   val unflat: 'a list list -> 'b list -> 'b list list
    87   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    88   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    89   val maps: ('a -> 'b list) -> 'a list -> 'b list
    90   val chop: int -> 'a list -> 'a list * 'a list
    91   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    92   val nth: 'a list -> int -> 'a
    93   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    94   val nth_list: 'a list list -> int -> 'a list
    95   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    96   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    97   val split_last: 'a list -> 'a list * 'a
    98   val find_index: ('a -> bool) -> 'a list -> int
    99   val find_index_eq: ''a -> ''a list -> int
   100   val find_first: ('a -> bool) -> 'a list -> 'a option
   101   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   102   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   103   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   104   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   105   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   106   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   107   val ~~ : 'a list * 'b list -> ('a * 'b) list
   108   val split_list: ('a * 'b) list -> 'a list * 'b list
   109   val separate: 'a -> 'a list -> 'a list
   110   val replicate: int -> 'a -> 'a list
   111   val multiply: 'a list -> 'a list list -> 'a list list
   112   val product: 'a list -> 'b list -> ('a * 'b) list
   113   val filter: ('a -> bool) -> 'a list -> 'a list
   114   val filter_out: ('a -> bool) -> 'a list -> 'a list
   115   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   116   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   117   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   118   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   119   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   120   val prefixes1: 'a list -> 'a list list
   121   val prefixes: 'a list -> 'a list list
   122   val suffixes1: 'a list -> 'a list list
   123   val suffixes: 'a list -> 'a list list
   124 
   125   (*integers*)
   126   val gcd: IntInf.int * IntInf.int -> IntInf.int
   127   val lcm: IntInf.int * IntInf.int -> IntInf.int
   128   val inc: int ref -> int
   129   val dec: int ref -> int
   130   val upto: int * int -> int list
   131   val downto: int * int -> int list
   132   val downto0: int list * int -> bool
   133   val radixpand: int * int -> int list
   134   val radixstring: int * string * int -> string
   135   val string_of_int: int -> string
   136   val signed_string_of_int: int -> string
   137   val string_of_indexname: string * int -> string
   138   val read_intinf: int -> string list -> IntInf.int * string list
   139   val read_int: string list -> int * string list
   140   val oct_char: string -> string
   141 
   142   (*strings*)
   143   val nth_string: string -> int -> string
   144   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   145   val exists_string: (string -> bool) -> string -> bool
   146   val forall_string: (string -> bool) -> string -> bool
   147   val enclose: string -> string -> string -> string
   148   val unenclose: string -> string
   149   val quote: string -> string
   150   val space_implode: string -> string list -> string
   151   val commas: string list -> string
   152   val commas_quote: string list -> string
   153   val cat_lines: string list -> string
   154   val space_explode: string -> string -> string list
   155   val split_lines: string -> string list
   156   val prefix_lines: string -> string -> string
   157   val untabify: string list -> string list
   158   val prefix: string -> string -> string
   159   val suffix: string -> string -> string
   160   val unprefix: string -> string -> string
   161   val unsuffix: string -> string -> string
   162   val replicate_string: int -> string -> string
   163   val translate_string: (string -> string) -> string -> string
   164 
   165   (*lists as sets -- see also Pure/General/ord_list.ML*)
   166   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   167   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   168   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   169   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   170   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   171   val mem: ''a * ''a list -> bool
   172   val mem_int: int * int list -> bool
   173   val mem_string: string * string list -> bool
   174   val union: ''a list * ''a list -> ''a list
   175   val union_int: int list * int list -> int list
   176   val union_string: string list * string list -> string list
   177   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   178   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   179   val inter: ''a list * ''a list -> ''a list
   180   val inter_int: int list * int list -> int list
   181   val inter_string: string list * string list -> string list
   182   val subset: ''a list * ''a list -> bool
   183   val subset_int: int list * int list -> bool
   184   val subset_string: string list * string list -> bool
   185   val eq_set: ''a list * ''a list -> bool
   186   val eq_set_string: string list * string list -> bool
   187   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   188   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   189   val \ : ''a list * ''a -> ''a list
   190   val \\ : ''a list * ''a list -> ''a list
   191   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   192   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   193   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   194 
   195   (* lists as multisets *)
   196   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   197   val gen_submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   198 
   199   (*lists as tables -- see also Pure/General/alist.ML*)
   200   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   201   val merge_lists: ''a list -> ''a list -> ''a list
   202   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   203 
   204   (*balanced trees*)
   205   exception Balance
   206   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   207   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   208   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   209 
   210   (*orders*)
   211   val is_equal: order -> bool
   212   val rev_order: order -> order
   213   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   214   val int_ord: int * int -> order
   215   val string_ord: string * string -> order
   216   val fast_string_ord: string * string -> order
   217   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   218   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   219   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   220   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   221   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   222   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   223   val sort_strings: string list -> string list
   224   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   225 
   226   (*random numbers*)
   227   exception RANDOM
   228   val random: unit -> real
   229   val random_range: int -> int -> int
   230   val one_of: 'a list -> 'a
   231   val frequency: (int * 'a) list -> 'a
   232 
   233   (*current directory*)
   234   val cd: string -> unit
   235   val pwd: unit -> string
   236 
   237   (*misc*)
   238   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   239   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   240   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   241   val gensym: string -> string
   242   type stamp
   243   val stamp: unit -> stamp
   244   type serial
   245   val serial: unit -> serial
   246   val serial_string: unit -> string
   247   structure Object: sig type T end
   248 end;
   249 
   250 signature LIBRARY =
   251 sig
   252   include BASIC_LIBRARY
   253   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   254   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   255   val take: int * 'a list -> 'a list
   256   val drop: int * 'a list -> 'a list
   257   val last_elem: 'a list -> 'a
   258   val seq: ('a -> unit) -> 'a list -> unit
   259 end;
   260 
   261 structure Library: LIBRARY =
   262 struct
   263 
   264 (* functions *)
   265 
   266 fun I x = x;
   267 fun K x = fn _ => x;
   268 fun curry f x y = f (x, y);
   269 fun uncurry f (x, y) = f x y;
   270 
   271 (*application and structured results -- old version*)
   272 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   273 
   274 (*conditional application*)
   275 fun b ? f = fn x => if b then f x else x;
   276 
   277 (*composition with multiple args*)
   278 fun (f oo g) x y = f (g x y);
   279 fun (f ooo g) x y z = f (g x y z);
   280 fun (f oooo g) x y z w = f (g x y z w);
   281 
   282 (*function exponentiation: f(...(f x)...) with n applications of f*)
   283 fun funpow n f x =
   284   let fun rep (0, x) = x
   285         | rep (n, x) = rep (n - 1, f x)
   286   in rep (n, x) end;
   287 
   288 
   289 (* exceptions *)
   290 
   291 val do_transform_failure = ref true;
   292 
   293 fun transform_failure exn f x =
   294   if ! do_transform_failure then
   295     f x handle Interrupt => raise Interrupt | e => raise exn e
   296   else f x;
   297 
   298 exception EXCEPTION of exn * string;
   299 
   300 datatype 'a result =
   301   Result of 'a |
   302   Exn of exn;
   303 
   304 fun capture f x = Result (f x) handle e => Exn e;
   305 
   306 fun release (Result y) = y
   307   | release (Exn e) = raise e;
   308 
   309 fun get_result (Result x) = SOME x
   310   | get_result _ = NONE;
   311 
   312 fun get_exn (Exn exn) = SOME exn
   313   | get_exn _ = NONE;
   314 
   315 
   316 (* errors *)
   317 
   318 exception SYS_ERROR of string;
   319 fun sys_error msg = raise SYS_ERROR msg;
   320 
   321 exception ERROR of string;
   322 fun error msg = raise ERROR msg;
   323 
   324 fun cat_error "" msg = error msg
   325   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   326 
   327 fun assert_all pred list msg =
   328   let
   329     fun ass [] = ()
   330       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   331   in ass list end;
   332 
   333 
   334 (* pairs *)
   335 
   336 fun pair x y = (x, y);
   337 fun rpair x y = (y, x);
   338 
   339 fun fst (x, y) = x;
   340 fun snd (x, y) = y;
   341 
   342 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   343 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   344 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   345 
   346 fun swap (x, y) = (y, x);
   347 
   348 (*apply function to components*)
   349 fun apfst f (x, y) = (f x, y);
   350 fun apsnd f (x, y) = (x, f y);
   351 fun pairself f (x, y) = (f x, f y);
   352 
   353 
   354 (* booleans *)
   355 
   356 (*polymorphic equality*)
   357 fun equal x y = x = y;
   358 fun not_equal x y = x <> y;
   359 
   360 (*combining predicates*)
   361 fun p orf q = fn x => p x orelse q x;
   362 fun p andf q = fn x => p x andalso q x;
   363 
   364 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   365 fun exists (pred: 'a -> bool) : 'a list -> bool =
   366   let fun boolf [] = false
   367         | boolf (x :: xs) = pred x orelse boolf xs
   368   in boolf end;
   369 
   370 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   371 fun forall (pred: 'a -> bool) : 'a list -> bool =
   372   let fun boolf [] = true
   373         | boolf (x :: xs) = pred x andalso boolf xs
   374   in boolf end;
   375 
   376 
   377 (* flags *)
   378 
   379 fun set flag = (flag := true; true);
   380 fun reset flag = (flag := false; false);
   381 fun toggle flag = (flag := not (! flag); ! flag);
   382 
   383 fun change r f = r := f (! r);
   384 
   385 (*temporarily set flag during execution*)
   386 fun setmp flag value f x =
   387   let
   388     val orig_value = ! flag;
   389     val _ = flag := value;
   390     val result = capture f x;
   391     val _ = flag := orig_value;
   392   in release result end;
   393 
   394 
   395 
   396 (** lists **)
   397 
   398 exception UnequalLengths;
   399 
   400 fun single x = [x];
   401 
   402 fun the_single [x] = x
   403   | the_single _ = raise Empty;
   404 
   405 fun singleton f x = the_single (f [x]);
   406 
   407 fun apply [] x = x
   408   | apply (f :: fs) x = apply fs (f x);
   409 
   410 
   411 (* fold -- old versions *)
   412 
   413 (*the following versions of fold are designed to fit nicely with infixes*)
   414 
   415 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   416     for operators that associate to the left (TAIL RECURSIVE)*)
   417 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   418   let fun itl (e, [])  = e
   419         | itl (e, a::l) = itl (f(e, a), l)
   420   in  itl end;
   421 
   422 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   423     for operators that associate to the right (not tail recursive)*)
   424 fun foldr f (l, e) =
   425   let fun itr [] = e
   426         | itr (a::l) = f(a, itr l)
   427   in  itr l  end;
   428 
   429 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   430     for n > 0, operators that associate to the right (not tail recursive)*)
   431 fun foldr1 f [] = raise Empty
   432   | foldr1 f l =
   433       let fun itr [x] = x
   434             | itr (x::l) = f(x, itr l)
   435       in  itr l  end;
   436 
   437 fun foldl_map f =
   438   let
   439     fun fold_aux (x, []) = (x, [])
   440       | fold_aux (x, y :: ys) =
   441           let
   442             val (x', y') = f (x, y);
   443             val (x'', ys') = fold_aux (x', ys);
   444           in (x'', y' :: ys') end;
   445   in fold_aux end;
   446 
   447 
   448 (* basic list functions *)
   449 
   450 fun eq_list eq (list1, list2) =
   451   let
   452     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   453       | eq_lst _ = true;
   454   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   455 
   456 fun maps f [] = []
   457   | maps f (x :: xs) = f x @ maps f xs;
   458 
   459 fun chop n xs = unfold_rev n dest xs;
   460 
   461 (*take the first n elements from a list*)
   462 fun take (n, []) = []
   463   | take (n, x :: xs) =
   464       if n > 0 then x :: take (n - 1, xs) else [];
   465 
   466 (*drop the first n elements from a list*)
   467 fun drop (n, []) = []
   468   | drop (n, x :: xs) =
   469       if n > 0 then drop (n - 1, xs) else x :: xs;
   470 
   471 fun dropwhile P [] = []
   472   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   473 
   474 (*return nth element of a list, where 0 designates the first element;
   475   raise Subscript if list too short*)
   476 fun nth xs i = List.nth (xs, i);
   477 
   478 fun nth_list xss i = nth xss i handle Subscript => [];
   479 
   480 fun nth_map 0 f (x :: xs) = f x :: xs
   481   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   482   | nth_map _ _ [] = raise Subscript;
   483 
   484 fun map_index f =
   485   let
   486     fun mapp _ [] = []
   487       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   488   in mapp 0 end;
   489 
   490 fun fold_index f =
   491   let
   492     fun fold_aux _ [] y = y
   493       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   494   in fold_aux 0 end;
   495 
   496 val last_elem = List.last;
   497 
   498 (*rear decomposition*)
   499 fun split_last [] = raise Empty
   500   | split_last [x] = ([], x)
   501   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   502 
   503 (*find the position of an element in a list*)
   504 fun find_index pred =
   505   let fun find _ [] = ~1
   506         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   507   in find 0 end;
   508 
   509 fun find_index_eq x = find_index (equal x);
   510 
   511 (*find first element satisfying predicate*)
   512 fun find_first _ [] = NONE
   513   | find_first pred (x :: xs) =
   514       if pred x then SOME x else find_first pred xs;
   515 
   516 (*get first element by lookup function*)
   517 fun get_first _ [] = NONE
   518   | get_first f (x :: xs) =
   519       (case f x of
   520         NONE => get_first f xs
   521       | some => some);
   522 
   523 fun get_index f =
   524   let
   525     fun get _ [] = NONE
   526       | get i (x :: xs) =
   527           case f x
   528            of NONE => get (i + 1) xs
   529             | SOME y => SOME (i, y)
   530   in get 0 end;
   531 
   532 val flat = List.concat;
   533 
   534 fun unflat (xs :: xss) ys =
   535       let val (ps, qs) = chop (length xs) ys
   536       in ps :: unflat xss qs end
   537   | unflat [] [] = []
   538   | unflat _ _ = raise UnequalLengths;
   539 
   540 fun burrow f xss = unflat xss (f (flat xss));
   541 
   542 fun fold_burrow f xss s =
   543   apfst (unflat xss) (f (flat xss) s);
   544 
   545 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   546   (proc x1; ...; proc xn) for side effects*)
   547 val seq = List.app;
   548 
   549 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   550 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   551   | separate _ xs = xs;
   552 
   553 (*make the list [x, x, ..., x] of length n*)
   554 fun replicate n (x: 'a) : 'a list =
   555   let fun rep (0, xs) = xs
   556         | rep (n, xs) = rep (n - 1, x :: xs)
   557   in
   558     if n < 0 then raise Subscript
   559     else rep (n, [])
   560   end;
   561 
   562 fun translate_string f = String.translate (f o String.str);
   563 
   564 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   565 fun multiply [] _ = []
   566   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   567 
   568 (*direct product*)
   569 fun product _ [] = []
   570   | product [] _ = []
   571   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   572 
   573 
   574 (* filter *)
   575 
   576 (*copy the list preserving elements that satisfy the predicate*)
   577 val filter = List.filter;
   578 fun filter_out f = filter (not o f);
   579 val map_filter = List.mapPartial;
   580 
   581 
   582 (* lists of pairs *)
   583 
   584 exception UnequalLengths;
   585 
   586 fun map2 _ [] [] = []
   587   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   588   | map2 _ _ _ = raise UnequalLengths;
   589 
   590 fun fold2 f =
   591   let
   592     fun fold_aux [] [] z = z
   593       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   594       | fold_aux _ _ _ = raise UnequalLengths;
   595   in fold_aux end;
   596 
   597 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   598   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   599   | zip_options _ [] = []
   600   | zip_options [] _ = raise UnequalLengths;
   601 
   602 (*combine two lists forming a list of pairs:
   603   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   604 fun [] ~~ [] = []
   605   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   606   | _ ~~ _ = raise UnequalLengths;
   607 
   608 (*inverse of ~~; the old 'split':
   609   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   610 val split_list = ListPair.unzip;
   611 
   612 
   613 (* prefixes, suffixes *)
   614 
   615 fun is_prefix _ [] _ = true
   616   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   617   | is_prefix eq _ _ = false;
   618 
   619 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   620    where xi is the first element that does not satisfy the predicate*)
   621 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   622   let fun take (rxs, []) = (rev rxs, [])
   623         | take (rxs, x :: xs) =
   624             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   625   in  take([], xs)  end;
   626 
   627 fun chop_prefix eq ([], ys) = ([], ([], ys))
   628   | chop_prefix eq (xs, []) = ([], (xs, []))
   629   | chop_prefix eq (xs as x::xs', ys as y::ys') =
   630       if eq (x, y) then
   631         let val (ps', xys'') = chop_prefix eq (xs', ys')
   632         in (x::ps', xys'') end
   633       else ([], (xs, ys));
   634 
   635 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   636    where xi is the last element that does not satisfy the predicate*)
   637 fun take_suffix _ [] = ([], [])
   638   | take_suffix pred (x :: xs) =
   639       (case take_suffix pred xs of
   640         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   641       | (prfx, sffx) => (x :: prfx, sffx));
   642 
   643 fun prefixes1 [] = []
   644   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   645 
   646 fun prefixes xs = [] :: prefixes1 xs;
   647 
   648 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   649 fun suffixes xs = [] :: suffixes1 xs;
   650 
   651 (** integers **)
   652 
   653 fun gcd (x, y) =
   654   let fun gxd x y : IntInf.int =
   655     if y = IntInf.fromInt 0 then x else gxd y (x mod y)
   656   in if x < y then gxd y x else gxd x y end;
   657 
   658 fun lcm (x, y) = (x * y) div gcd (x, y);
   659 
   660 fun inc i = (i := ! i + 1; ! i);
   661 fun dec i = (i := ! i - 1; ! i);
   662 
   663 
   664 (* lists of integers *)
   665 
   666 (*make the list [from, from + 1, ..., to]*)
   667 fun (i upto j) =
   668   if i > j then [] else i :: (i + 1 upto j);
   669 
   670 (*make the list [from, from - 1, ..., to]*)
   671 fun (i downto j) =
   672   if i < j then [] else i :: (i - 1 downto j);
   673 
   674 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   675 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   676   | downto0 ([], n) = n = ~1;
   677 
   678 
   679 (* convert integers to strings *)
   680 
   681 (*expand the number in the given base;
   682   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   683 fun radixpand (base, num) : int list =
   684   let
   685     fun radix (n, tail) =
   686       if n < base then n :: tail
   687       else radix (n div base, (n mod base) :: tail)
   688   in radix (num, []) end;
   689 
   690 (*expands a number into a string of characters starting from "zerochar";
   691   example: radixstring (2, "0", 8) gives "1000"*)
   692 fun radixstring (base, zerochar, num) =
   693   let val offset = ord zerochar;
   694       fun chrof n = chr (offset + n)
   695   in implode (map chrof (radixpand (base, num))) end;
   696 
   697 
   698 val string_of_int = Int.toString;
   699 
   700 fun signed_string_of_int i =
   701   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   702 
   703 fun string_of_indexname (a,0) = a
   704   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   705 
   706 
   707 (* read integers *)
   708 
   709 fun read_intinf radix cs =
   710   let
   711     val zero = ord "0";
   712     val limit = zero + radix;
   713     fun scan (num, []) = (num, [])
   714       | scan (num, c :: cs) =
   715         if zero <= ord c andalso ord c < limit then
   716           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   717         else (num, c :: cs);
   718   in scan (IntInf.fromInt 0, cs) end;
   719 
   720 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   721 
   722 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   723 
   724 
   725 
   726 (** strings **)
   727 
   728 (* functions tuned for strings, avoiding explode *)
   729 
   730 fun nth_string str i =
   731   (case try String.substring (str, i, 1) of
   732     SOME s => s
   733   | NONE => raise Subscript);
   734 
   735 fun fold_string f str x0 =
   736   let
   737     val n = size str;
   738     fun iter (x, i) =
   739       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   740   in iter (x0, 0) end;
   741 
   742 fun exists_string pred str =
   743   let
   744     val n = size str;
   745     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   746   in ex 0 end;
   747 
   748 fun forall_string pred = not o exists_string (not o pred);
   749 
   750 (*enclose in brackets*)
   751 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   752 fun unenclose str = String.substring (str, 1, size str - 2);
   753 
   754 (*simple quoting (does not escape special chars)*)
   755 val quote = enclose "\"" "\"";
   756 
   757 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   758 fun space_implode a bs = implode (separate a bs);
   759 
   760 val commas = space_implode ", ";
   761 val commas_quote = commas o map quote;
   762 
   763 (*concatenate messages, one per line, into a string*)
   764 val cat_lines = space_implode "\n";
   765 
   766 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   767 fun space_explode _ "" = []
   768   | space_explode sep s = String.fields (fn c => str c = sep) s;
   769 
   770 val split_lines = space_explode "\n";
   771 
   772 fun prefix_lines "" txt = txt
   773   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   774 
   775 fun untabify chs =
   776   let
   777     val tab_width = 8;
   778 
   779     fun untab pos [] ys = rev ys
   780       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   781       | untab pos ("\t" :: xs) ys =
   782           let val d = tab_width - (pos mod tab_width)
   783           in untab (pos + d) xs (replicate d " " @ ys) end
   784       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   785   in
   786     if not (exists (fn c => c = "\t") chs) then chs
   787     else untab 0 chs []
   788   end;
   789 
   790 fun prefix prfx s = prfx ^ s;
   791 fun suffix sffx s = s ^ sffx;
   792 
   793 fun unprefix prfx s =
   794   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   795   else raise Fail "unprefix";
   796 
   797 fun unsuffix sffx s =
   798   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   799   else raise Fail "unsuffix";
   800 
   801 fun replicate_string 0 _ = ""
   802   | replicate_string 1 a = a
   803   | replicate_string k a =
   804       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   805       else replicate_string (k div 2) (a ^ a) ^ a;
   806 
   807 
   808 (** lists as sets -- see also Pure/General/ord_list.ML **)
   809 
   810 (*canonical member, insert, remove*)
   811 fun member eq list x =
   812   let
   813     fun memb [] = false
   814       | memb (y :: ys) = eq (x, y) orelse memb ys;
   815   in memb list end;
   816 
   817 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   818 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   819 
   820 fun subtract eq = fold (remove eq);
   821 
   822 fun merge _ ([], ys) = ys
   823   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   824 
   825 (*old-style infixes*)
   826 fun x mem xs = member (op =) xs x;
   827 fun (x: int) mem_int xs = member (op =) xs x;
   828 fun (x: string) mem_string xs = member (op =) xs x;
   829 
   830 
   831 (*union of sets represented as lists: no repetitions*)
   832 fun xs union [] = xs
   833   | [] union ys = ys
   834   | (x :: xs) union ys = xs union (insert (op =) x ys);
   835 
   836 (*union of sets, optimized version for ints*)
   837 fun (xs:int list) union_int [] = xs
   838   | [] union_int ys = ys
   839   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   840 
   841 (*union of sets, optimized version for strings*)
   842 fun (xs:string list) union_string [] = xs
   843   | [] union_string ys = ys
   844   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   845 
   846 (*generalized union*)
   847 fun gen_union eq (xs, []) = xs
   848   | gen_union eq ([], ys) = ys
   849   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   850 
   851 
   852 (*intersection*)
   853 fun [] inter ys = []
   854   | (x :: xs) inter ys =
   855       if x mem ys then x :: (xs inter ys) else xs inter ys;
   856 
   857 (*intersection, optimized version for ints*)
   858 fun ([]:int list) inter_int ys = []
   859   | (x :: xs) inter_int ys =
   860       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   861 
   862 (*intersection, optimized version for strings *)
   863 fun ([]:string list) inter_string ys = []
   864   | (x :: xs) inter_string ys =
   865       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   866 
   867 (*generalized intersection*)
   868 fun gen_inter eq ([], ys) = []
   869   | gen_inter eq (x::xs, ys) =
   870       if member eq ys x then x :: gen_inter eq (xs, ys)
   871       else gen_inter eq (xs, ys);
   872 
   873 
   874 (*subset*)
   875 fun [] subset ys = true
   876   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   877 
   878 (*subset, optimized version for ints*)
   879 fun ([]: int list) subset_int ys = true
   880   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   881 
   882 (*subset, optimized version for strings*)
   883 fun ([]: string list) subset_string ys = true
   884   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   885 
   886 (*set equality*)
   887 fun eq_set (xs, ys) =
   888   xs = ys orelse (xs subset ys andalso ys subset xs);
   889 
   890 (*set equality for strings*)
   891 fun eq_set_string ((xs: string list), ys) =
   892   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   893 
   894 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   895 
   896 fun gen_eq_set eq (xs, ys) =
   897   eq_list eq (xs, ys) orelse
   898     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   899 
   900 
   901 (*removing an element from a list WITHOUT duplicates*)
   902 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   903   | [] \ x = [];
   904 fun ys \\ xs = foldl (op \) (ys,xs);
   905 
   906 
   907 (*makes a list of the distinct members of the input; preserves order, takes
   908   first of equal elements*)
   909 fun distinct eq lst =
   910   let
   911     fun dist (rev_seen, []) = rev rev_seen
   912       | dist (rev_seen, x :: xs) =
   913           if member eq rev_seen x then dist (rev_seen, xs)
   914           else dist (x :: rev_seen, xs);
   915   in dist ([], lst) end;
   916 
   917 (*returns a list containing all repeated elements exactly once; preserves
   918   order, takes first of equal elements*)
   919 fun duplicates eq lst =
   920   let
   921     fun dups (rev_dups, []) = rev rev_dups
   922       | dups (rev_dups, x :: xs) =
   923           if member eq rev_dups x orelse not (member eq xs x) then
   924             dups (rev_dups, xs)
   925           else dups (x :: rev_dups, xs);
   926   in dups ([], lst) end;
   927 
   928 fun has_duplicates eq =
   929   let
   930     fun dups [] = false
   931       | dups (x :: xs) = member eq xs x orelse dups xs;
   932   in dups end;
   933 
   934 
   935 (** lists as multisets **)
   936 
   937 fun remove1 _ _ [] = raise Empty
   938   | remove1 eq y (x::xs) = if eq(y,x) then xs else x :: remove1 eq y xs;
   939 
   940 fun gen_submultiset _  ([],    _)  = true
   941   | gen_submultiset eq (x::xs, ys) =
   942       member eq ys x  andalso  gen_submultiset eq (xs, remove1 eq x ys);
   943 
   944 
   945 (** association lists -- legacy operations **)
   946 
   947 fun gen_merge_lists _ xs [] = xs
   948   | gen_merge_lists _ [] ys = ys
   949   | gen_merge_lists eq xs ys = xs @ filter_out (member eq xs) ys;
   950 
   951 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
   952 fun merge_alists xs = gen_merge_lists (eq_fst (op =)) xs;
   953 
   954 
   955 (** balanced trees **)
   956 
   957 exception Balance;      (*indicates non-positive argument to balancing fun*)
   958 
   959 (*balanced folding; avoids deep nesting*)
   960 fun fold_bal f [x] = x
   961   | fold_bal f [] = raise Balance
   962   | fold_bal f xs =
   963       let val (ps, qs) = chop (length xs div 2) xs
   964       in  f (fold_bal f ps, fold_bal f qs)  end;
   965 
   966 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   967 fun access_bal (f, g, x) n i =
   968   let fun acc n i =     (*1<=i<=n*)
   969           if n=1 then x else
   970           let val n2 = n div 2
   971           in  if i<=n2 then f (acc n2 i)
   972                        else g (acc (n-n2) (i-n2))
   973           end
   974   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   975 
   976 (*construct ALL such accesses; could try harder to share recursive calls!*)
   977 fun accesses_bal (f, g, x) n =
   978   let fun acc n =
   979           if n=1 then [x] else
   980           let val n2 = n div 2
   981               val acc2 = acc n2
   982           in  if n-n2=n2 then map f acc2 @ map g acc2
   983                          else map f acc2 @ map g (acc (n-n2)) end
   984   in  if 1<=n then acc n else raise Balance  end;
   985 
   986 
   987 
   988 (** orders **)
   989 
   990 fun is_equal EQUAL = true
   991   | is_equal _ = false;
   992 
   993 fun rev_order LESS = GREATER
   994   | rev_order EQUAL = EQUAL
   995   | rev_order GREATER = LESS;
   996 
   997 (*assume rel is a linear strict order*)
   998 fun make_ord rel (x, y) =
   999   if rel (x, y) then LESS
  1000   else if rel (y, x) then GREATER
  1001   else EQUAL;
  1002 
  1003 val int_ord = Int.compare;
  1004 val string_ord = String.compare;
  1005 
  1006 fun fast_string_ord (s1, s2) =
  1007   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1008 
  1009 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1010   | option_ord _ (NONE, NONE) = EQUAL
  1011   | option_ord _ (NONE, SOME _) = LESS
  1012   | option_ord _ (SOME _, NONE) = GREATER;
  1013 
  1014 (*lexicographic product*)
  1015 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1016   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1017 
  1018 (*dictionary order -- in general NOT well-founded!*)
  1019 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1020       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1021   | dict_ord _ ([], []) = EQUAL
  1022   | dict_ord _ ([], _ :: _) = LESS
  1023   | dict_ord _ (_ :: _, []) = GREATER;
  1024 
  1025 (*lexicographic product of lists*)
  1026 fun list_ord elem_ord (xs, ys) =
  1027   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1028 
  1029 
  1030 (* sorting *)
  1031 
  1032 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1033 fun quicksort unique ord =
  1034   let
  1035     fun qsort [] = []
  1036       | qsort (xs as [_]) = xs
  1037       | qsort (xs as [x, y]) =
  1038           (case ord (x, y) of
  1039             LESS => xs
  1040           | EQUAL => if unique then [x] else xs
  1041           | GREATER => [y, x])
  1042       | qsort xs =
  1043           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1044           in qsort lts @ eqs @ qsort gts end
  1045     and part _ [] = ([], [], [])
  1046       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1047     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1048       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1049       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1050       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1051   in qsort end;
  1052 
  1053 fun sort ord = quicksort false ord;
  1054 fun sort_distinct ord = quicksort true ord;
  1055 
  1056 val sort_strings = sort string_ord;
  1057 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1058 
  1059 
  1060 
  1061 (** random numbers **)
  1062 
  1063 exception RANDOM;
  1064 
  1065 fun rmod x y = x - y * Real.realFloor (x / y);
  1066 
  1067 local
  1068   val a = 16807.0;
  1069   val m = 2147483647.0;
  1070   val random_seed = ref 1.0;
  1071 in
  1072 
  1073 fun random () =
  1074   let val r = rmod (a * !random_seed) m
  1075   in (random_seed := r; r) end;
  1076 
  1077 end;
  1078 
  1079 fun random_range l h =
  1080   if h < l orelse l < 0 then raise RANDOM
  1081   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1082 
  1083 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1084 
  1085 fun frequency xs =
  1086   let
  1087     val sum = foldl op + (0, map fst xs);
  1088     fun pick n ((k: int, x) :: xs) =
  1089       if n <= k then x else pick (n - k) xs
  1090   in pick (random_range 1 sum) xs end;
  1091 
  1092 
  1093 (** current directory **)
  1094 
  1095 val cd = OS.FileSys.chDir;
  1096 val pwd = OS.FileSys.getDir;
  1097 
  1098 
  1099 
  1100 (** misc **)
  1101 
  1102 fun divide_and_conquer decomp x =
  1103   let val (ys, recomb) = decomp x
  1104   in recomb (map (divide_and_conquer decomp) ys) end;
  1105 
  1106 
  1107 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1108    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1109 fun partition_list p i j =
  1110   let fun part k xs =
  1111             if k>j then
  1112               (case xs of [] => []
  1113                          | _ => raise Fail "partition_list")
  1114             else
  1115             let val (ns, rest) = List.partition (p k) xs;
  1116             in  ns :: part(k+1)rest  end
  1117   in  part i end;
  1118 
  1119 fun partition_eq (eq:'a * 'a -> bool) =
  1120   let
  1121     fun part [] = []
  1122       | part (x :: ys) =
  1123           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1124           in (x::xs)::(part xs') end
  1125   in part end;
  1126 
  1127 
  1128 
  1129 (* generating identifiers *)
  1130 
  1131 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1132 local
  1133 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1134 fun gensym_char i =
  1135   if i<26 then chr (ord "A" + i)
  1136   else if i<52 then chr (ord "a" + i - 26)
  1137   else chr (ord "0" + i - 52);
  1138 
  1139 val char_vec = Vector.tabulate (62, gensym_char);
  1140 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1141 
  1142 val gensym_seed = ref 0;
  1143 
  1144 in
  1145   fun gensym pre = pre ^ newid (inc gensym_seed);
  1146 end;
  1147 
  1148 
  1149 (* stamps and serial numbers *)
  1150 
  1151 type stamp = unit ref;
  1152 val stamp: unit -> stamp = ref;
  1153 
  1154 type serial = int;
  1155 local val count = ref 0
  1156 in fun serial () = inc count end;
  1157 
  1158 val serial_string = string_of_int o serial;
  1159 
  1160 
  1161 (* generic objects *)
  1162 
  1163 (*note that the builtin exception datatype may be extended by new
  1164   constructors at any time*)
  1165 structure Object = struct type T = exn end;
  1166 
  1167 end;
  1168 
  1169 structure BasicLibrary: BASIC_LIBRARY = Library;
  1170 open BasicLibrary;