src/HOL/Transitive_Closure.thy
author Christian Sternagel
Thu Aug 30 15:44:03 2012 +0900 (2012-08-30)
changeset 49093 fdc301f592c4
parent 48891 c0eafbd55de3
child 50616 5b6cf0fbc329
permissions -rw-r--r--
forgot to add lemmas
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Reflexive and Transitive closure of a relation *}
     7 
     8 theory Transitive_Closure
     9 imports Relation
    10 begin
    11 
    12 ML_file "~~/src/Provers/trancl.ML"
    13 
    14 text {*
    15   @{text rtrancl} is reflexive/transitive closure,
    16   @{text trancl} is transitive closure,
    17   @{text reflcl} is reflexive closure.
    18 
    19   These postfix operators have \emph{maximum priority}, forcing their
    20   operands to be atomic.
    21 *}
    22 
    23 inductive_set
    24   rtrancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"   ("(_^*)" [1000] 999)
    25   for r :: "('a \<times> 'a) set"
    26 where
    27     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    28   | rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    29 
    30 inductive_set
    31   trancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"  ("(_^+)" [1000] 999)
    32   for r :: "('a \<times> 'a) set"
    33 where
    34     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    35   | trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a, c) : r^+"
    36 
    37 declare rtrancl_def [nitpick_unfold del]
    38         rtranclp_def [nitpick_unfold del]
    39         trancl_def [nitpick_unfold del]
    40         tranclp_def [nitpick_unfold del]
    41 
    42 notation
    43   rtranclp  ("(_^**)" [1000] 1000) and
    44   tranclp  ("(_^++)" [1000] 1000)
    45 
    46 abbreviation
    47   reflclp :: "('a => 'a => bool) => 'a => 'a => bool"  ("(_^==)" [1000] 1000) where
    48   "r^== \<equiv> sup r op ="
    49 
    50 abbreviation
    51   reflcl :: "('a \<times> 'a) set => ('a \<times> 'a) set"  ("(_^=)" [1000] 999) where
    52   "r^= \<equiv> r \<union> Id"
    53 
    54 notation (xsymbols)
    55   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    56   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    57   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    58   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    59   trancl  ("(_\<^sup>+)" [1000] 999) and
    60   reflcl  ("(_\<^sup>=)" [1000] 999)
    61 
    62 notation (HTML output)
    63   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    64   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    65   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    66   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    67   trancl  ("(_\<^sup>+)" [1000] 999) and
    68   reflcl  ("(_\<^sup>=)" [1000] 999)
    69 
    70 
    71 subsection {* Reflexive closure *}
    72 
    73 lemma refl_reflcl[simp]: "refl(r^=)"
    74 by(simp add:refl_on_def)
    75 
    76 lemma antisym_reflcl[simp]: "antisym(r^=) = antisym r"
    77 by(simp add:antisym_def)
    78 
    79 lemma trans_reflclI[simp]: "trans r \<Longrightarrow> trans(r^=)"
    80 unfolding trans_def by blast
    81 
    82 
    83 subsection {* Reflexive-transitive closure *}
    84 
    85 lemma reflcl_set_eq [pred_set_conv]: "(sup (\<lambda>x y. (x, y) \<in> r) op =) = (\<lambda>x y. (x, y) \<in> r \<union> Id)"
    86   by (auto simp add: fun_eq_iff)
    87 
    88 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    89   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    90   apply (simp only: split_tupled_all)
    91   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    92   done
    93 
    94 lemma r_into_rtranclp [intro]: "r x y ==> r^** x y"
    95   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    96   by (erule rtranclp.rtrancl_refl [THEN rtranclp.rtrancl_into_rtrancl])
    97 
    98 lemma rtranclp_mono: "r \<le> s ==> r^** \<le> s^**"
    99   -- {* monotonicity of @{text rtrancl} *}
   100   apply (rule predicate2I)
   101   apply (erule rtranclp.induct)
   102    apply (rule_tac [2] rtranclp.rtrancl_into_rtrancl, blast+)
   103   done
   104 
   105 lemmas rtrancl_mono = rtranclp_mono [to_set]
   106 
   107 theorem rtranclp_induct [consumes 1, case_names base step, induct set: rtranclp]:
   108   assumes a: "r^** a b"
   109     and cases: "P a" "!!y z. [| r^** a y; r y z; P y |] ==> P z"
   110   shows "P b" using a
   111   by (induct x\<equiv>a b) (rule cases)+
   112 
   113 lemmas rtrancl_induct [induct set: rtrancl] = rtranclp_induct [to_set]
   114 
   115 lemmas rtranclp_induct2 =
   116   rtranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   117                  consumes 1, case_names refl step]
   118 
   119 lemmas rtrancl_induct2 =
   120   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   121                  consumes 1, case_names refl step]
   122 
   123 lemma refl_rtrancl: "refl (r^*)"
   124 by (unfold refl_on_def) fast
   125 
   126 text {* Transitivity of transitive closure. *}
   127 lemma trans_rtrancl: "trans (r^*)"
   128 proof (rule transI)
   129   fix x y z
   130   assume "(x, y) \<in> r\<^sup>*"
   131   assume "(y, z) \<in> r\<^sup>*"
   132   then show "(x, z) \<in> r\<^sup>*"
   133   proof induct
   134     case base
   135     show "(x, y) \<in> r\<^sup>*" by fact
   136   next
   137     case (step u v)
   138     from `(x, u) \<in> r\<^sup>*` and `(u, v) \<in> r`
   139     show "(x, v) \<in> r\<^sup>*" ..
   140   qed
   141 qed
   142 
   143 lemmas rtrancl_trans = trans_rtrancl [THEN transD]
   144 
   145 lemma rtranclp_trans:
   146   assumes xy: "r^** x y"
   147   and yz: "r^** y z"
   148   shows "r^** x z" using yz xy
   149   by induct iprover+
   150 
   151 lemma rtranclE [cases set: rtrancl]:
   152   assumes major: "(a::'a, b) : r^*"
   153   obtains
   154     (base) "a = b"
   155   | (step) y where "(a, y) : r^*" and "(y, b) : r"
   156   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   157   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   158    apply (rule_tac [2] major [THEN rtrancl_induct])
   159     prefer 2 apply blast
   160    prefer 2 apply blast
   161   apply (erule asm_rl exE disjE conjE base step)+
   162   done
   163 
   164 lemma rtrancl_Int_subset: "[| Id \<subseteq> s; (r^* \<inter> s) O r \<subseteq> s|] ==> r^* \<subseteq> s"
   165   apply (rule subsetI)
   166   apply (rule_tac p="x" in PairE, clarify)
   167   apply (erule rtrancl_induct, auto) 
   168   done
   169 
   170 lemma converse_rtranclp_into_rtranclp:
   171   "r a b \<Longrightarrow> r\<^sup>*\<^sup>* b c \<Longrightarrow> r\<^sup>*\<^sup>* a c"
   172   by (rule rtranclp_trans) iprover+
   173 
   174 lemmas converse_rtrancl_into_rtrancl = converse_rtranclp_into_rtranclp [to_set]
   175 
   176 text {*
   177   \medskip More @{term "r^*"} equations and inclusions.
   178 *}
   179 
   180 lemma rtranclp_idemp [simp]: "(r^**)^** = r^**"
   181   apply (auto intro!: order_antisym)
   182   apply (erule rtranclp_induct)
   183    apply (rule rtranclp.rtrancl_refl)
   184   apply (blast intro: rtranclp_trans)
   185   done
   186 
   187 lemmas rtrancl_idemp [simp] = rtranclp_idemp [to_set]
   188 
   189 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   190   apply (rule set_eqI)
   191   apply (simp only: split_tupled_all)
   192   apply (blast intro: rtrancl_trans)
   193   done
   194 
   195 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   196   apply (drule rtrancl_mono)
   197   apply simp
   198   done
   199 
   200 lemma rtranclp_subset: "R \<le> S ==> S \<le> R^** ==> S^** = R^**"
   201   apply (drule rtranclp_mono)
   202   apply (drule rtranclp_mono)
   203   apply simp
   204   done
   205 
   206 lemmas rtrancl_subset = rtranclp_subset [to_set]
   207 
   208 lemma rtranclp_sup_rtranclp: "(sup (R^**) (S^**))^** = (sup R S)^**"
   209   by (blast intro!: rtranclp_subset intro: rtranclp_mono [THEN predicate2D])
   210 
   211 lemmas rtrancl_Un_rtrancl = rtranclp_sup_rtranclp [to_set]
   212 
   213 lemma rtranclp_reflcl [simp]: "(R^==)^** = R^**"
   214   by (blast intro!: rtranclp_subset)
   215 
   216 lemmas rtrancl_reflcl [simp] = rtranclp_reflcl [to_set]
   217 
   218 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   219   apply (rule sym)
   220   apply (rule rtrancl_subset, blast, clarify)
   221   apply (rename_tac a b)
   222   apply (case_tac "a = b")
   223    apply blast
   224   apply blast
   225   done
   226 
   227 lemma rtranclp_r_diff_Id: "(inf r op ~=)^** = r^**"
   228   apply (rule sym)
   229   apply (rule rtranclp_subset)
   230    apply blast+
   231   done
   232 
   233 theorem rtranclp_converseD:
   234   assumes r: "(r^--1)^** x y"
   235   shows "r^** y x"
   236 proof -
   237   from r show ?thesis
   238     by induct (iprover intro: rtranclp_trans dest!: conversepD)+
   239 qed
   240 
   241 lemmas rtrancl_converseD = rtranclp_converseD [to_set]
   242 
   243 theorem rtranclp_converseI:
   244   assumes "r^** y x"
   245   shows "(r^--1)^** x y"
   246   using assms
   247   by induct (iprover intro: rtranclp_trans conversepI)+
   248 
   249 lemmas rtrancl_converseI = rtranclp_converseI [to_set]
   250 
   251 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   252   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   253 
   254 lemma sym_rtrancl: "sym r ==> sym (r^*)"
   255   by (simp only: sym_conv_converse_eq rtrancl_converse [symmetric])
   256 
   257 theorem converse_rtranclp_induct [consumes 1, case_names base step]:
   258   assumes major: "r^** a b"
   259     and cases: "P b" "!!y z. [| r y z; r^** z b; P z |] ==> P y"
   260   shows "P a"
   261   using rtranclp_converseI [OF major]
   262   by induct (iprover intro: cases dest!: conversepD rtranclp_converseD)+
   263 
   264 lemmas converse_rtrancl_induct = converse_rtranclp_induct [to_set]
   265 
   266 lemmas converse_rtranclp_induct2 =
   267   converse_rtranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   268                  consumes 1, case_names refl step]
   269 
   270 lemmas converse_rtrancl_induct2 =
   271   converse_rtrancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   272                  consumes 1, case_names refl step]
   273 
   274 lemma converse_rtranclpE [consumes 1, case_names base step]:
   275   assumes major: "r^** x z"
   276     and cases: "x=z ==> P"
   277       "!!y. [| r x y; r^** y z |] ==> P"
   278   shows P
   279   apply (subgoal_tac "x = z | (EX y. r x y & r^** y z)")
   280    apply (rule_tac [2] major [THEN converse_rtranclp_induct])
   281     prefer 2 apply iprover
   282    prefer 2 apply iprover
   283   apply (erule asm_rl exE disjE conjE cases)+
   284   done
   285 
   286 lemmas converse_rtranclE = converse_rtranclpE [to_set]
   287 
   288 lemmas converse_rtranclpE2 = converse_rtranclpE [of _ "(xa,xb)" "(za,zb)", split_rule]
   289 
   290 lemmas converse_rtranclE2 = converse_rtranclE [of "(xa,xb)" "(za,zb)", split_rule]
   291 
   292 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   293   by (blast elim: rtranclE converse_rtranclE
   294     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   295 
   296 lemma rtrancl_unfold: "r^* = Id Un r^* O r"
   297   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   298 
   299 lemma rtrancl_Un_separatorE:
   300   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (a,x) : P^* \<longrightarrow> (x,y) : Q \<longrightarrow> x=y \<Longrightarrow> (a,b) : P^*"
   301 apply (induct rule:rtrancl.induct)
   302  apply blast
   303 apply (blast intro:rtrancl_trans)
   304 done
   305 
   306 lemma rtrancl_Un_separator_converseE:
   307   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (x,b) : P^* \<longrightarrow> (y,x) : Q \<longrightarrow> y=x \<Longrightarrow> (a,b) : P^*"
   308 apply (induct rule:converse_rtrancl_induct)
   309  apply blast
   310 apply (blast intro:rtrancl_trans)
   311 done
   312 
   313 lemma Image_closed_trancl:
   314   assumes "r `` X \<subseteq> X" shows "r\<^sup>* `` X = X"
   315 proof -
   316   from assms have **: "{y. \<exists>x\<in>X. (x, y) \<in> r} \<subseteq> X" by auto
   317   have "\<And>x y. (y, x) \<in> r\<^sup>* \<Longrightarrow> y \<in> X \<Longrightarrow> x \<in> X"
   318   proof -
   319     fix x y
   320     assume *: "y \<in> X"
   321     assume "(y, x) \<in> r\<^sup>*"
   322     then show "x \<in> X"
   323     proof induct
   324       case base show ?case by (fact *)
   325     next
   326       case step with ** show ?case by auto
   327     qed
   328   qed
   329   then show ?thesis by auto
   330 qed
   331 
   332 
   333 subsection {* Transitive closure *}
   334 
   335 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   336   apply (simp add: split_tupled_all)
   337   apply (erule trancl.induct)
   338    apply (iprover dest: subsetD)+
   339   done
   340 
   341 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   342   by (simp only: split_tupled_all) (erule r_into_trancl)
   343 
   344 text {*
   345   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   346 *}
   347 
   348 lemma tranclp_into_rtranclp: "r^++ a b ==> r^** a b"
   349   by (erule tranclp.induct) iprover+
   350 
   351 lemmas trancl_into_rtrancl = tranclp_into_rtranclp [to_set]
   352 
   353 lemma rtranclp_into_tranclp1: assumes r: "r^** a b"
   354   shows "!!c. r b c ==> r^++ a c" using r
   355   by induct iprover+
   356 
   357 lemmas rtrancl_into_trancl1 = rtranclp_into_tranclp1 [to_set]
   358 
   359 lemma rtranclp_into_tranclp2: "[| r a b; r^** b c |] ==> r^++ a c"
   360   -- {* intro rule from @{text r} and @{text rtrancl} *}
   361   apply (erule rtranclp.cases)
   362    apply iprover
   363   apply (rule rtranclp_trans [THEN rtranclp_into_tranclp1])
   364     apply (simp | rule r_into_rtranclp)+
   365   done
   366 
   367 lemmas rtrancl_into_trancl2 = rtranclp_into_tranclp2 [to_set]
   368 
   369 text {* Nice induction rule for @{text trancl} *}
   370 lemma tranclp_induct [consumes 1, case_names base step, induct pred: tranclp]:
   371   assumes a: "r^++ a b"
   372   and cases: "!!y. r a y ==> P y"
   373     "!!y z. r^++ a y ==> r y z ==> P y ==> P z"
   374   shows "P b" using a
   375   by (induct x\<equiv>a b) (iprover intro: cases)+
   376 
   377 lemmas trancl_induct [induct set: trancl] = tranclp_induct [to_set]
   378 
   379 lemmas tranclp_induct2 =
   380   tranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   381     consumes 1, case_names base step]
   382 
   383 lemmas trancl_induct2 =
   384   trancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   385     consumes 1, case_names base step]
   386 
   387 lemma tranclp_trans_induct:
   388   assumes major: "r^++ x y"
   389     and cases: "!!x y. r x y ==> P x y"
   390       "!!x y z. [| r^++ x y; P x y; r^++ y z; P y z |] ==> P x z"
   391   shows "P x y"
   392   -- {* Another induction rule for trancl, incorporating transitivity *}
   393   by (iprover intro: major [THEN tranclp_induct] cases)
   394 
   395 lemmas trancl_trans_induct = tranclp_trans_induct [to_set]
   396 
   397 lemma tranclE [cases set: trancl]:
   398   assumes "(a, b) : r^+"
   399   obtains
   400     (base) "(a, b) : r"
   401   | (step) c where "(a, c) : r^+" and "(c, b) : r"
   402   using assms by cases simp_all
   403 
   404 lemma trancl_Int_subset: "[| r \<subseteq> s; (r^+ \<inter> s) O r \<subseteq> s|] ==> r^+ \<subseteq> s"
   405   apply (rule subsetI)
   406   apply (rule_tac p = x in PairE)
   407   apply clarify
   408   apply (erule trancl_induct)
   409    apply auto
   410   done
   411 
   412 lemma trancl_unfold: "r^+ = r Un r^+ O r"
   413   by (auto intro: trancl_into_trancl elim: tranclE)
   414 
   415 text {* Transitivity of @{term "r^+"} *}
   416 lemma trans_trancl [simp]: "trans (r^+)"
   417 proof (rule transI)
   418   fix x y z
   419   assume "(x, y) \<in> r^+"
   420   assume "(y, z) \<in> r^+"
   421   then show "(x, z) \<in> r^+"
   422   proof induct
   423     case (base u)
   424     from `(x, y) \<in> r^+` and `(y, u) \<in> r`
   425     show "(x, u) \<in> r^+" ..
   426   next
   427     case (step u v)
   428     from `(x, u) \<in> r^+` and `(u, v) \<in> r`
   429     show "(x, v) \<in> r^+" ..
   430   qed
   431 qed
   432 
   433 lemmas trancl_trans = trans_trancl [THEN transD]
   434 
   435 lemma tranclp_trans:
   436   assumes xy: "r^++ x y"
   437   and yz: "r^++ y z"
   438   shows "r^++ x z" using yz xy
   439   by induct iprover+
   440 
   441 lemma trancl_id [simp]: "trans r \<Longrightarrow> r^+ = r"
   442   apply auto
   443   apply (erule trancl_induct)
   444    apply assumption
   445   apply (unfold trans_def)
   446   apply blast
   447   done
   448 
   449 lemma rtranclp_tranclp_tranclp:
   450   assumes "r^** x y"
   451   shows "!!z. r^++ y z ==> r^++ x z" using assms
   452   by induct (iprover intro: tranclp_trans)+
   453 
   454 lemmas rtrancl_trancl_trancl = rtranclp_tranclp_tranclp [to_set]
   455 
   456 lemma tranclp_into_tranclp2: "r a b ==> r^++ b c ==> r^++ a c"
   457   by (erule tranclp_trans [OF tranclp.r_into_trancl])
   458 
   459 lemmas trancl_into_trancl2 = tranclp_into_tranclp2 [to_set]
   460 
   461 lemma trancl_insert:
   462   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   463   -- {* primitive recursion for @{text trancl} over finite relations *}
   464   apply (rule equalityI)
   465    apply (rule subsetI)
   466    apply (simp only: split_tupled_all)
   467    apply (erule trancl_induct, blast)
   468    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl trancl_trans)
   469   apply (rule subsetI)
   470   apply (blast intro: trancl_mono rtrancl_mono
   471     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   472   done
   473 
   474 lemma tranclp_converseI: "(r^++)^--1 x y ==> (r^--1)^++ x y"
   475   apply (drule conversepD)
   476   apply (erule tranclp_induct)
   477   apply (iprover intro: conversepI tranclp_trans)+
   478   done
   479 
   480 lemmas trancl_converseI = tranclp_converseI [to_set]
   481 
   482 lemma tranclp_converseD: "(r^--1)^++ x y ==> (r^++)^--1 x y"
   483   apply (rule conversepI)
   484   apply (erule tranclp_induct)
   485   apply (iprover dest: conversepD intro: tranclp_trans)+
   486   done
   487 
   488 lemmas trancl_converseD = tranclp_converseD [to_set]
   489 
   490 lemma tranclp_converse: "(r^--1)^++ = (r^++)^--1"
   491   by (fastforce simp add: fun_eq_iff
   492     intro!: tranclp_converseI dest!: tranclp_converseD)
   493 
   494 lemmas trancl_converse = tranclp_converse [to_set]
   495 
   496 lemma sym_trancl: "sym r ==> sym (r^+)"
   497   by (simp only: sym_conv_converse_eq trancl_converse [symmetric])
   498 
   499 lemma converse_tranclp_induct [consumes 1, case_names base step]:
   500   assumes major: "r^++ a b"
   501     and cases: "!!y. r y b ==> P(y)"
   502       "!!y z.[| r y z;  r^++ z b;  P(z) |] ==> P(y)"
   503   shows "P a"
   504   apply (rule tranclp_induct [OF tranclp_converseI, OF conversepI, OF major])
   505    apply (rule cases)
   506    apply (erule conversepD)
   507   apply (blast intro: assms dest!: tranclp_converseD)
   508   done
   509 
   510 lemmas converse_trancl_induct = converse_tranclp_induct [to_set]
   511 
   512 lemma tranclpD: "R^++ x y ==> EX z. R x z \<and> R^** z y"
   513   apply (erule converse_tranclp_induct)
   514    apply auto
   515   apply (blast intro: rtranclp_trans)
   516   done
   517 
   518 lemmas tranclD = tranclpD [to_set]
   519 
   520 lemma converse_tranclpE:
   521   assumes major: "tranclp r x z"
   522   assumes base: "r x z ==> P"
   523   assumes step: "\<And> y. [| r x y; tranclp r y z |] ==> P"
   524   shows P
   525 proof -
   526   from tranclpD[OF major]
   527   obtain y where "r x y" and "rtranclp r y z" by iprover
   528   from this(2) show P
   529   proof (cases rule: rtranclp.cases)
   530     case rtrancl_refl
   531     with `r x y` base show P by iprover
   532   next
   533     case rtrancl_into_rtrancl
   534     from this have "tranclp r y z"
   535       by (iprover intro: rtranclp_into_tranclp1)
   536     with `r x y` step show P by iprover
   537   qed
   538 qed
   539 
   540 lemmas converse_tranclE = converse_tranclpE [to_set]
   541 
   542 lemma tranclD2:
   543   "(x, y) \<in> R\<^sup>+ \<Longrightarrow> \<exists>z. (x, z) \<in> R\<^sup>* \<and> (z, y) \<in> R"
   544   by (blast elim: tranclE intro: trancl_into_rtrancl)
   545 
   546 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   547   by (blast elim: tranclE dest: trancl_into_rtrancl)
   548 
   549 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   550   by (blast dest: r_into_trancl)
   551 
   552 lemma trancl_subset_Sigma_aux:
   553     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   554   by (induct rule: rtrancl_induct) auto
   555 
   556 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   557   apply (rule subsetI)
   558   apply (simp only: split_tupled_all)
   559   apply (erule tranclE)
   560    apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   561   done
   562 
   563 lemma reflcl_tranclp [simp]: "(r^++)^== = r^**"
   564   apply (safe intro!: order_antisym)
   565    apply (erule tranclp_into_rtranclp)
   566   apply (blast elim: rtranclp.cases dest: rtranclp_into_tranclp1)
   567   done
   568 
   569 lemmas reflcl_trancl [simp] = reflcl_tranclp [to_set]
   570 
   571 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   572   apply safe
   573    apply (drule trancl_into_rtrancl, simp)
   574   apply (erule rtranclE, safe)
   575    apply (rule r_into_trancl, simp)
   576   apply (rule rtrancl_into_trancl1)
   577    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   578   done
   579 
   580 lemma rtrancl_trancl_reflcl [code]: "r^* = (r^+)^="
   581   by simp
   582 
   583 lemma trancl_empty [simp]: "{}^+ = {}"
   584   by (auto elim: trancl_induct)
   585 
   586 lemma rtrancl_empty [simp]: "{}^* = Id"
   587   by (rule subst [OF reflcl_trancl]) simp
   588 
   589 lemma rtranclpD: "R^** a b ==> a = b \<or> a \<noteq> b \<and> R^++ a b"
   590   by (force simp add: reflcl_tranclp [symmetric] simp del: reflcl_tranclp)
   591 
   592 lemmas rtranclD = rtranclpD [to_set]
   593 
   594 lemma rtrancl_eq_or_trancl:
   595   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   596   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   597 
   598 lemma trancl_unfold_right: "r^+ = r^* O r"
   599 by (auto dest: tranclD2 intro: rtrancl_into_trancl1)
   600 
   601 lemma trancl_unfold_left: "r^+ = r O r^*"
   602 by (auto dest: tranclD intro: rtrancl_into_trancl2)
   603 
   604 
   605 text {* Simplifying nested closures *}
   606 
   607 lemma rtrancl_trancl_absorb[simp]: "(R^*)^+ = R^*"
   608 by (simp add: trans_rtrancl)
   609 
   610 lemma trancl_rtrancl_absorb[simp]: "(R^+)^* = R^*"
   611 by (subst reflcl_trancl[symmetric]) simp
   612 
   613 lemma rtrancl_reflcl_absorb[simp]: "(R^*)^= = R^*"
   614 by auto
   615 
   616 
   617 text {* @{text Domain} and @{text Range} *}
   618 
   619 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   620   by blast
   621 
   622 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   623   by blast
   624 
   625 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   626   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   627 
   628 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   629   by (blast intro: subsetD [OF rtrancl_Un_subset])
   630 
   631 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   632   by (unfold Domain_unfold) (blast dest: tranclD)
   633 
   634 lemma trancl_range [simp]: "Range (r^+) = Range r"
   635   unfolding Domain_converse [symmetric] by (simp add: trancl_converse [symmetric])
   636 
   637 lemma Not_Domain_rtrancl:
   638     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   639   apply auto
   640   apply (erule rev_mp)
   641   apply (erule rtrancl_induct)
   642    apply auto
   643   done
   644 
   645 lemma trancl_subset_Field2: "r^+ <= Field r \<times> Field r"
   646   apply clarify
   647   apply (erule trancl_induct)
   648    apply (auto simp add: Field_def)
   649   done
   650 
   651 lemma finite_trancl[simp]: "finite (r^+) = finite r"
   652   apply auto
   653    prefer 2
   654    apply (rule trancl_subset_Field2 [THEN finite_subset])
   655    apply (rule finite_SigmaI)
   656     prefer 3
   657     apply (blast intro: r_into_trancl' finite_subset)
   658    apply (auto simp add: finite_Field)
   659   done
   660 
   661 text {* More about converse @{text rtrancl} and @{text trancl}, should
   662   be merged with main body. *}
   663 
   664 lemma single_valued_confluent:
   665   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   666   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   667   apply (erule rtrancl_induct)
   668   apply simp
   669   apply (erule disjE)
   670    apply (blast elim:converse_rtranclE dest:single_valuedD)
   671   apply(blast intro:rtrancl_trans)
   672   done
   673 
   674 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   675   by (fast intro: trancl_trans)
   676 
   677 lemma trancl_into_trancl [rule_format]:
   678     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   679   apply (erule trancl_induct)
   680    apply (fast intro: r_r_into_trancl)
   681   apply (fast intro: r_r_into_trancl trancl_trans)
   682   done
   683 
   684 lemma tranclp_rtranclp_tranclp:
   685     "r\<^sup>+\<^sup>+ a b ==> r\<^sup>*\<^sup>* b c ==> r\<^sup>+\<^sup>+ a c"
   686   apply (drule tranclpD)
   687   apply (elim exE conjE)
   688   apply (drule rtranclp_trans, assumption)
   689   apply (drule rtranclp_into_tranclp2, assumption, assumption)
   690   done
   691 
   692 lemmas trancl_rtrancl_trancl = tranclp_rtranclp_tranclp [to_set]
   693 
   694 lemmas transitive_closure_trans [trans] =
   695   r_r_into_trancl trancl_trans rtrancl_trans
   696   trancl.trancl_into_trancl trancl_into_trancl2
   697   rtrancl.rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   698   rtrancl_trancl_trancl trancl_rtrancl_trancl
   699 
   700 lemmas transitive_closurep_trans' [trans] =
   701   tranclp_trans rtranclp_trans
   702   tranclp.trancl_into_trancl tranclp_into_tranclp2
   703   rtranclp.rtrancl_into_rtrancl converse_rtranclp_into_rtranclp
   704   rtranclp_tranclp_tranclp tranclp_rtranclp_tranclp
   705 
   706 declare trancl_into_rtrancl [elim]
   707 
   708 subsection {* The power operation on relations *}
   709 
   710 text {* @{text "R ^^ n = R O ... O R"}, the n-fold composition of @{text R} *}
   711 
   712 overloading
   713   relpow == "compow :: nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
   714   relpowp == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)"
   715 begin
   716 
   717 primrec relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   718     "relpow 0 R = Id"
   719   | "relpow (Suc n) R = (R ^^ n) O R"
   720 
   721 primrec relpowp :: "nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)" where
   722     "relpowp 0 R = HOL.eq"
   723   | "relpowp (Suc n) R = (R ^^ n) OO R"
   724 
   725 end
   726 
   727 lemma relpowp_relpow_eq [pred_set_conv]:
   728   fixes R :: "'a rel"
   729   shows "(\<lambda>x y. (x, y) \<in> R) ^^ n = (\<lambda>x y. (x, y) \<in> R ^^ n)"
   730   by (induct n) (simp_all add: relcompp_relcomp_eq)
   731 
   732 text {* for code generation *}
   733 
   734 definition relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   735   relpow_code_def [code_abbrev]: "relpow = compow"
   736 
   737 definition relpowp :: "nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)" where
   738   relpowp_code_def [code_abbrev]: "relpowp = compow"
   739 
   740 lemma [code]:
   741   "relpow (Suc n) R = (relpow n R) O R"
   742   "relpow 0 R = Id"
   743   by (simp_all add: relpow_code_def)
   744 
   745 lemma [code]:
   746   "relpowp (Suc n) R = (R ^^ n) OO R"
   747   "relpowp 0 R = HOL.eq"
   748   by (simp_all add: relpowp_code_def)
   749 
   750 hide_const (open) relpow
   751 hide_const (open) relpowp
   752 
   753 lemma relpow_1 [simp]:
   754   fixes R :: "('a \<times> 'a) set"
   755   shows "R ^^ 1 = R"
   756   by simp
   757 
   758 lemma relpowp_1 [simp]:
   759   fixes P :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   760   shows "P ^^ 1 = P"
   761   by (fact relpow_1 [to_pred])
   762 
   763 lemma relpow_0_I: 
   764   "(x, x) \<in> R ^^ 0"
   765   by simp
   766 
   767 lemma relpowp_0_I:
   768   "(P ^^ 0) x x"
   769   by (fact relpow_0_I [to_pred])
   770 
   771 lemma relpow_Suc_I:
   772   "(x, y) \<in>  R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   773   by auto
   774 
   775 lemma relpowp_Suc_I:
   776   "(P ^^ n) x y \<Longrightarrow> P y z \<Longrightarrow> (P ^^ Suc n) x z"
   777   by (fact relpow_Suc_I [to_pred])
   778 
   779 lemma relpow_Suc_I2:
   780   "(x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   781   by (induct n arbitrary: z) (simp, fastforce)
   782 
   783 lemma relpowp_Suc_I2:
   784   "P x y \<Longrightarrow> (P ^^ n) y z \<Longrightarrow> (P ^^ Suc n) x z"
   785   by (fact relpow_Suc_I2 [to_pred])
   786 
   787 lemma relpow_0_E:
   788   "(x, y) \<in> R ^^ 0 \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   789   by simp
   790 
   791 lemma relpowp_0_E:
   792   "(P ^^ 0) x y \<Longrightarrow> (x = y \<Longrightarrow> Q) \<Longrightarrow> Q"
   793   by (fact relpow_0_E [to_pred])
   794 
   795 lemma relpow_Suc_E:
   796   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P) \<Longrightarrow> P"
   797   by auto
   798 
   799 lemma relpowp_Suc_E:
   800   "(P ^^ Suc n) x z \<Longrightarrow> (\<And>y. (P ^^ n) x y \<Longrightarrow> P y z \<Longrightarrow> Q) \<Longrightarrow> Q"
   801   by (fact relpow_Suc_E [to_pred])
   802 
   803 lemma relpow_E:
   804   "(x, z) \<in>  R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   805    \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in>  R ^^ m \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P)
   806    \<Longrightarrow> P"
   807   by (cases n) auto
   808 
   809 lemma relpowp_E:
   810   "(P ^^ n) x z \<Longrightarrow> (n = 0 \<Longrightarrow> x = z \<Longrightarrow> Q)
   811   \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (P ^^ m) x y \<Longrightarrow> P y z \<Longrightarrow> Q)
   812   \<Longrightarrow> Q"
   813   by (fact relpow_E [to_pred])
   814 
   815 lemma relpow_Suc_D2:
   816   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<exists>y. (x, y) \<in> R \<and> (y, z) \<in> R ^^ n)"
   817   apply (induct n arbitrary: x z)
   818    apply (blast intro: relpow_0_I elim: relpow_0_E relpow_Suc_E)
   819   apply (blast intro: relpow_Suc_I elim: relpow_0_E relpow_Suc_E)
   820   done
   821 
   822 lemma relpowp_Suc_D2:
   823   "(P ^^ Suc n) x z \<Longrightarrow> \<exists>y. P x y \<and> (P ^^ n) y z"
   824   by (fact relpow_Suc_D2 [to_pred])
   825 
   826 lemma relpow_Suc_E2:
   827   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> P) \<Longrightarrow> P"
   828   by (blast dest: relpow_Suc_D2)
   829 
   830 lemma relpowp_Suc_E2:
   831   "(P ^^ Suc n) x z \<Longrightarrow> (\<And>y. P x y \<Longrightarrow> (P ^^ n) y z \<Longrightarrow> Q) \<Longrightarrow> Q"
   832   by (fact relpow_Suc_E2 [to_pred])
   833 
   834 lemma relpow_Suc_D2':
   835   "\<forall>x y z. (x, y) \<in> R ^^ n \<and> (y, z) \<in> R \<longrightarrow> (\<exists>w. (x, w) \<in> R \<and> (w, z) \<in> R ^^ n)"
   836   by (induct n) (simp_all, blast)
   837 
   838 lemma relpowp_Suc_D2':
   839   "\<forall>x y z. (P ^^ n) x y \<and> P y z \<longrightarrow> (\<exists>w. P x w \<and> (P ^^ n) w z)"
   840   by (fact relpow_Suc_D2' [to_pred])
   841 
   842 lemma relpow_E2:
   843   "(x, z) \<in> R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   844      \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ m \<Longrightarrow> P)
   845    \<Longrightarrow> P"
   846   apply (cases n, simp)
   847   apply (cut_tac n=nat and R=R in relpow_Suc_D2', simp, blast)
   848   done
   849 
   850 lemma relpowp_E2:
   851   "(P ^^ n) x z \<Longrightarrow> (n = 0 \<Longrightarrow> x = z \<Longrightarrow> Q)
   852     \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> P x y \<Longrightarrow> (P ^^ m) y z \<Longrightarrow> Q)
   853   \<Longrightarrow> Q"
   854   by (fact relpow_E2 [to_pred])
   855 
   856 lemma relpow_add: "R ^^ (m+n) = R^^m O R^^n"
   857   by (induct n) auto
   858 
   859 lemma relpowp_add: "P ^^ (m + n) = P ^^ m OO P ^^ n"
   860   by (fact relpow_add [to_pred])
   861 
   862 lemma relpow_commute: "R O R ^^ n = R ^^ n O R"
   863   by (induct n) (simp, simp add: O_assoc [symmetric])
   864 
   865 lemma relpowp_commute: "P OO P ^^ n = P ^^ n OO P"
   866   by (fact relpow_commute [to_pred])
   867 
   868 lemma relpow_empty:
   869   "0 < n \<Longrightarrow> ({} :: ('a \<times> 'a) set) ^^ n = {}"
   870   by (cases n) auto
   871 
   872 lemma relpowp_bot:
   873   "0 < n \<Longrightarrow> (\<bottom> :: 'a \<Rightarrow> 'a \<Rightarrow> bool) ^^ n = \<bottom>"
   874   by (fact relpow_empty [to_pred])
   875 
   876 lemma rtrancl_imp_UN_relpow:
   877   assumes "p \<in> R^*"
   878   shows "p \<in> (\<Union>n. R ^^ n)"
   879 proof (cases p)
   880   case (Pair x y)
   881   with assms have "(x, y) \<in> R^*" by simp
   882   then have "(x, y) \<in> (\<Union>n. R ^^ n)" proof induct
   883     case base show ?case by (blast intro: relpow_0_I)
   884   next
   885     case step then show ?case by (blast intro: relpow_Suc_I)
   886   qed
   887   with Pair show ?thesis by simp
   888 qed
   889 
   890 lemma rtranclp_imp_Sup_relpowp:
   891   assumes "(P^**) x y"
   892   shows "(\<Squnion>n. P ^^ n) x y"
   893   using assms and rtrancl_imp_UN_relpow [to_pred] by blast
   894 
   895 lemma relpow_imp_rtrancl:
   896   assumes "p \<in> R ^^ n"
   897   shows "p \<in> R^*"
   898 proof (cases p)
   899   case (Pair x y)
   900   with assms have "(x, y) \<in> R ^^ n" by simp
   901   then have "(x, y) \<in> R^*" proof (induct n arbitrary: x y)
   902     case 0 then show ?case by simp
   903   next
   904     case Suc then show ?case
   905       by (blast elim: relpow_Suc_E intro: rtrancl_into_rtrancl)
   906   qed
   907   with Pair show ?thesis by simp
   908 qed
   909 
   910 lemma relpowp_imp_rtranclp:
   911   assumes "(P ^^ n) x y"
   912   shows "(P^**) x y"
   913   using assms and relpow_imp_rtrancl [to_pred] by blast
   914 
   915 lemma rtrancl_is_UN_relpow:
   916   "R^* = (\<Union>n. R ^^ n)"
   917   by (blast intro: rtrancl_imp_UN_relpow relpow_imp_rtrancl)
   918 
   919 lemma rtranclp_is_Sup_relpowp:
   920   "P^** = (\<Squnion>n. P ^^ n)"
   921   using rtrancl_is_UN_relpow [to_pred, of P] by auto
   922 
   923 lemma rtrancl_power:
   924   "p \<in> R^* \<longleftrightarrow> (\<exists>n. p \<in> R ^^ n)"
   925   by (simp add: rtrancl_is_UN_relpow)
   926 
   927 lemma rtranclp_power:
   928   "(P^**) x y \<longleftrightarrow> (\<exists>n. (P ^^ n) x y)"
   929   by (simp add: rtranclp_is_Sup_relpowp)
   930 
   931 lemma trancl_power:
   932   "p \<in> R^+ \<longleftrightarrow> (\<exists>n > 0. p \<in> R ^^ n)"
   933   apply (cases p)
   934   apply simp
   935   apply (rule iffI)
   936    apply (drule tranclD2)
   937    apply (clarsimp simp: rtrancl_is_UN_relpow)
   938    apply (rule_tac x="Suc n" in exI)
   939    apply (clarsimp simp: relcomp_unfold)
   940    apply fastforce
   941   apply clarsimp
   942   apply (case_tac n, simp)
   943   apply clarsimp
   944   apply (drule relpow_imp_rtrancl)
   945   apply (drule rtrancl_into_trancl1) apply auto
   946   done
   947 
   948 lemma tranclp_power:
   949   "(P^++) x y \<longleftrightarrow> (\<exists>n > 0. (P ^^ n) x y)"
   950   using trancl_power [to_pred, of P "(x, y)"] by simp
   951 
   952 lemma rtrancl_imp_relpow:
   953   "p \<in> R^* \<Longrightarrow> \<exists>n. p \<in> R ^^ n"
   954   by (auto dest: rtrancl_imp_UN_relpow)
   955 
   956 lemma rtranclp_imp_relpowp:
   957   "(P^**) x y \<Longrightarrow> \<exists>n. (P ^^ n) x y"
   958   by (auto dest: rtranclp_imp_Sup_relpowp)
   959 
   960 text{* By Sternagel/Thiemann: *}
   961 lemma relpow_fun_conv:
   962   "((a,b) \<in> R ^^ n) = (\<exists>f. f 0 = a \<and> f n = b \<and> (\<forall>i<n. (f i, f(Suc i)) \<in> R))"
   963 proof (induct n arbitrary: b)
   964   case 0 show ?case by auto
   965 next
   966   case (Suc n)
   967   show ?case
   968   proof (simp add: relcomp_unfold Suc)
   969     show "(\<exists>y. (\<exists>f. f 0 = a \<and> f n = y \<and> (\<forall>i<n. (f i,f(Suc i)) \<in> R)) \<and> (y,b) \<in> R)
   970      = (\<exists>f. f 0 = a \<and> f(Suc n) = b \<and> (\<forall>i<Suc n. (f i, f (Suc i)) \<in> R))"
   971     (is "?l = ?r")
   972     proof
   973       assume ?l
   974       then obtain c f where 1: "f 0 = a"  "f n = c"  "\<And>i. i < n \<Longrightarrow> (f i, f (Suc i)) \<in> R"  "(c,b) \<in> R" by auto
   975       let ?g = "\<lambda> m. if m = Suc n then b else f m"
   976       show ?r by (rule exI[of _ ?g], simp add: 1)
   977     next
   978       assume ?r
   979       then obtain f where 1: "f 0 = a"  "b = f (Suc n)"  "\<And>i. i < Suc n \<Longrightarrow> (f i, f (Suc i)) \<in> R" by auto
   980       show ?l by (rule exI[of _ "f n"], rule conjI, rule exI[of _ f], insert 1, auto)
   981     qed
   982   qed
   983 qed
   984 
   985 lemma relpowp_fun_conv:
   986   "(P ^^ n) x y \<longleftrightarrow> (\<exists>f. f 0 = x \<and> f n = y \<and> (\<forall>i<n. P (f i) (f (Suc i))))"
   987   by (fact relpow_fun_conv [to_pred])
   988 
   989 lemma relpow_finite_bounded1:
   990 assumes "finite(R :: ('a*'a)set)" and "k>0"
   991 shows "R^^k \<subseteq> (UN n:{n. 0<n & n <= card R}. R^^n)" (is "_ \<subseteq> ?r")
   992 proof-
   993   { fix a b k
   994     have "(a,b) : R^^(Suc k) \<Longrightarrow> EX n. 0<n & n <= card R & (a,b) : R^^n"
   995     proof(induct k arbitrary: b)
   996       case 0
   997       hence "R \<noteq> {}" by auto
   998       with card_0_eq[OF `finite R`] have "card R >= Suc 0" by auto
   999       thus ?case using 0 by force
  1000     next
  1001       case (Suc k)
  1002       then obtain a' where "(a,a') : R^^(Suc k)" and "(a',b) : R" by auto
  1003       from Suc(1)[OF `(a,a') : R^^(Suc k)`]
  1004       obtain n where "n \<le> card R" and "(a,a') \<in> R ^^ n" by auto
  1005       have "(a,b) : R^^(Suc n)" using `(a,a') \<in> R^^n` and `(a',b)\<in> R` by auto
  1006       { assume "n < card R"
  1007         hence ?case using `(a,b): R^^(Suc n)` Suc_leI[OF `n < card R`] by blast
  1008       } moreover
  1009       { assume "n = card R"
  1010         from `(a,b) \<in> R ^^ (Suc n)`[unfolded relpow_fun_conv]
  1011         obtain f where "f 0 = a" and "f(Suc n) = b"
  1012           and steps: "\<And>i. i <= n \<Longrightarrow> (f i, f (Suc i)) \<in> R" by auto
  1013         let ?p = "%i. (f i, f(Suc i))"
  1014         let ?N = "{i. i \<le> n}"
  1015         have "?p ` ?N <= R" using steps by auto
  1016         from card_mono[OF assms(1) this]
  1017         have "card(?p ` ?N) <= card R" .
  1018         also have "\<dots> < card ?N" using `n = card R` by simp
  1019         finally have "~ inj_on ?p ?N" by(rule pigeonhole)
  1020         then obtain i j where i: "i <= n" and j: "j <= n" and ij: "i \<noteq> j" and
  1021           pij: "?p i = ?p j" by(auto simp: inj_on_def)
  1022         let ?i = "min i j" let ?j = "max i j"
  1023         have i: "?i <= n" and j: "?j <= n" and pij: "?p ?i = ?p ?j" 
  1024           and ij: "?i < ?j"
  1025           using i j ij pij unfolding min_def max_def by auto
  1026         from i j pij ij obtain i j where i: "i<=n" and j: "j<=n" and ij: "i<j"
  1027           and pij: "?p i = ?p j" by blast
  1028         let ?g = "\<lambda> l. if l \<le> i then f l else f (l + (j - i))"
  1029         let ?n = "Suc(n - (j - i))"
  1030         have abl: "(a,b) \<in> R ^^ ?n" unfolding relpow_fun_conv
  1031         proof (rule exI[of _ ?g], intro conjI impI allI)
  1032           show "?g ?n = b" using `f(Suc n) = b` j ij by auto
  1033         next
  1034           fix k assume "k < ?n"
  1035           show "(?g k, ?g (Suc k)) \<in> R"
  1036           proof (cases "k < i")
  1037             case True
  1038             with i have "k <= n" by auto
  1039             from steps[OF this] show ?thesis using True by simp
  1040           next
  1041             case False
  1042             hence "i \<le> k" by auto
  1043             show ?thesis
  1044             proof (cases "k = i")
  1045               case True
  1046               thus ?thesis using ij pij steps[OF i] by simp
  1047             next
  1048               case False
  1049               with `i \<le> k` have "i < k" by auto
  1050               hence small: "k + (j - i) <= n" using `k<?n` by arith
  1051               show ?thesis using steps[OF small] `i<k` by auto
  1052             qed
  1053           qed
  1054         qed (simp add: `f 0 = a`)
  1055         moreover have "?n <= n" using i j ij by arith
  1056         ultimately have ?case using `n = card R` by blast
  1057       }
  1058       ultimately show ?case using `n \<le> card R` by force
  1059     qed
  1060   }
  1061   thus ?thesis using gr0_implies_Suc[OF `k>0`] by auto
  1062 qed
  1063 
  1064 lemma relpow_finite_bounded:
  1065 assumes "finite(R :: ('a*'a)set)"
  1066 shows "R^^k \<subseteq> (UN n:{n. n <= card R}. R^^n)"
  1067 apply(cases k)
  1068  apply force
  1069 using relpow_finite_bounded1[OF assms, of k] by auto
  1070 
  1071 lemma rtrancl_finite_eq_relpow:
  1072   "finite R \<Longrightarrow> R^* = (UN n : {n. n <= card R}. R^^n)"
  1073 by(fastforce simp: rtrancl_power dest: relpow_finite_bounded)
  1074 
  1075 lemma trancl_finite_eq_relpow:
  1076   "finite R \<Longrightarrow> R^+ = (UN n : {n. 0 < n & n <= card R}. R^^n)"
  1077 apply(auto simp add: trancl_power)
  1078 apply(auto dest: relpow_finite_bounded1)
  1079 done
  1080 
  1081 lemma finite_relcomp[simp,intro]:
  1082 assumes "finite R" and "finite S"
  1083 shows "finite(R O S)"
  1084 proof-
  1085   have "R O S = (UN (x,y) : R. \<Union>((%(u,v). if u=y then {(x,v)} else {}) ` S))"
  1086     by(force simp add: split_def)
  1087   thus ?thesis using assms by(clarsimp)
  1088 qed
  1089 
  1090 lemma finite_relpow[simp,intro]:
  1091   assumes "finite(R :: ('a*'a)set)" shows "n>0 \<Longrightarrow> finite(R^^n)"
  1092 apply(induct n)
  1093  apply simp
  1094 apply(case_tac n)
  1095  apply(simp_all add: assms)
  1096 done
  1097 
  1098 lemma single_valued_relpow:
  1099   fixes R :: "('a * 'a) set"
  1100   shows "single_valued R \<Longrightarrow> single_valued (R ^^ n)"
  1101 apply (induct n arbitrary: R)
  1102 apply simp_all
  1103 apply (rule single_valuedI)
  1104 apply (fast dest: single_valuedD elim: relpow_Suc_E)
  1105 done
  1106 
  1107 
  1108 subsection {* Bounded transitive closure *}
  1109 
  1110 definition ntrancl :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
  1111 where
  1112   "ntrancl n R = (\<Union>i\<in>{i. 0 < i \<and> i \<le> Suc n}. R ^^ i)"
  1113 
  1114 lemma ntrancl_Zero [simp, code]:
  1115   "ntrancl 0 R = R"
  1116 proof
  1117   show "R \<subseteq> ntrancl 0 R"
  1118     unfolding ntrancl_def by fastforce
  1119 next
  1120   { 
  1121     fix i have "0 < i \<and> i \<le> Suc 0 \<longleftrightarrow> i = 1" by auto
  1122   }
  1123   from this show "ntrancl 0 R \<le> R"
  1124     unfolding ntrancl_def by auto
  1125 qed
  1126 
  1127 lemma ntrancl_Suc [simp]:
  1128   "ntrancl (Suc n) R = ntrancl n R O (Id \<union> R)"
  1129 proof
  1130   {
  1131     fix a b
  1132     assume "(a, b) \<in> ntrancl (Suc n) R"
  1133     from this obtain i where "0 < i" "i \<le> Suc (Suc n)" "(a, b) \<in> R ^^ i"
  1134       unfolding ntrancl_def by auto
  1135     have "(a, b) \<in> ntrancl n R O (Id \<union> R)"
  1136     proof (cases "i = 1")
  1137       case True
  1138       from this `(a, b) \<in> R ^^ i` show ?thesis
  1139         unfolding ntrancl_def by auto
  1140     next
  1141       case False
  1142       from this `0 < i` obtain j where j: "i = Suc j" "0 < j"
  1143         by (cases i) auto
  1144       from this `(a, b) \<in> R ^^ i` obtain c where c1: "(a, c) \<in> R ^^ j" and c2:"(c, b) \<in> R"
  1145         by auto
  1146       from c1 j `i \<le> Suc (Suc n)` have "(a, c) \<in> ntrancl n R"
  1147         unfolding ntrancl_def by fastforce
  1148       from this c2 show ?thesis by fastforce
  1149     qed
  1150   }
  1151   from this show "ntrancl (Suc n) R \<subseteq> ntrancl n R O (Id \<union> R)"
  1152     by auto
  1153 next
  1154   show "ntrancl n R O (Id \<union> R) \<subseteq> ntrancl (Suc n) R"
  1155     unfolding ntrancl_def by fastforce
  1156 qed
  1157 
  1158 lemma [code]:
  1159   "ntrancl (Suc n) r = (let r' = ntrancl n r in r' Un r' O r)"
  1160 unfolding Let_def by auto
  1161 
  1162 lemma finite_trancl_ntranl:
  1163   "finite R \<Longrightarrow> trancl R = ntrancl (card R - 1) R"
  1164   by (cases "card R") (auto simp add: trancl_finite_eq_relpow relpow_empty ntrancl_def)
  1165 
  1166 
  1167 subsection {* Acyclic relations *}
  1168 
  1169 definition acyclic :: "('a * 'a) set => bool" where
  1170   "acyclic r \<longleftrightarrow> (!x. (x,x) ~: r^+)"
  1171 
  1172 abbreviation acyclicP :: "('a => 'a => bool) => bool" where
  1173   "acyclicP r \<equiv> acyclic {(x, y). r x y}"
  1174 
  1175 lemma acyclic_irrefl [code]:
  1176   "acyclic r \<longleftrightarrow> irrefl (r^+)"
  1177   by (simp add: acyclic_def irrefl_def)
  1178 
  1179 lemma acyclicI: "ALL x. (x, x) ~: r^+ ==> acyclic r"
  1180   by (simp add: acyclic_def)
  1181 
  1182 lemma acyclic_insert [iff]:
  1183      "acyclic(insert (y,x) r) = (acyclic r & (x,y) ~: r^*)"
  1184 apply (simp add: acyclic_def trancl_insert)
  1185 apply (blast intro: rtrancl_trans)
  1186 done
  1187 
  1188 lemma acyclic_converse [iff]: "acyclic(r^-1) = acyclic r"
  1189 by (simp add: acyclic_def trancl_converse)
  1190 
  1191 lemmas acyclicP_converse [iff] = acyclic_converse [to_pred]
  1192 
  1193 lemma acyclic_impl_antisym_rtrancl: "acyclic r ==> antisym(r^*)"
  1194 apply (simp add: acyclic_def antisym_def)
  1195 apply (blast elim: rtranclE intro: rtrancl_into_trancl1 rtrancl_trancl_trancl)
  1196 done
  1197 
  1198 (* Other direction:
  1199 acyclic = no loops
  1200 antisym = only self loops
  1201 Goalw [acyclic_def,antisym_def] "antisym( r^* ) ==> acyclic(r - Id)
  1202 ==> antisym( r^* ) = acyclic(r - Id)";
  1203 *)
  1204 
  1205 lemma acyclic_subset: "[| acyclic s; r <= s |] ==> acyclic r"
  1206 apply (simp add: acyclic_def)
  1207 apply (blast intro: trancl_mono)
  1208 done
  1209 
  1210 
  1211 subsection {* Setup of transitivity reasoner *}
  1212 
  1213 ML {*
  1214 
  1215 structure Trancl_Tac = Trancl_Tac
  1216 (
  1217   val r_into_trancl = @{thm trancl.r_into_trancl};
  1218   val trancl_trans  = @{thm trancl_trans};
  1219   val rtrancl_refl = @{thm rtrancl.rtrancl_refl};
  1220   val r_into_rtrancl = @{thm r_into_rtrancl};
  1221   val trancl_into_rtrancl = @{thm trancl_into_rtrancl};
  1222   val rtrancl_trancl_trancl = @{thm rtrancl_trancl_trancl};
  1223   val trancl_rtrancl_trancl = @{thm trancl_rtrancl_trancl};
  1224   val rtrancl_trans = @{thm rtrancl_trans};
  1225 
  1226   fun decomp (@{const Trueprop} $ t) =
  1227     let fun dec (Const (@{const_name Set.member}, _) $ (Const (@{const_name Pair}, _) $ a $ b) $ rel ) =
  1228         let fun decr (Const ("Transitive_Closure.rtrancl", _ ) $ r) = (r,"r*")
  1229               | decr (Const ("Transitive_Closure.trancl", _ ) $ r)  = (r,"r+")
  1230               | decr r = (r,"r");
  1231             val (rel,r) = decr (Envir.beta_eta_contract rel);
  1232         in SOME (a,b,rel,r) end
  1233       | dec _ =  NONE
  1234     in dec t end
  1235     | decomp _ = NONE;
  1236 );
  1237 
  1238 structure Tranclp_Tac = Trancl_Tac
  1239 (
  1240   val r_into_trancl = @{thm tranclp.r_into_trancl};
  1241   val trancl_trans  = @{thm tranclp_trans};
  1242   val rtrancl_refl = @{thm rtranclp.rtrancl_refl};
  1243   val r_into_rtrancl = @{thm r_into_rtranclp};
  1244   val trancl_into_rtrancl = @{thm tranclp_into_rtranclp};
  1245   val rtrancl_trancl_trancl = @{thm rtranclp_tranclp_tranclp};
  1246   val trancl_rtrancl_trancl = @{thm tranclp_rtranclp_tranclp};
  1247   val rtrancl_trans = @{thm rtranclp_trans};
  1248 
  1249   fun decomp (@{const Trueprop} $ t) =
  1250     let fun dec (rel $ a $ b) =
  1251         let fun decr (Const ("Transitive_Closure.rtranclp", _ ) $ r) = (r,"r*")
  1252               | decr (Const ("Transitive_Closure.tranclp", _ ) $ r)  = (r,"r+")
  1253               | decr r = (r,"r");
  1254             val (rel,r) = decr rel;
  1255         in SOME (a, b, rel, r) end
  1256       | dec _ =  NONE
  1257     in dec t end
  1258     | decomp _ = NONE;
  1259 );
  1260 *}
  1261 
  1262 setup {*
  1263   Simplifier.map_simpset_global (fn ss => ss
  1264     addSolver (mk_solver "Trancl" (Trancl_Tac.trancl_tac o Simplifier.the_context))
  1265     addSolver (mk_solver "Rtrancl" (Trancl_Tac.rtrancl_tac o Simplifier.the_context))
  1266     addSolver (mk_solver "Tranclp" (Tranclp_Tac.trancl_tac o Simplifier.the_context))
  1267     addSolver (mk_solver "Rtranclp" (Tranclp_Tac.rtrancl_tac o Simplifier.the_context)))
  1268 *}
  1269 
  1270 
  1271 text {* Optional methods. *}
  1272 
  1273 method_setup trancl =
  1274   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.trancl_tac) *}
  1275   {* simple transitivity reasoner *}
  1276 method_setup rtrancl =
  1277   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.rtrancl_tac) *}
  1278   {* simple transitivity reasoner *}
  1279 method_setup tranclp =
  1280   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.trancl_tac) *}
  1281   {* simple transitivity reasoner (predicate version) *}
  1282 method_setup rtranclp =
  1283   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.rtrancl_tac) *}
  1284   {* simple transitivity reasoner (predicate version) *}
  1285 
  1286 end
  1287