src/HOL/Library/Numeral_Type.thy
author huffman
Thu Feb 19 23:18:28 2009 -0800 (2009-02-19)
changeset 30001 dd27e16677b2
parent 29999 da85a244e328
child 30032 c7f0c1b8001b
permissions -rw-r--r--
cleaned up
     1 (*  Title:      HOL/Library/Numeral_Type.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Numeral Syntax for Types *}
     6 
     7 theory Numeral_Type
     8 imports Plain "~~/src/HOL/Presburger"
     9 begin
    10 
    11 subsection {* Preliminary lemmas *}
    12 (* These should be moved elsewhere *)
    13 
    14 lemma (in type_definition) univ:
    15   "UNIV = Abs ` A"
    16 proof
    17   show "Abs ` A \<subseteq> UNIV" by (rule subset_UNIV)
    18   show "UNIV \<subseteq> Abs ` A"
    19   proof
    20     fix x :: 'b
    21     have "x = Abs (Rep x)" by (rule Rep_inverse [symmetric])
    22     moreover have "Rep x \<in> A" by (rule Rep)
    23     ultimately show "x \<in> Abs ` A" by (rule image_eqI)
    24   qed
    25 qed
    26 
    27 lemma (in type_definition) card: "card (UNIV :: 'b set) = card A"
    28   by (simp add: univ card_image inj_on_def Abs_inject)
    29 
    30 
    31 subsection {* Cardinalities of types *}
    32 
    33 syntax "_type_card" :: "type => nat" ("(1CARD/(1'(_')))")
    34 
    35 translations "CARD(t)" => "CONST card (CONST UNIV \<Colon> t set)"
    36 
    37 typed_print_translation {*
    38 let
    39   fun card_univ_tr' show_sorts _ [Const (@{const_name UNIV}, Type(_,[T,_]))] =
    40     Syntax.const "_type_card" $ Syntax.term_of_typ show_sorts T;
    41 in [(@{const_syntax card}, card_univ_tr')]
    42 end
    43 *}
    44 
    45 lemma card_unit [simp]: "CARD(unit) = 1"
    46   unfolding UNIV_unit by simp
    47 
    48 lemma card_bool [simp]: "CARD(bool) = 2"
    49   unfolding UNIV_bool by simp
    50 
    51 lemma card_prod [simp]: "CARD('a \<times> 'b) = CARD('a::finite) * CARD('b::finite)"
    52   unfolding UNIV_Times_UNIV [symmetric] by (simp only: card_cartesian_product)
    53 
    54 lemma card_sum [simp]: "CARD('a + 'b) = CARD('a::finite) + CARD('b::finite)"
    55   unfolding UNIV_Plus_UNIV [symmetric] by (simp only: finite card_Plus)
    56 
    57 lemma card_option [simp]: "CARD('a option) = Suc CARD('a::finite)"
    58   unfolding insert_None_conv_UNIV [symmetric]
    59   apply (subgoal_tac "(None::'a option) \<notin> range Some")
    60   apply (simp add: card_image)
    61   apply fast
    62   done
    63 
    64 lemma card_set [simp]: "CARD('a set) = 2 ^ CARD('a::finite)"
    65   unfolding Pow_UNIV [symmetric]
    66   by (simp only: card_Pow finite numeral_2_eq_2)
    67 
    68 lemma card_nat [simp]: "CARD(nat) = 0"
    69   by (simp add: infinite_UNIV_nat card_eq_0_iff)
    70 
    71 
    72 subsection {* Classes with at least 1 and 2  *}
    73 
    74 text {* Class finite already captures "at least 1" *}
    75 
    76 lemma zero_less_card_finite [simp]: "0 < CARD('a::finite)"
    77   unfolding neq0_conv [symmetric] by simp
    78 
    79 lemma one_le_card_finite [simp]: "Suc 0 \<le> CARD('a::finite)"
    80   by (simp add: less_Suc_eq_le [symmetric])
    81 
    82 text {* Class for cardinality "at least 2" *}
    83 
    84 class card2 = finite + 
    85   assumes two_le_card: "2 \<le> CARD('a)"
    86 
    87 lemma one_less_card: "Suc 0 < CARD('a::card2)"
    88   using two_le_card [where 'a='a] by simp
    89 
    90 lemma one_less_int_card: "1 < int CARD('a::card2)"
    91   using one_less_card [where 'a='a] by simp
    92 
    93 
    94 subsection {* Numeral Types *}
    95 
    96 typedef (open) num0 = "UNIV :: nat set" ..
    97 typedef (open) num1 = "UNIV :: unit set" ..
    98 
    99 typedef (open) 'a bit0 = "{0 ..< 2 * int CARD('a::finite)}"
   100 proof
   101   show "0 \<in> {0 ..< 2 * int CARD('a)}"
   102     by simp
   103 qed
   104 
   105 typedef (open) 'a bit1 = "{0 ..< 1 + 2 * int CARD('a::finite)}"
   106 proof
   107   show "0 \<in> {0 ..< 1 + 2 * int CARD('a)}"
   108     by simp
   109 qed
   110 
   111 lemma card_num0 [simp]: "CARD (num0) = 0"
   112   unfolding type_definition.card [OF type_definition_num0]
   113   by simp
   114 
   115 lemma card_num1 [simp]: "CARD(num1) = 1"
   116   unfolding type_definition.card [OF type_definition_num1]
   117   by (simp only: card_unit)
   118 
   119 lemma card_bit0 [simp]: "CARD('a bit0) = 2 * CARD('a::finite)"
   120   unfolding type_definition.card [OF type_definition_bit0]
   121   by simp
   122 
   123 lemma card_bit1 [simp]: "CARD('a bit1) = Suc (2 * CARD('a::finite))"
   124   unfolding type_definition.card [OF type_definition_bit1]
   125   by simp
   126 
   127 instance num1 :: finite
   128 proof
   129   show "finite (UNIV::num1 set)"
   130     unfolding type_definition.univ [OF type_definition_num1]
   131     using finite by (rule finite_imageI)
   132 qed
   133 
   134 instance bit0 :: (finite) card2
   135 proof
   136   show "finite (UNIV::'a bit0 set)"
   137     unfolding type_definition.univ [OF type_definition_bit0]
   138     by simp
   139   show "2 \<le> CARD('a bit0)"
   140     by simp
   141 qed
   142 
   143 instance bit1 :: (finite) card2
   144 proof
   145   show "finite (UNIV::'a bit1 set)"
   146     unfolding type_definition.univ [OF type_definition_bit1]
   147     by simp
   148   show "2 \<le> CARD('a bit1)"
   149     by simp
   150 qed
   151 
   152 
   153 subsection {* Locale for modular arithmetic subtypes *}
   154 
   155 locale mod_type =
   156   fixes n :: int
   157   and Rep :: "'a::{zero,one,plus,times,uminus,minus,power} \<Rightarrow> int"
   158   and Abs :: "int \<Rightarrow> 'a::{zero,one,plus,times,uminus,minus,power}"
   159   assumes type: "type_definition Rep Abs {0..<n}"
   160   and size1: "1 < n"
   161   and zero_def: "0 = Abs 0"
   162   and one_def:  "1 = Abs 1"
   163   and add_def:  "x + y = Abs ((Rep x + Rep y) mod n)"
   164   and mult_def: "x * y = Abs ((Rep x * Rep y) mod n)"
   165   and diff_def: "x - y = Abs ((Rep x - Rep y) mod n)"
   166   and minus_def: "- x = Abs ((- Rep x) mod n)"
   167   and power_def: "x ^ k = Abs (Rep x ^ k mod n)"
   168 begin
   169 
   170 lemma size0: "0 < n"
   171 by (cut_tac size1, simp)
   172 
   173 lemmas definitions =
   174   zero_def one_def add_def mult_def minus_def diff_def power_def
   175 
   176 lemma Rep_less_n: "Rep x < n"
   177 by (rule type_definition.Rep [OF type, simplified, THEN conjunct2])
   178 
   179 lemma Rep_le_n: "Rep x \<le> n"
   180 by (rule Rep_less_n [THEN order_less_imp_le])
   181 
   182 lemma Rep_inject_sym: "x = y \<longleftrightarrow> Rep x = Rep y"
   183 by (rule type_definition.Rep_inject [OF type, symmetric])
   184 
   185 lemma Rep_inverse: "Abs (Rep x) = x"
   186 by (rule type_definition.Rep_inverse [OF type])
   187 
   188 lemma Abs_inverse: "m \<in> {0..<n} \<Longrightarrow> Rep (Abs m) = m"
   189 by (rule type_definition.Abs_inverse [OF type])
   190 
   191 lemma Rep_Abs_mod: "Rep (Abs (m mod n)) = m mod n"
   192 by (simp add: Abs_inverse IntDiv.pos_mod_conj [OF size0])
   193 
   194 lemma Rep_Abs_0: "Rep (Abs 0) = 0"
   195 by (simp add: Abs_inverse size0)
   196 
   197 lemma Rep_0: "Rep 0 = 0"
   198 by (simp add: zero_def Rep_Abs_0)
   199 
   200 lemma Rep_Abs_1: "Rep (Abs 1) = 1"
   201 by (simp add: Abs_inverse size1)
   202 
   203 lemma Rep_1: "Rep 1 = 1"
   204 by (simp add: one_def Rep_Abs_1)
   205 
   206 lemma Rep_mod: "Rep x mod n = Rep x"
   207 apply (rule_tac x=x in type_definition.Abs_cases [OF type])
   208 apply (simp add: type_definition.Abs_inverse [OF type])
   209 apply (simp add: mod_pos_pos_trivial)
   210 done
   211 
   212 lemmas Rep_simps =
   213   Rep_inject_sym Rep_inverse Rep_Abs_mod Rep_mod Rep_Abs_0 Rep_Abs_1
   214 
   215 lemma comm_ring_1: "OFCLASS('a, comm_ring_1_class)"
   216 apply (intro_classes, unfold definitions)
   217 apply (simp_all add: Rep_simps zmod_simps ring_simps)
   218 done
   219 
   220 lemma recpower: "OFCLASS('a, recpower_class)"
   221 apply (intro_classes, unfold definitions)
   222 apply (simp_all add: Rep_simps zmod_simps add_ac mult_assoc
   223                      mod_pos_pos_trivial size1)
   224 done
   225 
   226 end
   227 
   228 locale mod_ring = mod_type +
   229   constrains n :: int
   230   and Rep :: "'a::{number_ring,power} \<Rightarrow> int"
   231   and Abs :: "int \<Rightarrow> 'a::{number_ring,power}"
   232 begin
   233 
   234 lemma of_nat_eq: "of_nat k = Abs (int k mod n)"
   235 apply (induct k)
   236 apply (simp add: zero_def)
   237 apply (simp add: Rep_simps add_def one_def zmod_simps add_ac)
   238 done
   239 
   240 lemma of_int_eq: "of_int z = Abs (z mod n)"
   241 apply (cases z rule: int_diff_cases)
   242 apply (simp add: Rep_simps of_nat_eq diff_def zmod_simps)
   243 done
   244 
   245 lemma Rep_number_of:
   246   "Rep (number_of w) = number_of w mod n"
   247 by (simp add: number_of_eq of_int_eq Rep_Abs_mod)
   248 
   249 lemma iszero_number_of:
   250   "iszero (number_of w::'a) \<longleftrightarrow> number_of w mod n = 0"
   251 by (simp add: Rep_simps number_of_eq of_int_eq iszero_def zero_def)
   252 
   253 lemma cases:
   254   assumes 1: "\<And>z. \<lbrakk>(x::'a) = of_int z; 0 \<le> z; z < n\<rbrakk> \<Longrightarrow> P"
   255   shows "P"
   256 apply (cases x rule: type_definition.Abs_cases [OF type])
   257 apply (rule_tac z="y" in 1)
   258 apply (simp_all add: of_int_eq mod_pos_pos_trivial)
   259 done
   260 
   261 lemma induct:
   262   "(\<And>z. \<lbrakk>0 \<le> z; z < n\<rbrakk> \<Longrightarrow> P (of_int z)) \<Longrightarrow> P (x::'a)"
   263 by (cases x rule: cases) simp
   264 
   265 end
   266 
   267 
   268 subsection {* Number ring instances *}
   269 
   270 instantiation
   271   bit0 and bit1 :: (finite) "{zero,one,plus,times,uminus,minus,power}"
   272 begin
   273 
   274 definition Abs_bit0' :: "int \<Rightarrow> 'a bit0" where
   275   "Abs_bit0' x = Abs_bit0 (x mod int CARD('a bit0))"
   276 
   277 definition Abs_bit1' :: "int \<Rightarrow> 'a bit1" where
   278   "Abs_bit1' x = Abs_bit1 (x mod int CARD('a bit1))"
   279 
   280 definition "0 = Abs_bit0 0"
   281 definition "1 = Abs_bit0 1"
   282 definition "x + y = Abs_bit0' (Rep_bit0 x + Rep_bit0 y)"
   283 definition "x * y = Abs_bit0' (Rep_bit0 x * Rep_bit0 y)"
   284 definition "x - y = Abs_bit0' (Rep_bit0 x - Rep_bit0 y)"
   285 definition "- x = Abs_bit0' (- Rep_bit0 x)"
   286 definition "x ^ k = Abs_bit0' (Rep_bit0 x ^ k)"
   287 
   288 definition "0 = Abs_bit1 0"
   289 definition "1 = Abs_bit1 1"
   290 definition "x + y = Abs_bit1' (Rep_bit1 x + Rep_bit1 y)"
   291 definition "x * y = Abs_bit1' (Rep_bit1 x * Rep_bit1 y)"
   292 definition "x - y = Abs_bit1' (Rep_bit1 x - Rep_bit1 y)"
   293 definition "- x = Abs_bit1' (- Rep_bit1 x)"
   294 definition "x ^ k = Abs_bit1' (Rep_bit1 x ^ k)"
   295 
   296 instance ..
   297 
   298 end
   299 
   300 interpretation bit0!:
   301   mod_type "int CARD('a::finite bit0)"
   302            "Rep_bit0 :: 'a::finite bit0 \<Rightarrow> int"
   303            "Abs_bit0 :: int \<Rightarrow> 'a::finite bit0"
   304 apply (rule mod_type.intro)
   305 apply (simp add: int_mult type_definition_bit0)
   306 apply (rule one_less_int_card)
   307 apply (rule zero_bit0_def)
   308 apply (rule one_bit0_def)
   309 apply (rule plus_bit0_def [unfolded Abs_bit0'_def])
   310 apply (rule times_bit0_def [unfolded Abs_bit0'_def])
   311 apply (rule minus_bit0_def [unfolded Abs_bit0'_def])
   312 apply (rule uminus_bit0_def [unfolded Abs_bit0'_def])
   313 apply (rule power_bit0_def [unfolded Abs_bit0'_def])
   314 done
   315 
   316 interpretation bit1!:
   317   mod_type "int CARD('a::finite bit1)"
   318            "Rep_bit1 :: 'a::finite bit1 \<Rightarrow> int"
   319            "Abs_bit1 :: int \<Rightarrow> 'a::finite bit1"
   320 apply (rule mod_type.intro)
   321 apply (simp add: int_mult type_definition_bit1)
   322 apply (rule one_less_int_card)
   323 apply (rule zero_bit1_def)
   324 apply (rule one_bit1_def)
   325 apply (rule plus_bit1_def [unfolded Abs_bit1'_def])
   326 apply (rule times_bit1_def [unfolded Abs_bit1'_def])
   327 apply (rule minus_bit1_def [unfolded Abs_bit1'_def])
   328 apply (rule uminus_bit1_def [unfolded Abs_bit1'_def])
   329 apply (rule power_bit1_def [unfolded Abs_bit1'_def])
   330 done
   331 
   332 instance bit0 :: (finite) "{comm_ring_1,recpower}"
   333   by (rule bit0.comm_ring_1 bit0.recpower)+
   334 
   335 instance bit1 :: (finite) "{comm_ring_1,recpower}"
   336   by (rule bit1.comm_ring_1 bit1.recpower)+
   337 
   338 instantiation bit0 and bit1 :: (finite) number_ring
   339 begin
   340 
   341 definition "(number_of w :: _ bit0) = of_int w"
   342 
   343 definition "(number_of w :: _ bit1) = of_int w"
   344 
   345 instance proof
   346 qed (rule number_of_bit0_def number_of_bit1_def)+
   347 
   348 end
   349 
   350 interpretation bit0!:
   351   mod_ring "int CARD('a::finite bit0)"
   352            "Rep_bit0 :: 'a::finite bit0 \<Rightarrow> int"
   353            "Abs_bit0 :: int \<Rightarrow> 'a::finite bit0"
   354   ..
   355 
   356 interpretation bit1!:
   357   mod_ring "int CARD('a::finite bit1)"
   358            "Rep_bit1 :: 'a::finite bit1 \<Rightarrow> int"
   359            "Abs_bit1 :: int \<Rightarrow> 'a::finite bit1"
   360   ..
   361 
   362 text {* Set up cases, induction, and arithmetic *}
   363 
   364 lemmas bit0_cases [case_names of_int, cases type: bit0] = bit0.cases
   365 lemmas bit1_cases [case_names of_int, cases type: bit1] = bit1.cases
   366 
   367 lemmas bit0_induct [case_names of_int, induct type: bit0] = bit0.induct
   368 lemmas bit1_induct [case_names of_int, induct type: bit1] = bit1.induct
   369 
   370 lemmas bit0_iszero_number_of [simp] = bit0.iszero_number_of
   371 lemmas bit1_iszero_number_of [simp] = bit1.iszero_number_of
   372 
   373 declare power_Suc [where ?'a="'a::finite bit0", standard, simp]
   374 declare power_Suc [where ?'a="'a::finite bit1", standard, simp]
   375 
   376 
   377 subsection {* Syntax *}
   378 
   379 syntax
   380   "_NumeralType" :: "num_const => type"  ("_")
   381   "_NumeralType0" :: type ("0")
   382   "_NumeralType1" :: type ("1")
   383 
   384 translations
   385   "_NumeralType1" == (type) "num1"
   386   "_NumeralType0" == (type) "num0"
   387 
   388 parse_translation {*
   389 let
   390 
   391 val num1_const = Syntax.const "Numeral_Type.num1";
   392 val num0_const = Syntax.const "Numeral_Type.num0";
   393 val B0_const = Syntax.const "Numeral_Type.bit0";
   394 val B1_const = Syntax.const "Numeral_Type.bit1";
   395 
   396 fun mk_bintype n =
   397   let
   398     fun mk_bit n = if n = 0 then B0_const else B1_const;
   399     fun bin_of n =
   400       if n = 1 then num1_const
   401       else if n = 0 then num0_const
   402       else if n = ~1 then raise TERM ("negative type numeral", [])
   403       else
   404         let val (q, r) = Integer.div_mod n 2;
   405         in mk_bit r $ bin_of q end;
   406   in bin_of n end;
   407 
   408 fun numeral_tr (*"_NumeralType"*) [Const (str, _)] =
   409       mk_bintype (valOf (Int.fromString str))
   410   | numeral_tr (*"_NumeralType"*) ts = raise TERM ("numeral_tr", ts);
   411 
   412 in [("_NumeralType", numeral_tr)] end;
   413 *}
   414 
   415 print_translation {*
   416 let
   417 fun int_of [] = 0
   418   | int_of (b :: bs) = b + 2 * int_of bs;
   419 
   420 fun bin_of (Const ("num0", _)) = []
   421   | bin_of (Const ("num1", _)) = [1]
   422   | bin_of (Const ("bit0", _) $ bs) = 0 :: bin_of bs
   423   | bin_of (Const ("bit1", _) $ bs) = 1 :: bin_of bs
   424   | bin_of t = raise TERM("bin_of", [t]);
   425 
   426 fun bit_tr' b [t] =
   427   let
   428     val rev_digs = b :: bin_of t handle TERM _ => raise Match
   429     val i = int_of rev_digs;
   430     val num = string_of_int (abs i);
   431   in
   432     Syntax.const "_NumeralType" $ Syntax.free num
   433   end
   434   | bit_tr' b _ = raise Match;
   435 
   436 in [("bit0", bit_tr' 0), ("bit1", bit_tr' 1)] end;
   437 *}
   438 
   439 subsection {* Examples *}
   440 
   441 lemma "CARD(0) = 0" by simp
   442 lemma "CARD(17) = 17" by simp
   443 lemma "8 * 11 ^ 3 - 6 = (2::5)" by simp
   444 
   445 end