src/HOL/Word/Word.thy

clarified notation

(*  Title:      HOL/Word/Word.thy
    Author:     Jeremy Dawson and Gerwin Klein, NICTA
*)

section \<open>A type of finite bit strings\<close>

theory Word
imports
  "HOL-Library.Type_Length"
  "HOL-Library.Boolean_Algebra"
  Bits_Bit
  Bits_Int
  Misc_Typedef
  Misc_Arithmetic
begin

text \<open>See \<^file>\<open>Word_Examples.thy\<close> for examples.\<close>

subsection \<open>Type definition\<close>

typedef (overloaded) 'a word = "{(0::int) ..< 2 ^ LENGTH('a::len0)}"
  morphisms uint Abs_word by auto

lemma uint_nonnegative: "0 \<le> uint w"
  using word.uint [of w] by simp

lemma uint_bounded: "uint w < 2 ^ LENGTH('a)"
  for w :: "'a::len0 word"
  using word.uint [of w] by simp

lemma uint_idem: "uint w mod 2 ^ LENGTH('a) = uint w"
  for w :: "'a::len0 word"
  using uint_nonnegative uint_bounded by (rule mod_pos_pos_trivial)

lemma word_uint_eq_iff: "a = b \<longleftrightarrow> uint a = uint b"
  by (simp add: uint_inject)

lemma word_uint_eqI: "uint a = uint b \<Longrightarrow> a = b"
  by (simp add: word_uint_eq_iff)

definition word_of_int :: "int \<Rightarrow> 'a::len0 word"
  \<comment> \<open>representation of words using unsigned or signed bins,
    only difference in these is the type class\<close>
  where "word_of_int k = Abs_word (k mod 2 ^ LENGTH('a))"

lemma uint_word_of_int: "uint (word_of_int k :: 'a::len0 word) = k mod 2 ^ LENGTH('a)"
  by (auto simp add: word_of_int_def intro: Abs_word_inverse)

lemma word_of_int_uint: "word_of_int (uint w) = w"
  by (simp add: word_of_int_def uint_idem uint_inverse)

lemma split_word_all: "(\<And>x::'a::len0 word. PROP P x) \<equiv> (\<And>x. PROP P (word_of_int x))"
proof
  fix x :: "'a word"
  assume "\<And>x. PROP P (word_of_int x)"
  then have "PROP P (word_of_int (uint x))" .
  then show "PROP P x" by (simp add: word_of_int_uint)
qed


subsection \<open>Type conversions and casting\<close>

definition sint :: "'a::len word \<Rightarrow> int"
  \<comment> \<open>treats the most-significant-bit as a sign bit\<close>
  where sint_uint: "sint w = sbintrunc (LENGTH('a) - 1) (uint w)"

definition unat :: "'a::len0 word \<Rightarrow> nat"
  where "unat w = nat (uint w)"

definition uints :: "nat \<Rightarrow> int set"
  \<comment> \<open>the sets of integers representing the words\<close>
  where "uints n = range (bintrunc n)"

definition sints :: "nat \<Rightarrow> int set"
  where "sints n = range (sbintrunc (n - 1))"

lemma uints_num: "uints n = {i. 0 \<le> i \<and> i < 2 ^ n}"
  by (simp add: uints_def range_bintrunc)

lemma sints_num: "sints n = {i. - (2 ^ (n - 1)) \<le> i \<and> i < 2 ^ (n - 1)}"
  by (simp add: sints_def range_sbintrunc)

definition unats :: "nat \<Rightarrow> nat set"
  where "unats n = {i. i < 2 ^ n}"

definition norm_sint :: "nat \<Rightarrow> int \<Rightarrow> int"
  where "norm_sint n w = (w + 2 ^ (n - 1)) mod 2 ^ n - 2 ^ (n - 1)"

definition scast :: "'a::len word \<Rightarrow> 'b::len word"
  \<comment> \<open>cast a word to a different length\<close>
  where "scast w = word_of_int (sint w)"

definition ucast :: "'a::len0 word \<Rightarrow> 'b::len0 word"
  where "ucast w = word_of_int (uint w)"

instantiation word :: (len0) size
begin

definition word_size: "size (w :: 'a word) = LENGTH('a)"

instance ..

end

lemma word_size_gt_0 [iff]: "0 < size w"
  for w :: "'a::len word"
  by (simp add: word_size)

lemmas lens_gt_0 = word_size_gt_0 len_gt_0

lemma lens_not_0 [iff]:
  fixes w :: "'a::len word"
  shows "size w \<noteq> 0"
  and "LENGTH('a) \<noteq> 0"
  by auto

definition source_size :: "('a::len0 word \<Rightarrow> 'b) \<Rightarrow> nat"
  \<comment> \<open>whether a cast (or other) function is to a longer or shorter length\<close>
  where [code del]: "source_size c = (let arb = undefined; x = c arb in size arb)"

definition target_size :: "('a \<Rightarrow> 'b::len0 word) \<Rightarrow> nat"
  where [code del]: "target_size c = size (c undefined)"

definition is_up :: "('a::len0 word \<Rightarrow> 'b::len0 word) \<Rightarrow> bool"
  where "is_up c \<longleftrightarrow> source_size c \<le> target_size c"

definition is_down :: "('a::len0 word \<Rightarrow> 'b::len0 word) \<Rightarrow> bool"
  where "is_down c \<longleftrightarrow> target_size c \<le> source_size c"

definition of_bl :: "bool list \<Rightarrow> 'a::len0 word"
  where "of_bl bl = word_of_int (bl_to_bin bl)"

definition to_bl :: "'a::len0 word \<Rightarrow> bool list"
  where "to_bl w = bin_to_bl (LENGTH('a)) (uint w)"

definition word_reverse :: "'a::len0 word \<Rightarrow> 'a word"
  where "word_reverse w = of_bl (rev (to_bl w))"

definition word_int_case :: "(int \<Rightarrow> 'b) \<Rightarrow> 'a::len0 word \<Rightarrow> 'b"
  where "word_int_case f w = f (uint w)"

translations
  "case x of XCONST of_int y \<Rightarrow> b" \<rightleftharpoons> "CONST word_int_case (\<lambda>y. b) x"
  "case x of (XCONST of_int :: 'a) y \<Rightarrow> b" \<rightharpoonup> "CONST word_int_case (\<lambda>y. b) x"


subsection \<open>Correspondence relation for theorem transfer\<close>

definition cr_word :: "int \<Rightarrow> 'a::len0 word \<Rightarrow> bool"
  where "cr_word = (\<lambda>x y. word_of_int x = y)"

lemma Quotient_word:
  "Quotient (\<lambda>x y. bintrunc (LENGTH('a)) x = bintrunc (LENGTH('a)) y)
    word_of_int uint (cr_word :: _ \<Rightarrow> 'a::len0 word \<Rightarrow> bool)"
  unfolding Quotient_alt_def cr_word_def
  by (simp add: no_bintr_alt1 word_of_int_uint) (simp add: word_of_int_def Abs_word_inject)

lemma reflp_word:
  "reflp (\<lambda>x y. bintrunc (LENGTH('a::len0)) x = bintrunc (LENGTH('a)) y)"
  by (simp add: reflp_def)

setup_lifting Quotient_word reflp_word

text \<open>TODO: The next lemma could be generated automatically.\<close>

lemma uint_transfer [transfer_rule]:
  "(rel_fun pcr_word (=)) (bintrunc (LENGTH('a))) (uint :: 'a::len0 word \<Rightarrow> int)"
  unfolding rel_fun_def word.pcr_cr_eq cr_word_def
  by (simp add: no_bintr_alt1 uint_word_of_int)


subsection \<open>Basic code generation setup\<close>

definition Word :: "int \<Rightarrow> 'a::len0 word"
  where [code_post]: "Word = word_of_int"

lemma [code abstype]: "Word (uint w) = w"
  by (simp add: Word_def word_of_int_uint)

declare uint_word_of_int [code abstract]

instantiation word :: (len0) equal
begin

definition equal_word :: "'a word \<Rightarrow> 'a word \<Rightarrow> bool"
  where "equal_word k l \<longleftrightarrow> HOL.equal (uint k) (uint l)"

instance
  by standard (simp add: equal equal_word_def word_uint_eq_iff)

end

notation fcomp (infixl "\<circ>>" 60)
notation scomp (infixl "\<circ>\<rightarrow>" 60)

instantiation word :: ("{len0, typerep}") random
begin

definition
  "random_word i = Random.range i \<circ>\<rightarrow> (\<lambda>k. Pair (
     let j = word_of_int (int_of_integer (integer_of_natural k)) :: 'a word
     in (j, \<lambda>_::unit. Code_Evaluation.term_of j)))"

instance ..

end

no_notation fcomp (infixl "\<circ>>" 60)
no_notation scomp (infixl "\<circ>\<rightarrow>" 60)


subsection \<open>Type-definition locale instantiations\<close>

lemmas uint_0 = uint_nonnegative (* FIXME duplicate *)
lemmas uint_lt = uint_bounded (* FIXME duplicate *)
lemmas uint_mod_same = uint_idem (* FIXME duplicate *)

lemma td_ext_uint:
  "td_ext (uint :: 'a word \<Rightarrow> int) word_of_int (uints (LENGTH('a::len0)))
    (\<lambda>w::int. w mod 2 ^ LENGTH('a))"
  apply (unfold td_ext_def')
  apply (simp add: uints_num word_of_int_def bintrunc_mod2p)
  apply (simp add: uint_mod_same uint_0 uint_lt
                   word.uint_inverse word.Abs_word_inverse int_mod_lem)
  done

interpretation word_uint:
  td_ext
    "uint::'a::len0 word \<Rightarrow> int"
    word_of_int
    "uints (LENGTH('a::len0))"
    "\<lambda>w. w mod 2 ^ LENGTH('a::len0)"
  by (fact td_ext_uint)

lemmas td_uint = word_uint.td_thm
lemmas int_word_uint = word_uint.eq_norm

lemma td_ext_ubin:
  "td_ext (uint :: 'a word \<Rightarrow> int) word_of_int (uints (LENGTH('a::len0)))
    (bintrunc (LENGTH('a)))"
  by (unfold no_bintr_alt1) (fact td_ext_uint)

interpretation word_ubin:
  td_ext
    "uint::'a::len0 word \<Rightarrow> int"
    word_of_int
    "uints (LENGTH('a::len0))"
    "bintrunc (LENGTH('a::len0))"
  by (fact td_ext_ubin)


subsection \<open>Arithmetic operations\<close>

lift_definition word_succ :: "'a::len0 word \<Rightarrow> 'a word" is "\<lambda>x. x + 1"
  by (auto simp add: bintrunc_mod2p intro: mod_add_cong)

lift_definition word_pred :: "'a::len0 word \<Rightarrow> 'a word" is "\<lambda>x. x - 1"
  by (auto simp add: bintrunc_mod2p intro: mod_diff_cong)

instantiation word :: (len0) "{neg_numeral, modulo, comm_monoid_mult, comm_ring}"
begin

lift_definition zero_word :: "'a word" is "0" .

lift_definition one_word :: "'a word" is "1" .

lift_definition plus_word :: "'a word \<Rightarrow> 'a word \<Rightarrow> 'a word" is "(+)"
  by (auto simp add: bintrunc_mod2p intro: mod_add_cong)

lift_definition minus_word :: "'a word \<Rightarrow> 'a word \<Rightarrow> 'a word" is "(-)"
  by (auto simp add: bintrunc_mod2p intro: mod_diff_cong)

lift_definition uminus_word :: "'a word \<Rightarrow> 'a word" is uminus
  by (auto simp add: bintrunc_mod2p intro: mod_minus_cong)

lift_definition times_word :: "'a word \<Rightarrow> 'a word \<Rightarrow> 'a word" is "(*)"
  by (auto simp add: bintrunc_mod2p intro: mod_mult_cong)

definition word_div_def: "a div b = word_of_int (uint a div uint b)"

definition word_mod_def: "a mod b = word_of_int (uint a mod uint b)"

instance
  by standard (transfer, simp add: algebra_simps)+

end

text \<open>Legacy theorems:\<close>

lemma word_arith_wis [code]:
  shows word_add_def: "a + b = word_of_int (uint a + uint b)"
    and word_sub_wi: "a - b = word_of_int (uint a - uint b)"
    and word_mult_def: "a * b = word_of_int (uint a * uint b)"
    and word_minus_def: "- a = word_of_int (- uint a)"
    and word_succ_alt: "word_succ a = word_of_int (uint a + 1)"
    and word_pred_alt: "word_pred a = word_of_int (uint a - 1)"
    and word_0_wi: "0 = word_of_int 0"
    and word_1_wi: "1 = word_of_int 1"
  unfolding plus_word_def minus_word_def times_word_def uminus_word_def
  unfolding word_succ_def word_pred_def zero_word_def one_word_def
  by simp_all

lemma wi_homs:
  shows wi_hom_add: "word_of_int a + word_of_int b = word_of_int (a + b)"
    and wi_hom_sub: "word_of_int a - word_of_int b = word_of_int (a - b)"
    and wi_hom_mult: "word_of_int a * word_of_int b = word_of_int (a * b)"
    and wi_hom_neg: "- word_of_int a = word_of_int (- a)"
    and wi_hom_succ: "word_succ (word_of_int a) = word_of_int (a + 1)"
    and wi_hom_pred: "word_pred (word_of_int a) = word_of_int (a - 1)"
  by (transfer, simp)+

lemmas wi_hom_syms = wi_homs [symmetric]

lemmas word_of_int_homs = wi_homs word_0_wi word_1_wi

lemmas word_of_int_hom_syms = word_of_int_homs [symmetric]

instance word :: (len) comm_ring_1
proof
  have *: "0 < LENGTH('a)" by (rule len_gt_0)
  show "(0::'a word) \<noteq> 1"
    by transfer (use * in \<open>auto simp add: gr0_conv_Suc\<close>)
qed

lemma word_of_nat: "of_nat n = word_of_int (int n)"
  by (induct n) (auto simp add : word_of_int_hom_syms)

lemma word_of_int: "of_int = word_of_int"
  apply (rule ext)
  apply (case_tac x rule: int_diff_cases)
  apply (simp add: word_of_nat wi_hom_sub)
  done

definition udvd :: "'a::len word \<Rightarrow> 'a::len word \<Rightarrow> bool" (infixl "udvd" 50)
  where "a udvd b = (\<exists>n\<ge>0. uint b = n * uint a)"


subsection \<open>Ordering\<close>

instantiation word :: (len0) linorder
begin

definition word_le_def: "a \<le> b \<longleftrightarrow> uint a \<le> uint b"

definition word_less_def: "a < b \<longleftrightarrow> uint a < uint b"

instance
  by standard (auto simp: word_less_def word_le_def)

end

definition word_sle :: "'a::len word \<Rightarrow> 'a word \<Rightarrow> bool"  ("(_/ <=s _)" [50, 51] 50)
  where "a <=s b \<longleftrightarrow> sint a \<le> sint b"

definition word_sless :: "'a::len word \<Rightarrow> 'a word \<Rightarrow> bool"  ("(_/ <s _)" [50, 51] 50)
  where "x <s y \<longleftrightarrow> x <=s y \<and> x \<noteq> y"


subsection \<open>Bit-wise operations\<close>

instantiation word :: (len0) bits
begin

lift_definition bitNOT_word :: "'a word \<Rightarrow> 'a word" is bitNOT
  by (metis bin_trunc_not)

lift_definition bitAND_word :: "'a word \<Rightarrow> 'a word \<Rightarrow> 'a word" is bitAND
  by (metis bin_trunc_and)

lift_definition bitOR_word :: "'a word \<Rightarrow> 'a word \<Rightarrow> 'a word" is bitOR
  by (metis bin_trunc_or)

lift_definition bitXOR_word :: "'a word \<Rightarrow> 'a word \<Rightarrow> 'a word" is bitXOR
  by (metis bin_trunc_xor)

definition word_test_bit_def: "test_bit a = bin_nth (uint a)"

definition word_set_bit_def: "set_bit a n x = word_of_int (bin_sc n x (uint a))"

definition word_set_bits_def: "(BITS n. f n) = of_bl (bl_of_nth LENGTH('a) f)"

definition word_lsb_def: "lsb a \<longleftrightarrow> bin_last (uint a)"

definition "msb a \<longleftrightarrow> bin_sign (sbintrunc (LENGTH('a) - 1) (uint a)) = - 1"

definition shiftl1 :: "'a word \<Rightarrow> 'a word"
  where "shiftl1 w = word_of_int (uint w BIT False)"

definition shiftr1 :: "'a word \<Rightarrow> 'a word"
  \<comment> \<open>shift right as unsigned or as signed, ie logical or arithmetic\<close>
  where "shiftr1 w = word_of_int (bin_rest (uint w))"

definition shiftl_def: "w << n = (shiftl1 ^^ n) w"

definition shiftr_def: "w >> n = (shiftr1 ^^ n) w"

instance ..

end

lemma word_msb_def:
  "msb a \<longleftrightarrow> bin_sign (sint a) = - 1"
  by (simp add: msb_word_def sint_uint)

lemma [code]:
  shows word_not_def: "NOT (a::'a::len0 word) = word_of_int (NOT (uint a))"
    and word_and_def: "(a::'a word) AND b = word_of_int (uint a AND uint b)"
    and word_or_def: "(a::'a word) OR b = word_of_int (uint a OR uint b)"
    and word_xor_def: "(a::'a word) XOR b = word_of_int (uint a XOR uint b)"
  by (simp_all add: bitNOT_word_def bitAND_word_def bitOR_word_def bitXOR_word_def)

definition setBit :: "'a::len0 word \<Rightarrow> nat \<Rightarrow> 'a word"
  where "setBit w n = set_bit w n True"

definition clearBit :: "'a::len0 word \<Rightarrow> nat \<Rightarrow> 'a word"
  where "clearBit w n = set_bit w n False"


subsection \<open>Shift operations\<close>

definition sshiftr1 :: "'a::len word \<Rightarrow> 'a word"
  where "sshiftr1 w = word_of_int (bin_rest (sint w))"

definition bshiftr1 :: "bool \<Rightarrow> 'a::len word \<Rightarrow> 'a word"
  where "bshiftr1 b w = of_bl (b # butlast (to_bl w))"

definition sshiftr :: "'a::len word \<Rightarrow> nat \<Rightarrow> 'a word"  (infixl ">>>" 55)
  where "w >>> n = (sshiftr1 ^^ n) w"

definition mask :: "nat \<Rightarrow> 'a::len word"
  where "mask n = (1 << n) - 1"

definition revcast :: "'a::len0 word \<Rightarrow> 'b::len0 word"
  where "revcast w =  of_bl (takefill False (LENGTH('b)) (to_bl w))"

definition slice1 :: "nat \<Rightarrow> 'a::len0 word \<Rightarrow> 'b::len0 word"
  where "slice1 n w = of_bl (takefill False n (to_bl w))"

definition slice :: "nat \<Rightarrow> 'a::len0 word \<Rightarrow> 'b::len0 word"
  where "slice n w = slice1 (size w - n) w"


subsection \<open>Rotation\<close>

definition rotater1 :: "'a list \<Rightarrow> 'a list"
  where "rotater1 ys =
    (case ys of [] \<Rightarrow> [] | x # xs \<Rightarrow> last ys # butlast ys)"

definition rotater :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list"
  where "rotater n = rotater1 ^^ n"

definition word_rotr :: "nat \<Rightarrow> 'a::len0 word \<Rightarrow> 'a::len0 word"
  where "word_rotr n w = of_bl (rotater n (to_bl w))"

definition word_rotl :: "nat \<Rightarrow> 'a::len0 word \<Rightarrow> 'a::len0 word"
  where "word_rotl n w = of_bl (rotate n (to_bl w))"

definition word_roti :: "int \<Rightarrow> 'a::len0 word \<Rightarrow> 'a::len0 word"
  where "word_roti i w =
    (if i \<ge> 0 then word_rotr (nat i) w else word_rotl (nat (- i)) w)"


subsection \<open>Split and cat operations\<close>

definition word_cat :: "'a::len0 word \<Rightarrow> 'b::len0 word \<Rightarrow> 'c::len0 word"
  where "word_cat a b = word_of_int (bin_cat (uint a) (LENGTH('b)) (uint b))"

definition word_split :: "'a::len0 word \<Rightarrow> 'b::len0 word \<times> 'c::len0 word"
  where "word_split a =
    (case bin_split (LENGTH('c)) (uint a) of
      (u, v) \<Rightarrow> (word_of_int u, word_of_int v))"

definition word_rcat :: "'a::len0 word list \<Rightarrow> 'b::len0 word"
  where "word_rcat ws = word_of_int (bin_rcat (LENGTH('a)) (map uint ws))"

definition word_rsplit :: "'a::len0 word \<Rightarrow> 'b::len word list"
  where "word_rsplit w = map word_of_int (bin_rsplit (LENGTH('b)) (LENGTH('a), uint w))"

definition max_word :: "'a::len word"
  \<comment> \<open>Largest representable machine integer.\<close>
  where "max_word = word_of_int (2 ^ LENGTH('a) - 1)"

lemmas of_nth_def = word_set_bits_def (* FIXME duplicate *)


subsection \<open>Theorems about typedefs\<close>

lemma sint_sbintrunc': "sint (word_of_int bin :: 'a word) = sbintrunc (LENGTH('a::len) - 1) bin"
  by (auto simp: sint_uint word_ubin.eq_norm sbintrunc_bintrunc_lt)

lemma uint_sint: "uint w = bintrunc (LENGTH('a)) (sint w)"
  for w :: "'a::len word"
  by (auto simp: sint_uint bintrunc_sbintrunc_le)

lemma bintr_uint: "LENGTH('a) \<le> n \<Longrightarrow> bintrunc n (uint w) = uint w"
  for w :: "'a::len0 word"
  apply (subst word_ubin.norm_Rep [symmetric])
  apply (simp only: bintrunc_bintrunc_min word_size)
  apply (simp add: min.absorb2)
  done

lemma wi_bintr:
  "LENGTH('a::len0) \<le> n \<Longrightarrow>
    word_of_int (bintrunc n w) = (word_of_int w :: 'a word)"
  by (auto simp: word_ubin.norm_eq_iff [symmetric] min.absorb1)

lemma td_ext_sbin:
  "td_ext (sint :: 'a word \<Rightarrow> int) word_of_int (sints (LENGTH('a::len)))
    (sbintrunc (LENGTH('a) - 1))"
  apply (unfold td_ext_def' sint_uint)
  apply (simp add : word_ubin.eq_norm)
  apply (cases "LENGTH('a)")
   apply (auto simp add : sints_def)
  apply (rule sym [THEN trans])
   apply (rule word_ubin.Abs_norm)
  apply (simp only: bintrunc_sbintrunc)
  apply (drule sym)
  apply simp
  done

lemma td_ext_sint:
  "td_ext (sint :: 'a word \<Rightarrow> int) word_of_int (sints (LENGTH('a::len)))
     (\<lambda>w. (w + 2 ^ (LENGTH('a) - 1)) mod 2 ^ LENGTH('a) -
         2 ^ (LENGTH('a) - 1))"
  using td_ext_sbin [where ?'a = 'a] by (simp add: no_sbintr_alt2)

text \<open>
  We do \<open>sint\<close> before \<open>sbin\<close>, before \<open>sint\<close> is the user version
  and interpretations do not produce thm duplicates. I.e.
  we get the name \<open>word_sint.Rep_eqD\<close>, but not \<open>word_sbin.Req_eqD\<close>,
  because the latter is the same thm as the former.
\<close>
interpretation word_sint:
  td_ext
    "sint ::'a::len word \<Rightarrow> int"
    word_of_int
    "sints (LENGTH('a::len))"
    "\<lambda>w. (w + 2^(LENGTH('a::len) - 1)) mod 2^LENGTH('a::len) -
      2 ^ (LENGTH('a::len) - 1)"
  by (rule td_ext_sint)

interpretation word_sbin:
  td_ext
    "sint ::'a::len word \<Rightarrow> int"
    word_of_int
    "sints (LENGTH('a::len))"
    "sbintrunc (LENGTH('a::len) - 1)"
  by (rule td_ext_sbin)

lemmas int_word_sint = td_ext_sint [THEN td_ext.eq_norm]

lemmas td_sint = word_sint.td

lemma to_bl_def': "(to_bl :: 'a::len0 word \<Rightarrow> bool list) = bin_to_bl (LENGTH('a)) \<circ> uint"
  by (auto simp: to_bl_def)

lemmas word_reverse_no_def [simp] =
  word_reverse_def [of "numeral w"] for w

lemma uints_mod: "uints n = range (\<lambda>w. w mod 2 ^ n)"
  by (fact uints_def [unfolded no_bintr_alt1])

lemma word_numeral_alt: "numeral b = word_of_int (numeral b)"
  by (induct b, simp_all only: numeral.simps word_of_int_homs)

declare word_numeral_alt [symmetric, code_abbrev]

lemma word_neg_numeral_alt: "- numeral b = word_of_int (- numeral b)"
  by (simp only: word_numeral_alt wi_hom_neg)

declare word_neg_numeral_alt [symmetric, code_abbrev]

lemma word_numeral_transfer [transfer_rule]:
  "(rel_fun (=) pcr_word) numeral numeral"
  "(rel_fun (=) pcr_word) (- numeral) (- numeral)"
  apply (simp_all add: rel_fun_def word.pcr_cr_eq cr_word_def)
  using word_numeral_alt [symmetric] word_neg_numeral_alt [symmetric] by auto

lemma uint_bintrunc [simp]:
  "uint (numeral bin :: 'a word) =
    bintrunc (LENGTH('a::len0)) (numeral bin)"
  unfolding word_numeral_alt by (rule word_ubin.eq_norm)

lemma uint_bintrunc_neg [simp]:
  "uint (- numeral bin :: 'a word) = bintrunc (LENGTH('a::len0)) (- numeral bin)"
  by (simp only: word_neg_numeral_alt word_ubin.eq_norm)

lemma sint_sbintrunc [simp]:
  "sint (numeral bin :: 'a word) = sbintrunc (LENGTH('a::len) - 1) (numeral bin)"
  by (simp only: word_numeral_alt word_sbin.eq_norm)

lemma sint_sbintrunc_neg [simp]:
  "sint (- numeral bin :: 'a word) = sbintrunc (LENGTH('a::len) - 1) (- numeral bin)"
  by (simp only: word_neg_numeral_alt word_sbin.eq_norm)

lemma unat_bintrunc [simp]:
  "unat (numeral bin :: 'a::len0 word) = nat (bintrunc (LENGTH('a)) (numeral bin))"
  by (simp only: unat_def uint_bintrunc)

lemma unat_bintrunc_neg [simp]:
  "unat (- numeral bin :: 'a::len0 word) = nat (bintrunc (LENGTH('a)) (- numeral bin))"
  by (simp only: unat_def uint_bintrunc_neg)

lemma size_0_eq: "size w = 0 \<Longrightarrow> v = w"
  for v w :: "'a::len0 word"
  apply (unfold word_size)
  apply (rule word_uint.Rep_eqD)
  apply (rule box_equals)
    defer
    apply (rule word_ubin.norm_Rep)+
  apply simp
  done

lemma uint_ge_0 [iff]: "0 \<le> uint x"
  for x :: "'a::len0 word"
  using word_uint.Rep [of x] by (simp add: uints_num)

lemma uint_lt2p [iff]: "uint x < 2 ^ LENGTH('a)"
  for x :: "'a::len0 word"
  using word_uint.Rep [of x] by (simp add: uints_num)

lemma sint_ge: "- (2 ^ (LENGTH('a) - 1)) \<le> sint x"
  for x :: "'a::len word"
  using word_sint.Rep [of x] by (simp add: sints_num)

lemma sint_lt: "sint x < 2 ^ (LENGTH('a) - 1)"
  for x :: "'a::len word"
  using word_sint.Rep [of x] by (simp add: sints_num)

lemma sign_uint_Pls [simp]: "bin_sign (uint x) = 0"
  by (simp add: sign_Pls_ge_0)

lemma uint_m2p_neg: "uint x - 2 ^ LENGTH('a) < 0"
  for x :: "'a::len0 word"
  by (simp only: diff_less_0_iff_less uint_lt2p)

lemma uint_m2p_not_non_neg: "\<not> 0 \<le> uint x - 2 ^ LENGTH('a)"
  for x :: "'a::len0 word"
  by (simp only: not_le uint_m2p_neg)

lemma lt2p_lem: "LENGTH('a) \<le> n \<Longrightarrow> uint w < 2 ^ n"
  for w :: "'a::len0 word"
  by (metis bintr_uint bintrunc_mod2p int_mod_lem zless2p)

lemma uint_le_0_iff [simp]: "uint x \<le> 0 \<longleftrightarrow> uint x = 0"
  by (fact uint_ge_0 [THEN leD, THEN linorder_antisym_conv1])

lemma uint_nat: "uint w = int (unat w)"
  by (auto simp: unat_def)

lemma uint_numeral: "uint (numeral b :: 'a::len0 word) = numeral b mod 2 ^ LENGTH('a)"
  by (simp only: word_numeral_alt int_word_uint)

lemma uint_neg_numeral: "uint (- numeral b :: 'a::len0 word) = - numeral b mod 2 ^ LENGTH('a)"
  by (simp only: word_neg_numeral_alt int_word_uint)

lemma unat_numeral: "unat (numeral b :: 'a::len0 word) = numeral b mod 2 ^ LENGTH('a)"
  apply (unfold unat_def)
  apply (clarsimp simp only: uint_numeral)
  apply (rule nat_mod_distrib [THEN trans])
    apply (rule zero_le_numeral)
   apply (simp_all add: nat_power_eq)
  done

lemma sint_numeral:
  "sint (numeral b :: 'a::len word) =
    (numeral b +
      2 ^ (LENGTH('a) - 1)) mod 2 ^ LENGTH('a) -
      2 ^ (LENGTH('a) - 1)"
  unfolding word_numeral_alt by (rule int_word_sint)

lemma word_of_int_0 [simp, code_post]: "word_of_int 0 = 0"
  unfolding word_0_wi ..

lemma word_of_int_1 [simp, code_post]: "word_of_int 1 = 1"
  unfolding word_1_wi ..

lemma word_of_int_neg_1 [simp]: "word_of_int (- 1) = - 1"
  by (simp add: wi_hom_syms)

lemma word_of_int_numeral [simp] : "(word_of_int (numeral bin) :: 'a::len0 word) = numeral bin"
  by (simp only: word_numeral_alt)

lemma word_of_int_neg_numeral [simp]:
  "(word_of_int (- numeral bin) :: 'a::len0 word) = - numeral bin"
  by (simp only: word_numeral_alt wi_hom_syms)

lemma word_int_case_wi:
  "word_int_case f (word_of_int i :: 'b word) = f (i mod 2 ^ LENGTH('b::len0))"
  by (simp add: word_int_case_def word_uint.eq_norm)

lemma word_int_split:
  "P (word_int_case f x) =
    (\<forall>i. x = (word_of_int i :: 'b::len0 word) \<and> 0 \<le> i \<and> i < 2 ^ LENGTH('b) \<longrightarrow> P (f i))"
  by (auto simp: word_int_case_def word_uint.eq_norm mod_pos_pos_trivial)

lemma word_int_split_asm:
  "P (word_int_case f x) =
    (\<nexists>n. x = (word_of_int n :: 'b::len0 word) \<and> 0 \<le> n \<and> n < 2 ^ LENGTH('b::len0) \<and> \<not> P (f n))"
  by (auto simp: word_int_case_def word_uint.eq_norm mod_pos_pos_trivial)

lemmas uint_range' = word_uint.Rep [unfolded uints_num mem_Collect_eq]
lemmas sint_range' = word_sint.Rep [unfolded One_nat_def sints_num mem_Collect_eq]

lemma uint_range_size: "0 \<le> uint w \<and> uint w < 2 ^ size w"
  unfolding word_size by (rule uint_range')

lemma sint_range_size: "- (2 ^ (size w - Suc 0)) \<le> sint w \<and> sint w < 2 ^ (size w - Suc 0)"
  unfolding word_size by (rule sint_range')

lemma sint_above_size: "2 ^ (size w - 1) \<le> x \<Longrightarrow> sint w < x"
  for w :: "'a::len word"
  unfolding word_size by (rule less_le_trans [OF sint_lt])

lemma sint_below_size: "x \<le> - (2 ^ (size w - 1)) \<Longrightarrow> x \<le> sint w"
  for w :: "'a::len word"
  unfolding word_size by (rule order_trans [OF _ sint_ge])


subsection \<open>Testing bits\<close>

lemma test_bit_eq_iff: "test_bit u = test_bit v \<longleftrightarrow> u = v"
  for u v :: "'a::len0 word"
  unfolding word_test_bit_def by (simp add: bin_nth_eq_iff)

lemma test_bit_size [rule_format] : "w !! n \<longrightarrow> n < size w"
  for w :: "'a::len0 word"
  apply (unfold word_test_bit_def)
  apply (subst word_ubin.norm_Rep [symmetric])
  apply (simp only: nth_bintr word_size)
  apply fast
  done

lemma word_eq_iff: "x = y \<longleftrightarrow> (\<forall>n<LENGTH('a). x !! n = y !! n)"
  for x y :: "'a::len0 word"
  unfolding uint_inject [symmetric] bin_eq_iff word_test_bit_def [symmetric]
  by (metis test_bit_size [unfolded word_size])

lemma word_eqI: "(\<And>n. n < size u \<longrightarrow> u !! n = v !! n) \<Longrightarrow> u = v"
  for u :: "'a::len0 word"
  by (simp add: word_size word_eq_iff)

lemma word_eqD: "u = v \<Longrightarrow> u !! x = v !! x"
  for u v :: "'a::len0 word"
  by simp

lemma test_bit_bin': "w !! n \<longleftrightarrow> n < size w \<and> bin_nth (uint w) n"
  by (simp add: word_test_bit_def word_size nth_bintr [symmetric])

lemmas test_bit_bin = test_bit_bin' [unfolded word_size]

lemma bin_nth_uint_imp: "bin_nth (uint w) n \<Longrightarrow> n < LENGTH('a)"
  for w :: "'a::len0 word"
  apply (rule nth_bintr [THEN iffD1, THEN conjunct1])
  apply (subst word_ubin.norm_Rep)
  apply assumption
  done

lemma bin_nth_sint:
  "LENGTH('a) \<le> n \<Longrightarrow>
    bin_nth (sint w) n = bin_nth (sint w) (LENGTH('a) - 1)"
  for w :: "'a::len word"
  apply (subst word_sbin.norm_Rep [symmetric])
  apply (auto simp add: nth_sbintr)
  done

\<comment> \<open>type definitions theorem for in terms of equivalent bool list\<close>
lemma td_bl:
  "type_definition
    (to_bl :: 'a::len0 word \<Rightarrow> bool list)
    of_bl
    {bl. length bl = LENGTH('a)}"
  apply (unfold type_definition_def of_bl_def to_bl_def)
  apply (simp add: word_ubin.eq_norm)
  apply safe
  apply (drule sym)
  apply simp
  done

interpretation word_bl:
  type_definition
    "to_bl :: 'a::len0 word \<Rightarrow> bool list"
    of_bl
    "{bl. length bl = LENGTH('a::len0)}"
  by (fact td_bl)

lemmas word_bl_Rep' = word_bl.Rep [unfolded mem_Collect_eq, iff]

lemma word_size_bl: "size w = size (to_bl w)"
  by (auto simp: word_size)

lemma to_bl_use_of_bl: "to_bl w = bl \<longleftrightarrow> w = of_bl bl \<and> length bl = length (to_bl w)"
  by (fastforce elim!: word_bl.Abs_inverse [unfolded mem_Collect_eq])

lemma to_bl_word_rev: "to_bl (word_reverse w) = rev (to_bl w)"
  by (simp add: word_reverse_def word_bl.Abs_inverse)

lemma word_rev_rev [simp] : "word_reverse (word_reverse w) = w"
  by (simp add: word_reverse_def word_bl.Abs_inverse)

lemma word_rev_gal: "word_reverse w = u \<Longrightarrow> word_reverse u = w"
  by (metis word_rev_rev)

lemma word_rev_gal': "u = word_reverse w \<Longrightarrow> w = word_reverse u"
  by simp

lemma length_bl_gt_0 [iff]: "0 < length (to_bl x)"
  for x :: "'a::len word"
  unfolding word_bl_Rep' by (rule len_gt_0)

lemma bl_not_Nil [iff]: "to_bl x \<noteq> []"
  for x :: "'a::len word"
  by (fact length_bl_gt_0 [unfolded length_greater_0_conv])

lemma length_bl_neq_0 [iff]: "length (to_bl x) \<noteq> 0"
  for x :: "'a::len word"
  by (fact length_bl_gt_0 [THEN gr_implies_not0])

lemma hd_bl_sign_sint: "hd (to_bl w) = (bin_sign (sint w) = -1)"
  apply (unfold to_bl_def sint_uint)
  apply (rule trans [OF _ bl_sbin_sign])
  apply simp
  done

lemma of_bl_drop':
  "lend = length bl - LENGTH('a::len0) \<Longrightarrow>
    of_bl (drop lend bl) = (of_bl bl :: 'a word)"
  by (auto simp: of_bl_def trunc_bl2bin [symmetric])

lemma test_bit_of_bl:
  "(of_bl bl::'a::len0 word) !! n = (rev bl ! n \<and> n < LENGTH('a) \<and> n < length bl)"
  by (auto simp add: of_bl_def word_test_bit_def word_size
      word_ubin.eq_norm nth_bintr bin_nth_of_bl)

lemma no_of_bl: "(numeral bin ::'a::len0 word) = of_bl (bin_to_bl (LENGTH('a)) (numeral bin))"
  by (simp add: of_bl_def)

lemma uint_bl: "to_bl w = bin_to_bl (size w) (uint w)"
  by (auto simp: word_size to_bl_def)

lemma to_bl_bin: "bl_to_bin (to_bl w) = uint w"
  by (simp add: uint_bl word_size)

lemma to_bl_of_bin: "to_bl (word_of_int bin::'a::len0 word) = bin_to_bl (LENGTH('a)) bin"
  by (auto simp: uint_bl word_ubin.eq_norm word_size)

lemma to_bl_numeral [simp]:
  "to_bl (numeral bin::'a::len0 word) =
    bin_to_bl (LENGTH('a)) (numeral bin)"
  unfolding word_numeral_alt by (rule to_bl_of_bin)

lemma to_bl_neg_numeral [simp]:
  "to_bl (- numeral bin::'a::len0 word) =
    bin_to_bl (LENGTH('a)) (- numeral bin)"
  unfolding word_neg_numeral_alt by (rule to_bl_of_bin)

lemma to_bl_to_bin [simp] : "bl_to_bin (to_bl w) = uint w"
  by (simp add: uint_bl word_size)

lemma uint_bl_bin: "bl_to_bin (bin_to_bl (LENGTH('a)) (uint x)) = uint x"
  for x :: "'a::len0 word"
  by (rule trans [OF bin_bl_bin word_ubin.norm_Rep])

\<comment> \<open>naturals\<close>
lemma uints_unats: "uints n = int ` unats n"
  apply (unfold unats_def uints_num)
  apply safe
    apply (rule_tac image_eqI)
     apply (erule_tac nat_0_le [symmetric])
  by auto

lemma unats_uints: "unats n = nat ` uints n"
  by (auto simp: uints_unats image_iff)

lemmas bintr_num =
  word_ubin.norm_eq_iff [of "numeral a" "numeral b", symmetric, folded word_numeral_alt] for a b
lemmas sbintr_num =
  word_sbin.norm_eq_iff [of "numeral a" "numeral b", symmetric, folded word_numeral_alt] for a b

lemma num_of_bintr':
  "bintrunc (LENGTH('a::len0)) (numeral a) = (numeral b) \<Longrightarrow>
    numeral a = (numeral b :: 'a word)"
  unfolding bintr_num by (erule subst, simp)

lemma num_of_sbintr':
  "sbintrunc (LENGTH('a::len) - 1) (numeral a) = (numeral b) \<Longrightarrow>
    numeral a = (numeral b :: 'a word)"
  unfolding sbintr_num by (erule subst, simp)

lemma num_abs_bintr:
  "(numeral x :: 'a word) =
    word_of_int (bintrunc (LENGTH('a::len0)) (numeral x))"
  by (simp only: word_ubin.Abs_norm word_numeral_alt)

lemma num_abs_sbintr:
  "(numeral x :: 'a word) =
    word_of_int (sbintrunc (LENGTH('a::len) - 1) (numeral x))"
  by (simp only: word_sbin.Abs_norm word_numeral_alt)

text \<open>
  \<open>cast\<close> -- note, no arg for new length, as it's determined by type of result,
  thus in \<open>cast w = w\<close>, the type means cast to length of \<open>w\<close>!
\<close>

lemma ucast_id: "ucast w = w"
  by (auto simp: ucast_def)

lemma scast_id: "scast w = w"
  by (auto simp: scast_def)

lemma ucast_bl: "ucast w = of_bl (to_bl w)"
  by (auto simp: ucast_def of_bl_def uint_bl word_size)

lemma nth_ucast: "(ucast w::'a::len0 word) !! n = (w !! n \<and> n < LENGTH('a))"
  by (simp add: ucast_def test_bit_bin word_ubin.eq_norm nth_bintr word_size)
    (fast elim!: bin_nth_uint_imp)

\<comment> \<open>literal u(s)cast\<close>
lemma ucast_bintr [simp]:
  "ucast (numeral w :: 'a::len0 word) =
    word_of_int (bintrunc (LENGTH('a)) (numeral w))"
  by (simp add: ucast_def)

(* TODO: neg_numeral *)

lemma scast_sbintr [simp]:
  "scast (numeral w ::'a::len word) =
    word_of_int (sbintrunc (LENGTH('a) - Suc 0) (numeral w))"
  by (simp add: scast_def)

lemma source_size: "source_size (c::'a::len0 word \<Rightarrow> _) = LENGTH('a)"
  unfolding source_size_def word_size Let_def ..

lemma target_size: "target_size (c::_ \<Rightarrow> 'b::len0 word) = LENGTH('b)"
  unfolding target_size_def word_size Let_def ..

lemma is_down: "is_down c \<longleftrightarrow> LENGTH('b) \<le> LENGTH('a)"
  for c :: "'a::len0 word \<Rightarrow> 'b::len0 word"
  by (simp only: is_down_def source_size target_size)

lemma is_up: "is_up c \<longleftrightarrow> LENGTH('a) \<le> LENGTH('b)"
  for c :: "'a::len0 word \<Rightarrow> 'b::len0 word"
  by (simp only: is_up_def source_size target_size)

lemmas is_up_down = trans [OF is_up is_down [symmetric]]

lemma down_cast_same [OF refl]: "uc = ucast \<Longrightarrow> is_down uc \<Longrightarrow> uc = scast"
  apply (unfold is_down)
  apply safe
  apply (rule ext)
  apply (unfold ucast_def scast_def uint_sint)
  apply (rule word_ubin.norm_eq_iff [THEN iffD1])
  apply simp
  done

lemma word_rev_tf:
  "to_bl (of_bl bl::'a::len0 word) =
    rev (takefill False (LENGTH('a)) (rev bl))"
  by (auto simp: of_bl_def uint_bl bl_bin_bl_rtf word_ubin.eq_norm word_size)

lemma word_rep_drop:
  "to_bl (of_bl bl::'a::len0 word) =
    replicate (LENGTH('a) - length bl) False @
    drop (length bl - LENGTH('a)) bl"
  by (simp add: word_rev_tf takefill_alt rev_take)

lemma to_bl_ucast:
  "to_bl (ucast (w::'b::len0 word) ::'a::len0 word) =
    replicate (LENGTH('a) - LENGTH('b)) False @
    drop (LENGTH('b) - LENGTH('a)) (to_bl w)"
  apply (unfold ucast_bl)
  apply (rule trans)
   apply (rule word_rep_drop)
  apply simp
  done

lemma ucast_up_app [OF refl]:
  "uc = ucast \<Longrightarrow> source_size uc + n = target_size uc \<Longrightarrow>
    to_bl (uc w) = replicate n False @ (to_bl w)"
  by (auto simp add : source_size target_size to_bl_ucast)

lemma ucast_down_drop [OF refl]:
  "uc = ucast \<Longrightarrow> source_size uc = target_size uc + n \<Longrightarrow>
    to_bl (uc w) = drop n (to_bl w)"
  by (auto simp add : source_size target_size to_bl_ucast)

lemma scast_down_drop [OF refl]:
  "sc = scast \<Longrightarrow> source_size sc = target_size sc + n \<Longrightarrow>
    to_bl (sc w) = drop n (to_bl w)"
  apply (subgoal_tac "sc = ucast")
   apply safe
   apply simp
   apply (erule ucast_down_drop)
  apply (rule down_cast_same [symmetric])
  apply (simp add : source_size target_size is_down)
  done

lemma sint_up_scast [OF refl]: "sc = scast \<Longrightarrow> is_up sc \<Longrightarrow> sint (sc w) = sint w"
  apply (unfold is_up)
  apply safe
  apply (simp add: scast_def word_sbin.eq_norm)
  apply (rule box_equals)
    prefer 3
    apply (rule word_sbin.norm_Rep)
   apply (rule sbintrunc_sbintrunc_l)
   defer
   apply (subst word_sbin.norm_Rep)
   apply (rule refl)
  apply simp
  done

lemma uint_up_ucast [OF refl]: "uc = ucast \<Longrightarrow> is_up uc \<Longrightarrow> uint (uc w) = uint w"
  apply (unfold is_up)
  apply safe
  apply (rule bin_eqI)
  apply (fold word_test_bit_def)
  apply (auto simp add: nth_ucast)
  apply (auto simp add: test_bit_bin)
  done

lemma ucast_up_ucast [OF refl]: "uc = ucast \<Longrightarrow> is_up uc \<Longrightarrow> ucast (uc w) = ucast w"
  apply (simp (no_asm) add: ucast_def)
  apply (clarsimp simp add: uint_up_ucast)
  done

lemma scast_up_scast [OF refl]: "sc = scast \<Longrightarrow> is_up sc \<Longrightarrow> scast (sc w) = scast w"
  apply (simp (no_asm) add: scast_def)
  apply (clarsimp simp add: sint_up_scast)
  done

lemma ucast_of_bl_up [OF refl]: "w = of_bl bl \<Longrightarrow> size bl \<le> size w \<Longrightarrow> ucast w = of_bl bl"
  by (auto simp add : nth_ucast word_size test_bit_of_bl intro!: word_eqI)

lemmas ucast_up_ucast_id = trans [OF ucast_up_ucast ucast_id]
lemmas scast_up_scast_id = trans [OF scast_up_scast scast_id]

lemmas isduu = is_up_down [where c = "ucast", THEN iffD2]
lemmas isdus = is_up_down [where c = "scast", THEN iffD2]
lemmas ucast_down_ucast_id = isduu [THEN ucast_up_ucast_id]
lemmas scast_down_scast_id = isdus [THEN ucast_up_ucast_id]

lemma up_ucast_surj:
  "is_up (ucast :: 'b::len0 word \<Rightarrow> 'a::len0 word) \<Longrightarrow>
    surj (ucast :: 'a word \<Rightarrow> 'b word)"
  by (rule surjI) (erule ucast_up_ucast_id)

lemma up_scast_surj:
  "is_up (scast :: 'b::len word \<Rightarrow> 'a::len word) \<Longrightarrow>
    surj (scast :: 'a word \<Rightarrow> 'b word)"
  by (rule surjI) (erule scast_up_scast_id)

lemma down_scast_inj:
  "is_down (scast :: 'b::len word \<Rightarrow> 'a::len word) \<Longrightarrow>
    inj_on (ucast :: 'a word \<Rightarrow> 'b word) A"
  by (rule inj_on_inverseI, erule scast_down_scast_id)

lemma down_ucast_inj:
  "is_down (ucast :: 'b::len0 word \<Rightarrow> 'a::len0 word) \<Longrightarrow>
    inj_on (ucast :: 'a word \<Rightarrow> 'b word) A"
  by (rule inj_on_inverseI) (erule ucast_down_ucast_id)

lemma of_bl_append_same: "of_bl (X @ to_bl w) = w"
  by (rule word_bl.Rep_eqD) (simp add: word_rep_drop)

lemma ucast_down_wi [OF refl]: "uc = ucast \<Longrightarrow> is_down uc \<Longrightarrow> uc (word_of_int x) = word_of_int x"
  apply (unfold is_down)
  apply (clarsimp simp add: ucast_def word_ubin.eq_norm)
  apply (rule word_ubin.norm_eq_iff [THEN iffD1])
  apply (erule bintrunc_bintrunc_ge)
  done

lemma ucast_down_no [OF refl]: "uc = ucast \<Longrightarrow> is_down uc \<Longrightarrow> uc (numeral bin) = numeral bin"
  unfolding word_numeral_alt by clarify (rule ucast_down_wi)

lemma ucast_down_bl [OF refl]: "uc = ucast \<Longrightarrow> is_down uc \<Longrightarrow> uc (of_bl bl) = of_bl bl"
  unfolding of_bl_def by clarify (erule ucast_down_wi)

lemmas slice_def' = slice_def [unfolded word_size]
lemmas test_bit_def' = word_test_bit_def [THEN fun_cong]

lemmas word_log_defs = word_and_def word_or_def word_xor_def word_not_def


subsection \<open>Word Arithmetic\<close>

lemma word_less_alt: "a < b \<longleftrightarrow> uint a < uint b"
  by (fact word_less_def)

lemma signed_linorder: "class.linorder word_sle word_sless"
  by standard (auto simp: word_sle_def word_sless_def)

interpretation signed: linorder "word_sle" "word_sless"
  by (rule signed_linorder)

lemma udvdI: "0 \<le> n \<Longrightarrow> uint b = n * uint a \<Longrightarrow> a udvd b"
  by (auto simp: udvd_def)

lemmas word_div_no [simp] = word_div_def [of "numeral a" "numeral b"] for a b
lemmas word_mod_no [simp] = word_mod_def [of "numeral a" "numeral b"] for a b
lemmas word_less_no [simp] = word_less_def [of "numeral a" "numeral b"] for a b
lemmas word_le_no [simp] = word_le_def [of "numeral a" "numeral b"] for a b
lemmas word_sless_no [simp] = word_sless_def [of "numeral a" "numeral b"] for a b
lemmas word_sle_no [simp] = word_sle_def [of "numeral a" "numeral b"] for a b

lemma word_m1_wi: "- 1 = word_of_int (- 1)"
  by (simp add: word_neg_numeral_alt [of Num.One])

lemma word_0_bl [simp]: "of_bl [] = 0"
  by (simp add: of_bl_def)

lemma word_1_bl: "of_bl [True] = 1"
  by (simp add: of_bl_def bl_to_bin_def)

lemma uint_eq_0 [simp]: "uint 0 = 0"
  unfolding word_0_wi word_ubin.eq_norm by simp

lemma of_bl_0 [simp]: "of_bl (replicate n False) = 0"
  by (simp add: of_bl_def bl_to_bin_rep_False)

lemma to_bl_0 [simp]: "to_bl (0::'a::len0 word) = replicate (LENGTH('a)) False"
  by (simp add: uint_bl word_size bin_to_bl_zero)

lemma uint_0_iff: "uint x = 0 \<longleftrightarrow> x = 0"
  by (simp add: word_uint_eq_iff)

lemma unat_0_iff: "unat x = 0 \<longleftrightarrow> x = 0"
  by (auto simp: unat_def nat_eq_iff uint_0_iff)

lemma unat_0 [simp]: "unat 0 = 0"
  by (auto simp: unat_def)

lemma size_0_same': "size w = 0 \<Longrightarrow> w = v"
  for v w :: "'a::len0 word"
  apply (unfold word_size)
  apply (rule box_equals)
    defer
    apply (rule word_uint.Rep_inverse)+
  apply (rule word_ubin.norm_eq_iff [THEN iffD1])
  apply simp
  done

lemmas size_0_same = size_0_same' [unfolded word_size]

lemmas unat_eq_0 = unat_0_iff
lemmas unat_eq_zero = unat_0_iff

lemma unat_gt_0: "0 < unat x \<longleftrightarrow> x \<noteq> 0"
  by (auto simp: unat_0_iff [symmetric])

lemma ucast_0 [simp]: "ucast 0 = 0"
  by (simp add: ucast_def)

lemma sint_0 [simp]: "sint 0 = 0"
  by (simp add: sint_uint)

lemma scast_0 [simp]: "scast 0 = 0"
  by (simp add: scast_def)

lemma sint_n1 [simp] : "sint (- 1) = - 1"
  by (simp only: word_m1_wi word_sbin.eq_norm) simp

lemma scast_n1 [simp]: "scast (- 1) = - 1"
  by (simp add: scast_def)

lemma uint_1 [simp]: "uint (1::'a::len word) = 1"
  by (simp only: word_1_wi word_ubin.eq_norm) (simp add: bintrunc_minus_simps(4))

lemma unat_1 [simp]: "unat (1::'a::len word) = 1"
  by (simp add: unat_def)

lemma ucast_1 [simp]: "ucast (1::'a::len word) = 1"
  by (simp add: ucast_def)

\<comment> \<open>now, to get the weaker results analogous to \<open>word_div\<close>/\<open>mod_def\<close>\<close>


subsection \<open>Transferring goals from words to ints\<close>

lemma word_ths:
  shows word_succ_p1: "word_succ a = a + 1"
    and word_pred_m1: "word_pred a = a - 1"
    and word_pred_succ: "word_pred (word_succ a) = a"
    and word_succ_pred: "word_succ (word_pred a) = a"
    and word_mult_succ: "word_succ a * b = b + a * b"
  by (transfer, simp add: algebra_simps)+

lemma uint_cong: "x = y \<Longrightarrow> uint x = uint y"
  by simp

lemma uint_word_ariths:
  fixes a b :: "'a::len0 word"
  shows "uint (a + b) = (uint a + uint b) mod 2 ^ LENGTH('a::len0)"
    and "uint (a - b) = (uint a - uint b) mod 2 ^ LENGTH('a)"
    and "uint (a * b) = uint a * uint b mod 2 ^ LENGTH('a)"
    and "uint (- a) = - uint a mod 2 ^ LENGTH('a)"
    and "uint (word_succ a) = (uint a + 1) mod 2 ^ LENGTH('a)"
    and "uint (word_pred a) = (uint a - 1) mod 2 ^ LENGTH('a)"
    and "uint (0 :: 'a word) = 0 mod 2 ^ LENGTH('a)"
    and "uint (1 :: 'a word) = 1 mod 2 ^ LENGTH('a)"
  by (simp_all add: word_arith_wis [THEN trans [OF uint_cong int_word_uint]])

lemma uint_word_arith_bintrs:
  fixes a b :: "'a::len0 word"
  shows "uint (a + b) = bintrunc (LENGTH('a)) (uint a + uint b)"
    and "uint (a - b) = bintrunc (LENGTH('a)) (uint a - uint b)"
    and "uint (a * b) = bintrunc (LENGTH('a)) (uint a * uint b)"
    and "uint (- a) = bintrunc (LENGTH('a)) (- uint a)"
    and "uint (word_succ a) = bintrunc (LENGTH('a)) (uint a + 1)"
    and "uint (word_pred a) = bintrunc (LENGTH('a)) (uint a - 1)"
    and "uint (0 :: 'a word) = bintrunc (LENGTH('a)) 0"
    and "uint (1 :: 'a word) = bintrunc (LENGTH('a)) 1"
  by (simp_all add: uint_word_ariths bintrunc_mod2p)

lemma sint_word_ariths:
  fixes a b :: "'a::len word"
  shows "sint (a + b) = sbintrunc (LENGTH('a) - 1) (sint a + sint b)"
    and "sint (a - b) = sbintrunc (LENGTH('a) - 1) (sint a - sint b)"
    and "sint (a * b) = sbintrunc (LENGTH('a) - 1) (sint a * sint b)"
    and "sint (- a) = sbintrunc (LENGTH('a) - 1) (- sint a)"
    and "sint (word_succ a) = sbintrunc (LENGTH('a) - 1) (sint a + 1)"
    and "sint (word_pred a) = sbintrunc (LENGTH('a) - 1) (sint a - 1)"
    and "sint (0 :: 'a word) = sbintrunc (LENGTH('a) - 1) 0"
    and "sint (1 :: 'a word) = sbintrunc (LENGTH('a) - 1) 1"
         apply (simp_all only: word_sbin.inverse_norm [symmetric])
         apply (simp_all add: wi_hom_syms)
   apply transfer apply simp
  apply transfer apply simp
  done

lemmas uint_div_alt = word_div_def [THEN trans [OF uint_cong int_word_uint]]
lemmas uint_mod_alt = word_mod_def [THEN trans [OF uint_cong int_word_uint]]

lemma word_pred_0_n1: "word_pred 0 = word_of_int (- 1)"
  unfolding word_pred_m1 by simp

lemma succ_pred_no [simp]:
    "word_succ (numeral w) = numeral w + 1"
    "word_pred (numeral w) = numeral w - 1"
    "word_succ (- numeral w) = - numeral w + 1"
    "word_pred (- numeral w) = - numeral w - 1"
  by (simp_all add: word_succ_p1 word_pred_m1)

lemma word_sp_01 [simp]:
  "word_succ (- 1) = 0 \<and> word_succ 0 = 1 \<and> word_pred 0 = - 1 \<and> word_pred 1 = 0"
  by (simp_all add: word_succ_p1 word_pred_m1)

\<comment> \<open>alternative approach to lifting arithmetic equalities\<close>
lemma word_of_int_Ex: "\<exists>y. x = word_of_int y"
  by (rule_tac x="uint x" in exI) simp


subsection \<open>Order on fixed-length words\<close>

lemma word_zero_le [simp]: "0 \<le> y"
  for y :: "'a::len0 word"
  unfolding word_le_def by auto

lemma word_m1_ge [simp] : "word_pred 0 \<ge> y" (* FIXME: delete *)
  by (simp only: word_le_def word_pred_0_n1 word_uint.eq_norm m1mod2k) auto

lemma word_n1_ge [simp]: "y \<le> -1"
  for y :: "'a::len0 word"
  by (simp only: word_le_def word_m1_wi word_uint.eq_norm m1mod2k) auto

lemmas word_not_simps [simp] =
  word_zero_le [THEN leD] word_m1_ge [THEN leD] word_n1_ge [THEN leD]

lemma word_gt_0: "0 < y \<longleftrightarrow> 0 \<noteq> y"
  for y :: "'a::len0 word"
  by (simp add: less_le)

lemmas word_gt_0_no [simp] = word_gt_0 [of "numeral y"] for y

lemma word_sless_alt: "a <s b \<longleftrightarrow> sint a < sint b"
  by (auto simp add: word_sle_def word_sless_def less_le)

lemma word_le_nat_alt: "a \<le> b \<longleftrightarrow> unat a \<le> unat b"
  unfolding unat_def word_le_def
  by (rule nat_le_eq_zle [symmetric]) simp

lemma word_less_nat_alt: "a < b \<longleftrightarrow> unat a < unat b"
  unfolding unat_def word_less_alt
  by (rule nat_less_eq_zless [symmetric]) simp