src/HOL/Transitive_Closure.thy
author wenzelm
Thu Dec 08 20:15:50 2005 +0100 (2005-12-08)
changeset 18372 2bffdf62fe7f
parent 17876 b9c92f384109
child 19228 30fce6da8cbe
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Reflexive and Transitive closure of a relation *}
     8 
     9 theory Transitive_Closure
    10 imports Inductive
    11 uses ("../Provers/trancl.ML")
    12 begin
    13 
    14 text {*
    15   @{text rtrancl} is reflexive/transitive closure,
    16   @{text trancl} is transitive closure,
    17   @{text reflcl} is reflexive closure.
    18 
    19   These postfix operators have \emph{maximum priority}, forcing their
    20   operands to be atomic.
    21 *}
    22 
    23 consts
    24   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^*)" [1000] 999)
    25 
    26 inductive "r^*"
    27   intros
    28     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    29     rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    30 
    31 consts
    32   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^+)" [1000] 999)
    33 
    34 inductive "r^+"
    35   intros
    36     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    37     trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a,c) : r^+"
    38 
    39 syntax
    40   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^=)" [1000] 999)
    41 translations
    42   "r^=" == "r \<union> Id"
    43 
    44 syntax (xsymbols)
    45   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    46   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    47   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    48 
    49 syntax (HTML output)
    50   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    51   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    52   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    53 
    54 
    55 subsection {* Reflexive-transitive closure *}
    56 
    57 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    58   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    59   apply (simp only: split_tupled_all)
    60   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    61   done
    62 
    63 lemma rtrancl_mono: "r \<subseteq> s ==> r^* \<subseteq> s^*"
    64   -- {* monotonicity of @{text rtrancl} *}
    65   apply (rule subsetI)
    66   apply (simp only: split_tupled_all)
    67   apply (erule rtrancl.induct)
    68    apply (rule_tac [2] rtrancl_into_rtrancl, blast+)
    69   done
    70 
    71 theorem rtrancl_induct [consumes 1, induct set: rtrancl]:
    72   assumes a: "(a, b) : r^*"
    73     and cases: "P a" "!!y z. [| (a, y) : r^*; (y, z) : r; P y |] ==> P z"
    74   shows "P b"
    75 proof -
    76   from a have "a = a --> P b"
    77     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
    78   thus ?thesis by iprover
    79 qed
    80 
    81 lemmas rtrancl_induct2 =
    82   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
    83                  consumes 1, case_names refl step]
    84 
    85 lemma trans_rtrancl: "trans(r^*)"
    86   -- {* transitivity of transitive closure!! -- by induction *}
    87 proof (rule transI)
    88   fix x y z
    89   assume "(x, y) \<in> r\<^sup>*"
    90   assume "(y, z) \<in> r\<^sup>*"
    91   thus "(x, z) \<in> r\<^sup>*" by induct (iprover!)+
    92 qed
    93 
    94 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]
    95 
    96 lemma rtranclE:
    97   assumes major: "(a::'a,b) : r^*"
    98     and cases: "(a = b) ==> P"
    99       "!!y. [| (a,y) : r^*; (y,b) : r |] ==> P"
   100   shows P
   101   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   102   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   103    apply (rule_tac [2] major [THEN rtrancl_induct])
   104     prefer 2 apply blast
   105    prefer 2 apply blast
   106   apply (erule asm_rl exE disjE conjE cases)+
   107   done
   108 
   109 lemma converse_rtrancl_into_rtrancl:
   110   "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> r\<^sup>* \<Longrightarrow> (a, c) \<in> r\<^sup>*"
   111   by (rule rtrancl_trans) iprover+
   112 
   113 text {*
   114   \medskip More @{term "r^*"} equations and inclusions.
   115 *}
   116 
   117 lemma rtrancl_idemp [simp]: "(r^*)^* = r^*"
   118   apply auto
   119   apply (erule rtrancl_induct)
   120    apply (rule rtrancl_refl)
   121   apply (blast intro: rtrancl_trans)
   122   done
   123 
   124 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   125   apply (rule set_ext)
   126   apply (simp only: split_tupled_all)
   127   apply (blast intro: rtrancl_trans)
   128   done
   129 
   130 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   131 by (drule rtrancl_mono, simp)
   132 
   133 lemma rtrancl_subset: "R \<subseteq> S ==> S \<subseteq> R^* ==> S^* = R^*"
   134   apply (drule rtrancl_mono)
   135   apply (drule rtrancl_mono, simp)
   136   done
   137 
   138 lemma rtrancl_Un_rtrancl: "(R^* \<union> S^*)^* = (R \<union> S)^*"
   139   by (blast intro!: rtrancl_subset intro: r_into_rtrancl rtrancl_mono [THEN subsetD])
   140 
   141 lemma rtrancl_reflcl [simp]: "(R^=)^* = R^*"
   142   by (blast intro!: rtrancl_subset intro: r_into_rtrancl)
   143 
   144 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   145   apply (rule sym)
   146   apply (rule rtrancl_subset, blast, clarify)
   147   apply (rename_tac a b)
   148   apply (case_tac "a = b", blast)
   149   apply (blast intro!: r_into_rtrancl)
   150   done
   151 
   152 theorem rtrancl_converseD:
   153   assumes r: "(x, y) \<in> (r^-1)^*"
   154   shows "(y, x) \<in> r^*"
   155 proof -
   156   from r show ?thesis
   157     by induct (iprover intro: rtrancl_trans dest!: converseD)+
   158 qed
   159 
   160 theorem rtrancl_converseI:
   161   assumes r: "(y, x) \<in> r^*"
   162   shows "(x, y) \<in> (r^-1)^*"
   163 proof -
   164   from r show ?thesis
   165     by induct (iprover intro: rtrancl_trans converseI)+
   166 qed
   167 
   168 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   169   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   170 
   171 theorem converse_rtrancl_induct[consumes 1]:
   172   assumes major: "(a, b) : r^*"
   173     and cases: "P b" "!!y z. [| (y, z) : r; (z, b) : r^*; P z |] ==> P y"
   174   shows "P a"
   175 proof -
   176   from rtrancl_converseI [OF major]
   177   show ?thesis
   178     by induct (iprover intro: cases dest!: converseD rtrancl_converseD)+
   179 qed
   180 
   181 lemmas converse_rtrancl_induct2 =
   182   converse_rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   183                  consumes 1, case_names refl step]
   184 
   185 lemma converse_rtranclE:
   186   assumes major: "(x,z):r^*"
   187     and cases: "x=z ==> P"
   188       "!!y. [| (x,y):r; (y,z):r^* |] ==> P"
   189   shows P
   190   apply (subgoal_tac "x = z | (EX y. (x,y) : r & (y,z) : r^*)")
   191    apply (rule_tac [2] major [THEN converse_rtrancl_induct])
   192     prefer 2 apply iprover
   193    prefer 2 apply iprover
   194   apply (erule asm_rl exE disjE conjE cases)+
   195   done
   196 
   197 ML_setup {*
   198   bind_thm ("converse_rtranclE2", split_rule
   199     (read_instantiate [("x","(xa,xb)"), ("z","(za,zb)")] (thm "converse_rtranclE")));
   200 *}
   201 
   202 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   203   by (blast elim: rtranclE converse_rtranclE
   204     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   205 
   206 lemma rtrancl_unfold: "r^* = Id Un (r O r^*)"
   207   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   208 
   209 
   210 subsection {* Transitive closure *}
   211 
   212 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   213   apply (simp only: split_tupled_all)
   214   apply (erule trancl.induct)
   215   apply (iprover dest: subsetD)+
   216   done
   217 
   218 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   219   by (simp only: split_tupled_all) (erule r_into_trancl)
   220 
   221 text {*
   222   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   223 *}
   224 
   225 lemma trancl_into_rtrancl: "(a, b) \<in> r^+ ==> (a, b) \<in> r^*"
   226   by (erule trancl.induct) iprover+
   227 
   228 lemma rtrancl_into_trancl1: assumes r: "(a, b) \<in> r^*"
   229   shows "!!c. (b, c) \<in> r ==> (a, c) \<in> r^+" using r
   230   by induct iprover+
   231 
   232 lemma rtrancl_into_trancl2: "[| (a,b) : r;  (b,c) : r^* |]   ==>  (a,c) : r^+"
   233   -- {* intro rule from @{text r} and @{text rtrancl} *}
   234   apply (erule rtranclE, iprover)
   235   apply (rule rtrancl_trans [THEN rtrancl_into_trancl1])
   236    apply (assumption | rule r_into_rtrancl)+
   237   done
   238 
   239 lemma trancl_induct [consumes 1, induct set: trancl]:
   240   assumes a: "(a,b) : r^+"
   241   and cases: "!!y. (a, y) : r ==> P y"
   242     "!!y z. (a,y) : r^+ ==> (y, z) : r ==> P y ==> P z"
   243   shows "P b"
   244   -- {* Nice induction rule for @{text trancl} *}
   245 proof -
   246   from a have "a = a --> P b"
   247     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
   248   thus ?thesis by iprover
   249 qed
   250 
   251 lemma trancl_trans_induct:
   252   assumes major: "(x,y) : r^+"
   253     and cases: "!!x y. (x,y) : r ==> P x y"
   254       "!!x y z. [| (x,y) : r^+; P x y; (y,z) : r^+; P y z |] ==> P x z"
   255   shows "P x y"
   256   -- {* Another induction rule for trancl, incorporating transitivity *}
   257   by (iprover intro: r_into_trancl major [THEN trancl_induct] cases)
   258 
   259 inductive_cases tranclE: "(a, b) : r^+"
   260 
   261 lemma trancl_unfold: "r^+ = r Un (r O r^+)"
   262   by (auto intro: trancl_into_trancl elim: tranclE)
   263 
   264 lemma trans_trancl: "trans(r^+)"
   265   -- {* Transitivity of @{term "r^+"} *}
   266 proof (rule transI)
   267   fix x y z
   268   assume xy: "(x, y) \<in> r^+"
   269   assume "(y, z) \<in> r^+"
   270   thus "(x, z) \<in> r^+" by induct (insert xy, iprover)+
   271 qed
   272 
   273 lemmas trancl_trans = trans_trancl [THEN transD, standard]
   274 
   275 lemma rtrancl_trancl_trancl: assumes r: "(x, y) \<in> r^*"
   276   shows "!!z. (y, z) \<in> r^+ ==> (x, z) \<in> r^+" using r
   277   by induct (iprover intro: trancl_trans)+
   278 
   279 lemma trancl_into_trancl2: "(a, b) \<in> r ==> (b, c) \<in> r^+ ==> (a, c) \<in> r^+"
   280   by (erule transD [OF trans_trancl r_into_trancl])
   281 
   282 lemma trancl_insert:
   283   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   284   -- {* primitive recursion for @{text trancl} over finite relations *}
   285   apply (rule equalityI)
   286    apply (rule subsetI)
   287    apply (simp only: split_tupled_all)
   288    apply (erule trancl_induct, blast)
   289    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)
   290   apply (rule subsetI)
   291   apply (blast intro: trancl_mono rtrancl_mono
   292     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   293   done
   294 
   295 lemma trancl_converseI: "(x, y) \<in> (r^+)^-1 ==> (x, y) \<in> (r^-1)^+"
   296   apply (drule converseD)
   297   apply (erule trancl.induct)
   298   apply (iprover intro: converseI trancl_trans)+
   299   done
   300 
   301 lemma trancl_converseD: "(x, y) \<in> (r^-1)^+ ==> (x, y) \<in> (r^+)^-1"
   302   apply (rule converseI)
   303   apply (erule trancl.induct)
   304   apply (iprover dest: converseD intro: trancl_trans)+
   305   done
   306 
   307 lemma trancl_converse: "(r^-1)^+ = (r^+)^-1"
   308   by (fastsimp simp add: split_tupled_all
   309     intro!: trancl_converseI trancl_converseD)
   310 
   311 lemma converse_trancl_induct:
   312   assumes major: "(a,b) : r^+"
   313     and cases: "!!y. (y,b) : r ==> P(y)"
   314       "!!y z.[| (y,z) : r;  (z,b) : r^+;  P(z) |] ==> P(y)"
   315   shows "P a"
   316   apply (rule major [THEN converseI, THEN trancl_converseI [THEN trancl_induct]])
   317    apply (rule cases)
   318    apply (erule converseD)
   319   apply (blast intro: prems dest!: trancl_converseD)
   320   done
   321 
   322 lemma tranclD: "(x, y) \<in> R^+ ==> EX z. (x, z) \<in> R \<and> (z, y) \<in> R^*"
   323   apply (erule converse_trancl_induct, auto)
   324   apply (blast intro: rtrancl_trans)
   325   done
   326 
   327 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   328   by (blast elim: tranclE dest: trancl_into_rtrancl)
   329 
   330 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   331   by (blast dest: r_into_trancl)
   332 
   333 lemma trancl_subset_Sigma_aux:
   334     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   335   by (induct rule: rtrancl_induct) auto
   336 
   337 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   338   apply (rule subsetI)
   339   apply (simp only: split_tupled_all)
   340   apply (erule tranclE)
   341   apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   342   done
   343 
   344 lemma reflcl_trancl [simp]: "(r^+)^= = r^*"
   345   apply safe
   346    apply (erule trancl_into_rtrancl)
   347   apply (blast elim: rtranclE dest: rtrancl_into_trancl1)
   348   done
   349 
   350 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   351   apply safe
   352    apply (drule trancl_into_rtrancl, simp)
   353   apply (erule rtranclE, safe)
   354    apply (rule r_into_trancl, simp)
   355   apply (rule rtrancl_into_trancl1)
   356    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   357   done
   358 
   359 lemma trancl_empty [simp]: "{}^+ = {}"
   360   by (auto elim: trancl_induct)
   361 
   362 lemma rtrancl_empty [simp]: "{}^* = Id"
   363   by (rule subst [OF reflcl_trancl]) simp
   364 
   365 lemma rtranclD: "(a, b) \<in> R^* ==> a = b \<or> a \<noteq> b \<and> (a, b) \<in> R^+"
   366   by (force simp add: reflcl_trancl [symmetric] simp del: reflcl_trancl)
   367 
   368 lemma rtrancl_eq_or_trancl:
   369   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   370   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   371 
   372 text {* @{text Domain} and @{text Range} *}
   373 
   374 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   375   by blast
   376 
   377 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   378   by blast
   379 
   380 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   381   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   382 
   383 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   384   by (blast intro: subsetD [OF rtrancl_Un_subset])
   385 
   386 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   387   by (unfold Domain_def) (blast dest: tranclD)
   388 
   389 lemma trancl_range [simp]: "Range (r^+) = Range r"
   390   by (simp add: Range_def trancl_converse [symmetric])
   391 
   392 lemma Not_Domain_rtrancl:
   393     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   394   apply auto
   395   by (erule rev_mp, erule rtrancl_induct, auto)
   396 
   397 
   398 text {* More about converse @{text rtrancl} and @{text trancl}, should
   399   be merged with main body. *}
   400 
   401 lemma single_valued_confluent:
   402   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   403   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   404 apply(erule rtrancl_induct)
   405  apply simp
   406 apply(erule disjE)
   407  apply(blast elim:converse_rtranclE dest:single_valuedD)
   408 apply(blast intro:rtrancl_trans)
   409 done
   410 
   411 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   412   by (fast intro: trancl_trans)
   413 
   414 lemma trancl_into_trancl [rule_format]:
   415     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   416   apply (erule trancl_induct)
   417    apply (fast intro: r_r_into_trancl)
   418   apply (fast intro: r_r_into_trancl trancl_trans)
   419   done
   420 
   421 lemma trancl_rtrancl_trancl:
   422     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r\<^sup>* ==> (a, c) \<in> r\<^sup>+"
   423   apply (drule tranclD)
   424   apply (erule exE, erule conjE)
   425   apply (drule rtrancl_trans, assumption)
   426   apply (drule rtrancl_into_trancl2, assumption, assumption)
   427   done
   428 
   429 lemmas transitive_closure_trans [trans] =
   430   r_r_into_trancl trancl_trans rtrancl_trans
   431   trancl_into_trancl trancl_into_trancl2
   432   rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   433   rtrancl_trancl_trancl trancl_rtrancl_trancl
   434 
   435 declare trancl_into_rtrancl [elim]
   436 
   437 declare rtranclE [cases set: rtrancl]
   438 declare tranclE [cases set: trancl]
   439 
   440 
   441 
   442 
   443 
   444 subsection {* Setup of transitivity reasoner *}
   445 
   446 use "../Provers/trancl.ML";
   447 
   448 ML_setup {*
   449 
   450 structure Trancl_Tac = Trancl_Tac_Fun (
   451   struct
   452     val r_into_trancl = thm "r_into_trancl";
   453     val trancl_trans  = thm "trancl_trans";
   454     val rtrancl_refl = thm "rtrancl_refl";
   455     val r_into_rtrancl = thm "r_into_rtrancl";
   456     val trancl_into_rtrancl = thm "trancl_into_rtrancl";
   457     val rtrancl_trancl_trancl = thm "rtrancl_trancl_trancl";
   458     val trancl_rtrancl_trancl = thm "trancl_rtrancl_trancl";
   459     val rtrancl_trans = thm "rtrancl_trans";
   460 
   461   fun decomp (Trueprop $ t) =
   462     let fun dec (Const ("op :", _) $ (Const ("Pair", _) $ a $ b) $ rel ) =
   463         let fun decr (Const ("Transitive_Closure.rtrancl", _ ) $ r) = (r,"r*")
   464               | decr (Const ("Transitive_Closure.trancl", _ ) $ r)  = (r,"r+")
   465               | decr r = (r,"r");
   466             val (rel,r) = decr rel;
   467         in SOME (a,b,rel,r) end
   468       | dec _ =  NONE
   469     in dec t end;
   470 
   471   end); (* struct *)
   472 
   473 change_simpset (fn ss => ss
   474   addSolver (mk_solver "Trancl" (fn _ => Trancl_Tac.trancl_tac))
   475   addSolver (mk_solver "Rtrancl" (fn _ => Trancl_Tac.rtrancl_tac)));
   476 
   477 *}
   478 
   479 (* Optional methods
   480 
   481 method_setup trancl =
   482   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (trancl_tac)) *}
   483   {* simple transitivity reasoner *}
   484 method_setup rtrancl =
   485   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (rtrancl_tac)) *}
   486   {* simple transitivity reasoner *}
   487 
   488 *)
   489 
   490 end