src/HOL/Library/Numeral_Type.thy
author haftmann
Wed Apr 22 19:09:21 2009 +0200 (2009-04-22)
changeset 30960 fec1a04b7220
parent 30729 461ee3e49ad3
child 31021 53642251a04f
permissions -rw-r--r--
power operation defined generic
     1 (*  Title:      HOL/Library/Numeral_Type.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Numeral Syntax for Types *}
     6 
     7 theory Numeral_Type
     8 imports Main
     9 begin
    10 
    11 subsection {* Preliminary lemmas *}
    12 (* These should be moved elsewhere *)
    13 
    14 lemma (in type_definition) univ:
    15   "UNIV = Abs ` A"
    16 proof
    17   show "Abs ` A \<subseteq> UNIV" by (rule subset_UNIV)
    18   show "UNIV \<subseteq> Abs ` A"
    19   proof
    20     fix x :: 'b
    21     have "x = Abs (Rep x)" by (rule Rep_inverse [symmetric])
    22     moreover have "Rep x \<in> A" by (rule Rep)
    23     ultimately show "x \<in> Abs ` A" by (rule image_eqI)
    24   qed
    25 qed
    26 
    27 lemma (in type_definition) card: "card (UNIV :: 'b set) = card A"
    28   by (simp add: univ card_image inj_on_def Abs_inject)
    29 
    30 
    31 subsection {* Cardinalities of types *}
    32 
    33 syntax "_type_card" :: "type => nat" ("(1CARD/(1'(_')))")
    34 
    35 translations "CARD(t)" => "CONST card (CONST UNIV \<Colon> t set)"
    36 
    37 typed_print_translation {*
    38 let
    39   fun card_univ_tr' show_sorts _ [Const (@{const_syntax UNIV}, Type(_,[T,_]))] =
    40     Syntax.const "_type_card" $ Syntax.term_of_typ show_sorts T;
    41 in [(@{const_syntax card}, card_univ_tr')]
    42 end
    43 *}
    44 
    45 lemma card_unit [simp]: "CARD(unit) = 1"
    46   unfolding UNIV_unit by simp
    47 
    48 lemma card_bool [simp]: "CARD(bool) = 2"
    49   unfolding UNIV_bool by simp
    50 
    51 lemma card_prod [simp]: "CARD('a \<times> 'b) = CARD('a::finite) * CARD('b::finite)"
    52   unfolding UNIV_Times_UNIV [symmetric] by (simp only: card_cartesian_product)
    53 
    54 lemma card_sum [simp]: "CARD('a + 'b) = CARD('a::finite) + CARD('b::finite)"
    55   unfolding UNIV_Plus_UNIV [symmetric] by (simp only: finite card_Plus)
    56 
    57 lemma card_option [simp]: "CARD('a option) = Suc CARD('a::finite)"
    58   unfolding insert_None_conv_UNIV [symmetric]
    59   apply (subgoal_tac "(None::'a option) \<notin> range Some")
    60   apply (simp add: card_image)
    61   apply fast
    62   done
    63 
    64 lemma card_set [simp]: "CARD('a set) = 2 ^ CARD('a::finite)"
    65   unfolding Pow_UNIV [symmetric]
    66   by (simp only: card_Pow finite numeral_2_eq_2)
    67 
    68 lemma card_nat [simp]: "CARD(nat) = 0"
    69   by (simp add: infinite_UNIV_nat card_eq_0_iff)
    70 
    71 
    72 subsection {* Classes with at least 1 and 2  *}
    73 
    74 text {* Class finite already captures "at least 1" *}
    75 
    76 lemma zero_less_card_finite [simp]: "0 < CARD('a::finite)"
    77   unfolding neq0_conv [symmetric] by simp
    78 
    79 lemma one_le_card_finite [simp]: "Suc 0 \<le> CARD('a::finite)"
    80   by (simp add: less_Suc_eq_le [symmetric])
    81 
    82 text {* Class for cardinality "at least 2" *}
    83 
    84 class card2 = finite + 
    85   assumes two_le_card: "2 \<le> CARD('a)"
    86 
    87 lemma one_less_card: "Suc 0 < CARD('a::card2)"
    88   using two_le_card [where 'a='a] by simp
    89 
    90 lemma one_less_int_card: "1 < int CARD('a::card2)"
    91   using one_less_card [where 'a='a] by simp
    92 
    93 
    94 subsection {* Numeral Types *}
    95 
    96 typedef (open) num0 = "UNIV :: nat set" ..
    97 typedef (open) num1 = "UNIV :: unit set" ..
    98 
    99 typedef (open) 'a bit0 = "{0 ..< 2 * int CARD('a::finite)}"
   100 proof
   101   show "0 \<in> {0 ..< 2 * int CARD('a)}"
   102     by simp
   103 qed
   104 
   105 typedef (open) 'a bit1 = "{0 ..< 1 + 2 * int CARD('a::finite)}"
   106 proof
   107   show "0 \<in> {0 ..< 1 + 2 * int CARD('a)}"
   108     by simp
   109 qed
   110 
   111 lemma card_num0 [simp]: "CARD (num0) = 0"
   112   unfolding type_definition.card [OF type_definition_num0]
   113   by simp
   114 
   115 lemma card_num1 [simp]: "CARD(num1) = 1"
   116   unfolding type_definition.card [OF type_definition_num1]
   117   by (simp only: card_unit)
   118 
   119 lemma card_bit0 [simp]: "CARD('a bit0) = 2 * CARD('a::finite)"
   120   unfolding type_definition.card [OF type_definition_bit0]
   121   by simp
   122 
   123 lemma card_bit1 [simp]: "CARD('a bit1) = Suc (2 * CARD('a::finite))"
   124   unfolding type_definition.card [OF type_definition_bit1]
   125   by simp
   126 
   127 instance num1 :: finite
   128 proof
   129   show "finite (UNIV::num1 set)"
   130     unfolding type_definition.univ [OF type_definition_num1]
   131     using finite by (rule finite_imageI)
   132 qed
   133 
   134 instance bit0 :: (finite) card2
   135 proof
   136   show "finite (UNIV::'a bit0 set)"
   137     unfolding type_definition.univ [OF type_definition_bit0]
   138     by simp
   139   show "2 \<le> CARD('a bit0)"
   140     by simp
   141 qed
   142 
   143 instance bit1 :: (finite) card2
   144 proof
   145   show "finite (UNIV::'a bit1 set)"
   146     unfolding type_definition.univ [OF type_definition_bit1]
   147     by simp
   148   show "2 \<le> CARD('a bit1)"
   149     by simp
   150 qed
   151 
   152 
   153 subsection {* Locale for modular arithmetic subtypes *}
   154 
   155 locale mod_type =
   156   fixes n :: int
   157   and Rep :: "'a::{zero,one,plus,times,uminus,minus} \<Rightarrow> int"
   158   and Abs :: "int \<Rightarrow> 'a::{zero,one,plus,times,uminus,minus}"
   159   assumes type: "type_definition Rep Abs {0..<n}"
   160   and size1: "1 < n"
   161   and zero_def: "0 = Abs 0"
   162   and one_def:  "1 = Abs 1"
   163   and add_def:  "x + y = Abs ((Rep x + Rep y) mod n)"
   164   and mult_def: "x * y = Abs ((Rep x * Rep y) mod n)"
   165   and diff_def: "x - y = Abs ((Rep x - Rep y) mod n)"
   166   and minus_def: "- x = Abs ((- Rep x) mod n)"
   167 begin
   168 
   169 lemma size0: "0 < n"
   170 by (cut_tac size1, simp)
   171 
   172 lemmas definitions =
   173   zero_def one_def add_def mult_def minus_def diff_def
   174 
   175 lemma Rep_less_n: "Rep x < n"
   176 by (rule type_definition.Rep [OF type, simplified, THEN conjunct2])
   177 
   178 lemma Rep_le_n: "Rep x \<le> n"
   179 by (rule Rep_less_n [THEN order_less_imp_le])
   180 
   181 lemma Rep_inject_sym: "x = y \<longleftrightarrow> Rep x = Rep y"
   182 by (rule type_definition.Rep_inject [OF type, symmetric])
   183 
   184 lemma Rep_inverse: "Abs (Rep x) = x"
   185 by (rule type_definition.Rep_inverse [OF type])
   186 
   187 lemma Abs_inverse: "m \<in> {0..<n} \<Longrightarrow> Rep (Abs m) = m"
   188 by (rule type_definition.Abs_inverse [OF type])
   189 
   190 lemma Rep_Abs_mod: "Rep (Abs (m mod n)) = m mod n"
   191 by (simp add: Abs_inverse IntDiv.pos_mod_conj [OF size0])
   192 
   193 lemma Rep_Abs_0: "Rep (Abs 0) = 0"
   194 by (simp add: Abs_inverse size0)
   195 
   196 lemma Rep_0: "Rep 0 = 0"
   197 by (simp add: zero_def Rep_Abs_0)
   198 
   199 lemma Rep_Abs_1: "Rep (Abs 1) = 1"
   200 by (simp add: Abs_inverse size1)
   201 
   202 lemma Rep_1: "Rep 1 = 1"
   203 by (simp add: one_def Rep_Abs_1)
   204 
   205 lemma Rep_mod: "Rep x mod n = Rep x"
   206 apply (rule_tac x=x in type_definition.Abs_cases [OF type])
   207 apply (simp add: type_definition.Abs_inverse [OF type])
   208 apply (simp add: mod_pos_pos_trivial)
   209 done
   210 
   211 lemmas Rep_simps =
   212   Rep_inject_sym Rep_inverse Rep_Abs_mod Rep_mod Rep_Abs_0 Rep_Abs_1
   213 
   214 lemma comm_ring_1: "OFCLASS('a, comm_ring_1_class)"
   215 apply (intro_classes, unfold definitions)
   216 apply (simp_all add: Rep_simps zmod_simps ring_simps)
   217 done
   218 
   219 lemma recpower: "OFCLASS('a, recpower_class)"
   220 apply (intro_classes, unfold definitions)
   221 apply (simp_all add: Rep_simps zmod_simps add_ac mult_assoc
   222                      mod_pos_pos_trivial size1)
   223 done
   224 
   225 end
   226 
   227 locale mod_ring = mod_type +
   228   constrains n :: int
   229   and Rep :: "'a::{number_ring} \<Rightarrow> int"
   230   and Abs :: "int \<Rightarrow> 'a::{number_ring}"
   231 begin
   232 
   233 lemma of_nat_eq: "of_nat k = Abs (int k mod n)"
   234 apply (induct k)
   235 apply (simp add: zero_def)
   236 apply (simp add: Rep_simps add_def one_def zmod_simps add_ac)
   237 done
   238 
   239 lemma of_int_eq: "of_int z = Abs (z mod n)"
   240 apply (cases z rule: int_diff_cases)
   241 apply (simp add: Rep_simps of_nat_eq diff_def zmod_simps)
   242 done
   243 
   244 lemma Rep_number_of:
   245   "Rep (number_of w) = number_of w mod n"
   246 by (simp add: number_of_eq of_int_eq Rep_Abs_mod)
   247 
   248 lemma iszero_number_of:
   249   "iszero (number_of w::'a) \<longleftrightarrow> number_of w mod n = 0"
   250 by (simp add: Rep_simps number_of_eq of_int_eq iszero_def zero_def)
   251 
   252 lemma cases:
   253   assumes 1: "\<And>z. \<lbrakk>(x::'a) = of_int z; 0 \<le> z; z < n\<rbrakk> \<Longrightarrow> P"
   254   shows "P"
   255 apply (cases x rule: type_definition.Abs_cases [OF type])
   256 apply (rule_tac z="y" in 1)
   257 apply (simp_all add: of_int_eq mod_pos_pos_trivial)
   258 done
   259 
   260 lemma induct:
   261   "(\<And>z. \<lbrakk>0 \<le> z; z < n\<rbrakk> \<Longrightarrow> P (of_int z)) \<Longrightarrow> P (x::'a)"
   262 by (cases x rule: cases) simp
   263 
   264 end
   265 
   266 
   267 subsection {* Number ring instances *}
   268 
   269 text {*
   270   Unfortunately a number ring instance is not possible for
   271   @{typ num1}, since 0 and 1 are not distinct.
   272 *}
   273 
   274 instantiation num1 :: "{comm_ring,comm_monoid_mult,number}"
   275 begin
   276 
   277 lemma num1_eq_iff: "(x::num1) = (y::num1) \<longleftrightarrow> True"
   278   by (induct x, induct y) simp
   279 
   280 instance proof
   281 qed (simp_all add: num1_eq_iff)
   282 
   283 end
   284 
   285 instantiation
   286   bit0 and bit1 :: (finite) "{zero,one,plus,times,uminus,minus}"
   287 begin
   288 
   289 definition Abs_bit0' :: "int \<Rightarrow> 'a bit0" where
   290   "Abs_bit0' x = Abs_bit0 (x mod int CARD('a bit0))"
   291 
   292 definition Abs_bit1' :: "int \<Rightarrow> 'a bit1" where
   293   "Abs_bit1' x = Abs_bit1 (x mod int CARD('a bit1))"
   294 
   295 definition "0 = Abs_bit0 0"
   296 definition "1 = Abs_bit0 1"
   297 definition "x + y = Abs_bit0' (Rep_bit0 x + Rep_bit0 y)"
   298 definition "x * y = Abs_bit0' (Rep_bit0 x * Rep_bit0 y)"
   299 definition "x - y = Abs_bit0' (Rep_bit0 x - Rep_bit0 y)"
   300 definition "- x = Abs_bit0' (- Rep_bit0 x)"
   301 
   302 definition "0 = Abs_bit1 0"
   303 definition "1 = Abs_bit1 1"
   304 definition "x + y = Abs_bit1' (Rep_bit1 x + Rep_bit1 y)"
   305 definition "x * y = Abs_bit1' (Rep_bit1 x * Rep_bit1 y)"
   306 definition "x - y = Abs_bit1' (Rep_bit1 x - Rep_bit1 y)"
   307 definition "- x = Abs_bit1' (- Rep_bit1 x)"
   308 
   309 instance ..
   310 
   311 end
   312 
   313 interpretation bit0:
   314   mod_type "int CARD('a::finite bit0)"
   315            "Rep_bit0 :: 'a::finite bit0 \<Rightarrow> int"
   316            "Abs_bit0 :: int \<Rightarrow> 'a::finite bit0"
   317 apply (rule mod_type.intro)
   318 apply (simp add: int_mult type_definition_bit0)
   319 apply (rule one_less_int_card)
   320 apply (rule zero_bit0_def)
   321 apply (rule one_bit0_def)
   322 apply (rule plus_bit0_def [unfolded Abs_bit0'_def])
   323 apply (rule times_bit0_def [unfolded Abs_bit0'_def])
   324 apply (rule minus_bit0_def [unfolded Abs_bit0'_def])
   325 apply (rule uminus_bit0_def [unfolded Abs_bit0'_def])
   326 done
   327 
   328 interpretation bit1:
   329   mod_type "int CARD('a::finite bit1)"
   330            "Rep_bit1 :: 'a::finite bit1 \<Rightarrow> int"
   331            "Abs_bit1 :: int \<Rightarrow> 'a::finite bit1"
   332 apply (rule mod_type.intro)
   333 apply (simp add: int_mult type_definition_bit1)
   334 apply (rule one_less_int_card)
   335 apply (rule zero_bit1_def)
   336 apply (rule one_bit1_def)
   337 apply (rule plus_bit1_def [unfolded Abs_bit1'_def])
   338 apply (rule times_bit1_def [unfolded Abs_bit1'_def])
   339 apply (rule minus_bit1_def [unfolded Abs_bit1'_def])
   340 apply (rule uminus_bit1_def [unfolded Abs_bit1'_def])
   341 done
   342 
   343 instance bit0 :: (finite) "{comm_ring_1,recpower}"
   344   by (rule bit0.comm_ring_1 bit0.recpower)+
   345 
   346 instance bit1 :: (finite) "{comm_ring_1,recpower}"
   347   by (rule bit1.comm_ring_1 bit1.recpower)+
   348 
   349 instantiation bit0 and bit1 :: (finite) number_ring
   350 begin
   351 
   352 definition "(number_of w :: _ bit0) = of_int w"
   353 
   354 definition "(number_of w :: _ bit1) = of_int w"
   355 
   356 instance proof
   357 qed (rule number_of_bit0_def number_of_bit1_def)+
   358 
   359 end
   360 
   361 interpretation bit0:
   362   mod_ring "int CARD('a::finite bit0)"
   363            "Rep_bit0 :: 'a::finite bit0 \<Rightarrow> int"
   364            "Abs_bit0 :: int \<Rightarrow> 'a::finite bit0"
   365   ..
   366 
   367 interpretation bit1:
   368   mod_ring "int CARD('a::finite bit1)"
   369            "Rep_bit1 :: 'a::finite bit1 \<Rightarrow> int"
   370            "Abs_bit1 :: int \<Rightarrow> 'a::finite bit1"
   371   ..
   372 
   373 text {* Set up cases, induction, and arithmetic *}
   374 
   375 lemmas bit0_cases [case_names of_int, cases type: bit0] = bit0.cases
   376 lemmas bit1_cases [case_names of_int, cases type: bit1] = bit1.cases
   377 
   378 lemmas bit0_induct [case_names of_int, induct type: bit0] = bit0.induct
   379 lemmas bit1_induct [case_names of_int, induct type: bit1] = bit1.induct
   380 
   381 lemmas bit0_iszero_number_of [simp] = bit0.iszero_number_of
   382 lemmas bit1_iszero_number_of [simp] = bit1.iszero_number_of
   383 
   384 
   385 subsection {* Syntax *}
   386 
   387 syntax
   388   "_NumeralType" :: "num_const => type"  ("_")
   389   "_NumeralType0" :: type ("0")
   390   "_NumeralType1" :: type ("1")
   391 
   392 translations
   393   "_NumeralType1" == (type) "num1"
   394   "_NumeralType0" == (type) "num0"
   395 
   396 parse_translation {*
   397 let
   398 
   399 val num1_const = Syntax.const "Numeral_Type.num1";
   400 val num0_const = Syntax.const "Numeral_Type.num0";
   401 val B0_const = Syntax.const "Numeral_Type.bit0";
   402 val B1_const = Syntax.const "Numeral_Type.bit1";
   403 
   404 fun mk_bintype n =
   405   let
   406     fun mk_bit n = if n = 0 then B0_const else B1_const;
   407     fun bin_of n =
   408       if n = 1 then num1_const
   409       else if n = 0 then num0_const
   410       else if n = ~1 then raise TERM ("negative type numeral", [])
   411       else
   412         let val (q, r) = Integer.div_mod n 2;
   413         in mk_bit r $ bin_of q end;
   414   in bin_of n end;
   415 
   416 fun numeral_tr (*"_NumeralType"*) [Const (str, _)] =
   417       mk_bintype (valOf (Int.fromString str))
   418   | numeral_tr (*"_NumeralType"*) ts = raise TERM ("numeral_tr", ts);
   419 
   420 in [("_NumeralType", numeral_tr)] end;
   421 *}
   422 
   423 print_translation {*
   424 let
   425 fun int_of [] = 0
   426   | int_of (b :: bs) = b + 2 * int_of bs;
   427 
   428 fun bin_of (Const ("num0", _)) = []
   429   | bin_of (Const ("num1", _)) = [1]
   430   | bin_of (Const ("bit0", _) $ bs) = 0 :: bin_of bs
   431   | bin_of (Const ("bit1", _) $ bs) = 1 :: bin_of bs
   432   | bin_of t = raise TERM("bin_of", [t]);
   433 
   434 fun bit_tr' b [t] =
   435   let
   436     val rev_digs = b :: bin_of t handle TERM _ => raise Match
   437     val i = int_of rev_digs;
   438     val num = string_of_int (abs i);
   439   in
   440     Syntax.const "_NumeralType" $ Syntax.free num
   441   end
   442   | bit_tr' b _ = raise Match;
   443 
   444 in [("bit0", bit_tr' 0), ("bit1", bit_tr' 1)] end;
   445 *}
   446 
   447 subsection {* Examples *}
   448 
   449 lemma "CARD(0) = 0" by simp
   450 lemma "CARD(17) = 17" by simp
   451 lemma "8 * 11 ^ 3 - 6 = (2::5)" by simp
   452 
   453 end