src/HOL/IntDiv.thy
author wenzelm
Thu May 31 18:16:52 2007 +0200 (2007-05-31)
changeset 23164 69e55066dbca
child 23306 cdb027d0637e
permissions -rw-r--r--
moved Integ files to canonical place;
     1 (*  Title:      HOL/IntDiv.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1999  University of Cambridge
     5 
     6 *)
     7 
     8 header{*The Division Operators div and mod; the Divides Relation dvd*}
     9 
    10 theory IntDiv
    11 imports IntArith Divides FunDef
    12 begin
    13 
    14 declare zless_nat_conj [simp]
    15 
    16 constdefs
    17   quorem :: "(int*int) * (int*int) => bool"
    18     --{*definition of quotient and remainder*}
    19     [code func]: "quorem == %((a,b), (q,r)).
    20                       a = b*q + r &
    21                       (if 0 < b then 0\<le>r & r<b else b<r & r \<le> 0)"
    22 
    23   adjust :: "[int, int*int] => int*int"
    24     --{*for the division algorithm*}
    25     [code func]: "adjust b == %(q,r). if 0 \<le> r-b then (2*q + 1, r-b)
    26                          else (2*q, r)"
    27 
    28 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
    29 function
    30   posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int"
    31 where
    32   "posDivAlg a b =
    33      (if (a<b | b\<le>0) then (0,a)
    34         else adjust b (posDivAlg a (2*b)))"
    35 by auto
    36 termination by (relation "measure (%(a,b). nat(a - b + 1))") auto
    37 
    38 text{*algorithm for the case @{text "a<0, b>0"}*}
    39 function
    40   negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int"
    41 where
    42   "negDivAlg a b  =
    43      (if (0\<le>a+b | b\<le>0) then (-1,a+b)
    44       else adjust b (negDivAlg a (2*b)))"
    45 by auto
    46 termination by (relation "measure (%(a,b). nat(- a - b))") auto
    47 
    48 text{*algorithm for the general case @{term "b\<noteq>0"}*}
    49 constdefs
    50   negateSnd :: "int*int => int*int"
    51     [code func]: "negateSnd == %(q,r). (q,-r)"
    52 
    53 definition
    54   divAlg :: "int \<times> int \<Rightarrow> int \<times> int"
    55     --{*The full division algorithm considers all possible signs for a, b
    56        including the special case @{text "a=0, b<0"} because 
    57        @{term negDivAlg} requires @{term "a<0"}.*}
    58 where
    59   "divAlg = (\<lambda>(a, b). (if 0\<le>a then
    60                   if 0\<le>b then posDivAlg a b
    61                   else if a=0 then (0, 0)
    62                        else negateSnd (negDivAlg (-a) (-b))
    63                else 
    64                   if 0<b then negDivAlg a b
    65                   else negateSnd (posDivAlg (-a) (-b))))"
    66 
    67 instance int :: Divides.div
    68   div_def: "a div b == fst (divAlg (a, b))"
    69   mod_def: "a mod b == snd (divAlg (a, b))" ..
    70 
    71 lemma divAlg_mod_div:
    72   "divAlg (p, q) = (p div q, p mod q)"
    73   by (auto simp add: div_def mod_def)
    74 
    75 text{*
    76 Here is the division algorithm in ML:
    77 
    78 \begin{verbatim}
    79     fun posDivAlg (a,b) =
    80       if a<b then (0,a)
    81       else let val (q,r) = posDivAlg(a, 2*b)
    82 	       in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
    83 	   end
    84 
    85     fun negDivAlg (a,b) =
    86       if 0\<le>a+b then (~1,a+b)
    87       else let val (q,r) = negDivAlg(a, 2*b)
    88 	       in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
    89 	   end;
    90 
    91     fun negateSnd (q,r:int) = (q,~r);
    92 
    93     fun divAlg (a,b) = if 0\<le>a then 
    94 			  if b>0 then posDivAlg (a,b) 
    95 			   else if a=0 then (0,0)
    96 				else negateSnd (negDivAlg (~a,~b))
    97 		       else 
    98 			  if 0<b then negDivAlg (a,b)
    99 			  else        negateSnd (posDivAlg (~a,~b));
   100 \end{verbatim}
   101 *}
   102 
   103 
   104 
   105 subsection{*Uniqueness and Monotonicity of Quotients and Remainders*}
   106 
   107 lemma unique_quotient_lemma:
   108      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
   109       ==> q' \<le> (q::int)"
   110 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
   111  prefer 2 apply (simp add: right_diff_distrib)
   112 apply (subgoal_tac "0 < b * (1 + q - q') ")
   113 apply (erule_tac [2] order_le_less_trans)
   114  prefer 2 apply (simp add: right_diff_distrib right_distrib)
   115 apply (subgoal_tac "b * q' < b * (1 + q) ")
   116  prefer 2 apply (simp add: right_diff_distrib right_distrib)
   117 apply (simp add: mult_less_cancel_left)
   118 done
   119 
   120 lemma unique_quotient_lemma_neg:
   121      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
   122       ==> q \<le> (q'::int)"
   123 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
   124     auto)
   125 
   126 lemma unique_quotient:
   127      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  b \<noteq> 0 |]  
   128       ==> q = q'"
   129 apply (simp add: quorem_def linorder_neq_iff split: split_if_asm)
   130 apply (blast intro: order_antisym
   131              dest: order_eq_refl [THEN unique_quotient_lemma] 
   132              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
   133 done
   134 
   135 
   136 lemma unique_remainder:
   137      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  b \<noteq> 0 |]  
   138       ==> r = r'"
   139 apply (subgoal_tac "q = q'")
   140  apply (simp add: quorem_def)
   141 apply (blast intro: unique_quotient)
   142 done
   143 
   144 
   145 subsection{*Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends*}
   146 
   147 text{*And positive divisors*}
   148 
   149 lemma adjust_eq [simp]:
   150      "adjust b (q,r) = 
   151       (let diff = r-b in  
   152 	if 0 \<le> diff then (2*q + 1, diff)   
   153                      else (2*q, r))"
   154 by (simp add: Let_def adjust_def)
   155 
   156 declare posDivAlg.simps [simp del]
   157 
   158 text{*use with a simproc to avoid repeatedly proving the premise*}
   159 lemma posDivAlg_eqn:
   160      "0 < b ==>  
   161       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
   162 by (rule posDivAlg.simps [THEN trans], simp)
   163 
   164 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
   165 theorem posDivAlg_correct:
   166   assumes "0 \<le> a" and "0 < b"
   167   shows "quorem ((a, b), posDivAlg a b)"
   168 using prems apply (induct a b rule: posDivAlg.induct)
   169 apply auto
   170 apply (simp add: quorem_def)
   171 apply (subst posDivAlg_eqn, simp add: right_distrib)
   172 apply (case_tac "a < b")
   173 apply simp_all
   174 apply (erule splitE)
   175 apply (auto simp add: right_distrib Let_def)
   176 done
   177 
   178 
   179 subsection{*Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends*}
   180 
   181 text{*And positive divisors*}
   182 
   183 declare negDivAlg.simps [simp del]
   184 
   185 text{*use with a simproc to avoid repeatedly proving the premise*}
   186 lemma negDivAlg_eqn:
   187      "0 < b ==>  
   188       negDivAlg a b =       
   189        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
   190 by (rule negDivAlg.simps [THEN trans], simp)
   191 
   192 (*Correctness of negDivAlg: it computes quotients correctly
   193   It doesn't work if a=0 because the 0/b equals 0, not -1*)
   194 lemma negDivAlg_correct:
   195   assumes "a < 0" and "b > 0"
   196   shows "quorem ((a, b), negDivAlg a b)"
   197 using prems apply (induct a b rule: negDivAlg.induct)
   198 apply (auto simp add: linorder_not_le)
   199 apply (simp add: quorem_def)
   200 apply (subst negDivAlg_eqn, assumption)
   201 apply (case_tac "a + b < (0\<Colon>int)")
   202 apply simp_all
   203 apply (erule splitE)
   204 apply (auto simp add: right_distrib Let_def)
   205 done
   206 
   207 
   208 subsection{*Existence Shown by Proving the Division Algorithm to be Correct*}
   209 
   210 (*the case a=0*)
   211 lemma quorem_0: "b \<noteq> 0 ==> quorem ((0,b), (0,0))"
   212 by (auto simp add: quorem_def linorder_neq_iff)
   213 
   214 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
   215 by (subst posDivAlg.simps, auto)
   216 
   217 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
   218 by (subst negDivAlg.simps, auto)
   219 
   220 lemma negateSnd_eq [simp]: "negateSnd(q,r) = (q,-r)"
   221 by (simp add: negateSnd_def)
   222 
   223 lemma quorem_neg: "quorem ((-a,-b), qr) ==> quorem ((a,b), negateSnd qr)"
   224 by (auto simp add: split_ifs quorem_def)
   225 
   226 lemma divAlg_correct: "b \<noteq> 0 ==> quorem ((a,b), divAlg (a, b))"
   227 by (force simp add: linorder_neq_iff quorem_0 divAlg_def quorem_neg
   228                     posDivAlg_correct negDivAlg_correct)
   229 
   230 text{*Arbitrary definitions for division by zero.  Useful to simplify 
   231     certain equations.*}
   232 
   233 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
   234 by (simp add: div_def mod_def divAlg_def posDivAlg.simps)  
   235 
   236 
   237 text{*Basic laws about division and remainder*}
   238 
   239 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
   240 apply (case_tac "b = 0", simp)
   241 apply (cut_tac a = a and b = b in divAlg_correct)
   242 apply (auto simp add: quorem_def div_def mod_def)
   243 done
   244 
   245 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
   246 by(simp add: zmod_zdiv_equality[symmetric])
   247 
   248 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
   249 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
   250 
   251 text {* Tool setup *}
   252 
   253 ML_setup {*
   254 local 
   255 
   256 structure CancelDivMod = CancelDivModFun(
   257 struct
   258   val div_name = @{const_name Divides.div};
   259   val mod_name = @{const_name Divides.mod};
   260   val mk_binop = HOLogic.mk_binop;
   261   val mk_sum = Int_Numeral_Simprocs.mk_sum HOLogic.intT;
   262   val dest_sum = Int_Numeral_Simprocs.dest_sum;
   263   val div_mod_eqs =
   264     map mk_meta_eq [@{thm zdiv_zmod_equality},
   265       @{thm zdiv_zmod_equality2}];
   266   val trans = trans;
   267   val prove_eq_sums =
   268     let
   269       val simps = diff_int_def :: Int_Numeral_Simprocs.add_0s @ zadd_ac
   270     in NatArithUtils.prove_conv all_tac (NatArithUtils.simp_all_tac simps) end;
   271 end)
   272 
   273 in
   274 
   275 val cancel_zdiv_zmod_proc = NatArithUtils.prep_simproc
   276   ("cancel_zdiv_zmod", ["(m::int) + n"], K CancelDivMod.proc)
   277 
   278 end;
   279 
   280 Addsimprocs [cancel_zdiv_zmod_proc]
   281 *}
   282 
   283 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
   284 apply (cut_tac a = a and b = b in divAlg_correct)
   285 apply (auto simp add: quorem_def mod_def)
   286 done
   287 
   288 lemmas pos_mod_sign  [simp] = pos_mod_conj [THEN conjunct1, standard]
   289    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2, standard]
   290 
   291 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
   292 apply (cut_tac a = a and b = b in divAlg_correct)
   293 apply (auto simp add: quorem_def div_def mod_def)
   294 done
   295 
   296 lemmas neg_mod_sign  [simp] = neg_mod_conj [THEN conjunct1, standard]
   297    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2, standard]
   298 
   299 
   300 
   301 subsection{*General Properties of div and mod*}
   302 
   303 lemma quorem_div_mod: "b \<noteq> 0 ==> quorem ((a, b), (a div b, a mod b))"
   304 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   305 apply (force simp add: quorem_def linorder_neq_iff)
   306 done
   307 
   308 lemma quorem_div: "[| quorem((a,b),(q,r));  b \<noteq> 0 |] ==> a div b = q"
   309 by (simp add: quorem_div_mod [THEN unique_quotient])
   310 
   311 lemma quorem_mod: "[| quorem((a,b),(q,r));  b \<noteq> 0 |] ==> a mod b = r"
   312 by (simp add: quorem_div_mod [THEN unique_remainder])
   313 
   314 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
   315 apply (rule quorem_div)
   316 apply (auto simp add: quorem_def)
   317 done
   318 
   319 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
   320 apply (rule quorem_div)
   321 apply (auto simp add: quorem_def)
   322 done
   323 
   324 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
   325 apply (rule quorem_div)
   326 apply (auto simp add: quorem_def)
   327 done
   328 
   329 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
   330 
   331 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
   332 apply (rule_tac q = 0 in quorem_mod)
   333 apply (auto simp add: quorem_def)
   334 done
   335 
   336 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
   337 apply (rule_tac q = 0 in quorem_mod)
   338 apply (auto simp add: quorem_def)
   339 done
   340 
   341 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
   342 apply (rule_tac q = "-1" in quorem_mod)
   343 apply (auto simp add: quorem_def)
   344 done
   345 
   346 text{*There is no @{text mod_neg_pos_trivial}.*}
   347 
   348 
   349 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
   350 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
   351 apply (case_tac "b = 0", simp)
   352 apply (simp add: quorem_div_mod [THEN quorem_neg, simplified, 
   353                                  THEN quorem_div, THEN sym])
   354 
   355 done
   356 
   357 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
   358 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
   359 apply (case_tac "b = 0", simp)
   360 apply (subst quorem_div_mod [THEN quorem_neg, simplified, THEN quorem_mod],
   361        auto)
   362 done
   363 
   364 
   365 subsection{*Laws for div and mod with Unary Minus*}
   366 
   367 lemma zminus1_lemma:
   368      "quorem((a,b),(q,r))  
   369       ==> quorem ((-a,b), (if r=0 then -q else -q - 1),  
   370                           (if r=0 then 0 else b-r))"
   371 by (force simp add: split_ifs quorem_def linorder_neq_iff right_diff_distrib)
   372 
   373 
   374 lemma zdiv_zminus1_eq_if:
   375      "b \<noteq> (0::int)  
   376       ==> (-a) div b =  
   377           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
   378 by (blast intro: quorem_div_mod [THEN zminus1_lemma, THEN quorem_div])
   379 
   380 lemma zmod_zminus1_eq_if:
   381      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
   382 apply (case_tac "b = 0", simp)
   383 apply (blast intro: quorem_div_mod [THEN zminus1_lemma, THEN quorem_mod])
   384 done
   385 
   386 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
   387 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
   388 
   389 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
   390 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
   391 
   392 lemma zdiv_zminus2_eq_if:
   393      "b \<noteq> (0::int)  
   394       ==> a div (-b) =  
   395           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
   396 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
   397 
   398 lemma zmod_zminus2_eq_if:
   399      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
   400 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
   401 
   402 
   403 subsection{*Division of a Number by Itself*}
   404 
   405 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
   406 apply (subgoal_tac "0 < a*q")
   407  apply (simp add: zero_less_mult_iff, arith)
   408 done
   409 
   410 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
   411 apply (subgoal_tac "0 \<le> a* (1-q) ")
   412  apply (simp add: zero_le_mult_iff)
   413 apply (simp add: right_diff_distrib)
   414 done
   415 
   416 lemma self_quotient: "[| quorem((a,a),(q,r));  a \<noteq> (0::int) |] ==> q = 1"
   417 apply (simp add: split_ifs quorem_def linorder_neq_iff)
   418 apply (rule order_antisym, safe, simp_all)
   419 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
   420 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
   421 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
   422 done
   423 
   424 lemma self_remainder: "[| quorem((a,a),(q,r));  a \<noteq> (0::int) |] ==> r = 0"
   425 apply (frule self_quotient, assumption)
   426 apply (simp add: quorem_def)
   427 done
   428 
   429 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
   430 by (simp add: quorem_div_mod [THEN self_quotient])
   431 
   432 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
   433 lemma zmod_self [simp]: "a mod a = (0::int)"
   434 apply (case_tac "a = 0", simp)
   435 apply (simp add: quorem_div_mod [THEN self_remainder])
   436 done
   437 
   438 
   439 subsection{*Computation of Division and Remainder*}
   440 
   441 lemma zdiv_zero [simp]: "(0::int) div b = 0"
   442 by (simp add: div_def divAlg_def)
   443 
   444 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
   445 by (simp add: div_def divAlg_def)
   446 
   447 lemma zmod_zero [simp]: "(0::int) mod b = 0"
   448 by (simp add: mod_def divAlg_def)
   449 
   450 lemma zdiv_minus1: "(0::int) < b ==> -1 div b = -1"
   451 by (simp add: div_def divAlg_def)
   452 
   453 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
   454 by (simp add: mod_def divAlg_def)
   455 
   456 text{*a positive, b positive *}
   457 
   458 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
   459 by (simp add: div_def divAlg_def)
   460 
   461 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
   462 by (simp add: mod_def divAlg_def)
   463 
   464 text{*a negative, b positive *}
   465 
   466 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
   467 by (simp add: div_def divAlg_def)
   468 
   469 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
   470 by (simp add: mod_def divAlg_def)
   471 
   472 text{*a positive, b negative *}
   473 
   474 lemma div_pos_neg:
   475      "[| 0 < a;  b < 0 |] ==> a div b = fst (negateSnd (negDivAlg (-a) (-b)))"
   476 by (simp add: div_def divAlg_def)
   477 
   478 lemma mod_pos_neg:
   479      "[| 0 < a;  b < 0 |] ==> a mod b = snd (negateSnd (negDivAlg (-a) (-b)))"
   480 by (simp add: mod_def divAlg_def)
   481 
   482 text{*a negative, b negative *}
   483 
   484 lemma div_neg_neg:
   485      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (negateSnd (posDivAlg (-a) (-b)))"
   486 by (simp add: div_def divAlg_def)
   487 
   488 lemma mod_neg_neg:
   489      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (negateSnd (posDivAlg (-a) (-b)))"
   490 by (simp add: mod_def divAlg_def)
   491 
   492 text {*Simplify expresions in which div and mod combine numerical constants*}
   493 
   494 lemmas div_pos_pos_number_of [simp] =
   495     div_pos_pos [of "number_of v" "number_of w", standard]
   496 
   497 lemmas div_neg_pos_number_of [simp] =
   498     div_neg_pos [of "number_of v" "number_of w", standard]
   499 
   500 lemmas div_pos_neg_number_of [simp] =
   501     div_pos_neg [of "number_of v" "number_of w", standard]
   502 
   503 lemmas div_neg_neg_number_of [simp] =
   504     div_neg_neg [of "number_of v" "number_of w", standard]
   505 
   506 
   507 lemmas mod_pos_pos_number_of [simp] =
   508     mod_pos_pos [of "number_of v" "number_of w", standard]
   509 
   510 lemmas mod_neg_pos_number_of [simp] =
   511     mod_neg_pos [of "number_of v" "number_of w", standard]
   512 
   513 lemmas mod_pos_neg_number_of [simp] =
   514     mod_pos_neg [of "number_of v" "number_of w", standard]
   515 
   516 lemmas mod_neg_neg_number_of [simp] =
   517     mod_neg_neg [of "number_of v" "number_of w", standard]
   518 
   519 
   520 lemmas posDivAlg_eqn_number_of [simp] =
   521     posDivAlg_eqn [of "number_of v" "number_of w", standard]
   522 
   523 lemmas negDivAlg_eqn_number_of [simp] =
   524     negDivAlg_eqn [of "number_of v" "number_of w", standard]
   525 
   526 
   527 text{*Special-case simplification *}
   528 
   529 lemma zmod_1 [simp]: "a mod (1::int) = 0"
   530 apply (cut_tac a = a and b = 1 in pos_mod_sign)
   531 apply (cut_tac [2] a = a and b = 1 in pos_mod_bound)
   532 apply (auto simp del:pos_mod_bound pos_mod_sign)
   533 done
   534 
   535 lemma zdiv_1 [simp]: "a div (1::int) = a"
   536 by (cut_tac a = a and b = 1 in zmod_zdiv_equality, auto)
   537 
   538 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
   539 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
   540 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
   541 apply (auto simp del: neg_mod_sign neg_mod_bound)
   542 done
   543 
   544 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
   545 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
   546 
   547 (** The last remaining special cases for constant arithmetic:
   548     1 div z and 1 mod z **)
   549 
   550 lemmas div_pos_pos_1_number_of [simp] =
   551     div_pos_pos [OF int_0_less_1, of "number_of w", standard]
   552 
   553 lemmas div_pos_neg_1_number_of [simp] =
   554     div_pos_neg [OF int_0_less_1, of "number_of w", standard]
   555 
   556 lemmas mod_pos_pos_1_number_of [simp] =
   557     mod_pos_pos [OF int_0_less_1, of "number_of w", standard]
   558 
   559 lemmas mod_pos_neg_1_number_of [simp] =
   560     mod_pos_neg [OF int_0_less_1, of "number_of w", standard]
   561 
   562 
   563 lemmas posDivAlg_eqn_1_number_of [simp] =
   564     posDivAlg_eqn [of concl: 1 "number_of w", standard]
   565 
   566 lemmas negDivAlg_eqn_1_number_of [simp] =
   567     negDivAlg_eqn [of concl: 1 "number_of w", standard]
   568 
   569 
   570 
   571 subsection{*Monotonicity in the First Argument (Dividend)*}
   572 
   573 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
   574 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   575 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
   576 apply (rule unique_quotient_lemma)
   577 apply (erule subst)
   578 apply (erule subst, simp_all)
   579 done
   580 
   581 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
   582 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   583 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
   584 apply (rule unique_quotient_lemma_neg)
   585 apply (erule subst)
   586 apply (erule subst, simp_all)
   587 done
   588 
   589 
   590 subsection{*Monotonicity in the Second Argument (Divisor)*}
   591 
   592 lemma q_pos_lemma:
   593      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
   594 apply (subgoal_tac "0 < b'* (q' + 1) ")
   595  apply (simp add: zero_less_mult_iff)
   596 apply (simp add: right_distrib)
   597 done
   598 
   599 lemma zdiv_mono2_lemma:
   600      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
   601          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
   602       ==> q \<le> (q'::int)"
   603 apply (frule q_pos_lemma, assumption+) 
   604 apply (subgoal_tac "b*q < b* (q' + 1) ")
   605  apply (simp add: mult_less_cancel_left)
   606 apply (subgoal_tac "b*q = r' - r + b'*q'")
   607  prefer 2 apply simp
   608 apply (simp (no_asm_simp) add: right_distrib)
   609 apply (subst add_commute, rule zadd_zless_mono, arith)
   610 apply (rule mult_right_mono, auto)
   611 done
   612 
   613 lemma zdiv_mono2:
   614      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
   615 apply (subgoal_tac "b \<noteq> 0")
   616  prefer 2 apply arith
   617 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   618 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
   619 apply (rule zdiv_mono2_lemma)
   620 apply (erule subst)
   621 apply (erule subst, simp_all)
   622 done
   623 
   624 lemma q_neg_lemma:
   625      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
   626 apply (subgoal_tac "b'*q' < 0")
   627  apply (simp add: mult_less_0_iff, arith)
   628 done
   629 
   630 lemma zdiv_mono2_neg_lemma:
   631      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
   632          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
   633       ==> q' \<le> (q::int)"
   634 apply (frule q_neg_lemma, assumption+) 
   635 apply (subgoal_tac "b*q' < b* (q + 1) ")
   636  apply (simp add: mult_less_cancel_left)
   637 apply (simp add: right_distrib)
   638 apply (subgoal_tac "b*q' \<le> b'*q'")
   639  prefer 2 apply (simp add: mult_right_mono_neg, arith)
   640 done
   641 
   642 lemma zdiv_mono2_neg:
   643      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
   644 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
   645 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
   646 apply (rule zdiv_mono2_neg_lemma)
   647 apply (erule subst)
   648 apply (erule subst, simp_all)
   649 done
   650 
   651 subsection{*More Algebraic Laws for div and mod*}
   652 
   653 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
   654 
   655 lemma zmult1_lemma:
   656      "[| quorem((b,c),(q,r));  c \<noteq> 0 |]  
   657       ==> quorem ((a*b, c), (a*q + a*r div c, a*r mod c))"
   658 by (force simp add: split_ifs quorem_def linorder_neq_iff right_distrib)
   659 
   660 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
   661 apply (case_tac "c = 0", simp)
   662 apply (blast intro: quorem_div_mod [THEN zmult1_lemma, THEN quorem_div])
   663 done
   664 
   665 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
   666 apply (case_tac "c = 0", simp)
   667 apply (blast intro: quorem_div_mod [THEN zmult1_lemma, THEN quorem_mod])
   668 done
   669 
   670 lemma zmod_zmult1_eq': "(a*b) mod (c::int) = ((a mod c) * b) mod c"
   671 apply (rule trans)
   672 apply (rule_tac s = "b*a mod c" in trans)
   673 apply (rule_tac [2] zmod_zmult1_eq)
   674 apply (simp_all add: mult_commute)
   675 done
   676 
   677 lemma zmod_zmult_distrib: "(a*b) mod (c::int) = ((a mod c) * (b mod c)) mod c"
   678 apply (rule zmod_zmult1_eq' [THEN trans])
   679 apply (rule zmod_zmult1_eq)
   680 done
   681 
   682 lemma zdiv_zmult_self1 [simp]: "b \<noteq> (0::int) ==> (a*b) div b = a"
   683 by (simp add: zdiv_zmult1_eq)
   684 
   685 lemma zdiv_zmult_self2 [simp]: "b \<noteq> (0::int) ==> (b*a) div b = a"
   686 by (subst mult_commute, erule zdiv_zmult_self1)
   687 
   688 lemma zmod_zmult_self1 [simp]: "(a*b) mod b = (0::int)"
   689 by (simp add: zmod_zmult1_eq)
   690 
   691 lemma zmod_zmult_self2 [simp]: "(b*a) mod b = (0::int)"
   692 by (simp add: mult_commute zmod_zmult1_eq)
   693 
   694 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
   695 proof
   696   assume "m mod d = 0"
   697   with zmod_zdiv_equality[of m d] show "EX q::int. m = d*q" by auto
   698 next
   699   assume "EX q::int. m = d*q"
   700   thus "m mod d = 0" by auto
   701 qed
   702 
   703 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
   704 
   705 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
   706 
   707 lemma zadd1_lemma:
   708      "[| quorem((a,c),(aq,ar));  quorem((b,c),(bq,br));  c \<noteq> 0 |]  
   709       ==> quorem ((a+b, c), (aq + bq + (ar+br) div c, (ar+br) mod c))"
   710 by (force simp add: split_ifs quorem_def linorder_neq_iff right_distrib)
   711 
   712 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   713 lemma zdiv_zadd1_eq:
   714      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
   715 apply (case_tac "c = 0", simp)
   716 apply (blast intro: zadd1_lemma [OF quorem_div_mod quorem_div_mod] quorem_div)
   717 done
   718 
   719 lemma zmod_zadd1_eq: "(a+b) mod (c::int) = (a mod c + b mod c) mod c"
   720 apply (case_tac "c = 0", simp)
   721 apply (blast intro: zadd1_lemma [OF quorem_div_mod quorem_div_mod] quorem_mod)
   722 done
   723 
   724 lemma mod_div_trivial [simp]: "(a mod b) div b = (0::int)"
   725 apply (case_tac "b = 0", simp)
   726 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
   727 done
   728 
   729 lemma mod_mod_trivial [simp]: "(a mod b) mod b = a mod (b::int)"
   730 apply (case_tac "b = 0", simp)
   731 apply (force simp add: linorder_neq_iff mod_pos_pos_trivial mod_neg_neg_trivial)
   732 done
   733 
   734 lemma zmod_zadd_left_eq: "(a+b) mod (c::int) = ((a mod c) + b) mod c"
   735 apply (rule trans [symmetric])
   736 apply (rule zmod_zadd1_eq, simp)
   737 apply (rule zmod_zadd1_eq [symmetric])
   738 done
   739 
   740 lemma zmod_zadd_right_eq: "(a+b) mod (c::int) = (a + (b mod c)) mod c"
   741 apply (rule trans [symmetric])
   742 apply (rule zmod_zadd1_eq, simp)
   743 apply (rule zmod_zadd1_eq [symmetric])
   744 done
   745 
   746 lemma zdiv_zadd_self1[simp]: "a \<noteq> (0::int) ==> (a+b) div a = b div a + 1"
   747 by (simp add: zdiv_zadd1_eq)
   748 
   749 lemma zdiv_zadd_self2[simp]: "a \<noteq> (0::int) ==> (b+a) div a = b div a + 1"
   750 by (simp add: zdiv_zadd1_eq)
   751 
   752 lemma zmod_zadd_self1[simp]: "(a+b) mod a = b mod (a::int)"
   753 apply (case_tac "a = 0", simp)
   754 apply (simp add: zmod_zadd1_eq)
   755 done
   756 
   757 lemma zmod_zadd_self2[simp]: "(b+a) mod a = b mod (a::int)"
   758 apply (case_tac "a = 0", simp)
   759 apply (simp add: zmod_zadd1_eq)
   760 done
   761 
   762 
   763 subsection{*Proving  @{term "a div (b*c) = (a div b) div c"} *}
   764 
   765 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
   766   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
   767   to cause particular problems.*)
   768 
   769 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
   770 
   771 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
   772 apply (subgoal_tac "b * (c - q mod c) < r * 1")
   773 apply (simp add: right_diff_distrib)
   774 apply (rule order_le_less_trans)
   775 apply (erule_tac [2] mult_strict_right_mono)
   776 apply (rule mult_left_mono_neg)
   777 apply (auto simp add: compare_rls add_commute [of 1]
   778                       add1_zle_eq pos_mod_bound)
   779 done
   780 
   781 lemma zmult2_lemma_aux2:
   782      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
   783 apply (subgoal_tac "b * (q mod c) \<le> 0")
   784  apply arith
   785 apply (simp add: mult_le_0_iff)
   786 done
   787 
   788 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
   789 apply (subgoal_tac "0 \<le> b * (q mod c) ")
   790 apply arith
   791 apply (simp add: zero_le_mult_iff)
   792 done
   793 
   794 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
   795 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
   796 apply (simp add: right_diff_distrib)
   797 apply (rule order_less_le_trans)
   798 apply (erule mult_strict_right_mono)
   799 apply (rule_tac [2] mult_left_mono)
   800 apply (auto simp add: compare_rls add_commute [of 1]
   801                       add1_zle_eq pos_mod_bound)
   802 done
   803 
   804 lemma zmult2_lemma: "[| quorem ((a,b), (q,r));  b \<noteq> 0;  0 < c |]  
   805       ==> quorem ((a, b*c), (q div c, b*(q mod c) + r))"
   806 by (auto simp add: mult_ac quorem_def linorder_neq_iff
   807                    zero_less_mult_iff right_distrib [symmetric] 
   808                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
   809 
   810 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
   811 apply (case_tac "b = 0", simp)
   812 apply (force simp add: quorem_div_mod [THEN zmult2_lemma, THEN quorem_div])
   813 done
   814 
   815 lemma zmod_zmult2_eq:
   816      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
   817 apply (case_tac "b = 0", simp)
   818 apply (force simp add: quorem_div_mod [THEN zmult2_lemma, THEN quorem_mod])
   819 done
   820 
   821 
   822 subsection{*Cancellation of Common Factors in div*}
   823 
   824 lemma zdiv_zmult_zmult1_aux1:
   825      "[| (0::int) < b;  c \<noteq> 0 |] ==> (c*a) div (c*b) = a div b"
   826 by (subst zdiv_zmult2_eq, auto)
   827 
   828 lemma zdiv_zmult_zmult1_aux2:
   829      "[| b < (0::int);  c \<noteq> 0 |] ==> (c*a) div (c*b) = a div b"
   830 apply (subgoal_tac " (c * (-a)) div (c * (-b)) = (-a) div (-b) ")
   831 apply (rule_tac [2] zdiv_zmult_zmult1_aux1, auto)
   832 done
   833 
   834 lemma zdiv_zmult_zmult1: "c \<noteq> (0::int) ==> (c*a) div (c*b) = a div b"
   835 apply (case_tac "b = 0", simp)
   836 apply (auto simp add: linorder_neq_iff zdiv_zmult_zmult1_aux1 zdiv_zmult_zmult1_aux2)
   837 done
   838 
   839 lemma zdiv_zmult_zmult2: "c \<noteq> (0::int) ==> (a*c) div (b*c) = a div b"
   840 apply (drule zdiv_zmult_zmult1)
   841 apply (auto simp add: mult_commute)
   842 done
   843 
   844 
   845 
   846 subsection{*Distribution of Factors over mod*}
   847 
   848 lemma zmod_zmult_zmult1_aux1:
   849      "[| (0::int) < b;  c \<noteq> 0 |] ==> (c*a) mod (c*b) = c * (a mod b)"
   850 by (subst zmod_zmult2_eq, auto)
   851 
   852 lemma zmod_zmult_zmult1_aux2:
   853      "[| b < (0::int);  c \<noteq> 0 |] ==> (c*a) mod (c*b) = c * (a mod b)"
   854 apply (subgoal_tac " (c * (-a)) mod (c * (-b)) = c * ((-a) mod (-b))")
   855 apply (rule_tac [2] zmod_zmult_zmult1_aux1, auto)
   856 done
   857 
   858 lemma zmod_zmult_zmult1: "(c*a) mod (c*b) = (c::int) * (a mod b)"
   859 apply (case_tac "b = 0", simp)
   860 apply (case_tac "c = 0", simp)
   861 apply (auto simp add: linorder_neq_iff zmod_zmult_zmult1_aux1 zmod_zmult_zmult1_aux2)
   862 done
   863 
   864 lemma zmod_zmult_zmult2: "(a*c) mod (b*c) = (a mod b) * (c::int)"
   865 apply (cut_tac c = c in zmod_zmult_zmult1)
   866 apply (auto simp add: mult_commute)
   867 done
   868 
   869 
   870 subsection {*Splitting Rules for div and mod*}
   871 
   872 text{*The proofs of the two lemmas below are essentially identical*}
   873 
   874 lemma split_pos_lemma:
   875  "0<k ==> 
   876     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
   877 apply (rule iffI, clarify)
   878  apply (erule_tac P="P ?x ?y" in rev_mp)  
   879  apply (subst zmod_zadd1_eq) 
   880  apply (subst zdiv_zadd1_eq) 
   881  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
   882 txt{*converse direction*}
   883 apply (drule_tac x = "n div k" in spec) 
   884 apply (drule_tac x = "n mod k" in spec, simp)
   885 done
   886 
   887 lemma split_neg_lemma:
   888  "k<0 ==>
   889     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
   890 apply (rule iffI, clarify)
   891  apply (erule_tac P="P ?x ?y" in rev_mp)  
   892  apply (subst zmod_zadd1_eq) 
   893  apply (subst zdiv_zadd1_eq) 
   894  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
   895 txt{*converse direction*}
   896 apply (drule_tac x = "n div k" in spec) 
   897 apply (drule_tac x = "n mod k" in spec, simp)
   898 done
   899 
   900 lemma split_zdiv:
   901  "P(n div k :: int) =
   902   ((k = 0 --> P 0) & 
   903    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
   904    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
   905 apply (case_tac "k=0", simp)
   906 apply (simp only: linorder_neq_iff)
   907 apply (erule disjE) 
   908  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
   909                       split_neg_lemma [of concl: "%x y. P x"])
   910 done
   911 
   912 lemma split_zmod:
   913  "P(n mod k :: int) =
   914   ((k = 0 --> P n) & 
   915    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
   916    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
   917 apply (case_tac "k=0", simp)
   918 apply (simp only: linorder_neq_iff)
   919 apply (erule disjE) 
   920  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
   921                       split_neg_lemma [of concl: "%x y. P y"])
   922 done
   923 
   924 (* Enable arith to deal with div 2 and mod 2: *)
   925 declare split_zdiv [of _ _ "number_of k", simplified, standard, arith_split]
   926 declare split_zmod [of _ _ "number_of k", simplified, standard, arith_split]
   927 
   928 
   929 subsection{*Speeding up the Division Algorithm with Shifting*}
   930 
   931 text{*computing div by shifting *}
   932 
   933 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
   934 proof cases
   935   assume "a=0"
   936     thus ?thesis by simp
   937 next
   938   assume "a\<noteq>0" and le_a: "0\<le>a"   
   939   hence a_pos: "1 \<le> a" by arith
   940   hence one_less_a2: "1 < 2*a" by arith
   941   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
   942     by (simp add: mult_le_cancel_left add_commute [of 1] add1_zle_eq)
   943   with a_pos have "0 \<le> b mod a" by simp
   944   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
   945     by (simp add: mod_pos_pos_trivial one_less_a2)
   946   with  le_2a
   947   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
   948     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
   949                   right_distrib) 
   950   thus ?thesis
   951     by (subst zdiv_zadd1_eq,
   952         simp add: zdiv_zmult_zmult1 zmod_zmult_zmult1 one_less_a2
   953                   div_pos_pos_trivial)
   954 qed
   955 
   956 lemma neg_zdiv_mult_2: "a \<le> (0::int) ==> (1 + 2*b) div (2*a) = (b+1) div a"
   957 apply (subgoal_tac " (1 + 2* (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a) ")
   958 apply (rule_tac [2] pos_zdiv_mult_2)
   959 apply (auto simp add: minus_mult_right [symmetric] right_diff_distrib)
   960 apply (subgoal_tac " (-1 - (2 * b)) = - (1 + (2 * b))")
   961 apply (simp only: zdiv_zminus_zminus diff_minus minus_add_distrib [symmetric],
   962        simp) 
   963 done
   964 
   965 
   966 (*Not clear why this must be proved separately; probably number_of causes
   967   simplification problems*)
   968 lemma not_0_le_lemma: "~ 0 \<le> x ==> x \<le> (0::int)"
   969 by auto
   970 
   971 lemma zdiv_number_of_BIT[simp]:
   972      "number_of (v BIT b) div number_of (w BIT bit.B0) =  
   973           (if b=bit.B0 | (0::int) \<le> number_of w                    
   974            then number_of v div (number_of w)     
   975            else (number_of v + (1::int)) div (number_of w))"
   976 apply (simp only: number_of_eq numeral_simps UNIV_I split: split_if) 
   977 apply (simp add: zdiv_zmult_zmult1 pos_zdiv_mult_2 neg_zdiv_mult_2 add_ac 
   978             split: bit.split)
   979 done
   980 
   981 
   982 subsection{*Computing mod by Shifting (proofs resemble those for div)*}
   983 
   984 lemma pos_zmod_mult_2:
   985      "(0::int) \<le> a ==> (1 + 2*b) mod (2*a) = 1 + 2 * (b mod a)"
   986 apply (case_tac "a = 0", simp)
   987 apply (subgoal_tac "1 < a * 2")
   988  prefer 2 apply arith
   989 apply (subgoal_tac "2* (1 + b mod a) \<le> 2*a")
   990  apply (rule_tac [2] mult_left_mono)
   991 apply (auto simp add: add_commute [of 1] mult_commute add1_zle_eq 
   992                       pos_mod_bound)
   993 apply (subst zmod_zadd1_eq)
   994 apply (simp add: zmod_zmult_zmult2 mod_pos_pos_trivial)
   995 apply (rule mod_pos_pos_trivial)
   996 apply (auto simp add: mod_pos_pos_trivial left_distrib)
   997 apply (subgoal_tac "0 \<le> b mod a", arith, simp)
   998 done
   999 
  1000 lemma neg_zmod_mult_2:
  1001      "a \<le> (0::int) ==> (1 + 2*b) mod (2*a) = 2 * ((b+1) mod a) - 1"
  1002 apply (subgoal_tac "(1 + 2* (-b - 1)) mod (2* (-a)) = 
  1003                     1 + 2* ((-b - 1) mod (-a))")
  1004 apply (rule_tac [2] pos_zmod_mult_2)
  1005 apply (auto simp add: minus_mult_right [symmetric] right_diff_distrib)
  1006 apply (subgoal_tac " (-1 - (2 * b)) = - (1 + (2 * b))")
  1007  prefer 2 apply simp 
  1008 apply (simp only: zmod_zminus_zminus diff_minus minus_add_distrib [symmetric])
  1009 done
  1010 
  1011 lemma zmod_number_of_BIT [simp]:
  1012      "number_of (v BIT b) mod number_of (w BIT bit.B0) =  
  1013       (case b of
  1014           bit.B0 => 2 * (number_of v mod number_of w)
  1015         | bit.B1 => if (0::int) \<le> number_of w  
  1016                 then 2 * (number_of v mod number_of w) + 1     
  1017                 else 2 * ((number_of v + (1::int)) mod number_of w) - 1)"
  1018 apply (simp only: number_of_eq numeral_simps UNIV_I split: bit.split) 
  1019 apply (simp add: zmod_zmult_zmult1 pos_zmod_mult_2 
  1020                  not_0_le_lemma neg_zmod_mult_2 add_ac)
  1021 done
  1022 
  1023 
  1024 subsection{*Quotients of Signs*}
  1025 
  1026 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  1027 apply (subgoal_tac "a div b \<le> -1", force)
  1028 apply (rule order_trans)
  1029 apply (rule_tac a' = "-1" in zdiv_mono1)
  1030 apply (auto simp add: zdiv_minus1)
  1031 done
  1032 
  1033 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a;  b < 0 |] ==> a div b \<le> 0"
  1034 by (drule zdiv_mono1_neg, auto)
  1035 
  1036 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  1037 apply auto
  1038 apply (drule_tac [2] zdiv_mono1)
  1039 apply (auto simp add: linorder_neq_iff)
  1040 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  1041 apply (blast intro: div_neg_pos_less0)
  1042 done
  1043 
  1044 lemma neg_imp_zdiv_nonneg_iff:
  1045      "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  1046 apply (subst zdiv_zminus_zminus [symmetric])
  1047 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  1048 done
  1049 
  1050 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  1051 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  1052 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  1053 
  1054 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  1055 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  1056 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  1057 
  1058 
  1059 subsection {* The Divides Relation *}
  1060 
  1061 lemma zdvd_iff_zmod_eq_0: "(m dvd n) = (n mod m = (0::int))"
  1062 by(simp add:dvd_def zmod_eq_0_iff)
  1063 
  1064 lemmas zdvd_iff_zmod_eq_0_number_of [simp] =
  1065   zdvd_iff_zmod_eq_0 [of "number_of x" "number_of y", standard]
  1066 
  1067 lemma zdvd_0_right [iff]: "(m::int) dvd 0"
  1068 by (simp add: dvd_def)
  1069 
  1070 lemma zdvd_0_left [iff]: "(0 dvd (m::int)) = (m = 0)"
  1071   by (simp add: dvd_def)
  1072 
  1073 lemma zdvd_1_left [iff]: "1 dvd (m::int)"
  1074   by (simp add: dvd_def)
  1075 
  1076 lemma zdvd_refl [simp]: "m dvd (m::int)"
  1077 by (auto simp add: dvd_def intro: zmult_1_right [symmetric])
  1078 
  1079 lemma zdvd_trans: "m dvd n ==> n dvd k ==> m dvd (k::int)"
  1080 by (auto simp add: dvd_def intro: mult_assoc)
  1081 
  1082 lemma zdvd_zminus_iff: "(m dvd -n) = (m dvd (n::int))"
  1083   apply (simp add: dvd_def, auto)
  1084    apply (rule_tac [!] x = "-k" in exI, auto)
  1085   done
  1086 
  1087 lemma zdvd_zminus2_iff: "(-m dvd n) = (m dvd (n::int))"
  1088   apply (simp add: dvd_def, auto)
  1089    apply (rule_tac [!] x = "-k" in exI, auto)
  1090   done
  1091 lemma zdvd_abs1: "( \<bar>i::int\<bar> dvd j) = (i dvd j)" 
  1092   apply (cases "i > 0", simp)
  1093   apply (simp add: dvd_def)
  1094   apply (rule iffI)
  1095   apply (erule exE)
  1096   apply (rule_tac x="- k" in exI, simp)
  1097   apply (erule exE)
  1098   apply (rule_tac x="- k" in exI, simp)
  1099   done
  1100 lemma zdvd_abs2: "( (i::int) dvd \<bar>j\<bar>) = (i dvd j)" 
  1101   apply (cases "j > 0", simp)
  1102   apply (simp add: dvd_def)
  1103   apply (rule iffI)
  1104   apply (erule exE)
  1105   apply (rule_tac x="- k" in exI, simp)
  1106   apply (erule exE)
  1107   apply (rule_tac x="- k" in exI, simp)
  1108   done
  1109 
  1110 lemma zdvd_anti_sym:
  1111     "0 < m ==> 0 < n ==> m dvd n ==> n dvd m ==> m = (n::int)"
  1112   apply (simp add: dvd_def, auto)
  1113   apply (simp add: mult_assoc zero_less_mult_iff zmult_eq_1_iff)
  1114   done
  1115 
  1116 lemma zdvd_zadd: "k dvd m ==> k dvd n ==> k dvd (m + n :: int)"
  1117   apply (simp add: dvd_def)
  1118   apply (blast intro: right_distrib [symmetric])
  1119   done
  1120 
  1121 lemma zdvd_dvd_eq: assumes anz:"a \<noteq> 0" and ab: "(a::int) dvd b" and ba:"b dvd a" 
  1122   shows "\<bar>a\<bar> = \<bar>b\<bar>"
  1123 proof-
  1124   from ab obtain k where k:"b = a*k" unfolding dvd_def by blast 
  1125   from ba obtain k' where k':"a = b*k'" unfolding dvd_def by blast 
  1126   from k k' have "a = a*k*k'" by simp
  1127   with mult_cancel_left1[where c="a" and b="k*k'"]
  1128   have kk':"k*k' = 1" using anz by (simp add: mult_assoc)
  1129   hence "k = 1 \<and> k' = 1 \<or> k = -1 \<and> k' = -1" by (simp add: zmult_eq_1_iff)
  1130   thus ?thesis using k k' by auto
  1131 qed
  1132 
  1133 lemma zdvd_zdiff: "k dvd m ==> k dvd n ==> k dvd (m - n :: int)"
  1134   apply (simp add: dvd_def)
  1135   apply (blast intro: right_diff_distrib [symmetric])
  1136   done
  1137 
  1138 lemma zdvd_zdiffD: "k dvd m - n ==> k dvd n ==> k dvd (m::int)"
  1139   apply (subgoal_tac "m = n + (m - n)")
  1140    apply (erule ssubst)
  1141    apply (blast intro: zdvd_zadd, simp)
  1142   done
  1143 
  1144 lemma zdvd_zmult: "k dvd (n::int) ==> k dvd m * n"
  1145   apply (simp add: dvd_def)
  1146   apply (blast intro: mult_left_commute)
  1147   done
  1148 
  1149 lemma zdvd_zmult2: "k dvd (m::int) ==> k dvd m * n"
  1150   apply (subst mult_commute)
  1151   apply (erule zdvd_zmult)
  1152   done
  1153 
  1154 lemma zdvd_triv_right [iff]: "(k::int) dvd m * k"
  1155   apply (rule zdvd_zmult)
  1156   apply (rule zdvd_refl)
  1157   done
  1158 
  1159 lemma zdvd_triv_left [iff]: "(k::int) dvd k * m"
  1160   apply (rule zdvd_zmult2)
  1161   apply (rule zdvd_refl)
  1162   done
  1163 
  1164 lemma zdvd_zmultD2: "j * k dvd n ==> j dvd (n::int)"
  1165   apply (simp add: dvd_def)
  1166   apply (simp add: mult_assoc, blast)
  1167   done
  1168 
  1169 lemma zdvd_zmultD: "j * k dvd n ==> k dvd (n::int)"
  1170   apply (rule zdvd_zmultD2)
  1171   apply (subst mult_commute, assumption)
  1172   done
  1173 
  1174 lemma zdvd_zmult_mono: "i dvd m ==> j dvd (n::int) ==> i * j dvd m * n"
  1175   apply (simp add: dvd_def, clarify)
  1176   apply (rule_tac x = "k * ka" in exI)
  1177   apply (simp add: mult_ac)
  1178   done
  1179 
  1180 lemma zdvd_reduce: "(k dvd n + k * m) = (k dvd (n::int))"
  1181   apply (rule iffI)
  1182    apply (erule_tac [2] zdvd_zadd)
  1183    apply (subgoal_tac "n = (n + k * m) - k * m")
  1184     apply (erule ssubst)
  1185     apply (erule zdvd_zdiff, simp_all)
  1186   done
  1187 
  1188 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  1189   apply (simp add: dvd_def)
  1190   apply (auto simp add: zmod_zmult_zmult1)
  1191   done
  1192 
  1193 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  1194   apply (subgoal_tac "k dvd n * (m div n) + m mod n")
  1195    apply (simp add: zmod_zdiv_equality [symmetric])
  1196   apply (simp only: zdvd_zadd zdvd_zmult2)
  1197   done
  1198 
  1199 lemma zdvd_not_zless: "0 < m ==> m < n ==> \<not> n dvd (m::int)"
  1200   apply (simp add: dvd_def, auto)
  1201   apply (subgoal_tac "0 < n")
  1202    prefer 2
  1203    apply (blast intro: order_less_trans)
  1204   apply (simp add: zero_less_mult_iff)
  1205   apply (subgoal_tac "n * k < n * 1")
  1206    apply (drule mult_less_cancel_left [THEN iffD1], auto)
  1207   done
  1208 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  1209   using zmod_zdiv_equality[where a="m" and b="n"]
  1210   by (simp add: ring_eq_simps)
  1211 
  1212 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  1213 apply (subgoal_tac "m mod n = 0")
  1214  apply (simp add: zmult_div_cancel)
  1215 apply (simp only: zdvd_iff_zmod_eq_0)
  1216 done
  1217 
  1218 lemma zdvd_mult_cancel: assumes d:"k * m dvd k * n" and kz:"k \<noteq> (0::int)"
  1219   shows "m dvd n"
  1220 proof-
  1221   from d obtain h where h: "k*n = k*m * h" unfolding dvd_def by blast
  1222   {assume "n \<noteq> m*h" hence "k* n \<noteq> k* (m*h)" using kz by simp
  1223     with h have False by (simp add: mult_assoc)}
  1224   hence "n = m * h" by blast
  1225   thus ?thesis by blast
  1226 qed
  1227 
  1228 theorem ex_nat: "(\<exists>x::nat. P x) = (\<exists>x::int. 0 <= x \<and> P (nat x))"
  1229   apply (simp split add: split_nat)
  1230   apply (rule iffI)
  1231   apply (erule exE)
  1232   apply (rule_tac x = "int x" in exI)
  1233   apply simp
  1234   apply (erule exE)
  1235   apply (rule_tac x = "nat x" in exI)
  1236   apply (erule conjE)
  1237   apply (erule_tac x = "nat x" in allE)
  1238   apply simp
  1239   done
  1240 
  1241 theorem zdvd_int: "(x dvd y) = (int x dvd int y)"
  1242   apply (simp only: dvd_def ex_nat int_int_eq [symmetric] zmult_int [symmetric]
  1243     nat_0_le cong add: conj_cong)
  1244   apply (rule iffI)
  1245   apply iprover
  1246   apply (erule exE)
  1247   apply (case_tac "x=0")
  1248   apply (rule_tac x=0 in exI)
  1249   apply simp
  1250   apply (case_tac "0 \<le> k")
  1251   apply iprover
  1252   apply (simp add: linorder_not_le)
  1253   apply (drule mult_strict_left_mono_neg [OF iffD2 [OF zero_less_int_conv]])
  1254   apply assumption
  1255   apply (simp add: mult_ac)
  1256   done
  1257 
  1258 lemma zdvd1_eq[simp]: "(x::int) dvd 1 = ( \<bar>x\<bar> = 1)"
  1259 proof
  1260   assume d: "x dvd 1" hence "int (nat \<bar>x\<bar>) dvd int (nat 1)" by (simp add: zdvd_abs1)
  1261   hence "nat \<bar>x\<bar> dvd 1" by (simp add: zdvd_int)
  1262   hence "nat \<bar>x\<bar> = 1"  by simp
  1263   thus "\<bar>x\<bar> = 1" by (cases "x < 0", auto)
  1264 next
  1265   assume "\<bar>x\<bar>=1" thus "x dvd 1" 
  1266     by(cases "x < 0",simp_all add: minus_equation_iff zdvd_iff_zmod_eq_0)
  1267 qed
  1268 lemma zdvd_mult_cancel1: 
  1269   assumes mp:"m \<noteq>(0::int)" shows "(m * n dvd m) = (\<bar>n\<bar> = 1)"
  1270 proof
  1271   assume n1: "\<bar>n\<bar> = 1" thus "m * n dvd m" 
  1272     by (cases "n >0", auto simp add: zdvd_zminus2_iff minus_equation_iff)
  1273 next
  1274   assume H: "m * n dvd m" hence H2: "m * n dvd m * 1" by simp
  1275   from zdvd_mult_cancel[OF H2 mp] show "\<bar>n\<bar> = 1" by (simp only: zdvd1_eq)
  1276 qed
  1277 
  1278 lemma int_dvd_iff: "(int m dvd z) = (m dvd nat (abs z))"
  1279   apply (auto simp add: dvd_def nat_abs_mult_distrib)
  1280   apply (auto simp add: nat_eq_iff abs_if split add: split_if_asm)
  1281    apply (rule_tac x = "-(int k)" in exI)
  1282   apply (auto simp add: int_mult)
  1283   done
  1284 
  1285 lemma dvd_int_iff: "(z dvd int m) = (nat (abs z) dvd m)"
  1286   apply (auto simp add: dvd_def abs_if int_mult)
  1287     apply (rule_tac [3] x = "nat k" in exI)
  1288     apply (rule_tac [2] x = "-(int k)" in exI)
  1289     apply (rule_tac x = "nat (-k)" in exI)
  1290     apply (cut_tac [3] k = m in int_less_0_conv)
  1291     apply (cut_tac k = m in int_less_0_conv)
  1292     apply (auto simp add: zero_le_mult_iff mult_less_0_iff
  1293       nat_mult_distrib [symmetric] nat_eq_iff2)
  1294   done
  1295 
  1296 lemma nat_dvd_iff: "(nat z dvd m) = (if 0 \<le> z then (z dvd int m) else m = 0)"
  1297   apply (auto simp add: dvd_def int_mult)
  1298   apply (rule_tac x = "nat k" in exI)
  1299   apply (cut_tac k = m in int_less_0_conv)
  1300   apply (auto simp add: zero_le_mult_iff mult_less_0_iff
  1301     nat_mult_distrib [symmetric] nat_eq_iff2)
  1302   done
  1303 
  1304 lemma zminus_dvd_iff [iff]: "(-z dvd w) = (z dvd (w::int))"
  1305   apply (auto simp add: dvd_def)
  1306    apply (rule_tac [!] x = "-k" in exI, auto)
  1307   done
  1308 
  1309 lemma dvd_zminus_iff [iff]: "(z dvd -w) = (z dvd (w::int))"
  1310   apply (auto simp add: dvd_def)
  1311    apply (drule minus_equation_iff [THEN iffD1])
  1312    apply (rule_tac [!] x = "-k" in exI, auto)
  1313   done
  1314 
  1315 lemma zdvd_imp_le: "[| z dvd n; 0 < n |] ==> z \<le> (n::int)"
  1316   apply (rule_tac z=n in int_cases)
  1317   apply (auto simp add: dvd_int_iff) 
  1318   apply (rule_tac z=z in int_cases) 
  1319   apply (auto simp add: dvd_imp_le) 
  1320   done
  1321 
  1322 
  1323 subsection{*Integer Powers*} 
  1324 
  1325 instance int :: power ..
  1326 
  1327 primrec
  1328   "p ^ 0 = 1"
  1329   "p ^ (Suc n) = (p::int) * (p ^ n)"
  1330 
  1331 
  1332 instance int :: recpower
  1333 proof
  1334   fix z :: int
  1335   fix n :: nat
  1336   show "z^0 = 1" by simp
  1337   show "z^(Suc n) = z * (z^n)" by simp
  1338 qed
  1339 
  1340 
  1341 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  1342 apply (induct "y", auto)
  1343 apply (rule zmod_zmult1_eq [THEN trans])
  1344 apply (simp (no_asm_simp))
  1345 apply (rule zmod_zmult_distrib [symmetric])
  1346 done
  1347 
  1348 lemma zpower_zadd_distrib: "x^(y+z) = ((x^y)*(x^z)::int)"
  1349   by (rule Power.power_add)
  1350 
  1351 lemma zpower_zpower: "(x^y)^z = (x^(y*z)::int)"
  1352   by (rule Power.power_mult [symmetric])
  1353 
  1354 lemma zero_less_zpower_abs_iff [simp]:
  1355      "(0 < (abs x)^n) = (x \<noteq> (0::int) | n=0)"
  1356 apply (induct "n")
  1357 apply (auto simp add: zero_less_mult_iff)
  1358 done
  1359 
  1360 lemma zero_le_zpower_abs [simp]: "(0::int) <= (abs x)^n"
  1361 apply (induct "n")
  1362 apply (auto simp add: zero_le_mult_iff)
  1363 done
  1364 
  1365 lemma int_power: "int (m^n) = (int m) ^ n"
  1366   by (induct n, simp_all add: int_mult)
  1367 
  1368 text{*Compatibility binding*}
  1369 lemmas zpower_int = int_power [symmetric]
  1370 
  1371 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  1372 apply (subst split_div, auto)
  1373 apply (subst split_zdiv, auto)
  1374 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in IntDiv.unique_quotient)
  1375 apply (auto simp add: IntDiv.quorem_def int_eq_of_nat)
  1376 done
  1377 
  1378 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  1379 apply (subst split_mod, auto)
  1380 apply (subst split_zmod, auto)
  1381 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  1382        in unique_remainder)
  1383 apply (auto simp add: IntDiv.quorem_def int_eq_of_nat)
  1384 done
  1385 
  1386 text{*Suggested by Matthias Daum*}
  1387 lemma int_power_div_base:
  1388      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  1389 apply (subgoal_tac "k ^ m = k ^ ((m - 1) + 1)")
  1390  apply (erule ssubst)
  1391  apply (simp only: power_add)
  1392  apply simp_all
  1393 done
  1394 
  1395 text {* code serializer setup *}
  1396 
  1397 code_modulename SML
  1398   IntDiv Integer
  1399 
  1400 code_modulename OCaml
  1401   IntDiv Integer
  1402 
  1403 code_modulename Haskell
  1404   IntDiv Divides
  1405 
  1406 end